t/lib/DebbugsTest.pm

   1
   2 package DebbugsTest;
   3
   4 =head1 NAME
   5
   6 DebbugsTest
   7
   8 =head1 SYNOPSIS
   9
  10 use DebbugsTest
  11
  12
  13 =head1 DESCRIPTION
  14
  15 This module contains various testing routines used to test debbugs in
  16 a "pseudo install"
  17
  18 =head1 FUNCTIONS
  19
  20 =cut
  21
  22 use warnings;
  23 use strict;
  24 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  25 use base qw(Exporter);
  26
  27 use IO::File;
  28 use File::Temp qw(tempdir);
  29 use Cwd qw(getcwd);
  30 use Debbugs::MIME qw(create_mime_message);
  31 use File::Basename qw(dirname basename);
  32 use IPC::Open3;
  33 use IO::Handle;
  34 use Test::More;
  35
  36 use Params::Validate qw(validate_with :types);
  37
  38 BEGIN{
  39      $VERSION = 1.00;
  40      $DEBUG = 0 unless defined $DEBUG;
  41
  42      @EXPORT = ();
  43      %EXPORT_TAGS = (configuration => [qw(dirsize create_debbugs_configuration send_message)],
  44                      mail          => [qw(num_messages_sent)],
  45                     );
  46      @EXPORT_OK = ();
  47      Exporter::export_ok_tags(qw(configuration mail));
  48      $EXPORT_TAGS{all} = [@EXPORT_OK];
  49 }
  50
  51 # First, we're going to send mesages to receive.
  52 # To do so, we'll first send a message to submit,
  53 # then send messages to the newly created bugnumber.
  54
  55
  56
  57 sub create_debbugs_configuration {
  58      my %param = validate_with(params => \@_,
  59                                spec   => {debug => {type => BOOLEAN,
  60                                                     default => 0,
  61                                                    },
  62                                           cleanup => {type => BOOLEAN,
  63                                                       optional => 1,
  64                                                      },
  65                                          },
  66                               );
  67      $param{cleanup} = $param{debug}?0:1 if not exists $param{cleanup};
  68      my $sendmail_dir = tempdir(CLEANUP => $param{cleanup});
  69      my $spool_dir = tempdir(CLEANUP => $param{cleanup});
  70      my $config_dir = tempdir(CLEANUP => $param{cleanup});
  71
  72
  73      $ENV{DEBBUGS_CONFIG_FILE}  ="$config_dir/debbugs_config";
  74      $ENV{PERL5LIB} = getcwd();
  75      $ENV{SENDMAIL_TESTDIR} = $sendmail_dir;
  76      my $sendmail_tester = getcwd().'/t/sendmail_tester';
  77      unless (-x $sendmail_tester) {
  78           die q(t/sendmail_tester doesn't exist or isn't executable. You may be in the wrong directory.);
  79      }
  80      my %files_to_create = ("$config_dir/debbugs_config" => <<END,
  81 \$gSendmail='$sendmail_tester';
  82 \$gSpoolDir='$spool_dir';
  83 \$gLibPath='@{[getcwd()]}/scripts';
  84 \$gTemplateDir='@{[getcwd()]}/templates';
  85 \$gWebHost='localhost';
  86 1;
  87 END
  88                             "$spool_dir/nextnumber" => qq(1\n),
  89                             "$config_dir/Maintainers" => qq(foo Blah Bleargh <foo\@baz.com>\nbar Bar Bleargh <bar\@baz.com>\n),
  90                             "$config_dir/Maintainers.override" => qq(),
  91                             "$config_dir/Source_maintainers" => qq(foo Blah Bleargh <foo\@baz.com>\nbar Bar Bleargh <bar\@baz.com>\n),
  92                             "$config_dir/indices/sources" => <<END,
  93 foo main foo
  94 END
  95                             "$config_dir/pseudo-packages.description" => '',
  96                             "$config_dir/pseudo-packages.maintainers" => '',
  97                            );
  98      while (my ($file,$contents) = each %files_to_create) {
  99           system('mkdir','-p',dirname($file));
 100           my $fh = IO::File->new($file,'w') or
 101                die "Unable to create $file: $!";
 102           print {$fh} $contents or die "Unable to write $contents to $file: $!";
 103           close $fh or die "Unable to close $file: $!";
 104      }
 105
 106      system('touch',"$spool_dir/index.db.realtime");
 107      system('ln','-s','index.db.realtime',
 108             "$spool_dir/index.db");
 109      system('touch',"$spool_dir/index.archive.realtime");
 110      system('ln','-s','index.archive.realtime',
 111             "$spool_dir/index.archive");
 112
 113      # create the spool files and sub directories
 114      for my $dir (0..99) {
 115          for my $archive (qw(db-h archive)) {
 116              system('mkdir','-p',"$spool_dir/$archive/".sprintf('%02d',$dir));
 117          }
 118      }
 119      system('mkdir','-p',"$spool_dir/incoming");
 120      system('mkdir','-p',"$spool_dir/lock");
 121
 122      return (spool_dir => $spool_dir,
 123              sendmail_dir => $sendmail_dir,
 124              config_dir => $config_dir,
 125             );
 126 }
 127
 128 sub dirsize{
 129      my ($dir) = @_;
 130      opendir(DIR,$dir);
 131      my @content = grep {!/^\.\.?$/} readdir(DIR);
 132      closedir(DIR);
 133      return scalar @content;
 134 }
 135
 136
 137 # We're going to use create mime message to create these messages, and
 138 # then just send them to receive.
 139 # First, check that submit@ works
 140
 141 sub send_message{
 142      my %param = validate_with(params => \@_,
 143                                spec   => {to => {type => SCALAR,
 144                                                  default => 'submit@bugs.something',
 145                                                 },
 146                                           headers => {type => ARRAYREF,
 147                                                      },
 148                                           body    => {type => SCALAR,
 149                                                      },
 150                                           attachments => {type => ARRAYREF,
 151                                                           default => [],
 152                                                          },
 153                                           run_processall =>{type => BOOLEAN,
 154                                                             default => 1,
 155                                                            },
 156                                          }
 157                               );
 158      $ENV{LOCAL_PART} = $param{to};
 159      my ($rfd,$wfd);
 160      my $output='';
 161      my $pipe_handler = $SIG{PIPE};
 162      $SIG{PIPE} = 'IGNORE';
 163      $SIG{CHLD} = 'DEFAULT';
 164      my $pid = open3($wfd,$rfd,$rfd,'scripts/receive')
 165           or die "Unable to start receive: $!";
 166      print {$wfd} create_mime_message($param{headers},
 167                                       $param{body},
 168                                       $param{attachments}) or
 169                                           die "Unable to to print to receive";
 170      close($wfd) or die "Unable to close receive";
 171      $SIG{PIPE} = $pipe_handler;
 172      my $err = $? >> 8;
 173      my $childpid = waitpid($pid,0);
 174      if ($childpid != -1) {
 175           $err = $? >> 8;
 176           print STDERR "receive pid: $pid doesn't match childpid: $childpid\n" if $childpid != $pid;
 177      }
 178      if ($err != 0 ) {
 179           my $rfh =  IO::Handle->new_from_fd($rfd,'r') or die "Unable to create filehandle: $!";
 180           $rfh->blocking(0);
 181           my $rv;
 182           while ($rv = $rfh->sysread($output,1000,length($output))) {}
 183           if (not defined $rv) {
 184                print STDERR "Reading from STDOUT/STDERR would have blocked.";
 185           }
 186           print STDERR $output,qq(\n);
 187           die "receive failed with exit status $err";
 188      }
 189      # now we should run processall to see if the message gets processed
 190      if ($param{run_processall}) {
 191           system('scripts/processall') == 0 or die "processall failed";
 192      }
 193 }
 194
 195 {
 196      package DebbugsTest::HTTPServer;
 197      use base qw(HTTP::Server::Simple::CGI);
 198
 199      our $child_pid = undef;
 200      our $webserver = undef;
 201      our $server_handler = undef;
 202
 203      END {
 204           if (defined $child_pid) {
 205                # stop the child
 206                my $temp_exit = $?;
 207                kill(15,$child_pid);
 208                waitpid(-1,0);
 209                $? = $temp_exit;
 210           }
 211      }
 212
 213      sub fork_and_create_webserver {
 214           my ($handler,$port) = @_;
 215           $port ||= 8080;
 216           if (defined $child_pid) {
 217                die "We appear to have already forked once";
 218           }
 219           $server_handler = $handler;
 220           my $pid = fork;
 221           return 0 if not defined $pid;
 222           if ($pid) {
 223                $child_pid = $pid;
 224                # Wait here for a second to let the child start up
 225                sleep 1;
 226                return $pid;
 227           }
 228           else {
 229                $webserver = DebbugsTest::HTTPServer->new($port);
 230                $webserver->run;
 231           }
 232
 233      }
 234
 235      sub handle_request {
 236           if (defined $server_handler) {
 237                $server_handler->(@_);
 238           }
 239           else {
 240                warn "No handler defined\n";
 241                print "No handler defined\n";
 242           }
 243      }
 244 }
 245
 246 =head2 num_messages_sent
 247
 248      $SD_SIZE = num_messages_sent($SD_SIZE,2,$sendmail_dir,'2 messages have been sent properly');
 249
 250 Tests to make sure that at least a certain number of messages have
 251 been sent since the last time this command was run. Usefull to test to
 252 make sure that mail has been sent.
 253
 254 =cut
 255
 256 sub num_messages_sent {
 257     my ($prev_size,$num_messages,$sendmail_dir,$test_name) = @_;
 258     my $cur_size = dirsize($sendmail_dir);
 259     ## print STDERR "sendmail: $sendmail_dir, want: $num_messages,
 260     ## size: $cur_size, prev_size: $prev_size\n";
 261     ok($cur_size-$prev_size >= $num_messages, $test_name);
 262     return $cur_size;
 263 }
 264
 265
 266 1;
 267
 268 __END__
 269
 270
 271