cgi/bugreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 use warnings;
   4 use strict;
   5
   6 use POSIX qw(strftime);
   7 use MIME::Parser;
   8 use MIME::Decoder;
   9 use IO::Scalar;
  10 use IO::File;
  11
  12 use Debbugs::Config qw(:globals :text);
  13
  14 # for read_log_records
  15 use Debbugs::Log qw(read_log_records);
  16 use Debbugs::CGI qw(:url :html :util);
  17 use Debbugs::CGI::Bugreport qw(:all);
  18 use Debbugs::Common qw(buglog getmaintainers make_list);
  19 use Debbugs::Packages qw(getpkgsrc);
  20 use Debbugs::Status qw(splitpackages get_bug_status isstrongseverity);
  21
  22 use Scalar::Util qw(looks_like_number);
  23
  24 use Debbugs::Text qw(:templates);
  25
  26
  27 use CGI::Simple;
  28 my $q = new CGI::Simple;
  29
  30 my %param = cgi_parameters(query => $q,
  31                            single => [qw(bug msg att boring terse),
  32                                       qw(reverse mbox mime trim),
  33                                       qw(mboxstat mboxmaint archive),
  34                                       qw(repeatmerged)
  35                                      ],
  36                            default => {# msg       => '',
  37                                        boring    => 'no',
  38                                        terse     => 'no',
  39                                        reverse   => 'no',
  40                                        mbox      => 'no',
  41                                        mime      => 'no',
  42                                        mboxstat  => 'no',
  43                                        mboxmaint => 'no',
  44                                        archive   => 'no',
  45                                        repeatmerged => 'yes',
  46                                       },
  47                           );
  48 # This is craptacular.
  49
  50 my $ref = $param{bug} or quitcgi("No bug number");
  51 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  52 $ref = $1;
  53 my $short = "#$ref";
  54 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  55 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  56 my $boring = $param{'boring'} eq 'yes';
  57 my $terse = $param{'terse'} eq 'yes';
  58 my $reverse = $param{'reverse'} eq 'yes';
  59 my $mbox = $param{'mbox'} eq 'yes';
  60 my $mime = $param{'mime'} eq 'yes';
  61
  62 my %bugusertags;
  63 my %ut;
  64 my %seen_users;
  65
  66 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
  67     next unless length($user);
  68     add_user($user,\%ut,\%bugusertags,\%seen_users);
  69 }
  70
  71 if (defined $param{usertag}) {
  72      for my $usertag (make_list($param{usertag})) {
  73           my %select_ut = ();
  74           my ($u, $t) = split /:/, $usertag, 2;
  75           Debbugs::User::read_usertags(\%select_ut, $u);
  76           unless (defined $t && $t ne "") {
  77                $t = join(",", keys(%select_ut));
  78           }
  79           add_user($u,\%ut,\%bugusertags,\%seen_users);
  80           push @{$param{tag}}, split /,/, $t;
  81      }
  82 }
  83
  84
  85 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
  86
  87 my $mbox_status_message = $param{mboxstat} eq 'yes';
  88 my $mbox_maint = $param{mboxmaint} eq 'yes';
  89 $mbox = 1 if $mbox_status_message or $mbox_maint;
  90
  91
  92 # Not used by this script directly, but fetch these so that pkgurl() and
  93 # friends can propagate them correctly.
  94 my $archive = $param{'archive'} eq 'yes';
  95 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
  96
  97 my $buglog = buglog($ref);
  98 if (not defined $buglog) {
  99      print $q->header(-status => "404 No such bug",
 100                       -type => "text/html",
 101                       -charset => 'utf-8',
 102                      );
 103      print fill_in_template(template=>'cgi/no_such_bug',
 104                             variables => {modify_time => strftime('%a, %e %b %Y %T UTC', gmtime),
 105                                           bug_num     => $ref,
 106                                          },
 107                            );
 108      exit 0;
 109 }
 110
 111 my @stat = stat $buglog;
 112 my $mtime = '';
 113 if (@stat) {
 114      $mtime = strftime '%a, %d %b %Y %T GMT', gmtime($stat[9]);
 115 }
 116
 117 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
 118      print $q->header(-type => "text/html",
 119                       -charset => 'utf-8',
 120                       (length $mtime)?(-last_modified => $mtime):(),
 121                      );
 122      exit 0;
 123 }
 124
 125
 126 my $buglogfh;
 127 if ($buglog =~ m/\.gz$/) {
 128     my $oldpath = $ENV{'PATH'};
 129     $ENV{'PATH'} = '/bin:/usr/bin';
 130     $buglogfh = IO::File->new("zcat $buglog |") or quitcgi("open log for $ref: $!");
 131     $ENV{'PATH'} = $oldpath;
 132 } else {
 133     $buglogfh = IO::File->new($buglog,'r') or quitcgi("open log for $ref: $!");
 134 }
 135
 136
 137 my %status = %{get_bug_status(bug=>$ref,
 138                               bugusertags => \%bugusertags,
 139                              )};
 140
 141 my @records;
 142 eval{
 143      @records = read_log_records($buglogfh);
 144 };
 145 if ($@) {
 146      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 147 }
 148 undef $buglogfh;
 149
 150
 151 my $log='';
 152 my $msg_num = 0;
 153 my $skip_next = 0;
 154 if (defined($msg) and ($msg-1) <= $#records) {
 155      @records = ($records[$msg-1]);
 156      $msg_num = $msg - 1;
 157 }
 158 my @log;
 159 if ( $mbox ) {
 160      my $date = strftime "%a %b %d %T %Y", localtime;
 161      if (@records > 1) {
 162           print qq(Content-Disposition: attachment; filename="bug_${ref}.mbox"\n);
 163           print "Content-Type: text/plain\n\n";
 164      }
 165      else {
 166           $msg_num++;
 167           print qq(Content-Disposition: attachment; filename="bug_${ref}_message_${msg_num}.mbox"\n);
 168           print "Content-Type: message/rfc822\n\n";
 169      }
 170      if ($mbox_status_message and @records > 1) {
 171           my $status_message='';
 172           my @status_fields = (retitle   => 'subject',
 173                                package   => 'package',
 174                                submitter => 'originator',
 175                                severity  => 'severity',
 176                                tag       => 'tags',
 177                                owner     => 'owner',
 178                                blocks    => 'blocks',
 179                                forward   => 'forward',
 180                               );
 181           my ($key,$value);
 182           while (($key,$value) = splice(@status_fields,0,2)) {
 183                if (defined $status{$value} and length $status{$value}) {
 184                     $status_message .= qq($key $ref $status{$value}\n);
 185                }
 186           }
 187           print STDOUT qq(From unknown $date\n),
 188                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 189                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 190                                     Subject    => "Status: $status{subject}",
 191                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 192                                    ],
 193                                    <<END,);
 194 $status_message
 195 thanks
 196
 197
 198 END
 199      }
 200      my $message_number=0;
 201      my %seen_message_ids;
 202      for my $record (@records) {
 203           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 204           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 205           # we want to include control messages anyway
 206           my $record_wanted_anyway = 0;
 207           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 208           next if exists $seen_message_ids{$msg_id};
 209           next if $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 210           $record_wanted_anyway = 1 if $record->{text} =~ /^Received: \(at control\)/;
 211           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 212           $seen_message_ids{$msg_id} = 1;
 213           my @lines = split( "\n", $record->{text}, -1 );
 214           if ( $lines[ 1 ] =~ m/^From / ) {
 215                my $tmp = $lines[ 0 ];
 216                $lines[ 0 ] = $lines[ 1 ];
 217                $lines[ 1 ] = $tmp;
 218           }
 219           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 220                unshift @lines, "From unknown $date";
 221           }
 222           map { s/^(>*From )/>$1/ } @lines[ 1 .. $#lines ];
 223           print join( "\n", @lines ) . "\n";
 224      }
 225      exit 0;
 226 }
 227
 228 else {
 229      if (defined $att and defined $msg and @records) {
 230           $msg_num++;
 231           print handle_email_message($records[0]->{text},
 232                                      ref => $ref,
 233                                      msg_num => $msg_num,
 234                                      att => $att,
 235                                      msg => $msg,
 236                                     );
 237           exit 0;
 238      }
 239      my %seen_msg_ids;
 240      for my $record (@records) {
 241           $msg_num++;
 242           if ($skip_next) {
 243                $skip_next = 0;
 244                next;
 245           }
 246           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 247           push @log, handle_record($record,$ref,$msg_num,\%seen_msg_ids);
 248      }
 249 }
 250
 251 @log = reverse @log if $reverse;
 252 $log = join("\n",@log);
 253
 254
 255 # All of the below should be turned into a template
 256
 257 my %maintainer = %{getmaintainers()};
 258 my %pkgsrc = %{getpkgsrc()};
 259
 260 my $indexentry;
 261 my $showseverity;
 262
 263 my $tpack;
 264 my $tmain;
 265
 266 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 267
 268 unless (%status) {
 269     print $q->header(-type => "text/html",
 270                      -charset => 'utf-8',
 271                      (length $mtime)?(-last_modified => $mtime):(),
 272                     );
 273     print fill_in_template(template=>'cgi/no_such_bug',
 274                            variables => {modify_time => $dtime,
 275                                          bug_num     => $ref,
 276                                         },
 277                           );
 278     exit 0;
 279 }
 280
 281 #$|=1;
 282
 283 my %package;
 284 my @packages = splitpackages($status{package});
 285
 286 foreach my $pkg (@packages) {
 287      $package{$pkg} = {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 288                        exists($pkgsrc{$pkg}) ? (source => $pkgsrc{$pkg}) : (),
 289                        package    => $pkg,
 290                       };
 291 }
 292
 293 # fixup various bits of the status
 294 $status{tags_array} = [sort(split(/\s+/, $status{tags}))];
 295 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 296 $status{mergedwith_array} = [split(/ /,$status{mergedwith})];
 297
 298
 299 my $version_graph = '';
 300 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 301      $version_graph = q(<a href=").
 302           html_escape(version_url(package => $status{package},
 303                                   found => $status{found_versions},
 304                                   fixed => $status{fixed_versions},
 305                                  )
 306                      ).
 307           q("><img alt="version graph" src=").
 308           html_escape(version_url(package => $status{package},
 309                                   found => $status{found_versions},
 310                                   fixed => $status{fixed_versions},
 311                                   width => 2,
 312                                   height => 2,
 313                                  )
 314                      ).
 315           qq{"></a>};
 316 }
 317
 318
 319
 320 my @blockedby= split(/ /, $status{blockedby});
 321 $status{blockedby_array} = [];
 322 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 323     for my $b (@blockedby) {
 324         my %s = %{get_bug_status($b)};
 325         next if $s{"pending"} eq 'fixed' || length $s{done};
 326         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 327    }
 328 }
 329
 330 my @blocks= split(/ /, $status{blocks});
 331 $status{blocks_array} = [];
 332 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 333     for my $b (@blocks) {
 334         my %s = %{get_bug_status($b)};
 335         next if $s{"pending"} eq 'fixed' || length $s{done};
 336         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 337     }
 338 }
 339
 340 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 341      $status{archived} = 1;
 342 }
 343
 344 my $descriptivehead = $indexentry;
 345
 346 print $q->header(-type => "text/html",
 347                  -charset => 'utf-8',
 348                  (length $mtime)?(-last_modified => $mtime):(),
 349                 );
 350
 351 print fill_in_template(template => 'cgi/bugreport',
 352                        variables => {status => \%status,
 353                                      package => \%package,
 354                                      log           => $log,
 355                                      bug_num       => $ref,
 356                                      version_graph => $version_graph,
 357                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 358                                      html_escape   => \&Debbugs::CGI::html_escape,
 359                                      looks_like_number => \&Scalar::Util::looks_like_number,
 360                                     },
 361                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 362                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 363                                      '&version_url'   => \&Debbugs::CGI::version_url,
 364                                      '&bug_url'       => \&Debbugs::CGI::bug_url,
 365                                      '&strftime'      => \&POSIX::strftime,
 366                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 367                                     },
 368                       );