scripts/process

   1 #!/usr/bin/perl
   2 # $Id: process.in,v 1.109 2006/02/09 22:02:04 don Exp $
   3 #
   4 # Usage: process nn
   5 # Temps:  incoming/Pnn
   6
   7 use warnings;
   8 use strict;
   9
  10 use POSIX qw(strftime locale_h);
  11 setlocale(LC_TIME, "C");
  12
  13 use IO::File;
  14
  15 use Getopt::Long;
  16 use Pod::Usage;
  17 use MIME::Parser;
  18 use Debbugs::MIME qw(decode_rfc1522 create_mime_message getmailbody);
  19 use Debbugs::Mail qw(send_mail_message encode_headers get_addresses);
  20 use Debbugs::Packages qw(getpkgsrc binary_to_source);
  21 use Debbugs::User qw(read_usertags write_usertags);
  22 use Debbugs::Common qw(:lock get_hashname buglog package_maintainer overwritefile make_list);
  23 use Debbugs::Status qw(writebug isstrongseverity lockreadbugmerge lockreadbug new_bug read_bug splitpackages  :versions);
  24
  25 use Debbugs::CGI qw(html_escape bug_links);
  26
  27 use Debbugs::Log qw(:misc :write);
  28
  29 use Debbugs::Text qw(:templates);
  30
  31 use Debbugs::Config qw(:globals :config);
  32
  33 use Debbugs::Control qw(append_action_to_log valid_usertag);
  34 use Debbugs::Control::Service qw(valid_control control_line);
  35 use Debbugs::Recipients qw(determine_recipients);
  36 use Encode qw(encode_utf8 decode);
  37 use List::AllUtils qw(first uniqnum);
  38
  39 =head1 NAME
  40
  41 process - Handle e-mails emails sent to bugs
  42
  43 =head1 SYNOPSIS
  44
  45 process nn
  46
  47  Options:
  48   --debug, -d debugging level (Default 0)
  49
  50 =head1 OPTIONS
  51
  52 =over
  53
  54 =item <--debug,-d>
  55
  56 Debugging level (default 0)
  57
  58 =back
  59
  60 =cut
  61
  62 use vars qw($DEBUG);
  63
  64 my %options = (debug           => 0,
  65                help            => 0,
  66                man             => 0,
  67               );
  68
  69 GetOptions(\%options,
  70            'debug|d+','help|h|?','man|m');
  71
  72 pod2usage() if $options{help};
  73 pod2usage({verbose=>2}) if $options{man};
  74
  75
  76 $DEBUG=$options{debug};
  77 my $debugfh = IO::File->new('/dev/null','w') or
  78     die "Unable to open /dev/null for writing; $!";
  79 if ($DEBUG > 0) {
  80     $debugfh = \*STDERR;
  81 }
  82 binmode($debugfh,':raw:encoding(UTF-8)');
  83
  84 # these are the valid bug addresses
  85 my %baddress = (B => 'submit',
  86                 M => 'maintonly',
  87                 Q => 'quiet',
  88                 F => 'forwarded',
  89                 D => 'done',
  90                 U => 'submitter',
  91                 L => 'list',
  92                );
  93 my $valid_codeletters = join('',keys %baddress);
  94
  95
  96 chdir($config{spool_dir}) or die "Unable to chdir to spool ($config{spool_dir}): $!";
  97
  98 umask(002);
  99
 100 my $intdate = time or die "failed to get time: $!";
 101
 102 my ($nn) = @ARGV;
 103 my ($codeletter,$tryref) =
 104     $nn =~ m/^([$valid_codeletters])(\d*)\.\d+$/
 105     or die "bad argument: $_";
 106 $tryref = undef unless length ($tryref) and
 107     $tryref > 0;
 108
 109 if (!rename("incoming/G$nn","incoming/P$nn"))  {
 110     my $error = $!;
 111     $error = '' if not defined $error;
 112     # this is very fragile, but we should probably die here anyway
 113     if ($error =~ m/no such file or directory/i) {
 114         exit 0;
 115     }
 116     die "Unable to rename incoming/G$nn to lock: $error";
 117 }
 118
 119 # die here to avoid continuously processing this mail
 120 if (not exists $baddress{$codeletter}) {
 121     die "bad codeletter $codeletter";
 122 }
 123
 124 my $baddress = $baddress{$codeletter};
 125 if ($baddress eq 'list') {
 126     bug_list_forward($nn) if $codeletter eq 'L';
 127 }
 128
 129
 130 my $baddressroot= $baddress;
 131 $baddress= "$tryref-$baddress" if defined $tryref;
 132
 133 my $msg;
 134 my @msg;
 135
 136 {
 137     my $log = IO::File->new("incoming/P$nn",'r') or
 138         die "Unable to open 'incoming/P$nn' for reading; $!";
 139     local $/;
 140     $msg=<$log>;
 141     @msg = split /\n/, $msg;
 142     close($log);
 143 }
 144
 145
 146 my $tdate = strftime "%a, %d %h %Y %T +0000", gmtime;
 147 my $fwd= "Received: via spool by $baddress\@$gEmailDomain id=$nn\n".
 148     "          (code $codeletter".(defined($tryref)?" ref $tryref":'')."); $tdate\n";
 149
 150 # header and decoded body respectively
 151 my (@headerlines, @bodylines);
 152
 153 # whether maintainer addresses have been checked
 154 our $maintainerschecked = 0;
 155 #maintainer address for this message
 156 our @maintaddrs;
 157 # other src addresses
 158 our @addsrcaddrs;
 159 our @resentccs;
 160 our @bccs;
 161
 162 my $resentccexplain='';
 163
 164 # whether there's a new reference with this email
 165 our $newref = 0;
 166
 167 our $brokenness = '';
 168
 169 my $parser_output = Debbugs::MIME::parse($msg);
 170
 171 @headerlines = @{$parser_output->{header}};
 172 @bodylines = @{$parser_output->{body}};
 173
 174 my %header;
 175
 176 my @common_headers;
 177 for my $hdr (@headerlines) {
 178     my $orig_hdr = $hdr;
 179     $hdr = decode_rfc1522($hdr);
 180     $_ = $hdr;
 181     s/\n\s/ /g;
 182     finish() if m/^x-loop: (\S+)$/i && $1 eq "$gMaintainerEmail";
 183     my $ins = !m/^(?:(?:subject|reply-to|return-path|
 184                          mail-followup-to|
 185                          references):
 186                  |From\s|X-Debbugs-)/xi;
 187     $fwd .= $orig_hdr."\n" if $ins;
 188     # print {$debugfh} ">$_<\n";
 189     if (s/^(\S+):\s*//) {
 190         my $v = lc $1;
 191         if ($v eq 'x-loop') {
 192             push @common_headers, 'X-Loop',$_;
 193         }
 194         print {$debugfh} ">$v=$_<\n";
 195         # Handle a comma which is escaped being passed through un-escaped. See
 196         # https://bugs.debian.org/1041638
 197         if ($_ =~ m/,/ and not $orig_hdr =~ m/,/) {
 198             $header{$v} = handle_escaped_commas($_,$orig_hdr);
 199         } else {
 200             $header{$v} = $_;
 201         }
 202     } else {
 203         print {$debugfh} "!>$_<\n";
 204     }
 205 }
 206 $header{'message-id'} = '' if not defined $header{'message-id'};
 207
 208 push @common_headers, 'X-Loop',$gMaintainerEmail;
 209
 210 # remove blank lines
 211 shift @bodylines while @bodylines and $bodylines[0] !~ /\S/;
 212
 213 # Strip off RFC2440-style PGP clearsigning.
 214 if (@bodylines and $bodylines[0] =~ /^-----BEGIN PGP SIGNED/) {
 215     shift @bodylines while @bodylines and length $bodylines[0];
 216     shift @bodylines while @bodylines and $bodylines[0] !~ /\S/;
 217     for my $findsig (0 .. $#bodylines) {
 218         if ($bodylines[$findsig] =~ /^-----BEGIN PGP SIGNATURE/) {
 219             $#bodylines = $findsig - 1;
 220             last;
 221         }
 222     }
 223     map { s/^- // } @bodylines;
 224 }
 225
 226 #psuedoheaders
 227 my %pheader;
 228 my @control_bits;
 229 my @usertag_bits;
 230 # extract pseudo-headers
 231 for my $phline (@bodylines)
 232 {
 233     # Remove BOM markers from UTF-8 strings
 234     # Fixes #488554
 235     $phline =~ s/\xef\xbb\xbf//g;
 236     $phline =~ s/\N{U+FEFF}//g;
 237     last if $phline !~ m/^([\w-]+): # psuedoheader
 238                          (?:\s|\N{U+00A0})* # zero or more spaces, including
 239                                             # non-breaking space
 240                          (\S.*)/x; # pseudoheader value
 241     my ($fn, $fv) = ($1, $2);
 242     $fv =~ s/\s*$//;
 243     $fn = lc $fn;
 244     # pluralize tag/usertag
 245     $fn = $fn.'s' if $fn =~ /^(?:tag|usertag)$/;
 246     print {$debugfh} ">$fn|$fv|\n";
 247     if ($fn =~ /^control$/) {
 248         push @control_bits,$fv;
 249     } elsif ($fn =~ /^(?:user|usertags)$/) {
 250         $fv = lc $fv;
 251         push @usertag_bits, [$fn, $fv];
 252     } else {
 253         # Don't lc owner or forwarded
 254         $fv = lc $fv unless $fn =~ /^(?:owner|forwarded|version|source-version|done)$/;
 255         $pheader{$fn} = $fv;
 256     }
 257     print {$debugfh} ">$fn~$fv<\n";
 258 }
 259
 260 # Allow pseudo headers to set x-debbugs- stuff [#179340]
 261 for my $key (grep /X-Debbugs-.*/i, keys %pheader) {
 262      $header{$key} = $pheader{$key} if not exists $header{$key};
 263 }
 264
 265 # set $i to beginning of encoded body data, so we can dump it out
 266 # verbatim later
 267 my $i = 0;
 268 ++$i while $i <= $#msg and $msg[$i] =~ /./;
 269 $fwd .= join("\n",@msg[$i..$#msg]);
 270
 271 binmode($debugfh,':raw');
 272 print {$debugfh} "***\n$fwd\n***\n";
 273 binmode($debugfh,':raw:encoding(UTF-8)');
 274
 275 if (defined $header{'resent-from'} && !defined $header{'from'}) {
 276     $header{'from'} = $header{'resent-from'};
 277 }
 278 defined($header{'from'}) || die "no From header";
 279
 280 my $replyto = $header{'reply-to'};
 281 $replyto = '' unless defined $replyto;
 282 $replyto =~ s/^ +//;
 283 $replyto =~ s/ +$//;
 284 unless (length $replyto) {
 285     $replyto = $header{'from'};
 286 }
 287
 288 my $subject = '(no subject)';
 289 if (!defined($header{'subject'}))
 290 {
 291         $brokenness.= fill_template('mail/process_broken_subject');
 292
 293 } else {
 294     $subject= $header{'subject'};
 295 }
 296
 297 my $ref=-1;
 298 # remove Re: from the subject line
 299 $subject =~ s/^Re:\s*//i;
 300 # remove remaining mailing list name markers from the subject line if
 301 # this appears to be a message that has traversed a mailing list
 302 if (exists $header{'list-id'} or exists $header{'list-subscribe'} or
 303     (exists $header{'precedence'} and defined $header{'precedence'} and
 304      $header{'precedence'} eq 'bulk') or
 305     exists $header{'mailing-list'} or exists $header{'list-processor-version'}
 306    ){
 307     # if a mailing list didn't match any of the above, it's probably
 308     # so horribly configured that we wouldn't be able to figure it out
 309     # anyway.
 310     $subject =~ s/^\[.*\]\s*//i;
 311 }
 312 $_= $subject."\n";
 313 if (not defined $tryref and m/^Bug ?\#(\d+)\D/i) {
 314     $tryref = $1 if $1 > 0;
 315 }
 316 my $locks = 0;
 317 my $data;
 318 if (defined $tryref) {
 319      my $locks_recv;
 320      ($locks_recv, $data)= &lockreadbugmerge($tryref);
 321      $locks += $locks_recv;
 322     if ($locks_recv and not $data->{archived}) {
 323         $ref= $tryref;
 324     } else {
 325         &sendmessage(create_mime_message(
 326           [From          =>  qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 327            To            => $replyto,
 328            Subject       => "Unknown problem report $gBug#$tryref ($subject)",
 329            'Message-ID'  => "<handler.x.$nn.unknown\@$gEmailDomain>",
 330            'In-Reply-To' => $header{'message-id'},
 331            References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 332            Precedence    => 'bulk',
 333            "X-$gProject-PR-Message" => 'error',
 334            @common_headers,
 335           ],message_body_template('mail/process_unknown_bug_number',
 336                                   {subject => $subject,
 337                                    date    => $header{date},
 338                                    baddress => $baddress,
 339                                    tryref   => $tryref,
 340                                    messageid => $header{'message-id'},
 341                                   },
 342                                  )),'');
 343         appendlog($ref,$msg);
 344         finish();
 345     }
 346 } else {
 347     &filelock('lock/-1');
 348 }
 349
 350 # Attempt to determine which source package this is
 351 my $source_pr_header = '';
 352 my $source_package = '';
 353 if (defined $pheader{source}) {
 354      $source_package = $pheader{source};
 355 }
 356 elsif (defined $data->{package} or defined $pheader{package}) {
 357      $source_package = binary_to_source(binary => $data->{package} // $pheader{package});
 358 }
 359 $source_pr_header = "X-$gProject-PR-Source: $source_package\n"
 360      if defined $source_package and length $source_package;
 361
 362 # Done and Forwarded Bugs
 363 if ($codeletter eq 'D' || $codeletter eq 'F')
 364 {
 365     if ($replyto =~ m/$gBounceFroms/o ||
 366         $header{'from'} =~ m/$gBounceFroms/o)
 367     {
 368          print STDERR "bounce detected !  Mwaap! Mwaap!";
 369          exit 1;
 370     }
 371     my $markedby= $header{'from'} eq $replyto ? $replyto :
 372                "$header{'from'} (reply to $replyto)";
 373     my @generalcc;
 374     my $receivedat;
 375     my $markaswhat;
 376     my $set_forwarded;
 377     my $generalcc;
 378     my $set_done;
 379     if ($codeletter eq 'F') { # Forwarded
 380         (appendlog($ref,$msg),finish()) if defined $data->{forwarded} and length($data->{forwarded});
 381         $receivedat= "forwarded\@$gEmailDomain";
 382         $markaswhat= 'forwarded';
 383         $set_forwarded= $header{'to'};
 384         # Dissallow forwarded being set to this bug tracking system
 385         if (defined $set_forwarded and $set_forwarded =~ /\Q$gEmailDomain\E/) {
 386              undef $set_forwarded;
 387         }
 388         if ( length( $gListDomain ) > 0 && length( $gForwardList ) > 0 ) {
 389             push @generalcc, "$gForwardList\@$gListDomain";
 390             $generalcc= "$gForwardList\@$gListDomain";
 391         } else {
 392             $generalcc='';
 393         }
 394     } else { # Done
 395         if (defined $data->{done} and length($data->{done}) and
 396                 not defined $pheader{'source-version'} and
 397                 not defined $pheader{'version'}) {
 398             appendlog($ref,$msg);
 399             finish();
 400         }
 401         $receivedat= "done\@$gEmailDomain";
 402         $markaswhat= 'done';
 403         $set_done= $pheader{'done'} // $header{'from'};
 404         if ( length( $gListDomain ) > 0 && length( $gDoneList ) > 0 ) {
 405             $generalcc= "$gDoneList\@$gListDomain";
 406             push @generalcc, "$gDoneList\@$gListDomain";
 407         } else {
 408             $generalcc='';
 409         }
 410     }
 411     if (defined $gStrongList and isstrongseverity($data->{severity})) {
 412         $generalcc = join ', ', $generalcc, "$gStrongList\@$gListDomain";
 413         push @generalcc,"$gStrongList\@$gListDomain";
 414     }
 415     if ($ref<0) {
 416         &sendmessage(create_mime_message(
 417           [From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 418            To            => $replyto,
 419            Subject       => "Message with no $gBug number ignored by $receivedat ($subject)",
 420            'Message-ID'  => "<handler.x.$nn.warnignore\@$gEmailDomain>",
 421            'In-Reply-To' => $header{'message-id'},
 422            References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 423            Precedence    => 'bulk',
 424            "X-$gProject-PR-Message" => 'error',
 425            @common_headers,
 426           ],message_body_template('mail/process_no_bug_number',
 427                                   {subject => $subject,
 428                                    date    => $header{date},
 429                                    markaswhat => $markaswhat,
 430                                    receivedat => $receivedat,
 431                                    messageid => $header{'message-id'},
 432                                   },
 433                                  )),'');
 434         appendlog($ref,$msg);
 435         finish();
 436     }
 437
 438     &checkmaintainers;
 439
 440     my @noticecc = grep($_ ne $replyto,@maintaddrs);
 441     my $noticeccval.= join(', ', grep($_ ne $replyto,@maintaddrs));
 442     $noticeccval =~ s/\s+\n\s+/ /g;
 443     $noticeccval =~ s/^\s+/ /; $noticeccval =~ s/\s+$//;
 444
 445     my @process= ($ref,split(/ /,$data->{mergedwith}));
 446     my $orgref= $ref;
 447
 448     for $ref (@process) {
 449         if ($ref != $orgref) {
 450             &unfilelock;
 451             $locks--;
 452             $data = &lockreadbug($ref)
 453                 || die "huh ? $ref from $orgref out of ".join(' ',@process);
 454             $locks++;
 455         }
 456         $data->{done}= $set_done if defined($set_done);
 457         $data->{forwarded}= $set_forwarded if defined($set_forwarded);
 458         if ($codeletter eq 'D') {
 459             $data->{keywords} = join ' ', grep $_ ne 'pending',
 460                                      split ' ', $data->{keywords};
 461             if (defined $pheader{'source-version'}) {
 462                  if ($pheader{'source-version'} !~ m/^$config{package_version_re}$/) {
 463                       $brokenness .= fill_template('mail/invalid_version',
 464                                                    {version => $pheader{'source-version'}},
 465                                                   );
 466                  }
 467                  else {
 468                       addfixedversions($data, $pheader{source}, $pheader{'source-version'}, '');
 469                  }
 470             } elsif (defined $pheader{version}) {
 471                  if ($pheader{version} !~ m/^$config{package_version_re}$/) {
 472                       $brokenness .= fill_template('mail/invalid_version',
 473                                                    {version => $pheader{version}},
 474                                                   );
 475                  }
 476                  else {
 477                       addfixedversions($data, $pheader{package}, $pheader{version}, '');
 478                  }
 479             }
 480         }
 481
 482         # Add bug mailing list to $generalbcc as appropriate
 483         # This array is used to specify bcc in the cases where we're using create_mime_message.
 484         my @generalbcc = @generalcc;
 485         if (defined $config{subscription_domain} and length $config{subscription_domain}) {
 486             @generalbcc = (@generalbcc, @addsrcaddrs);
 487         }
 488         if (defined $config{bug_subscription_domain} and length $config{bug_subscription_domain}) {
 489             @generalbcc = (@generalbcc, "bugs=$ref\@$config{bug_subscription_domain}");
 490         }
 491         my $generalbcc = join(', ', @generalbcc);
 492         $generalbcc =~ s/\s+\n\s+/ /g;
 493         $generalbcc =~ s/^\s+/ /; $generalbcc =~ s/\s+$//;
 494         if (length $generalbcc) {$generalbcc = "Bcc: $generalbcc\n"};
 495
 496         writebug($ref, $data);
 497
 498         my $hash = get_hashname($ref);
 499         my $orig_report_fh = IO::File->new("db-h/$hash/$ref.report") or
 500             die "Unable to read original report: $!";
 501         my $orig_report;
 502         { local $/; $orig_report = <$orig_report_fh>;}
 503         close($orig_report_fh) or
 504             die "Unable to close original report filehandle: $!";
 505         if ($codeletter eq 'F') {
 506             &htmllog("Reply","sent",$replyto,"You have marked $gBug as forwarded.");
 507             &sendmessage(create_mime_message(
 508              [@common_headers,
 509               From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 510               To            => "$replyto",
 511               Subject       => "$gBug#$ref: marked as forwarded ($data->{subject})",
 512               "Message-ID"  => "<header.$ref.$nn.ackfwdd\@$gEmailDomain>",
 513               "In-Reply-To" => $header{'message-id'},
 514               References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 515               Precedence    => 'bulk',
 516               "X-$gProject-PR-Message"  => "forwarded $ref",
 517               "X-$gProject-PR-Package"  => $data->{package},
 518               "X-$gProject-PR-Keywords" => $data->{keywords},
 519               # Only have a X-$gProject-PR-Source when we know the source package
 520               (defined($source_package) and length($source_package))?("X-$gProject-PR-Source" => $source_package):(),
 521               "Reply-To"                => "$ref\@$gEmailDomain",
 522               "Content-Type"            => 'text/plain; charset="utf-8"',
 523              ],message_body_template('mail/process_mark_as_forwarded',
 524                                      {date => $header{date},
 525                                       messageid => $header{'message-id'},
 526                                       data      => $data,
 527                                      },
 528                                     ),
 529              [join("\n",@msg)]),'',[$replyto,@generalbcc,@noticecc],1);
 530         } else {
 531             &htmllog("Reply","sent",$replyto,"You have taken responsibility.");
 532             &sendmessage(create_mime_message(
 533              [@common_headers,
 534               From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 535               To            => $replyto,
 536               Subject       => "$gBug#$ref: marked as done ($data->{subject})",
 537               "Message-ID"  => "<handler.$ref.$nn.ackdone\@$gEmailDomain>",
 538               "In-Reply-To" => $header{'message-id'},
 539               References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 540               Precedence    => 'bulk',
 541               "X-$gProject-PR-Message"  => "closed $ref",
 542               "X-$gProject-PR-Package"  => $data->{package},
 543               "X-$gProject-PR-Keywords" => $data->{keywords},
 544               # Only have a X-$gProject-PR-Source when we know the source package
 545               (defined($source_package) and length($source_package))?("X-$gProject-PR-Source" => $source_package):(),
 546               "Reply-To"                => "$ref\@$gEmailDomain",
 547               "Content-Type"            => 'text/plain; charset="utf-8"',
 548              ],message_body_template('mail/process_mark_as_done',
 549                                      {date => $header{date},
 550                                       messageid => $header{'message-id'},
 551                                       subject   => $header{subject},
 552                                       data      => $data,
 553                                      },
 554                                     ),
 555              [$orig_report,join("\n",@msg)]),'',[$replyto,@generalbcc,@noticecc],1);
 556             &htmllog("Notification","sent",$data->{originator},
 557                 "$gBug acknowledged by developer.");
 558             &sendmessage(create_mime_message(
 559              [@common_headers,
 560               From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 561               To            => "$data->{originator}",
 562               Subject       => "$gBug#$ref closed by $markedby ($header{'subject'})",
 563               "Message-ID"  => "<handler.$ref.$nn.notifdone\@$gEmailDomain>",
 564               (defined $data->{msgid})?("In-Reply-To" => $data->{msgid}):(),
 565               References    => join(' ',grep {defined $_} ($header{'message-id'},$data->{msgid},'')),
 566               "X-$gProject-PR-Message"  => "they-closed $ref",
 567               (defined $data->{package})?("X-$gProject-PR-Package"  => $data->{package}):(),
 568               (defined $data->{keywords})?("X-$gProject-PR-Keywords" => $data->{keywords}):(),
 569               # Only have a X-$gProject-PR-Source when we know the source package
 570               (defined($source_package) and length($source_package))?("X-$gProject-PR-Source" => $source_package):(),
 571               "Reply-To"                => "$ref\@$gEmailDomain",
 572               "Content-Type"            => 'text/plain; charset="utf-8"',
 573              ],message_body_template('mail/process_your_bug_done',
 574                                      {data      => $data,
 575                                       markedby  => $markedby,
 576                                       messageid => $header{'message-id'},
 577                                       subject   => $header{subject},
 578                                      },
 579                                     ),
 580              [join("\n",@msg),$orig_report]),'',undef,1);
 581         }
 582         appendlog($ref,$msg);
 583     }
 584     finish();
 585 }
 586
 587 if ($ref<0) { # new bug report
 588     if ($codeletter eq 'U') { # -submitter
 589         &sendmessage(create_mime_message(
 590           [@common_headers,
 591            From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 592            To            => $replyto,
 593            Subject       => "Message with no $gBug number cannot be sent to submitter! ($subject)",
 594            'Message-ID'  => "<handler.x.$nn.nonumnosub\@$gEmailDomain>",
 595            'In-Reply-To' => $header{'message-id'},
 596            References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 597            Precedence    => 'bulk',
 598            "X-$gProject-PR-Message" => 'error',
 599           ],message_body_template('mail/process_no_bug_number',
 600                                   {subject => $subject,
 601                                    date    => $header{date},
 602                                    markaswhat => 'submitter',
 603                                    receivedat => "$baddress\@$gEmailDomain",
 604                                    messageid => $header{'message-id'},
 605                                   },
 606                                  )),'');
 607         appendlog($ref,$msg);
 608         finish();
 609     }
 610
 611     $data->{found_versions} = [];
 612     $data->{fixed_versions} = [];
 613
 614     if (defined $pheader{source}) {
 615         # source packages are identified by the src: prefix
 616         $data->{package} = $pheader{source};
 617         $data->{package} =~ s/(^|,\s*)/${1}src:/g;
 618     } elsif (defined $pheader{package}) {
 619         $data->{package} = $pheader{package};
 620         if ($data->{package} =~ /^src:(.+)/) {
 621             $pheader{source} = $1;
 622         }
 623     } elsif (defined $config{default_package}) {
 624         $data->{package} = $config{default_package},
 625     }
 626     else {
 627         my $body = message_body_template('mail/process_no_package',
 628                                         );
 629         &sendmessage(create_mime_message(
 630                        [@common_headers,
 631                         From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
 632                         To            => $replyto,
 633                         Subject       => "Message with no Package: tag cannot be processed! ($subject)",
 634                         "Message-ID"  => "<handler.x.$nn.nonumnosub\@$gEmailDomain>",
 635                         "In-Reply-To" => $header{'message-id'},
 636                         References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
 637                         Precedence    => 'bulk',
 638                         "X-$gProject-PR-Message" => 'error'
 639                        ],
 640            message_body_template('mail/process_no_package',
 641                                  {date => $header{date},
 642                                   subject => $subject,
 643                                   messageid => $header{'message-id'},
 644                                   baddress => $baddress,
 645                                  },
 646                                 ),[join("\n", @msg)]), '',undef,1);
 647         appendlog($ref,$msg);
 648         finish();
 649     }
 650
 651     if (defined $config{default_package}) {
 652          &checkmaintainers;
 653          # if there are no maintainers for this package, assign it to the default package
 654          if (not @maintaddrs) {
 655               $data->{package} = $config{default_package};
 656               $brokenness.= fill_template('mail/process_default_package_selected',
 657                                           {old_package => $pheader{source} || $pheader{package} || 'No package',
 658                                            new_package => $data->{package},
 659                                           }
 660                                          );
 661               # force the maintainers to be rechecked
 662               $maintainerschecked = 0;
 663               &checkmaintainers;
 664          }
 665     }
 666
 667     $data->{keywords}= '';
 668     if (defined($pheader{'keywords'})) {
 669         $data->{keywords}= $pheader{'keywords'};
 670     } elsif (defined($pheader{'tags'})) {
 671         $data->{keywords}= $pheader{'tags'};
 672     }
 673     if (length($data->{keywords})) {
 674         my @kws;
 675         my %gkws = map { ($_, 1) } @gTags;
 676         foreach my $kw (sort split(/[,\s]+/, lc($data->{keywords}))) {
 677             push @kws, $kw if (defined $gkws{$kw});
 678         }
 679         $data->{keywords} = join(" ", @kws);
 680     }
 681     $data->{severity}= '';
 682     if (defined($pheader{'severity'}) || defined($pheader{'priority'})) {
 683         $data->{severity}= $pheader{'severity'};
 684         $data->{severity}= $pheader{'priority'} unless ($data->{severity});
 685         $data->{severity} =~ s/^\s*(.+)\s*$/$1/;
 686
 687         if (!grep($_ eq $data->{severity}, @gSeverityList, "$gDefaultSeverity")) {
 688             $brokenness.= fill_template('mail/invalid_severity',
 689                                         {severity=>$data->{severity}}
 690                                        );
 691             $data->{severity}= '';
 692         }
 693     }
 694     if (defined($pheader{owner})) {
 695         $data->{owner}= $pheader{owner};
 696     }
 697     if (defined($pheader{forwarded})) {
 698         $data->{forwarded} = $pheader{forwarded};
 699     }
 700     $ref = new_bug();
 701     $newref = $ref;
 702     my $hash = get_hashname($ref);
 703     $data->{originator} = $replyto;
 704     $data->{date} = $intdate;
 705     $data->{subject} = $subject;
 706     $data->{msgid} = $header{'message-id'};
 707     writebug($ref, $data);
 708     # Deal with usertags
 709     my $current_user;
 710     unshift @usertag_bits, ['user', $replyto];
 711     for my $field (@usertag_bits) {
 712         my ($name, $value) = @$field;
 713         if ($name eq 'user') {
 714             my $user = $value;
 715             $user =~ s/,.*//;
 716             $user =~ s/^.*<(.*)>.*$/$1/;
 717             $user =~ s/[(].*[)]//;
 718             $user =~ s/^\s*(\S+)\s+.*$/$1/;
 719             if ($user ne '' and Debbugs::User::is_valid_user($user)) {
 720                 $current_user = $user;
 721             } else {
 722                 $brokenness .= fill_template('mail/invalid_user',
 723                                              {user => $user}
 724                                             );
 725             }
 726         }
 727         if ($name eq 'usertags' and defined $current_user){
 728             my %user_tags;
 729             read_usertags(\%user_tags, $current_user);
 730             $value =~ s/(?:^\s+|\s+$)//g;
 731             for my $tag (split /[,\s]+/, $value) {
 732                 if (valid_usertag($tag)) {
 733                     my %bugs_with_tag;
 734                     @bugs_with_tag{@{$user_tags{$tag}||[]}} = (1) x @{$user_tags{$tag}||[]};
 735                     $bugs_with_tag{$ref} = 1;
 736                     $user_tags{$tag} = [keys %bugs_with_tag];
 737                 }
 738             }
 739             write_usertags(\%user_tags,$current_user);
 740         }
 741     }
 742     overwritefile("db-h/$hash/$ref.report",
 743                   map {"$_\n"} @msg);
 744 }
 745
 746 &checkmaintainers;
 747
 748 print {$debugfh} "maintainers >".join(' ',@maintaddrs)."<\n";
 749
 750 my $orgsender= defined($header{'sender'}) ? "Original-Sender: $header{'sender'}\n" : '';
 751 my $newsubject= $subject;  $newsubject =~ s/^$gBug#$ref:*\s*//;
 752
 753 my $xcchdr= $header{ 'x-debbugs-cc' } || '';
 754 if ($xcchdr =~ m/\S/) {
 755     push(@resentccs,get_addresses($xcchdr));
 756     $resentccexplain.= fill_template('mail/xdebbugscc',
 757                                      {xcchdr => $xcchdr},
 758                                     );
 759 }
 760
 761 if (@maintaddrs && ($codeletter eq 'B' || $codeletter eq 'M')) {
 762     push(@resentccs,@maintaddrs);
 763     $resentccexplain.= fill_template('mail/maintainercc',
 764                                      {maintaddrs => \@maintaddrs,
 765                                      },
 766                                     );
 767 }
 768
 769 @bccs = @addsrcaddrs;
 770 if (defined $gStrongList and isstrongseverity($data->{severity})) {
 771     push @bccs, "$gStrongList\@$gListDomain";
 772 }
 773
 774 # Send mail to the per bug list subscription too
 775 if (defined $config{bug_subscription_domain} and length $config{bug_subscription_domain}) {
 776     push @bccs, "bugs=$ref\@$config{bug_subscription_domain}";
 777 }
 778
 779 if (defined $pheader{source}) {
 780     # Prefix source versions with the name of the source package. They
 781     # appear that way in version trees so that we can deal with binary
 782     # packages moving from one source package to another.
 783     if (defined $pheader{'source-version'}) {
 784          if ($pheader{'source-version'} !~ m/^$config{package_version_re}$/) {
 785               $brokenness .= fill_template('mail/invalid_version',
 786                                            {version => $pheader{'source-version'}},
 787                                           );
 788          }
 789          else {
 790               addfoundversions($data, $pheader{source}, $pheader{'source-version'}, '');
 791          }
 792     } elsif (defined $pheader{version}) {
 793          if ($pheader{version} !~ m/^$config{package_version_re}$/) {
 794               $brokenness .= fill_template('mail/invalid_version',
 795                                            {version => $pheader{version}},
 796                                           );
 797          }
 798          else {
 799               addfoundversions($data, $pheader{source}, $pheader{version}, '');
 800          }
 801     }
 802     writebug($ref, $data);
 803 } elsif (defined $pheader{package}) {
 804     # TODO: could handle Source-Version: by looking up the source package?
 805      if (defined $pheader{version}) {
 806           if ($pheader{version} !~ m/^$config{package_version_re}$/) {
 807                $brokenness .= fill_template('mail/invalid_version',
 808                                             {version => $pheader{version}},
 809                                            );
 810           }
 811           else {
 812                addfoundversions($data, $pheader{package}, $pheader{version}, 'binary');
 813           }
 814      }
 815      writebug($ref, $data);
 816 }
 817
 818 my $veryquiet= $codeletter eq 'Q';
 819 if ($codeletter eq 'M' && !@maintaddrs) {
 820     $veryquiet= 1;
 821     $brokenness.= fill_template('mail/invalid_maintainer',
 822                                 {},
 823                                );
 824 }
 825
 826 my $resentccval.= join(', ',@resentccs);
 827 $resentccval =~ s/\s+\n\s+/ /g; $resentccval =~ s/^\s+/ /; $resentccval =~ s/\s+$//;
 828 my $resentcc = '';
 829 if (length($resentccval)) {
 830     $resentcc= "Resent-CC: $resentccval\n";
 831 }
 832
 833 my $referencesval = join(' ',grep {defined $_} $header{'references'},$data->{msgid});
 834 my $references = '';
 835 if (!$newref && length($referencesval)) {
 836     $references = "References: $referencesval\n";
 837 }
 838
 839 my $common_headers='';
 840 {
 841     my @tmp = @common_headers;
 842     while (my ($key,$value) = splice(@tmp, 0,2)) {
 843         $common_headers .= qq($key: $value\n);
 844     }
 845 }
 846 if ($codeletter eq 'U') { # sent to -submitter
 847     &htmllog("Message", "sent on", $data->{originator}, "$gBug#$ref.");
 848     my $enc_msg=<<END;
 849 Subject: $gBug#$ref: $newsubject
 850 Reply-To: $replyto, $ref-quiet\@$gEmailDomain
 851 ${orgsender}Resent-To: $data->{originator}
 852 ${resentcc}${common_headers}Resent-Date: $tdate
 853 Resent-Message-ID: <handler.$ref.$nn\@$gEmailDomain>
 854 Resent-Sender: $gMaintainerEmail
 855 X-$gProject-PR-Message: report $ref
 856 X-$gProject-PR-Package: $data->{package}
 857 X-$gProject-PR-Keywords: $data->{keywords}
 858 ${references}${source_pr_header}
 859 END
 860     chomp $enc_msg;
 861     $enc_msg = encode_utf8($enc_msg).$fwd."\n";
 862     &sendmessage($enc_msg,[$data->{originator},@resentccs],[@bccs]);
 863 } elsif ($codeletter eq 'B') { # Sent to submit
 864     my $report_followup = $newref ? 'report' : 'followup';
 865     &htmllog($newref ? "Report" : "Information", "forwarded",
 866              join(', ',"$gSubmitList\@$gListDomain",@resentccs),
 867              "<code>$gBug#$ref</code>".
 868              (length($data->{package})? "; Package <code>".html_escape($data->{package})."</code>" : '').
 869              ".");
 870     my $enc_msg=<<END;
 871 Subject: $gBug#$ref: $newsubject
 872 Reply-To: $replyto, $ref\@$gEmailDomain
 873 Resent-From: $header{'from'}
 874 ${orgsender}Resent-To: $gSubmitList\@$gListDomain
 875 ${resentcc}${common_headers}Resent-Date: $tdate
 876 Resent-Message-ID: <handler.$ref.$nn\@$gEmailDomain>
 877 Resent-Sender: $gMaintainerEmail
 878 X-$gProject-PR-Message: $report_followup $ref
 879 X-$gProject-PR-Package: $data->{package}
 880 X-$gProject-PR-Keywords: $data->{keywords}
 881 ${references}${source_pr_header}
 882 END
 883     chomp $enc_msg;
 884     $enc_msg = encode_utf8($enc_msg).$fwd."\n";
 885     &sendmessage($enc_msg,["$gSubmitList\@$gListDomain",@resentccs],[@bccs]);
 886 } elsif (@resentccs or @bccs) { # Quiet or Maintainer
 887     # D and F done far earlier; B just done - so this must be M or Q
 888     # We preserve whichever it was in the Reply-To (possibly adding
 889     # the $gBug#).
 890     my $report_followup = $newref ? 'report' : 'followup';
 891     if (@resentccs) {
 892         &htmllog($newref ? "Report" : "Information", "forwarded",
 893                  $resentccval,
 894                  "<code>$gBug#$ref</code>".
 895                  (length($data->{package}) ? "; Package <code>".html_escape($data->{package})."</code>" : '').
 896                  ".");
 897     } else {
 898         &htmllog($newref ? "Report" : "Information", "stored",
 899                  "",
 900                  "<code>$gBug#$ref</code>".
 901                  (length($data->{package}) ? "; Package <code>".html_escape($data->{package})."</code>" : '').
 902                  ".");
 903     }
 904     my $enc_msg=<<END;
 905 Subject: $gBug#$ref: $newsubject
 906 Reply-To: $replyto, $ref-$baddressroot\@$gEmailDomain
 907 Resent-From: $header{'from'}
 908 ${orgsender}Resent-To: $resentccval
 909 Resent-Date: $tdate
 910 Resent-Message-ID: <handler.$ref.$nn\@$gEmailDomain>
 911 Resent-Sender: $gMaintainerEmail
 912 ${common_headers}X-$gProject-PR-Message: $report_followup $ref
 913 X-$gProject-PR-Package: $data->{package}
 914 X-$gProject-PR-Keywords: $data->{keywords}
 915 ${references}${source_pr_header}
 916 END
 917     chomp $enc_msg;
 918     $enc_msg = encode_utf8($enc_msg).$fwd."\n";
 919     &sendmessage($enc_msg,[@resentccs],[@bccs]);
 920 }
 921
 922 my $htmlbreak= length($brokenness) ? "<p>\n".html_escape($brokenness)."\n<p>\n" : '';
 923 $htmlbreak =~ s/\n\n/\n<P>\n\n/g;
 924 if (length($resentccval)) {
 925     $htmlbreak = "  Copy sent to <code>".html_escape($resentccval)."</code>.".
 926         $htmlbreak;
 927 }
 928
 929 # Should we send an ack out?
 930 if (not exists $header{'x-debbugs-no-ack'} and
 931     ($newref or
 932      ($codeletter ne 'U' and
 933       (not defined $header{precedence} or
 934        $header{'precedence'} !~ /\b(?:bulk|junk|list)\b/
 935       )
 936      )
 937     )
 938    ){
 939
 940      # figure out forward explanation
 941      my $forwardexplain = '';
 942      my $thanks = '';
 943      my $extra_vars;
 944      # will contain info and -info in moreinfo messages
 945      my $info = '';
 946      my $infod = '';
 947      # temporary headers
 948      my %t_h;
 949      if ($newref) {
 950           &htmllog("Acknowledgement","sent",$replyto,
 951                    ($veryquiet ?
 952                     "New $gBug report received and filed, but not forwarded." :
 953                     "New $gBug report received and forwarded."). $htmlbreak);
 954           $thanks = fill_template('mail/process_ack_thanks_new');
 955      }
 956      else {
 957           &htmllog("Acknowledgement","sent",$replyto,
 958                    ($veryquiet ? "Extra info received and filed, but not forwarded." :
 959                     $codeletter eq 'M' ? "Extra info received and forwarded to maintainer." :
 960                     "Extra info received and forwarded to list."). $htmlbreak);
 961           $thanks = fill_template('mail/process_ack_thanks_additional');
 962           $info = 'info';
 963           $infod = '-info';
 964      }
 965      if ($veryquiet) {
 966           $forwardexplain = fill_template('mail/forward_veryquiet',
 967                                          );
 968           # these are the headers that quiet messages override
 969           $t_h{messageid}  = "<handler.$ref.$nn.ack${info}quiet\@$gEmailDomain>";
 970           $t_h{pr_message} = "ack${infod}-quiet $ref";
 971           $t_h{reply_to}   = "$ref-quiet\@$gEmailDomain";
 972           $extra_vars->{refreplyto} = "$ref-quiet\@$gEmailDomain";
 973           $t_h{subject}    = length($info)?
 974                "$gBug#$ref: Info received and FILED only ($subject)":
 975                "$gBug#$ref: Acknowledgement of QUIET report ($subject)";
 976      }
 977      elsif ($codeletter eq 'M') {
 978           $forwardexplain = fill_template('mail/forward_maintonly',
 979                                          );
 980           # these are the headers that maintonly messages override
 981           $t_h{messageid}  = "<handler.$ref.$nn.ack{$info}maintonly\@$gEmailDomain>";
 982           $t_h{pr_message} = "ack${infod}-maintonly $ref";
 983           $t_h{reply_to}   = "$ref-maintonly\@$gEmailDomain";
 984           $extra_vars->{refreplyto} = "$ref-maintonly\@$gEmailDomain";
 985           $t_h{subject}    = length($info)?
 986                "$gBug#$ref: Info received for maintainer only ($subject)":
 987                "$gBug#$ref: Acknowledgement of maintainer-only report ($subject)";
 988      }
 989      else {
 990           $forwardexplain = fill_template('mail/forward_normal',
 991                                          );
 992           $t_h{messageid}  = "<handler.$ref.$nn.ack${info}\@$gEmailDomain>";
 993           $t_h{pr_message} = "ack${infod} $ref";
 994           $t_h{reply_to}   = "$ref\@$gEmailDomain";
 995           $extra_vars->{refreplyto} = "$ref\@$gEmailDomain";
 996           $t_h{subject}    = (defined $info and length($info))?
 997                "$gBug#$ref: Info received ($subject)" :
 998                "$gBug#$ref: Acknowledgement ($subject)";
 999      }
1000      my $body = message_body_template('mail/process_ack',
1001                                       {forwardexplain  => $forwardexplain,
1002                                        resentccexplain => $resentccexplain,
1003                                        thanks          => $thanks,
1004                                        %{$extra_vars}
1005                                       }
1006                                      );
1007      &sendmessage(create_mime_message(
1008                        [@common_headers,
1009                         From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
1010                         To            => $replyto,
1011                         Subject       => $t_h{subject},
1012                         "Message-ID"  => $t_h{messageid},
1013                         "In-Reply-To" => $header{'message-id'},
1014                         References    => $header{'message-id'},
1015                         Precedence    => 'bulk',
1016                         "X-$gProject-PR-Message"  => $t_h{pr_message} || "ack $ref",
1017                         "X-$gProject-PR-Package"  => $data->{package},
1018                         "X-$gProject-PR-Keywords" => $data->{keywords},
1019                         # Only have a X-$gProject-PR-Source when we know the source package
1020                         (defined($source_package) and length($source_package))?("X-$gProject-PR-Source" => $source_package):(),
1021                         "Reply-To"                => $t_h{reply_to} || "$ref\@$gEmailDomain",
1022                        ],$body,[]), '',undef,1);
1023 }
1024
1025 appendlog($ref,$msg);
1026 # unlock the locks we have received
1027 while ($locks--) {unfilelock();}
1028
1029 ## handle control messages at this point, immediately before finishing
1030 my %clonebugs = (-1 => $ref);
1031 my %bug_affected;
1032 if (@control_bits) {
1033     my $transcript_scalar = '';
1034     open my $transcript, ">:scalar:utf8", \$transcript_scalar or
1035         die "Unable to create transcript scalar: $!";
1036     print {$transcript} "Processing control commands:\n\n";
1037     my %affected_packages;
1038     my %recipients;
1039     # this is the hashref which is passed to all control calls
1040     my %limit = ();
1041     my $errors = 0;
1042     my $unknowns = 0;
1043
1044     my @common_control_options =
1045         (transcript        => $transcript,
1046          requester         => $header{from},
1047          request_addr      => $baddress.'@'.$config{email_domain},
1048          request_msgid     => $header{'message-id'},
1049          request_subject   => $header{subject},
1050          request_nn        => $nn,
1051          request_replyto   => $replyto,
1052          message           => [$msg],
1053          affected_bugs     => \%bug_affected,
1054          affected_packages => \%affected_packages,
1055          recipients        => \%recipients,
1056          limit             => \%limit,
1057         );
1058     if (@gExcludeFromControl and grep {$replyto =~ m/\Q$_\E/} @gExcludeFromControl) {
1059         print {$transcript} fill_template('mail/excluded_from_control');
1060         print {$transcript} "Stopping processing here.\n\n";
1061     } else {
1062         for my $control_bit (@control_bits) {
1063             $control_bit =~ s/\xef\xbb\xbf//g;
1064             next unless $control_bit =~ m/\S/;
1065             eval {
1066                 my $temp = decode("utf8",$control_bit,Encode::FB_CROAK);
1067                 $control_bit = $temp;
1068             };
1069             print {$transcript} "> $control_bit\n";
1070             next if $control_bit =~ /^\s*\#/;
1071             my $action = '';
1072             my $ok;
1073             if (defined valid_control($control_bit)) {
1074                 my ($new_errors,$terminate_control) =
1075                     control_line(line => $control_bit,
1076                                  clonebugs => \%clonebugs,
1077                                  limit => \%limit,
1078                                  common_control_options => \@common_control_options,
1079                                  errors => \$errors,
1080                                  transcript => $transcript,
1081                                  debug => 0,
1082                                  ok => \$ok,
1083                                  replyto => $replyto,
1084                                 );
1085                 if ($terminate_control) {
1086                     last;
1087                 }
1088             }
1089             else {
1090                 print {$transcript} "Unknown command or malformed arguments to command.\n\n";
1091                 $errors++;
1092                 if (++$unknowns >= 5) {
1093                     print {$transcript} "Too many unknown commands, stopping here.\n\n";
1094                     last;
1095                 }
1096             }
1097         }
1098     }
1099     my $temp_transcript = $transcript_scalar;
1100     eval{
1101         $temp_transcript = decode("utf8",$temp_transcript,Encode::FB_CROAK);
1102     };
1103     my @maintccs = determine_recipients(recipients => \%recipients,
1104                                         address_only => 1,
1105                                         cc => 1,
1106                                        );
1107     my $error_text = $errors > 0 ? " (with $errors error" . ($errors > 1 ? "s" : "") . ")" : "";
1108     my $reply =
1109         create_mime_message(['X-Loop'      => $gMaintainerEmail,
1110                              From          => qq("$gProject $gBug Tracking System" <$gMaintainerEmail>),
1111                              To            => $replyto,
1112                              @maintccs ? (Cc => join(', ',@maintccs)):(),
1113                              Subject       => "Processed${error_text}: $header{subject}",
1114                              'Message-ID'  => "<handler.s.$nn.transcript\@$gEmailDomain>",
1115                              'In-Reply-To' => $header{'message-id'},
1116                              References    => join(' ',grep {defined $_} $header{'message-id'},$data->{msgid}),
1117                              Precedence    => 'bulk',
1118                              keys %affected_packages ?("X-${gProject}-PR-Package" => join(' ',keys %affected_packages)):(),
1119                              keys %affected_packages ?("X-${gProject}-PR-Source" =>
1120                                                        join(' ',
1121                                                             map {defined $_ ?(ref($_)?@{$_}:$_):()}
1122                                                             binary_to_source(binary => [keys %affected_packages],
1123                                                                              source_only => 1))):(),
1124                              "X-$gProject-PR-Message" => 'transcript',
1125                              @common_headers,
1126                             ],
1127                             fill_template('mail/message_body',
1128                                           {body => $temp_transcript},
1129                                          ));
1130
1131     utime(time,time,"db-h");
1132
1133     send_mail_message(message => $reply,
1134                       recipients => [exists $header{'x-debbugs-no-ack'}?():$replyto,
1135                                      make_list(values %{{determine_recipients(recipients => \%recipients,
1136                                                                               address_only => 1,
1137                                                                              )}}
1138                                               ),
1139                                     ]
1140                      );
1141
1142 }
1143
1144
1145 finish();
1146
1147 sub appendlog {
1148     my ($ref,$msg) = @_;
1149     my $log_location = buglog($ref);
1150     die "Unable to find .log for $ref"
1151         if not defined $log_location;
1152     my $logfh = IO::File->new(">>$log_location") or
1153         die "Unable to open $log_location for appending: $!";
1154     write_log_records(logfh => $logfh,
1155                       records => [{type => 'incoming-recv',
1156                                    text => $msg,
1157                                   }]);
1158     close ($logfh) or die "Unable to close $log_location: $!";
1159 }
1160
1161 sub finish {
1162     my ($exit) = @_;
1163     $exit ||= 0;
1164     utime(time,time,"db");
1165     # cleanups are run in an end block now.
1166     #my ($u);
1167     #while ($u= $cleanups[$#cleanups]) { &$u; }
1168     unlink("incoming/P$nn") || die "unlinking incoming/P$nn: $!";
1169     exit $exit;
1170 }
1171
1172 die "wot no exit";
1173
1174 sub htmllog {
1175     my ($whatobj,$whatverb,$where,$desc) = @_;
1176     append_action_to_log(bug => $ref,
1177                          action => "$whatobj $whatverb",
1178                          requester => '',
1179                          request_addr => $where,
1180                          desc         => $desc,
1181                          get_lock     => 0,
1182                         );
1183 }
1184
1185 sub stripbccs {
1186     my $msg = shift;
1187     my $ret = '';
1188     my $bcc = 0;
1189     while ($msg =~ s/(.*\n)//) {
1190         local $_ = $1;
1191         if (/^$/) {
1192             $ret .= $_;
1193             last;
1194         }
1195         if ($bcc) {
1196             # strip continuation lines too
1197             next if /^\s/;
1198             $bcc = 0;
1199         }
1200         if (/^Bcc:/i) {
1201             $bcc = 1;
1202         } else {
1203             $ret .= $_;
1204         }
1205     }
1206     return $ret . $msg;
1207 }
1208
1209 =head2 send_message
1210
1211      send_message($the_message,\@recipients,\@bcc,$do_not_encode)
1212
1213 The first argument is the scalar message, the second argument is the
1214 arrayref of recipients, the third is the arrayref of Bcc:'ed
1215 recipients.
1216
1217 The final argument turns off header encoding and the addition of the
1218 X-Loop header if true, defaults to false.
1219
1220 =cut
1221
1222
1223 sub sendmessage {
1224     my ($msg,$recips,$bcc,$no_encode) = @_;
1225     if (not defined $recips or (!ref($recips) && $recips eq '')
1226         or @$recips == 0) {
1227         $recips = ['-t'];
1228     }
1229     # This is suboptimal. The right solution is to send headers
1230     # separately from the rest of the message and encode them rather
1231     # than doing this.
1232     $msg = "X-Loop: $gMaintainerEmail\n" . $msg unless $no_encode;
1233     # The original message received is written out in appendlog, so
1234     # before writing out the other messages we've sent out, we need to
1235     # RFC1522 encode the header.
1236     $msg = encode_headers($msg) unless $no_encode;
1237
1238     my $hash = get_hashname($ref);
1239     #save email to the log
1240     my $logfh = IO::File->new(">>db-h/${hash}/${ref}.log") or
1241         die "opening db-h/$hash/${ref}.log: $!";
1242     write_log_records(logfh => $logfh,
1243                       records => {text => stripbccs($msg),
1244                                   type => 'recips',
1245                                   recips => [map {encode_utf8($_)} @{$recips}],
1246                                  },
1247                      );
1248     if (ref($bcc)) {
1249         shift @$recips if $recips->[0] eq '-t';
1250         push @$recips, @$bcc;
1251     }
1252
1253     send_mail_message(message        => $msg,
1254                       # Because we encode the headers above, we do not want to encode them here
1255                       encode_headers => 0,
1256                       recipients     => $recips);
1257 }
1258
1259 =head2 message_body_template
1260
1261      message_body_template('mail/ack',{ref=>'foo'});
1262
1263 Creates a message body using a template
1264
1265 =cut
1266
1267 sub message_body_template{
1268      my ($template,$extra_var) = @_;
1269      $extra_var ||={};
1270      my $body = fill_template($template,$extra_var);
1271      return fill_template('mail/message_body',
1272                           {%{$extra_var},
1273                            body => $body,
1274                           },
1275                          );
1276 }
1277
1278 =head2 fill_template
1279
1280      fill_template('mail/foo',{foo=>'bar'});
1281
1282 Calls fill_in_template with a default set of variables and any extras
1283 added in.
1284
1285 =cut
1286
1287 sub fill_template{
1288      my ($template,$extra_var) = @_;
1289      $extra_var ||={};
1290      my $variables = {config => \%config,
1291                       defined($ref)?(ref    => $ref):(),
1292                       defined($data)?(data  => $data):(),
1293                       refs => [sort
1294                                uniqnum(defined($ref)?($ref):(),
1295                                        map {exists $clonebugs{$_}?$clonebugs{$_}:$_}
1296                                        keys %bug_affected)],
1297                       %{$extra_var},
1298                      };
1299      return fill_in_template(template => $template,
1300                              variables => $variables,
1301                              output_type => 'text',
1302                             );
1303 }
1304
1305
1306 # this shole routine is *bad*; will be changed to use
1307 # Debbugs::Recipients and stuff therin in short order.
1308 sub checkmaintainers {
1309     return if $maintainerschecked++;
1310     return if !length($data->{package});
1311
1312     my $anymaintfound=0; my $anymaintnotfound=0;
1313     for my $p (splitpackages($data->{package})) {
1314         $p =~ y/A-Z/a-z/;
1315         $p =~ /((?:src:)?[a-z0-9.+-]+)/;
1316         $p = $1;
1317         next unless defined $p;
1318         if (defined $config{subscription_domain} and length $config{subscription_domain}) {
1319             my @source = binary_to_source(binary => $p,
1320                                           source_only => 1,
1321                                          );
1322             if (@source) {
1323                 push @addsrcaddrs,
1324                     map {"$_\@$config{subscription_domain}"} @source;
1325             } else {
1326                 push @addsrcaddrs, "$p\@$config{subscription_domain}";
1327             }
1328         }
1329         # this is utter hackery until we switch to Debbugs::Recipients
1330         my @maints = package_maintainer(binary => $p);
1331         if (@maints) {
1332             print {$debugfh} "maintainer add >$p|".join(',',@maints)."<\n";
1333             my %temp;
1334             @temp{@maintaddrs} = @maintaddrs;
1335             push(@maintaddrs,
1336                  grep {$_ ne $replyto and
1337                            not exists $temp{$_}} @maints);
1338             $anymaintfound++;
1339         } else {
1340             print {$debugfh} "maintainer none >$p<\n";
1341             push(@maintaddrs,$gUnknownMaintainerEmail) unless $anymaintnotfound;
1342             $anymaintnotfound++;
1343             last;
1344         }
1345     }
1346
1347     if (defined $data->{owner} and length $data->{owner}) {
1348         print {$debugfh} "owner add >$data->{package}|$data->{owner}<\n";
1349         my $addmaint = $data->{owner};
1350         push(@maintaddrs, $addmaint) unless
1351             $addmaint eq $replyto or grep($_ eq $addmaint, @maintaddrs);
1352     }
1353 }
1354
1355 =head2 bug_list_forward
1356
1357      bug_list_forward($spool_filename) if $codeletter eq 'L';
1358
1359
1360 Given the spool file, will forward a bug to the per bug mailing list
1361 subscription system.
1362
1363 =cut
1364
1365 sub bug_list_forward{
1366      my ($bug_fn) = @_;
1367      # Read the bug information and package information for passing to
1368      # the mailing list
1369      my $bug_fh = IO::File->new("incoming/P$bug_fn",'r') or
1370           die "Unable to open incoming/P$bug_fn $!";
1371
1372      if (not defined $config{bug_subscription_domain} or not
1373          length $config{bug_subscription_domain}) {
1374           unlink("incoming/P$bug_fn") or
1375                die "unlinking incoming/P$bug_fn: $!";
1376           exit 0;
1377      }
1378
1379      my ($bug_number) = $bug_fn =~ /^L(\d+)\./;
1380      my $data = read_bug(bug => $bug_number);
1381
1382      local $/ = undef;
1383      my $bug_message = <$bug_fh>;
1384      my ($bug_address) = $bug_message =~ /^Received: \(at ([^\)]+)\) by/;
1385      my ($envelope_from) = $bug_message =~ s/\nFrom\s+([^\s]+)[^\n]+\n/\n/;
1386      if (not defined $envelope_from) {
1387           # Try to use the From: header or something to set it
1388           ($envelope_from) = $bug_message =~ /\nFrom:\s+(.+?)\n/;
1389           # Kludgy, and should really be using a full scale header
1390           # parser to do this.
1391           $envelope_from =~ s/^.+?<([^>]+)>.+$/$1/;
1392      }
1393      my ($header,$body) = split /\n\n/, $bug_message, 2;
1394      # Add X-$gProject-PR-Message: list bug_number, package name, and bug title headers
1395      $header .= qq(\nX-$gProject-PR-Message: list $bug_number\n).
1396           qq(X-$gProject-PR-Package: $data->{package}\n).
1397                qq(X-$gProject-PR-Title: $data->{subject})
1398                if defined $data;
1399      print STDERR "Tried to loop me with $envelope_from\n"
1400           and exit 1 if $envelope_from =~ /\Q$gListDomain\E|\Q$gEmailDomain\E/;
1401      print {$debugfh} $envelope_from,qq(\n);
1402      # If we don't have a bug address, something has gone horribly wrong.
1403      print STDERR "Doesn't match: $bug_address\n" and exit 1 unless defined $bug_address;
1404      $bug_address =~ s/\@.+//;
1405      print {$debugfh} "Sending message to bugs=$bug_address\@$config{bug_subscription_domain}\n";
1406      print {$debugfh} $header.qq(\n\n).$body;
1407      send_mail_message(message        => $header.qq(\n\n).$body,
1408                        recipients     => ["bugs=$bug_address\@$config{bug_subscription_domain}"],
1409                        envelope_from  => $envelope_from,
1410                        encode_headers => 0,
1411                       );
1412      unlink("incoming/P$bug_fn") || die "unlinking incoming/P$bug_fn: $!";
1413      exit 0;
1414 }