cgi/bugreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 use warnings;
   4 use strict;
   5
   6 use POSIX qw(strftime);
   7 use MIME::Parser;
   8 use MIME::Decoder;
   9 use IO::Scalar;
  10 use IO::File;
  11
  12 use Debbugs::Config qw(:globals :text);
  13
  14 # for read_log_records
  15 use Debbugs::Log qw(read_log_records);
  16 use Debbugs::CGI qw(:url :html :util);
  17 use Debbugs::CGI::Bugreport qw(:all);
  18 use Debbugs::Common qw(buglog getmaintainers make_list);
  19 use Debbugs::Packages qw(getpkgsrc);
  20 use Debbugs::Status qw(splitpackages get_bug_status isstrongseverity);
  21
  22 use Scalar::Util qw(looks_like_number);
  23
  24 use Debbugs::Text qw(:templates);
  25
  26
  27 use CGI::Simple;
  28 my $q = new CGI::Simple;
  29
  30 my %param = cgi_parameters(query => $q,
  31                            single => [qw(bug msg att boring terse),
  32                                       qw(reverse mbox mime trim),
  33                                       qw(mboxstat mboxmaint archive),
  34                                       qw(repeatmerged)
  35                                      ],
  36                            default => {# msg       => '',
  37                                        boring    => 'no',
  38                                        terse     => 'no',
  39                                        reverse   => 'no',
  40                                        mbox      => 'no',
  41                                        mime      => 'no',
  42                                        mboxstat  => 'no',
  43                                        mboxmaint => 'no',
  44                                        archive   => 'no',
  45                                        repeatmerged => 'yes',
  46                                       },
  47                           );
  48 # This is craptacular.
  49
  50 my $ref = $param{bug} or quitcgi("No bug number");
  51 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  52 $ref = $1;
  53 my $short = "#$ref";
  54 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  55 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  56 my $boring = $param{'boring'} eq 'yes';
  57 my $terse = $param{'terse'} eq 'yes';
  58 my $reverse = $param{'reverse'} eq 'yes';
  59 my $mbox = $param{'mbox'} eq 'yes';
  60 my $mime = $param{'mime'} eq 'yes';
  61
  62 my %bugusertags;
  63 my %ut;
  64 my %seen_users;
  65
  66 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
  67     next unless length($user);
  68     add_user($user,\%ut,\%bugusertags,\%seen_users);
  69 }
  70
  71 if (defined $param{usertag}) {
  72      for my $usertag (make_list($param{usertag})) {
  73           my %select_ut = ();
  74           my ($u, $t) = split /:/, $usertag, 2;
  75           Debbugs::User::read_usertags(\%select_ut, $u);
  76           unless (defined $t && $t ne "") {
  77                $t = join(",", keys(%select_ut));
  78           }
  79           add_user($u,\%ut,\%bugusertags,\%seen_users);
  80           push @{$param{tag}}, split /,/, $t;
  81      }
  82 }
  83
  84
  85 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
  86
  87 my $mbox_status_message = $param{mboxstat} eq 'yes';
  88 my $mbox_maint = $param{mboxmaint} eq 'yes';
  89 $mbox = 1 if $mbox_status_message or $mbox_maint;
  90
  91
  92 # Not used by this script directly, but fetch these so that pkgurl() and
  93 # friends can propagate them correctly.
  94 my $archive = $param{'archive'} eq 'yes';
  95 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
  96
  97 my $buglog = buglog($ref);
  98 if (not defined $buglog) {
  99      print $q->header(-status => "404 No such bug",
 100                       -type => "text/html",
 101                       -charset => 'utf-8',
 102                      );
 103      print fill_in_template(template=>'cgi/no_such_bug',
 104                             variables => {modify_time => strftime('%a, %e %b %Y %T UTC', gmtime),
 105                                           bug_num     => $ref,
 106                                          },
 107                            );
 108      exit 0;
 109 }
 110
 111 my @stat = stat $buglog;
 112 my $mtime = '';
 113 if (@stat) {
 114      $mtime = strftime '%a, %d %b %Y %T GMT', gmtime($stat[9]);
 115 }
 116
 117 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
 118      print $q->header(-type => "text/html",
 119                       -charset => 'utf-8',
 120                       (length $mtime)?(-last_modified => $mtime):(),
 121                      );
 122      exit 0;
 123 }
 124
 125
 126 my $buglogfh;
 127 if ($buglog =~ m/\.gz$/) {
 128     my $oldpath = $ENV{'PATH'};
 129     $ENV{'PATH'} = '/bin:/usr/bin';
 130     $buglogfh = IO::File->new("zcat $buglog |") or quitcgi("open log for $ref: $!");
 131     $ENV{'PATH'} = $oldpath;
 132 } else {
 133     $buglogfh = IO::File->new($buglog,'r') or quitcgi("open log for $ref: $!");
 134 }
 135
 136
 137 my %status = %{get_bug_status(bug=>$ref,
 138                               bugusertags => \%bugusertags,
 139                              )};
 140
 141 my @records;
 142 eval{
 143      @records = read_log_records($buglogfh);
 144 };
 145 if ($@) {
 146      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 147 }
 148 undef $buglogfh;
 149
 150
 151 my $log='';
 152 my $msg_num = 0;
 153 my $skip_next = 0;
 154 if (defined($msg) and ($msg-1) <= $#records) {
 155      @records = ($records[$msg-1]);
 156      $msg_num = $msg - 1;
 157 }
 158 my @log;
 159 if ( $mbox ) {
 160      my $date = strftime "%a %b %d %T %Y", localtime;
 161      if (@records > 1) {
 162          print $q->header(-type => "text/plain",
 163                           content_disposition => qq(attachment; filename="bug_${ref}.mbox"),
 164                           (length $mtime)?(-last_modified => $mtime):(),
 165                          );
 166      }
 167      else {
 168           $msg_num++;
 169           print $q->header(-type => "message/rfc822",
 170                            content_disposition => qq(attachment; filename="bug_${ref}_message_${msg_num}.mbox"),
 171                            (length $mtime)?(-last_modified => $mtime):(),
 172                           );
 173      }
 174      if ($mbox_status_message and @records > 1) {
 175           my $status_message='';
 176           my @status_fields = (retitle   => 'subject',
 177                                package   => 'package',
 178                                submitter => 'originator',
 179                                severity  => 'severity',
 180                                tag       => 'tags',
 181                                owner     => 'owner',
 182                                blocks    => 'blocks',
 183                                forward   => 'forward',
 184                               );
 185           my ($key,$value);
 186           while (($key,$value) = splice(@status_fields,0,2)) {
 187                if (defined $status{$value} and length $status{$value}) {
 188                     $status_message .= qq($key $ref $status{$value}\n);
 189                }
 190           }
 191           print STDOUT qq(From unknown $date\n),
 192                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 193                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 194                                     Subject    => "Status: $status{subject}",
 195                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 196                                    ],
 197                                    <<END,);
 198 $status_message
 199 thanks
 200
 201
 202 END
 203      }
 204      my $message_number=0;
 205      my %seen_message_ids;
 206      for my $record (@records) {
 207           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 208           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 209           # we want to include control messages anyway
 210           my $record_wanted_anyway = 0;
 211           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 212           next if exists $seen_message_ids{$msg_id};
 213           next if $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 214           $record_wanted_anyway = 1 if $record->{text} =~ /^Received: \(at control\)/;
 215           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 216           $seen_message_ids{$msg_id} = 1;
 217           my @lines = split( "\n", $record->{text}, -1 );
 218           if ( $lines[ 1 ] =~ m/^From / ) {
 219                my $tmp = $lines[ 0 ];
 220                $lines[ 0 ] = $lines[ 1 ];
 221                $lines[ 1 ] = $tmp;
 222           }
 223           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 224                unshift @lines, "From unknown $date";
 225           }
 226           map { s/^(>*From )/>$1/ } @lines[ 1 .. $#lines ];
 227           print join( "\n", @lines ) . "\n";
 228      }
 229      exit 0;
 230 }
 231
 232 else {
 233      if (defined $att and defined $msg and @records) {
 234           $msg_num++;
 235           print handle_email_message($records[0]->{text},
 236                                      ref => $ref,
 237                                      msg_num => $msg_num,
 238                                      att => $att,
 239                                      msg => $msg,
 240                                     );
 241           exit 0;
 242      }
 243      my %seen_msg_ids;
 244      for my $record (@records) {
 245           $msg_num++;
 246           if ($skip_next) {
 247                $skip_next = 0;
 248                next;
 249           }
 250           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 251           push @log, handle_record($record,$ref,$msg_num,\%seen_msg_ids);
 252      }
 253 }
 254
 255 @log = reverse @log if $reverse;
 256 $log = join("\n",@log);
 257
 258
 259 # All of the below should be turned into a template
 260
 261 my %maintainer = %{getmaintainers()};
 262 my %pkgsrc = %{getpkgsrc()};
 263
 264 my $indexentry;
 265 my $showseverity;
 266
 267 my $tpack;
 268 my $tmain;
 269
 270 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 271
 272 unless (%status) {
 273     print $q->header(-type => "text/html",
 274                      -charset => 'utf-8',
 275                      (length $mtime)?(-last_modified => $mtime):(),
 276                     );
 277     print fill_in_template(template=>'cgi/no_such_bug',
 278                            variables => {modify_time => $dtime,
 279                                          bug_num     => $ref,
 280                                         },
 281                           );
 282     exit 0;
 283 }
 284
 285 #$|=1;
 286
 287 my %package;
 288 my @packages = splitpackages($status{package});
 289
 290 foreach my $pkg (@packages) {
 291      $package{$pkg} = {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 292                        exists($pkgsrc{$pkg}) ? (source => $pkgsrc{$pkg}) : (),
 293                        package    => $pkg,
 294                       };
 295 }
 296
 297 # fixup various bits of the status
 298 $status{tags_array} = [sort(split(/\s+/, $status{tags}))];
 299 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 300 $status{mergedwith_array} = [split(/ /,$status{mergedwith})];
 301
 302
 303 my $version_graph = '';
 304 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 305      $version_graph = q(<a href=").
 306           html_escape(version_url(package => $status{package},
 307                                   found => $status{found_versions},
 308                                   fixed => $status{fixed_versions},
 309                                  )
 310                      ).
 311           q("><img alt="version graph" src=").
 312           html_escape(version_url(package => $status{package},
 313                                   found => $status{found_versions},
 314                                   fixed => $status{fixed_versions},
 315                                   width => 2,
 316                                   height => 2,
 317                                  )
 318                      ).
 319           qq{"></a>};
 320 }
 321
 322
 323
 324 my @blockedby= split(/ /, $status{blockedby});
 325 $status{blockedby_array} = [];
 326 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 327     for my $b (@blockedby) {
 328         my %s = %{get_bug_status($b)};
 329         next if $s{"pending"} eq 'fixed' || length $s{done};
 330         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 331    }
 332 }
 333
 334 my @blocks= split(/ /, $status{blocks});
 335 $status{blocks_array} = [];
 336 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 337     for my $b (@blocks) {
 338         my %s = %{get_bug_status($b)};
 339         next if $s{"pending"} eq 'fixed' || length $s{done};
 340         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 341     }
 342 }
 343
 344 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 345      $status{archived} = 1;
 346 }
 347
 348 my $descriptivehead = $indexentry;
 349
 350 print $q->header(-type => "text/html",
 351                  -charset => 'utf-8',
 352                  (length $mtime)?(-last_modified => $mtime):(),
 353                 );
 354
 355 print fill_in_template(template => 'cgi/bugreport',
 356                        variables => {status => \%status,
 357                                      package => \%package,
 358                                      log           => $log,
 359                                      bug_num       => $ref,
 360                                      version_graph => $version_graph,
 361                                      msg           => $msg,
 362                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 363                                      html_escape   => \&Debbugs::CGI::html_escape,
 364                                      looks_like_number => \&Scalar::Util::looks_like_number,
 365                                     },
 366                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 367                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 368                                      '&version_url'   => \&Debbugs::CGI::version_url,
 369                                      '&bug_url'       => \&Debbugs::CGI::bug_url,
 370                                      '&strftime'      => \&POSIX::strftime,
 371                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 372                                     },
 373                       );