cgi/bugreport.cgi

   1 #!/usr/bin/perl -wT
   2
   3 use warnings;
   4 use strict;
   5
   6 use POSIX qw(strftime);
   7 use MIME::Parser;
   8 use MIME::Decoder;
   9 use IO::Scalar;
  10 use IO::File;
  11
  12 use Debbugs::Config qw(:globals :text);
  13
  14 # for read_log_records
  15 use Debbugs::Log qw(read_log_records);
  16 use Debbugs::CGI qw(:url :html :util);
  17 use Debbugs::CGI::Bugreport qw(:all);
  18 use Debbugs::Common qw(buglog getmaintainers);
  19 use Debbugs::Packages qw(getpkgsrc);
  20 use Debbugs::Status qw(splitpackages get_bug_status isstrongseverity);
  21
  22 use Scalar::Util qw(looks_like_number);
  23
  24 use Debbugs::Text qw(:templates);
  25
  26 use CGI::Simple;
  27 my $q = new CGI::Simple;
  28
  29 my %param = cgi_parameters(query => $q,
  30                            single => [qw(bug msg att boring terse),
  31                                       qw(reverse mbox mime trim),
  32                                       qw(mboxstat mboxmaint archive),
  33                                       qw(repeatmerged)
  34                                      ],
  35                            default => {# msg       => '',
  36                                        boring    => 'no',
  37                                        terse     => 'no',
  38                                        reverse   => 'no',
  39                                        mbox      => 'no',
  40                                        mime      => 'no',
  41                                        mboxstat  => 'no',
  42                                        mboxmaint => 'no',
  43                                        archive   => 'no',
  44                                        repeatmerged => 'yes',
  45                                       },
  46                           );
  47 # This is craptacular.
  48
  49 my $ref = $param{bug} or quitcgi("No bug number");
  50 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  51 $ref = $1;
  52 my $short = "#$ref";
  53 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  54 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  55 my $boring = $param{'boring'} eq 'yes';
  56 my $terse = $param{'terse'} eq 'yes';
  57 my $reverse = $param{'reverse'} eq 'yes';
  58 my $mbox = $param{'mbox'} eq 'yes';
  59 my $mime = $param{'mime'} eq 'yes';
  60
  61 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
  62
  63 my $mbox_status_message = $param{mboxstat} eq 'yes';
  64 my $mbox_maint = $param{mboxmaint} eq 'yes';
  65 $mbox = 1 if $mbox_status_message or $mbox_maint;
  66
  67
  68 # Not used by this script directly, but fetch these so that pkgurl() and
  69 # friends can propagate them correctly.
  70 my $archive = $param{'archive'} eq 'yes';
  71 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
  72
  73 my $buglog = buglog($ref);
  74 if (not defined $buglog) {
  75      print $q->header(-status => "404 No such bug",
  76                       -type => "text/html",
  77                       -charset => 'utf-8',
  78                      );
  79      exit 0;
  80 }
  81
  82 my @stat = stat $buglog;
  83 my $mtime = '';
  84 if (@stat) {
  85      $mtime = strftime '%a, %d %b %Y %T GMT', gmtime($stat[9]);
  86 }
  87
  88 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
  89      print $q->header(-type => "text/html",
  90                       -charset => 'utf-8',
  91                       (length $mtime)?(-last_modified => $mtime):(),
  92                      );
  93      exit 0;
  94 }
  95
  96
  97 my $buglogfh;
  98 if ($buglog =~ m/\.gz$/) {
  99     my $oldpath = $ENV{'PATH'};
 100     $ENV{'PATH'} = '/bin:/usr/bin';
 101     $buglogfh = IO::File->new("zcat $buglog |") or quitcgi("open log for $ref: $!");
 102     $ENV{'PATH'} = $oldpath;
 103 } else {
 104     $buglogfh = IO::File->new($buglog,'r') or quitcgi("open log for $ref: $!");
 105 }
 106
 107
 108 my %status = %{get_bug_status(bug=>$ref)};
 109
 110 my @records;
 111 eval{
 112      @records = read_log_records($buglogfh);
 113 };
 114 if ($@) {
 115      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 116 }
 117 undef $buglogfh;
 118
 119
 120 my $log='';
 121 my $msg_num = 0;
 122 my $skip_next = 0;
 123 if (defined($msg) and ($msg-1) <= $#records) {
 124      @records = ($records[$msg-1]);
 125      $msg_num = $msg - 1;
 126 }
 127 my @log;
 128 if ( $mbox ) {
 129      my $date = strftime "%a %b %d %T %Y", localtime;
 130      if (@records > 1) {
 131           print qq(Content-Disposition: attachment; filename="bug_${ref}.mbox"\n);
 132           print "Content-Type: text/plain\n\n";
 133      }
 134      else {
 135           $msg_num++;
 136           print qq(Content-Disposition: attachment; filename="bug_${ref}_message_${msg_num}.mbox"\n);
 137           print "Content-Type: message/rfc822\n\n";
 138      }
 139      if ($mbox_status_message and @records > 1) {
 140           my $status_message='';
 141           my @status_fields = (retitle   => 'subject',
 142                                package   => 'package',
 143                                submitter => 'originator',
 144                                severity  => 'severity',
 145                                tag       => 'tags',
 146                                owner     => 'owner',
 147                                blocks    => 'blocks',
 148                                forward   => 'forward',
 149                               );
 150           my ($key,$value);
 151           while (($key,$value) = splice(@status_fields,0,2)) {
 152                if (defined $status{$value} and length $status{$value}) {
 153                     $status_message .= qq($key $ref $status{$value}\n);
 154                }
 155           }
 156           print STDOUT qq(From unknown $date\n),
 157                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 158                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 159                                     Subject    => "Status: $status{subject}",
 160                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 161                                    ],
 162                                    <<END,);
 163 $status_message
 164 thanks
 165
 166
 167 END
 168      }
 169      my $message_number=0;
 170      my %seen_message_ids;
 171      for my $record (@records) {
 172           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 173           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 174           # we want to include control messages anyway
 175           my $record_wanted_anyway = 0;
 176           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 177           next if exists $seen_message_ids{$msg_id};
 178           next if $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 179           $record_wanted_anyway = 1 if $record->{text} =~ /^Received: \(at control\)/;
 180           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 181           $seen_message_ids{$msg_id} = 1;
 182           my @lines = split( "\n", $record->{text}, -1 );
 183           if ( $lines[ 1 ] =~ m/^From / ) {
 184                my $tmp = $lines[ 0 ];
 185                $lines[ 0 ] = $lines[ 1 ];
 186                $lines[ 1 ] = $tmp;
 187           }
 188           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 189                unshift @lines, "From unknown $date";
 190           }
 191           map { s/^(>*From )/>$1/ } @lines[ 1 .. $#lines ];
 192           print join( "\n", @lines ) . "\n";
 193      }
 194      exit 0;
 195 }
 196
 197 else {
 198      if (defined $att and defined $msg and @records) {
 199           $msg_num++;
 200           print handle_email_message($records[0]->{text},
 201                                      ref => $ref,
 202                                      msg_num => $msg_num,
 203                                      att => $att,
 204                                      msg => $msg,
 205                                     );
 206           exit 0;
 207      }
 208      my %seen_msg_ids;
 209      for my $record (@records) {
 210           $msg_num++;
 211           if ($skip_next) {
 212                $skip_next = 0;
 213                next;
 214           }
 215           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 216           push @log, handle_record($record,$ref,$msg_num,\%seen_msg_ids);
 217      }
 218 }
 219
 220 @log = reverse @log if $reverse;
 221 $log = join("\n",@log);
 222
 223
 224 # All of the below should be turned into a template
 225
 226 my %maintainer = %{getmaintainers()};
 227 my %pkgsrc = %{getpkgsrc()};
 228
 229 my $indexentry;
 230 my $showseverity;
 231
 232 my $tpack;
 233 my $tmain;
 234
 235 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 236
 237 unless (%status) {
 238     print $q->header(-type => "text/html",
 239                      -charset => 'utf-8',
 240                      (length $mtime)?(-last_modified => $mtime):(),
 241                     );
 242     print fill_in_template(template=>'cgi/no_such_bug',
 243                            variables => {modify_time => $dtime,
 244                                          bug_num     => $ref,
 245                                         },
 246                           );
 247     exit 0;
 248 }
 249
 250 #$|=1;
 251
 252 my %package;
 253 my @packages = splitpackages($status{package});
 254
 255 foreach my $pkg (@packages) {
 256      $package{$pkg} = {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 257                        source     => exists($pkgsrc{$pkg}) ? $pkgsrc{$pkg} : '(unknown)',
 258                        package    => $pkg,
 259                       };
 260 }
 261
 262 # fixup various bits of the status
 263 $status{tags_array} = [sort(split(/\s+/, $status{tags}))];
 264 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 265 $status{mergedwith_array} = [split(/ /,$status{mergedwith})];
 266
 267
 268 my $version_graph = '';
 269 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 270      $version_graph = q(<a href=").
 271           html_escape(version_url(package => $status{package},
 272                                   found => $status{found_versions},
 273                                   fixed => $status{fixed_versions},
 274                                  )
 275                      ).
 276           q("><img alt="version graph" src=").
 277           html_escape(version_url(package => $status{package},
 278                                   found => $status{found_versions},
 279                                   fixed => $status{fixed_versions},
 280                                   width => 2,
 281                                   height => 2,
 282                                  )
 283                      ).
 284           qq{"></a>};
 285 }
 286
 287
 288
 289 my @blockedby= split(/ /, $status{blockedby});
 290 $status{blockedby_array} = [];
 291 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 292     for my $b (@blockedby) {
 293         my %s = %{get_bug_status($b)};
 294         next if $s{"pending"} eq 'fixed' || length $s{done};
 295         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 296    }
 297 }
 298
 299 my @blocks= split(/ /, $status{blocks});
 300 $status{blocks_array} = [];
 301 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 302     for my $b (@blocks) {
 303         my %s = %{get_bug_status($b)};
 304         next if $s{"pending"} eq 'fixed' || length $s{done};
 305         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 306     }
 307 }
 308
 309 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 310      $status{archived} = 1;
 311 }
 312
 313 my $descriptivehead = $indexentry;
 314
 315 print $q->header(-type => "text/html",
 316                  -charset => 'utf-8',
 317                  (length $mtime)?(-last_modified => $mtime):(),
 318                 );
 319
 320 print fill_in_template(template => 'cgi/bugreport',
 321                        variables => {status => \%status,
 322                                      package => \%package,
 323                                      log           => $log,
 324                                      bug_num       => $ref,
 325                                      version_graph => $version_graph,
 326                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 327                                      html_escape   => \&Debbugs::CGI::html_escape,
 328                                      looks_like_number => \&Scalar::Util::looks_like_number,
 329                                     },
 330                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 331                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 332                                      '&version_url'   => \&Debbugs::CGI::version_url,
 333                                      '&bug_url'       => \&Debbugs::CGI::bug_url,
 334                                      '&strftime'      => \&POSIX::strftime,
 335                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 336                                     },
 337                       );