cgi/bugreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 use warnings;
   4 use strict;
   5
   6 use POSIX qw(strftime);
   7 use MIME::Parser;
   8 use MIME::Decoder;
   9 use IO::Scalar;
  10 use IO::File;
  11
  12 use Debbugs::Config qw(:globals :text);
  13
  14 # for read_log_records
  15 use Debbugs::Log qw(read_log_records);
  16 use Debbugs::CGI qw(:url :html :util);
  17 use Debbugs::CGI::Bugreport qw(:all);
  18 use Debbugs::Common qw(buglog getmaintainers make_list bug_status);
  19 use Debbugs::Packages qw(getpkgsrc);
  20 use Debbugs::Status qw(splitpackages get_bug_status isstrongseverity);
  21
  22 use Scalar::Util qw(looks_like_number);
  23
  24 use Debbugs::Text qw(:templates);
  25
  26 use List::Util qw(max);
  27
  28
  29 use CGI::Simple;
  30 my $q = new CGI::Simple;
  31
  32 my %param = cgi_parameters(query => $q,
  33                            single => [qw(bug msg att boring terse),
  34                                       qw(reverse mbox mime trim),
  35                                       qw(mboxstat mboxmaint archive),
  36                                       qw(repeatmerged)
  37                                      ],
  38                            default => {# msg       => '',
  39                                        boring    => 'no',
  40                                        terse     => 'no',
  41                                        reverse   => 'no',
  42                                        mbox      => 'no',
  43                                        mime      => 'no',
  44                                        mboxstat  => 'no',
  45                                        mboxmaint => 'no',
  46                                        archive   => 'no',
  47                                        repeatmerged => 'yes',
  48                                       },
  49                           );
  50 # This is craptacular.
  51
  52 my $ref = $param{bug} or quitcgi("No bug number");
  53 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  54 $ref = $1;
  55 my $short = "#$ref";
  56 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  57 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  58 my $boring = $param{'boring'} eq 'yes';
  59 my $terse = $param{'terse'} eq 'yes';
  60 my $reverse = $param{'reverse'} eq 'yes';
  61 my $mbox = $param{'mbox'} eq 'yes';
  62 my $mime = $param{'mime'} eq 'yes';
  63
  64 my %bugusertags;
  65 my %ut;
  66 my %seen_users;
  67
  68 my $buglog = buglog($ref);
  69 my $bug_status = bug_status($ref);
  70 if (not defined $buglog or not defined $bug_status) {
  71      print $q->header(-status => "404 No such bug",
  72                       -type => "text/html",
  73                       -charset => 'utf-8',
  74                      );
  75      print fill_in_template(template=>'cgi/no_such_bug',
  76                             variables => {modify_time => strftime('%a, %e %b %Y %T UTC', gmtime),
  77                                           bug_num     => $ref,
  78                                          },
  79                            );
  80      exit 0;
  81 }
  82
  83 # the log should almost always be newer, but just in case
  84 my $log_mtime = +(stat $buglog)[9] || time;
  85 my $status_mtime = +(stat $bug_status)[9] || time;
  86 my $mtime = strftime '%a, %d %b %Y %T GMT', gmtime(max($status_mtime,$log_mtime));
  87
  88 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
  89      print $q->header(-type => "text/html",
  90                       -charset => 'utf-8',
  91                       (length $mtime)?(-last_modified => $mtime):(),
  92                      );
  93      exit 0;
  94 }
  95
  96 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
  97     next unless length($user);
  98     add_user($user,\%ut,\%bugusertags,\%seen_users);
  99 }
 100
 101 if (defined $param{usertag}) {
 102      for my $usertag (make_list($param{usertag})) {
 103           my %select_ut = ();
 104           my ($u, $t) = split /:/, $usertag, 2;
 105           Debbugs::User::read_usertags(\%select_ut, $u);
 106           unless (defined $t && $t ne "") {
 107                $t = join(",", keys(%select_ut));
 108           }
 109           add_user($u,\%ut,\%bugusertags,\%seen_users);
 110           push @{$param{tag}}, split /,/, $t;
 111      }
 112 }
 113
 114
 115 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
 116
 117 my $mbox_status_message = $param{mboxstat} eq 'yes';
 118 my $mbox_maint = $param{mboxmaint} eq 'yes';
 119 $mbox = 1 if $mbox_status_message or $mbox_maint;
 120
 121
 122 # Not used by this script directly, but fetch these so that pkgurl() and
 123 # friends can propagate them correctly.
 124 my $archive = $param{'archive'} eq 'yes';
 125 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
 126
 127
 128
 129 my $buglogfh;
 130 if ($buglog =~ m/\.gz$/) {
 131     my $oldpath = $ENV{'PATH'};
 132     $ENV{'PATH'} = '/bin:/usr/bin';
 133     $buglogfh = IO::File->new("zcat $buglog |") or quitcgi("open log for $ref: $!");
 134     $ENV{'PATH'} = $oldpath;
 135 } else {
 136     $buglogfh = IO::File->new($buglog,'r') or quitcgi("open log for $ref: $!");
 137 }
 138
 139
 140 my %status = %{get_bug_status(bug=>$ref,
 141                               bugusertags => \%bugusertags,
 142                              )};
 143
 144 my @records;
 145 eval{
 146      @records = read_log_records($buglogfh);
 147 };
 148 if ($@) {
 149      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 150 }
 151 undef $buglogfh;
 152
 153
 154 my $log='';
 155 my $msg_num = 0;
 156 my $skip_next = 0;
 157 if (defined($msg) and ($msg-1) <= $#records) {
 158      @records = ($records[$msg-1]);
 159      $msg_num = $msg - 1;
 160 }
 161 my @log;
 162 if ( $mbox ) {
 163      my $date = strftime "%a %b %d %T %Y", localtime;
 164      if (@records > 1) {
 165          print $q->header(-type => "text/plain",
 166                           content_disposition => qq(attachment; filename="bug_${ref}.mbox"),
 167                           (length $mtime)?(-last_modified => $mtime):(),
 168                          );
 169      }
 170      else {
 171           $msg_num++;
 172           print $q->header(-type => "message/rfc822",
 173                            content_disposition => qq(attachment; filename="bug_${ref}_message_${msg_num}.mbox"),
 174                            (length $mtime)?(-last_modified => $mtime):(),
 175                           );
 176      }
 177      if ($mbox_status_message and @records > 1) {
 178           my $status_message='';
 179           my @status_fields = (retitle   => 'subject',
 180                                package   => 'package',
 181                                submitter => 'originator',
 182                                severity  => 'severity',
 183                                tag       => 'tags',
 184                                owner     => 'owner',
 185                                blocks    => 'blocks',
 186                                forward   => 'forward',
 187                               );
 188           my ($key,$value);
 189           while (($key,$value) = splice(@status_fields,0,2)) {
 190                if (defined $status{$value} and length $status{$value}) {
 191                     $status_message .= qq($key $ref $status{$value}\n);
 192                }
 193           }
 194           print STDOUT qq(From unknown $date\n),
 195                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 196                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 197                                     Subject    => "Status: $status{subject}",
 198                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 199                                    ],
 200                                    <<END,);
 201 $status_message
 202 thanks
 203
 204
 205 END
 206      }
 207      my $message_number=0;
 208      my %seen_message_ids;
 209      for my $record (@records) {
 210           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 211           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 212           # we want to include control messages anyway
 213           my $record_wanted_anyway = 0;
 214           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 215           next if exists $seen_message_ids{$msg_id};
 216           next if $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 217           $record_wanted_anyway = 1 if $record->{text} =~ /^Received: \(at control\)/;
 218           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 219           $seen_message_ids{$msg_id} = 1;
 220           my @lines = split( "\n", $record->{text}, -1 );
 221           if ( $lines[ 1 ] =~ m/^From / ) {
 222                my $tmp = $lines[ 0 ];
 223                $lines[ 0 ] = $lines[ 1 ];
 224                $lines[ 1 ] = $tmp;
 225           }
 226           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 227                unshift @lines, "From unknown $date";
 228           }
 229           map { s/^(>*From )/>$1/ } @lines[ 1 .. $#lines ];
 230           print join( "\n", @lines ) . "\n";
 231      }
 232      exit 0;
 233 }
 234
 235 else {
 236      if (defined $att and defined $msg and @records) {
 237           $msg_num++;
 238           print handle_email_message($records[0]->{text},
 239                                      ref => $ref,
 240                                      msg_num => $msg_num,
 241                                      att => $att,
 242                                      msg => $msg,
 243                                      trim_headers => $trim_headers,
 244                                     );
 245           exit 0;
 246      }
 247      my %seen_msg_ids;
 248      for my $record (@records) {
 249           $msg_num++;
 250           if ($skip_next) {
 251                $skip_next = 0;
 252                next;
 253           }
 254           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 255           push @log, handle_record($record,$ref,$msg_num,\%seen_msg_ids);
 256      }
 257 }
 258
 259 @log = reverse @log if $reverse;
 260 $log = join("\n",@log);
 261
 262
 263 # All of the below should be turned into a template
 264
 265 my %maintainer = %{getmaintainers()};
 266 my %pkgsrc = %{getpkgsrc()};
 267
 268 my $indexentry;
 269 my $showseverity;
 270
 271 my $tpack;
 272 my $tmain;
 273
 274 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 275
 276 unless (%status) {
 277     print $q->header(-type => "text/html",
 278                      -charset => 'utf-8',
 279                      (length $mtime)?(-last_modified => $mtime):(),
 280                     );
 281     print fill_in_template(template=>'cgi/no_such_bug',
 282                            variables => {modify_time => $dtime,
 283                                          bug_num     => $ref,
 284                                         },
 285                           );
 286     exit 0;
 287 }
 288
 289 #$|=1;
 290
 291 my %package;
 292 my @packages = splitpackages($status{package});
 293
 294 foreach my $pkg (@packages) {
 295      if ($pkg =~ /^src\:/) {
 296           my ($srcpkg) = $pkg =~ /^src:(.*)/;
 297           $package{$pkg} = {maintainer => exists($maintainer{$srcpkg}) ? $maintainer{$srcpkg} : '(unknown)',
 298                             source     => $srcpkg,
 299                             package    => $pkg,
 300                             is_source  => 1,
 301                            };
 302      }
 303      else {
 304           $package{$pkg} = {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 305                             exists($pkgsrc{$pkg}) ? (source => $pkgsrc{$pkg}) : (),
 306                             package    => $pkg,
 307                            };
 308      }
 309 }
 310
 311 # fixup various bits of the status
 312 $status{tags_array} = [sort(split(/\s+/, $status{tags}))];
 313 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 314 $status{mergedwith_array} = [split(/ /,$status{mergedwith})];
 315
 316
 317 my $version_graph = '';
 318 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 319      $version_graph = q(<a href=").
 320           html_escape(version_url(package => $status{package},
 321                                   found => $status{found_versions},
 322                                   fixed => $status{fixed_versions},
 323                                  )
 324                      ).
 325           q("><img alt="version graph" src=").
 326           html_escape(version_url(package => $status{package},
 327                                   found => $status{found_versions},
 328                                   fixed => $status{fixed_versions},
 329                                   width => 2,
 330                                   height => 2,
 331                                  )
 332                      ).
 333           qq{"></a>};
 334 }
 335
 336
 337
 338 my @blockedby= split(/ /, $status{blockedby});
 339 $status{blockedby_array} = [];
 340 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 341     for my $b (@blockedby) {
 342         my %s = %{get_bug_status($b)};
 343         next if $s{"pending"} eq 'fixed' || length $s{done};
 344         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 345    }
 346 }
 347
 348 my @blocks= split(/ /, $status{blocks});
 349 $status{blocks_array} = [];
 350 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 351     for my $b (@blocks) {
 352         my %s = %{get_bug_status($b)};
 353         next if $s{"pending"} eq 'fixed' || length $s{done};
 354         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 355     }
 356 }
 357
 358 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 359      $status{archived} = 1;
 360 }
 361
 362 my $descriptivehead = $indexentry;
 363
 364 print $q->header(-type => "text/html",
 365                  -charset => 'utf-8',
 366                  (length $mtime)?(-last_modified => $mtime):(),
 367                 );
 368
 369 print fill_in_template(template => 'cgi/bugreport',
 370                        variables => {status => \%status,
 371                                      package => \%package,
 372                                      log           => $log,
 373                                      bug_num       => $ref,
 374                                      version_graph => $version_graph,
 375                                      msg           => $msg,
 376                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 377                                      html_escape   => \&Debbugs::CGI::html_escape,
 378                                      looks_like_number => \&Scalar::Util::looks_like_number,
 379                                     },
 380                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 381                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 382                                      '&version_url'   => \&Debbugs::CGI::version_url,
 383                                      '&bug_url'       => \&Debbugs::CGI::bug_url,
 384                                      '&strftime'      => \&POSIX::strftime,
 385                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 386                                     },
 387                       );