cgi/pkgreport.cgi

   1 #!/usr/bin/perl -wT
   2 # This script is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later
   4 # version at your option.
   5 # See the file README and COPYING for more information.
   6 #
   7 # [Other people have contributed to this file; their copyrights should
   8 # go here too.]
   9 # Copyright 2004-2006 by Anthony Towns <ajt@debian.org>
  10 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
  11
  12
  13 use warnings;
  14 use strict;
  15
  16 use POSIX qw(strftime nice);
  17
  18 use Debbugs::Config qw(:globals :text :config);
  19
  20 use Debbugs::User;
  21
  22 use Debbugs::Common qw(getparsedaddrs make_list getmaintainers getpseudodesc);
  23
  24 use Debbugs::Bugs qw(get_bugs bug_filter newest_bug);
  25 use Debbugs::Packages qw(getsrcpkgs getpkgsrc get_versions);
  26
  27 use Debbugs::Status qw(splitpackages);
  28
  29 use Debbugs::CGI qw(:all);
  30
  31 use Debbugs::CGI::Pkgreport qw(:all);
  32
  33 use Debbugs::Text qw(:templates);
  34
  35 use CGI::Simple;
  36 my $q = new CGI::Simple;
  37
  38 if ($q->request_method() eq 'HEAD') {
  39      print $q->header(-type => "text/html",
  40                       -charset => 'utf-8',
  41                      );
  42      exit 0;
  43 }
  44
  45 my $default_params = {ordering => 'normal',
  46                       archive  => 0,
  47                       repeatmerged => 0,
  48                       include      => [],
  49                       exclude      => [],
  50                      };
  51
  52 our %param = cgi_parameters(query => $q,
  53                             single => [qw(ordering archive repeatmerged),
  54                                        qw(bug-rev pend-rev sev-rev),
  55                                        qw(maxdays mindays version),
  56                                        qw(data which dist newest),
  57                                       ],
  58                             default => $default_params,
  59                            );
  60
  61 my ($form_options,$param) = ({},undef);
  62 ($form_options,$param)= form_options_and_normal_param(\%param)
  63      if $param{form_options};
  64
  65 %param = %{$param} if defined $param;
  66
  67 if (exists $param{form_options} and defined $param{form_options}) {
  68      delete $param{form_options};
  69      delete $param{submit} if exists $param{submit};
  70      for my $default (keys %{$default_params}) {
  71           if (exists $param{$default} and
  72               not ref($default_params->{$default}) and
  73               $default_params->{$default} eq $param{$default}
  74              ) {
  75                delete $param{$default};
  76           }
  77      }
  78      for my $incexc (qw(include exclude)) {
  79           next unless exists $param{$incexc};
  80           $param{$incexc} = [grep /\S\:\S/, make_list($param{$incexc})];
  81      }
  82      for my $key (keys %package_search_keys) {
  83           next unless exists $param{key};
  84           $param{$key} = [map {split /\s*,\s*/} make_list($param{$key})];
  85      }
  86      # kill off keys for which empty values are meaningless
  87      for my $key (qw(package src submitter affects severity status dist)) {
  88           next unless exists $param{$key};
  89           $param{$key} = [grep {defined $_ and length $_}
  90                           make_list($param{$key})];
  91      }
  92      print $q->redirect(munge_url('pkgreport.cgi?',%param));
  93      exit 0;
  94 }
  95
  96 # map from yes|no to 1|0
  97 for my $key (qw(repeatmerged bug-rev pend-rev sev-rev)) {
  98      if (exists $param{$key}){
  99           if ($param{$key} =~ /^no$/i) {
 100                $param{$key} = 0;
 101           }
 102           elsif ($param{$key}) {
 103                $param{$key} = 1;
 104           }
 105      }
 106 }
 107
 108 if (lc($param{archive}) eq 'no') {
 109      $param{archive} = 0;
 110 }
 111 elsif (lc($param{archive}) eq 'yes') {
 112      $param{archive} = 1;
 113 }
 114
 115 # fixup dist
 116 if (exists $param{dist} and $param{dist} eq '') {
 117      delete $param{dist};
 118 }
 119
 120 my $include = $param{'&include'} || $param{'include'} || "";
 121 my $exclude = $param{'&exclude'} || $param{'exclude'} || "";
 122
 123 my $users = $param{'users'} || "";
 124
 125 my $ordering = $param{'ordering'};
 126 my $raw_sort = ($param{'raw'} || "no") eq "yes";
 127 my $old_view = ($param{'oldview'} || "no") eq "yes";
 128 my $age_sort = ($param{'age'} || "no") eq "yes";
 129 unless (defined $ordering) {
 130    $ordering = "normal";
 131    $ordering = "oldview" if $old_view;
 132    $ordering = "raw" if $raw_sort;
 133    $ordering = 'age' if $age_sort;
 134 }
 135 $param{ordering} = $ordering;
 136
 137 our ($bug_order) = $ordering =~ /(age(?:rev)?)/;
 138 $bug_order = '' if not defined $bug_order;
 139
 140 my $bug_rev = ($param{'bug-rev'} || "no") eq "yes";
 141 my $pend_rev = ($param{'pend-rev'} || "no") eq "yes";
 142 my $sev_rev = ($param{'sev-rev'} || "no") eq "yes";
 143
 144 my @inc_exc_mapping = ({name   => 'pending',
 145                         incexc => 'include',
 146                         key    => 'pend-inc',
 147                        },
 148                        {name   => 'pending',
 149                         incexc => 'exclude',
 150                         key    => 'pend-exc',
 151                        },
 152                        {name   => 'severity',
 153                         incexc => 'include',
 154                         key    => 'sev-inc',
 155                        },
 156                        {name   => 'severity',
 157                         incexc => 'exclude',
 158                         key    => 'sev-exc',
 159                        },
 160                        {name   => 'subject',
 161                         incexc => 'include',
 162                         key    => 'includesubj',
 163                        },
 164                        {name   => 'subject',
 165                         incexc => 'exclude',
 166                         key    => 'excludesubj',
 167                        },
 168                       );
 169 for my $incexcmap (@inc_exc_mapping) {
 170      push @{$param{$incexcmap->{incexc}}}, map {"$incexcmap->{name}:$_"}
 171           map{split /\s*,\s*/} make_list($param{$incexcmap->{key}})
 172                if exists $param{$incexcmap->{key}};
 173      delete $param{$incexcmap->{key}};
 174 }
 175
 176
 177 my $maxdays = ($param{'maxdays'} || -1);
 178 my $mindays = ($param{'mindays'} || 0);
 179 my $version = $param{'version'} || undef;
 180
 181
 182 our %hidden = map { $_, 1 } qw(status severity classification);
 183 our %cats = (
 184     "status" => [ {
 185         "nam" => "Status",
 186         "pri" => [map { "pending=$_" }
 187             qw(pending forwarded pending-fixed fixed done absent)],
 188         "ttl" => ["Outstanding","Forwarded","Pending Upload",
 189                   "Fixed in NMU","Resolved","From other Branch"],
 190         "def" => "Unknown Pending Status",
 191         "ord" => [0,1,2,3,4,5,6],
 192     } ],
 193     "severity" => [ {
 194         "nam" => "Severity",
 195         "pri" => [map { "severity=$_" } @gSeverityList],
 196         "ttl" => [map { $gSeverityDisplay{$_} } @gSeverityList],
 197         "def" => "Unknown Severity",
 198         "ord" => [0..@gSeverityList],
 199     } ],
 200     "classification" => [ {
 201         "nam" => "Classification",
 202         "pri" => [qw(pending=pending+tag=wontfix
 203                      pending=pending+tag=moreinfo
 204                      pending=pending+tag=patch
 205                      pending=pending+tag=confirmed
 206                      pending=pending)],
 207         "ttl" => ["Will Not Fix","More information needed",
 208                   "Patch Available","Confirmed"],
 209         "def" => "Unclassified",
 210         "ord" => [2,3,4,1,0,5],
 211     } ],
 212     "oldview" => [ qw(status severity) ],
 213     "normal" => [ qw(status severity classification) ],
 214 );
 215
 216 if (exists $param{which} and exists $param{data}) {
 217      $param{$param{which}} = [exists $param{$param{which}}?(make_list($param{$param{which}})):(),
 218                               make_list($param{data}),
 219                              ];
 220      delete $param{which};
 221      delete $param{data};
 222 }
 223
 224 if (defined $param{maintenc}) {
 225      $param{maint} = maint_decode($param{maintenc});
 226      delete $param{maintenc}
 227 }
 228
 229 if (exists $param{pkg}) {
 230      $param{package} = $param{pkg};
 231      delete $param{pkg};
 232 }
 233
 234 if (not grep {exists $param{$_}} keys %package_search_keys and exists $param{users}) {
 235      $param{usertag} = [make_list($param{users})];
 236 }
 237
 238 my %bugusertags;
 239 my %ut;
 240 my %seen_users;
 241
 242 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 243     next unless length($user);
 244     add_user($user,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 245 }
 246
 247 if (defined $param{usertag}) {
 248      for my $usertag (make_list($param{usertag})) {
 249           my %select_ut = ();
 250           my ($u, $t) = split /:/, $usertag, 2;
 251           Debbugs::User::read_usertags(\%select_ut, $u);
 252           unless (defined $t && $t ne "") {
 253                $t = join(",", keys(%select_ut));
 254           }
 255           add_user($u,\%ut,\%bugusertags,\%seen_users,\%cats,\%hidden);
 256           push @{$param{tag}}, split /,/, $t;
 257      }
 258 }
 259
 260 quitcgi("You have to choose something to select by") unless grep {exists $param{$_}} keys %package_search_keys;
 261
 262
 263 my $Archived = $param{archive} ? " Archived" : "";
 264
 265 my $this = munge_url('pkgreport.cgi?',
 266                       %param,
 267                      );
 268
 269 my %indexentry;
 270 my %strings = ();
 271
 272 my @bugs;
 273
 274 # addusers for source and binary packages being searched for
 275 my $pkgsrc = getpkgsrc();
 276 my $srcpkg = getsrcpkgs();
 277 for my $package (# For binary packages, add the binary package
 278                  # and corresponding source package
 279                  make_list($param{package}||[]),
 280                  (map {defined $pkgsrc->{$_}?($pkgsrc->{$_}):()}
 281                   make_list($param{package}||[]),
 282                  ),
 283                  # For source packages, add the source package
 284                  # and corresponding binary packages
 285                  make_list($param{src}||[]),
 286                  (map {defined $srcpkg->{$_}?($srcpkg->{$_}):()}
 287                   make_list($param{src}||[]),
 288                  ),
 289                 ) {
 290      next unless defined $package;
 291      add_user($package.'@'.$config{usertag_package_domain},
 292               \%ut,\%bugusertags,\%seen_users,\%cats,\%hidden)
 293           if defined $config{usertag_package_domain};
 294 }
 295
 296
 297 # walk through the keys and make the right get_bugs query.
 298
 299 my $form_option_variables = {};
 300 $form_option_variables->{search_key_order} = [@package_search_key_order];
 301
 302 # Set the title sanely and clean up parameters
 303 my @title;
 304 my @temp = @package_search_key_order;
 305 while (my ($key,$value) = splice @temp, 0, 2) {
 306      next unless exists $param{$key};
 307      my @entries = ();
 308      for my $entry (make_list($param{$key})) {
 309           # we'll handle newest below
 310           next if $key eq 'newest';
 311           my $extra = '';
 312           if (exists $param{dist} and ($key eq 'package' or $key eq 'src')) {
 313                my %versions = get_versions(package => $entry,
 314                                            (exists $param{dist}?(dist => $param{dist}):()),
 315                                            (exists $param{arch}?(arch => $param{arch}):(arch => $config{default_architectures})),
 316                                            ($key eq 'src'?(arch => q(source)):()),
 317                                            no_source_arch => 1,
 318                                            return_archs => 1,
 319                                           );
 320                my $verdesc;
 321                if (keys %versions > 1) {
 322                     $verdesc = 'versions '. join(', ',
 323                                     map { $_ .' ['.join(', ',
 324                                                     sort @{$versions{$_}}
 325                                                    ).']';
 326                                    } keys %versions);
 327                }
 328                else {
 329                     $verdesc = 'version '.join(', ',
 330                                                keys %versions
 331                                               );
 332                }
 333                $extra= " ($verdesc)" if keys %versions;
 334           }
 335           if ($key eq 'maint' and $entry eq '') {
 336                push @entries, "no one (packages without maintainers)"
 337           }
 338           else {
 339                push @entries, $entry.$extra;
 340           }
 341      }
 342      push @title,$value.' '.join(' or ', @entries) if @entries;
 343 }
 344 if (defined $param{newest}) {
 345      my $newest_bug = newest_bug();
 346      @bugs = ($newest_bug - $param{newest} + 1) .. $newest_bug;
 347      push @title, 'in '.@bugs.' newest reports';
 348      $param{bugs} = [exists $param{bugs}?make_list($param{bugs}):(),
 349                      @bugs,
 350                     ];
 351 }
 352
 353 my $title = $gBugs.' '.join(' and ', map {/ or /?"($_)":$_} @title);
 354 @title = ();
 355
 356 #yeah for magick!
 357 @bugs = get_bugs((map {exists $param{$_}?($_,$param{$_}):()}
 358                   grep {$_ ne 'newest'}
 359                   keys %package_search_keys, 'archive'),
 360                  usertags => \%ut,
 361                 );
 362
 363 # shove in bugs which affect this package if there is a package or a
 364 # source given (by default), but no affects options given
 365 if (not exists $param{affects} and not exists $param{noaffects} and
 366     (exists $param{src} or
 367      exists $param{package})) {
 368     push @bugs, get_bugs((map {my $key = $_;
 369                                exists $param{$key}?($key =~ /^(?:package|src)$/?'affects':$key,
 370                                                   ($key eq 'src'?[map {"src:$_"}make_list($param{$key})]:$param{$_})):()}
 371                           grep {$_ ne 'newest'}
 372                           keys %package_search_keys, 'archive'),
 373                          usertags => \%ut,
 374                         );
 375 }
 376
 377 # filter out included or excluded bugs
 378
 379
 380 if (defined $param{version}) {
 381      $title .= " at version $param{version}";
 382 }
 383 elsif (defined $param{dist}) {
 384      $title .= " in $param{dist}";
 385 }
 386
 387 $title = html_escape($title);
 388
 389 my @names; my @prior; my @order;
 390 determine_ordering(cats => \%cats,
 391                    param => \%param,
 392                    ordering => \$ordering,
 393                    names => \@names,
 394                    prior => \@prior,
 395                    title => \@title,
 396                    order => \@order,
 397                   );
 398
 399 # strip out duplicate bugs
 400 my %bugs;
 401 @bugs{@bugs} = @bugs;
 402 @bugs = keys %bugs;
 403
 404 my $result = pkg_htmlizebugs(bugs => \@bugs,
 405                              names => \@names,
 406                              title => \@title,
 407                              order => \@order,
 408                              prior => \@prior,
 409                              ordering => $ordering,
 410                              bugusertags => \%bugusertags,
 411                              bug_rev => $bug_rev,
 412                              bug_order => $bug_order,
 413                              repeatmerged => $param{repeatmerged},
 414                              include => $include,
 415                              exclude => $exclude,
 416                              this => $this,
 417                              options => \%param,
 418                              (exists $param{dist})?(dist    => $param{dist}):(),
 419                             );
 420
 421 print "Content-Type: text/html; charset=utf-8\n\n";
 422
 423 print "<!DOCTYPE HTML PUBLIC \"-//W3C//DTD HTML 4.01 Transitional//EN\">\n";
 424 print "<HTML><HEAD>\n" .
 425     "<TITLE>$title -- $gProject$Archived $gBug report logs</TITLE>\n" .
 426     qq(<link rel="stylesheet" href="$gWebHostBugDir/css/bugs.css" type="text/css">) .
 427     "</HEAD>\n" .
 428     '<BODY onload="pagemain();">' .
 429     "\n";
 430 print qq(<DIV id="status_mask"></DIV>\n);
 431 print "<H1>" . "$gProject$Archived $gBug report logs: $title" .
 432       "</H1>\n";
 433
 434 my $showresult = 1;
 435
 436 my $pkg = $param{package} if defined $param{package};
 437 my $src = $param{src} if defined $param{src};
 438
 439 my $pseudodesc = getpseudodesc();
 440 if (defined $pseudodesc and defined $pkg and exists $pseudodesc->{$pkg}) {
 441      delete $param{dist};
 442 }
 443
 444 # output information about the packages
 445
 446 for my $package (make_list($param{package}||[])) {
 447      print generate_package_info(binary => 1,
 448                                  package => $package,
 449                                  options => \%param,
 450                                  bugs    => \@bugs,
 451                                 );
 452 }
 453 for my $package (make_list($param{src}||[])) {
 454      print generate_package_info(binary => 0,
 455                                  package => $package,
 456                                  options => \%param,
 457                                  bugs    => \@bugs,
 458                                 );
 459 }
 460
 461 if (exists $param{maint} or exists $param{maintenc}) {
 462     print "<p>Note that maintainers may use different Maintainer fields for\n";
 463     print "different packages, so there may be other reports filed under\n";
 464     print "different addresses.\n";
 465 }
 466 if (exists $param{submitter}) {
 467     print "<p>Note that people may use different email accounts for\n";
 468     print "different bugs, so there may be other reports filed under\n";
 469     print "different addresses.\n";
 470 }
 471
 472 print $result;
 473
 474 print fill_in_template(template=>'cgi/pkgreport_javascript');
 475
 476 print qq(<h2 class="outstanding"><!--<a class="options" href="javascript:toggle(1)">-->Options<!--</a>--></h2>\n);
 477
 478 print option_form(template => 'cgi/pkgreport_options',
 479                   param    => \%param,
 480                   form_options => $form_options,
 481                   variables => $form_option_variables,
 482                  );
 483
 484 print "<hr>\n";
 485 print fill_in_template(template=>'html/html_tail',
 486                        hole_var => {'&strftime' => \&POSIX::strftime,
 487                                    },
 488                       );
 489 print "</body></html>\n";
 490