cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2 # This script is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later
   4 # version at your option.
   5 # See the file README and COPYING for more information.
   6 #
   7 # [Other people have contributed to this file; their copyrights should
   8 # go here too.]
   9 # Copyright 2004-2006 by Anthony Towns <ajt@debian.org>
  10 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
  11
  12
  13 use warnings;
  14 use strict;
  15
  16 # Sanitize environent for taint
  17 BEGIN{
  18     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
  19 }
  20
  21 use POSIX qw(strftime nice);
  22
  23 use Debbugs::Config qw(:globals :text :config);
  24
  25 use Debbugs::User;
  26
  27 use Debbugs::Common qw(getparsedaddrs make_list getmaintainers getpseudodesc);
  28
  29 use Debbugs::Bugs qw(get_bugs bug_filter newest_bug);
  30 use Debbugs::Packages qw(getsrcpkgs getpkgsrc get_versions);
  31
  32 use Debbugs::Status qw(splitpackages);
  33
  34 use Debbugs::CGI qw(:all);
  35
  36 use Debbugs::CGI::Pkgreport qw(:all);
  37
  38 use Debbugs::Text qw(:templates);
  39
  40 use CGI::Simple;
  41 my $q = new CGI::Simple;
  42
  43 if ($q->request_method() eq 'HEAD') {
  44      print $q->header(-type => "text/html",
  45                       -charset => 'utf-8',
  46                      );
  47      exit 0;
  48 }
  49
  50 my $default_params = {ordering => 'normal',
  51                       archive  => 0,
  52                       repeatmerged => 0,
  53                       include      => [],
  54                       exclude      => [],
  55                      };
  56
  57 our %param = cgi_parameters(query => $q,
  58                             single => [qw(ordering archive repeatmerged),
  59                                        qw(bug-rev pend-rev sev-rev),
  60                                        qw(maxdays mindays version),
  61                                        qw(data which dist newest),
  62                                        qw(noaffects),
  63                                       ],
  64                             default => $default_params,
  65                            );
  66
  67 my ($form_options,$param) = ({},undef);
  68 ($form_options,$param)= form_options_and_normal_param(\%param)
  69      if $param{form_options};
  70
  71 %param = %{$param} if defined $param;
  72
  73 if (exists $param{form_options} and defined $param{form_options}) {
  74      delete $param{form_options};
  75      delete $param{submit} if exists $param{submit};
  76      for my $default (keys %{$default_params}) {
  77           if (exists $param{$default} and
  78               not ref($default_params->{$default}) and
  79               $default_params->{$default} eq $param{$default}
  80              ) {
  81                delete $param{$default};
  82           }
  83      }
  84      for my $incexc (qw(include exclude)) {
  85           next unless exists $param{$incexc};
  86           # normalize tag to tags
  87           $param{$incexc} = [map {s/^tag:/tags:/; $_} grep /\S\:\S/, make_list($param{$incexc})];
  88      }
  89      for my $key (keys %package_search_keys) {
  90           next unless exists $param{key};
  91           $param{$key} = [map {split /\s*,\s*/} make_list($param{$key})];
  92      }
  93      # kill off keys for which empty values are meaningless
  94      for my $key (qw(package src submitter affects severity status dist)) {
  95           next unless exists $param{$key};
  96           $param{$key} = [grep {defined $_ and length $_}
  97                           make_list($param{$key})];
  98      }
  99      print $q->redirect(munge_url('pkgreport.cgi?',%param));
 100      exit 0;
 101 }
 102
 103 # normalize innclude/exclude keys; currently this is in two locations,
 104 # which is suboptimal. Closes: #567407
 105 for my $incexc (qw(include exclude)) {
 106     next unless exists $param{$incexc};
 107     # normalize tag to tags
 108     $param{$incexc} = [map {s/^tag:/tags:/; $_} make_list($param{$incexc})];
 109 }
 110
 111
 112
 113 # map from yes|no to 1|0
 114 for my $key (qw(repeatmerged bug-rev pend-rev sev-rev)) {
 115      if (exists $param{$key}){
 116           if ($param{$key} =~ /^no$/i) {
 117                $param{$key} = 0;
 118           }
 119           elsif ($param{$key}) {
 120                $param{$key} = 1;
 121           }
 122      }
 123 }
 124
 125 if (lc($param{archive}) eq 'no') {
 126      $param{archive} = 0;
 127 }
 128 elsif (lc($param{archive}) eq 'yes') {
 129      $param{archive} = 1;
 130 }
 131
 132 # fixup dist
 133 if (exists $param{dist} and $param{dist} eq '') {
 134      delete $param{dist};
 135 }
 136
 137 my $include = $param{'&include'} || $param{'include'} || "";
 138 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
 139
 140 my $users = $param{'users'} || "";
 141
 142 my $ordering = $param{'ordering'};
 143 my $raw_sort = ($param{'raw'} || "no") eq "yes";
 144 my $old_view = ($param{'oldview'} || "no") eq "yes";
 145 my $age_sort = ($param{'age'} || "no") eq "yes";
 146 unless (defined $ordering) {
 147    $ordering = "normal";
 148    $ordering = "oldview" if $old_view;
 149    $ordering = "raw" if $raw_sort;
 150    $ordering = 'age' if $age_sort;
 151 }
 152 $param{ordering} = $ordering;
 153
 154 our ($bug_order) = $ordering =~ /(age(?:rev)?)/;
 155 $bug_order = '' if not defined $bug_order;
 156
 157 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
 158 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
 159 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
 160
 161 my @inc_exc_mapping = ({name   => 'pending',
 162                         incexc => 'include',
 163                         key    => 'pend-inc',
 164                        },
 165                        {name   => 'pending',
 166                         incexc => 'exclude',
 167                         key    => 'pend-exc',
 168                        },
 169                        {name   => 'severity',
 170                         incexc => 'include',
 171                         key    => 'sev-inc',
 172                        },
 173                        {name   => 'severity',
 174                         incexc => 'exclude',
 175                         key    => 'sev-exc',
 176                        },
 177                        {name   => 'subject',
 178                         incexc => 'include',
 179                         key    => 'includesubj',
 180                        },
 181                        {name   => 'subject',
 182                         incexc => 'exclude',
 183                         key    => 'excludesubj',
 184                        },
 185                       );
 186 for my $incexcmap (@inc_exc_mapping) {
 187      push @{$param{$incexcmap->{incexc}}}, map {"$incexcmap->{name}:$_"}
 188           map{split /\s*,\s*/} make_list($param{$incexcmap->{key}})
 189                if exists $param{$incexcmap->{key}};
 190      delete $param{$incexcmap->{key}};
 191 }
 192
 193
 194 my $maxdays = ($param{'maxdays'} || -1);
 195 my $mindays = ($param{'mindays'} || 0);
 196 my $version = $param{'version'} || undef;
 197
 198
 199 our %hidden = map { $_, 1 } qw(status severity classification);
 200 our %cats = (
 201     "status" => [ {
 202         "nam" => "Status",
 203         "pri" => [map { "pending=$_" }
 204             qw(pending forwarded pending-fixed fixed done absent)],
 205         "ttl" => ["Outstanding","Forwarded","Pending Upload",
 206                   "Fixed in NMU","Resolved","From other Branch"],
 207         "def" => "Unknown Pending Status",
 208         "ord" => [0,1,2,3,4,5,6],
 209     } ],
 210     "severity" => [ {
 211         "nam" => "Severity",
 212         "pri" => [map { "severity=$_" } @gSeverityList],
 213         "ttl" => [map { $gSeverityDisplay{$_} } @gSeverityList],
 214         "def" => "Unknown Severity",
 215         "ord" => [0..@gSeverityList],
 216     } ],
 217     "classification" => [ {
 218         "nam" => "Classification",
 219         "pri" => [qw(pending=pending+tag=wontfix
 220                      pending=pending+tag=moreinfo
 221                      pending=pending+tag=patch
 222                      pending=pending+tag=confirmed
 223                      pending=pending)],
 224         "ttl" => ["Will Not Fix","More information needed",
 225                   "Patch Available","Confirmed"],
 226         "def" => "Unclassified",
 227         "ord" => [2,3,4,1,0,5],
 228     } ],
 229     "oldview" => [ qw(status severity) ],
 230     "normal" => [ qw(status severity classification) ],
 231 );
 232
 233 if (exists $param{which} and exists $param{data}) {
 234      $param{$param{which}} = [exists $param{$param{which}}?(make_list($param{$param{which}})):(),
 235                               make_list($param{data}),
 236                              ];
 237      delete $param{which};
 238      delete $param{data};
 239 }
 240
 241 if (defined $param{maintenc}) {
 242      $param{maint} = maint_decode($param{maintenc});
 243      delete $param{maintenc}
 244 }
 245
 246 if (exists $param{pkg}) {
 247      $param{package} = $param{pkg};
 248      delete $param{pkg};
 249 }
 250
 251 if (not grep {exists $param{$_}} keys %package_search_keys and exists $param{users}) {
 252      $param{usertag} = [make_list($param{users})];
 253 }
 254
 255 my %bugusertags;
 256 my %ut;
 257 my %seen_users;
 258
 259 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 260     next unless length($user);
 261     add_user($user,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 262 }
 263
 264 if (defined $param{usertag}) {
 265      for my $usertag (make_list($param{usertag})) {
 266           my %select_ut = ();
 267           my ($u, $t) = split /:/, $usertag, 2;
 268           Debbugs::User::read_usertags(\%select_ut, $u);
 269           unless (defined $t && $t ne "") {
 270                $t = join(",", keys(%select_ut));
 271           }
 272           add_user($u,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 273           push @{$param{tag}}, split /,/, $t;
 274      }
 275 }
 276
 277 quitcgi("You have to choose something to select by") unless grep {exists $param{$_}} keys %package_search_keys;
 278
 279
 280 my $Archived = $param{archive} ? " Archived" : "";
 281
 282 my $this = munge_url('pkgreport.cgi?',
 283                       %param,
 284                      );
 285
 286 my %indexentry;
 287 my %strings = ();
 288
 289 my @bugs;
 290
 291 # addusers for source and binary packages being searched for
 292 my $pkgsrc = getpkgsrc();
 293 my $srcpkg = getsrcpkgs();
 294 for my $package (# For binary packages, add the binary package
 295                  # and corresponding source package
 296                  make_list($param{package}||[]),
 297                  (map {defined $pkgsrc->{$_}?($pkgsrc->{$_}):()}
 298                   make_list($param{package}||[]),
 299                  ),
 300                  # For source packages, add the source package
 301                  # and corresponding binary packages
 302                  make_list($param{src}||[]),
 303                  (map {defined $srcpkg->{$_}?($srcpkg->{$_}):()}
 304                   make_list($param{src}||[]),
 305                  ),
 306                 ) {
 307      next unless defined $package;
 308      add_user($package.'@'.$config{usertag_package_domain},
 309               \%ut,\%bugusertags,\%seen_users,\%cats,\%hidden)
 310           if defined $config{usertag_package_domain};
 311 }
 312
 313
 314 # walk through the keys and make the right get_bugs query.
 315
 316 my $form_option_variables = {};
 317 $form_option_variables->{search_key_order} = [@package_search_key_order];
 318
 319 # Set the title sanely and clean up parameters
 320 my @title;
 321 my @temp = @package_search_key_order;
 322 while (my ($key,$value) = splice @temp, 0, 2) {
 323      next unless exists $param{$key};
 324      my @entries = ();
 325      for my $entry (make_list($param{$key})) {
 326           # we'll handle newest below
 327           next if $key eq 'newest';
 328           my $extra = '';
 329           if (exists $param{dist} and ($key eq 'package' or $key eq 'src')) {
 330                my %versions = get_versions(package => $entry,
 331                                            (exists $param{dist}?(dist => $param{dist}):()),
 332                                            (exists $param{arch}?(arch => $param{arch}):(arch => $config{default_architectures})),
 333                                            ($key eq 'src'?(arch => q(source)):()),
 334                                            no_source_arch => 1,
 335                                            return_archs => 1,
 336                                           );
 337                my $verdesc;
 338                if (keys %versions > 1) {
 339                     $verdesc = 'versions '. join(', ',
 340                                     map { $_ .' ['.join(', ',
 341                                                     sort @{$versions{$_}}
 342                                                    ).']';
 343                                    } keys %versions);
 344                }
 345                else {
 346                     $verdesc = 'version '.join(', ',
 347                                                keys %versions
 348                                               );
 349                }
 350                $extra= " ($verdesc)" if keys %versions;
 351           }
 352           if ($key eq 'maint' and $entry eq '') {
 353                push @entries, "no one (packages without maintainers)"
 354           }
 355           else {
 356                push @entries, $entry.$extra;
 357           }
 358      }
 359      push @title,$value.' '.join(' or ', @entries) if @entries;
 360 }
 361 if (defined $param{newest}) {
 362      my $newest_bug = newest_bug();
 363      @bugs = ($newest_bug - $param{newest} + 1) .. $newest_bug;
 364      push @title, 'in '.@bugs.' newest reports';
 365      $param{bugs} = [exists $param{bugs}?make_list($param{bugs}):(),
 366                      @bugs,
 367                     ];
 368 }
 369
 370 my $title = $gBugs.' '.join(' and ', map {/ or /?"($_)":$_} @title);
 371 @title = ();
 372
 373 #yeah for magick!
 374 @bugs = get_bugs((map {exists $param{$_}?($_,$param{$_}):()}
 375                   grep {$_ ne 'newest'}
 376                   keys %package_search_keys, 'archive'),
 377                  usertags => \%ut,
 378                 );
 379
 380 # shove in bugs which affect this package if there is a package or a
 381 # source given (by default), but no affects options given
 382 if (not exists $param{affects} and not exists $param{noaffects} and
 383     (exists $param{src} or
 384      exists $param{package})) {
 385     push @bugs, get_bugs((map {my $key = $_;
 386                                exists $param{$key}?($key =~ /^(?:package|src)$/?'affects':$key,
 387                                                   ($key eq 'src'?[map {"src:$_"}make_list($param{$key})]:$param{$_})):()}
 388                           grep {$_ ne 'newest'}
 389                           keys %package_search_keys, 'archive'),
 390                          usertags => \%ut,
 391                         );
 392 }
 393
 394 # filter out included or excluded bugs
 395
 396
 397 if (defined $param{version}) {
 398      $title .= " at version $param{version}";
 399 }
 400 elsif (defined $param{dist}) {
 401      $title .= " in $param{dist}";
 402 }
 403
 404 $title = html_escape($title);
 405
 406 my @names; my @prior; my @order;
 407 determine_ordering(cats => \%cats,
 408                    param => \%param,
 409                    ordering => \$ordering,
 410                    names => \@names,
 411                    prior => \@prior,
 412                    title => \@title,
 413                    order => \@order,
 414                   );
 415
 416 # strip out duplicate bugs
 417 my %bugs;
 418 @bugs{@bugs} = @bugs;
 419 @bugs = keys %bugs;
 420
 421 my $result = pkg_htmlizebugs(bugs => \@bugs,
 422                              names => \@names,
 423                              title => \@title,
 424                              order => \@order,
 425                              prior => \@prior,
 426                              ordering => $ordering,
 427                              bugusertags => \%bugusertags,
 428                              bug_rev => $bug_rev,
 429                              bug_order => $bug_order,
 430                              repeatmerged => $param{repeatmerged},
 431                              include => $include,
 432                              exclude => $exclude,
 433                              this => $this,
 434                              options => \%param,
 435                              (exists $param{dist})?(dist    => $param{dist}):(),
 436                             );
 437
 438 print "Content-Type: text/html; charset=utf-8\n\n";
 439
 440 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 441 print "<HTML><HEAD>\n" .
 442     "<TITLE>$title -- $gProject$Archived $gBug report logs</TITLE>\n" .
 443     qq(<link rel="stylesheet" href="$gWebHostBugDir/css/bugs.css" type="text/css">) .
 444     "</HEAD>\n" .
 445     '<BODY onload="pagemain();">' .
 446     "\n";
 447 print qq(<DIV id="status_mask"></DIV>\n);
 448 print "<H1>" . "$gProject$Archived $gBug report logs: $title" .
 449       "</H1>\n";
 450
 451 my $showresult = 1;
 452
 453 my $pkg = $param{package} if defined $param{package};
 454 my $src = $param{src} if defined $param{src};
 455
 456 my $pseudodesc = getpseudodesc();
 457 if (defined $pseudodesc and defined $pkg and exists $pseudodesc->{$pkg}) {
 458      delete $param{dist};
 459 }
 460
 461 # output information about the packages
 462
 463 for my $package (make_list($param{package}||[])) {
 464      print generate_package_info(binary => 1,
 465                                  package => $package,
 466                                  options => \%param,
 467                                  bugs    => \@bugs,
 468                                 );
 469 }
 470 for my $package (make_list($param{src}||[])) {
 471      print generate_package_info(binary => 0,
 472                                  package => $package,
 473                                  options => \%param,
 474                                  bugs    => \@bugs,
 475                                 );
 476 }
 477
 478 if (exists $param{maint} or exists $param{maintenc}) {
 479     print "<p>Note that maintainers may use different Maintainer fields for\n";
 480     print "different packages, so there may be other reports filed under\n";
 481     print "different addresses.\n";
 482 }
 483 if (exists $param{submitter}) {
 484     print "<p>Note that people may use different email accounts for\n";
 485     print "different bugs, so there may be other reports filed under\n";
 486     print "different addresses.\n";
 487 }
 488
 489 print $result;
 490
 491 print fill_in_template(template=>'cgi/pkgreport_javascript');
 492
 493 print qq(<h2 class="outstanding"><!--<a class="options" href="javascript:toggle(1)">-->Options<!--</a>--></h2>\n);
 494
 495 print option_form(template => 'cgi/pkgreport_options',
 496                   param    => \%param,
 497                   form_options => $form_options,
 498                   variables => $form_option_variables,
 499                  );
 500
 501 print "<hr>\n";
 502 print fill_in_template(template=>'html/html_tail',
 503                        hole_var => {'&strftime' => \&POSIX::strftime,
 504                                    },
 505                       );
 506 print "</body></html>\n";
 507