cgi/bugreport.cgi

   1 #!/usr/bin/perl
   2
   3 use warnings;
   4 use strict;
   5
   6 # Sanitize environent for taint
   7 BEGIN{
   8     delete @ENV{qw(IFS CDPATH ENV BASH_ENV)};
   9 }
  10
  11
  12 use POSIX qw(strftime);
  13 use MIME::Parser;
  14 use MIME::Decoder;
  15 use IO::Scalar;
  16 use IO::File;
  17
  18 use Debbugs::Config qw(:globals :text);
  19
  20 # for read_log_records
  21 use Debbugs::Log qw(read_log_records);
  22 use Debbugs::CGI qw(:url :html :util);
  23 use Debbugs::CGI::Bugreport qw(:all);
  24 use Debbugs::Common qw(buglog getmaintainers make_list bug_status);
  25 use Debbugs::Packages qw(getpkgsrc);
  26 use Debbugs::Status qw(splitpackages split_status_fields get_bug_status isstrongseverity);
  27
  28 use Debbugs::User;
  29
  30 use Scalar::Util qw(looks_like_number);
  31
  32 use Debbugs::Text qw(:templates);
  33
  34 use List::Util qw(max);
  35
  36
  37 use CGI::Simple;
  38 my $q = new CGI::Simple;
  39 # STDOUT should be using the utf8 io layer
  40 binmode(STDOUT,':raw:encoding(UTF-8)');
  41
  42 my %param = cgi_parameters(query => $q,
  43                            single => [qw(bug msg att boring terse),
  44                                       qw(reverse mbox mime trim),
  45                                       qw(mboxstat mboxmaint archive),
  46                                       qw(repeatmerged avatars),
  47                                      ],
  48                            default => {# msg       => '',
  49                                        boring    => 'no',
  50                                        terse     => 'no',
  51                                        reverse   => 'no',
  52                                        mbox      => 'no',
  53                                        mime      => 'no',
  54                                        mboxstat  => 'no',
  55                                        mboxmaint => 'no',
  56                                        archive   => 'no',
  57                                        repeatmerged => 'yes',
  58                                        avatars   => 'yes',
  59                                       },
  60                           );
  61 # This is craptacular.
  62
  63 my $ref = $param{bug} or quitcgi("No bug number");
  64 $ref =~ /(\d+)/ or quitcgi("Invalid bug number");
  65 $ref = $1;
  66 my $short = "#$ref";
  67 my ($msg) = $param{msg} =~ /^(\d+)$/ if exists $param{msg};
  68 my ($att) = $param{att} =~ /^(\d+)$/ if exists $param{att};
  69 my $boring = $param{'boring'} eq 'yes';
  70 my $terse = $param{'terse'} eq 'yes';
  71 my $reverse = $param{'reverse'} eq 'yes';
  72 my $mbox = $param{'mbox'} eq 'yes';
  73 my $mime = $param{'mime'} eq 'yes';
  74 my $avatars = $param{avatars} eq 'yes';
  75
  76 my %bugusertags;
  77 my %ut;
  78 my %seen_users;
  79
  80 my $buglog = buglog($ref);
  81 my $bug_status = bug_status($ref);
  82 if (not defined $buglog or not defined $bug_status) {
  83      print $q->header(-status => "404 No such bug",
  84                       -type => "text/html",
  85                       -charset => 'utf-8',
  86                      );
  87      print fill_in_template(template=>'cgi/no_such_bug',
  88                             variables => {modify_time => strftime('%a, %e %b %Y %T UTC', gmtime),
  89                                           bug_num     => $ref,
  90                                          },
  91                            );
  92      exit 0;
  93 }
  94
  95 # the log should almost always be newer, but just in case
  96 my $log_mtime = +(stat $buglog)[9] || time;
  97 my $status_mtime = +(stat $bug_status)[9] || time;
  98 my $mtime = strftime '%a, %d %b %Y %T GMT', gmtime(max($status_mtime,$log_mtime));
  99
 100 if ($q->request_method() eq 'HEAD' and not defined($att) and not $mbox) {
 101      print $q->header(-type => "text/html",
 102                       -charset => 'utf-8',
 103                       (length $mtime)?(-last_modified => $mtime):(),
 104                      );
 105      exit 0;
 106 }
 107
 108 for my $user (map {split /[\s*,\s*]+/} make_list($param{users}||[])) {
 109     next unless length($user);
 110     add_user($user,\%ut,\%bugusertags,\%seen_users);
 111 }
 112
 113 if (defined $param{usertag}) {
 114      for my $usertag (make_list($param{usertag})) {
 115           my %select_ut = ();
 116           my ($u, $t) = split /:/, $usertag, 2;
 117           Debbugs::User::read_usertags(\%select_ut, $u);
 118           unless (defined $t && $t ne "") {
 119                $t = join(",", keys(%select_ut));
 120           }
 121           add_user($u,\%ut,\%bugusertags,\%seen_users);
 122           push @{$param{tag}}, split /,/, $t;
 123      }
 124 }
 125
 126
 127 my $trim_headers = ($param{trim} || ((defined $msg and $msg)?'no':'yes')) eq 'yes';
 128
 129 my $mbox_status_message = $param{mboxstat} eq 'yes';
 130 my $mbox_maint = $param{mboxmaint} eq 'yes';
 131 $mbox = 1 if $mbox_status_message or $mbox_maint;
 132
 133
 134 # Not used by this script directly, but fetch these so that pkgurl() and
 135 # friends can propagate them correctly.
 136 my $archive = $param{'archive'} eq 'yes';
 137 my $repeatmerged = $param{'repeatmerged'} eq 'yes';
 138
 139
 140
 141 my $buglogfh;
 142 if ($buglog =~ m/\.gz$/) {
 143     my $oldpath = $ENV{'PATH'};
 144     $ENV{'PATH'} = '/bin:/usr/bin';
 145     $buglogfh = IO::File->new("zcat $buglog |") or quitcgi("open log for $ref: $!");
 146     $ENV{'PATH'} = $oldpath;
 147 } else {
 148     $buglogfh = IO::File->new($buglog,'r') or quitcgi("open log for $ref: $!");
 149 }
 150
 151
 152 my %status =
 153     %{split_status_fields(get_bug_status(bug=>$ref,
 154                                          bugusertags => \%bugusertags,
 155                                         ))};
 156
 157 my @records;
 158 eval{
 159      @records = read_log_records(logfh => $buglogfh,inner_file => 1);
 160 };
 161 if ($@) {
 162      quitcgi("Bad bug log for $gBug $ref. Unable to read records: $@");
 163 }
 164 undef $buglogfh;
 165
 166
 167 my $log='';
 168 my $msg_num = 0;
 169 my $skip_next = 0;
 170 if (defined($msg) and ($msg-1) <= $#records) {
 171      @records = ($records[$msg-1]);
 172      $msg_num = $msg - 1;
 173 }
 174 my @log;
 175 if ( $mbox ) {
 176      binmode(STDOUT,":raw");
 177      my $date = strftime "%a %b %d %T %Y", localtime;
 178      if (@records > 1) {
 179          print $q->header(-type => "text/plain",
 180                           content_disposition => qq(attachment; filename="bug_${ref}.mbox"),
 181                           (length $mtime)?(-last_modified => $mtime):(),
 182                          );
 183      }
 184      else {
 185           $msg_num++;
 186           print $q->header(-type => "message/rfc822",
 187                            content_disposition => qq(attachment; filename="bug_${ref}_message_${msg_num}.mbox"),
 188                            (length $mtime)?(-last_modified => $mtime):(),
 189                           );
 190      }
 191      if ($mbox_status_message and @records > 1) {
 192           my $status_message='';
 193           my @status_fields = (retitle   => 'subject',
 194                                package   => 'package',
 195                                submitter => 'originator',
 196                                severity  => 'severity',
 197                                tag       => 'tags',
 198                                owner     => 'owner',
 199                                blocks    => 'blocks',
 200                                forward   => 'forward',
 201                               );
 202           my ($key,$value);
 203           while (($key,$value) = splice(@status_fields,0,2)) {
 204                if (defined $status{$value} and length $status{$value}) {
 205                     $status_message .= qq($key $ref $status{$value}\n);
 206                }
 207           }
 208           print STDOUT qq(From unknown $date\n),
 209                create_mime_message([From       => "$gBug#$ref <$ref\@$gEmailDomain>",
 210                                     To         => "$gBug#$ref <$ref\@$gEmailDomain>",
 211                                     Subject    => "Status: $status{subject}",
 212                                     "Reply-To" => "$gBug#$ref <$ref\@$gEmailDomain>",
 213                                    ],
 214                                    <<END,);
 215 $status_message
 216 thanks
 217
 218
 219 END
 220      }
 221      my $message_number=0;
 222      my %seen_message_ids;
 223      for my $record (@records) {
 224           next if $record->{type} !~ /^(?:recips|incoming-recv)$/;
 225           my $wanted_type = $mbox_maint?'recips':'incoming-recv';
 226           # we want to include control messages anyway
 227           my $record_wanted_anyway = 0;
 228           my ($msg_id) = record_regex($record,qr/^Message-Id:\s+<(.+)>/im);
 229           next if defined $msg_id and exists $seen_message_ids{$msg_id};
 230           next if defined $msg_id and $msg_id =~/handler\..+\.ack(?:info|done)?\@/;
 231           $record_wanted_anyway = 1 if record_regex($record,qr/^Received: \(at control\)/);
 232           next if not $boring and not $record->{type} eq $wanted_type and not $record_wanted_anyway and @records > 1;
 233           $seen_message_ids{$msg_id} = 1 if defined $msg_id;
 234       my @lines;
 235       if ($record->{inner_file}) {
 236           push @lines, $record->{fh}->getline;
 237           push @lines, $record->{fh}->getline;
 238       } else {
 239           @lines = split( "\n", $record->{text}, -1 );
 240       }
 241           if ( $lines[ 1 ] =~ m/^From / ) {
 242           @lines = reverse @lines;
 243           }
 244           if ( !( $lines[ 0 ] =~ m/^From / ) ) {
 245                unshift @lines, "From unknown $date";
 246           }
 247           print map { s/^(>*From )/>$1/; $_."\n" } @lines[ 1 .. $#lines ];
 248       if ($record->{inner_file}) {
 249           my $fh = $record->{fh};
 250           print <$fh>;
 251       }
 252      }
 253      exit 0;
 254 }
 255
 256 else {
 257      if (defined $att and defined $msg and @records) {
 258          binmode(STDOUT,":raw");
 259           $msg_num++;
 260           print handle_email_message($records[0],
 261                                      ref => $ref,
 262                                      msg_num => $msg_num,
 263                                      att => $att,
 264                                      msg => $msg,
 265                                      trim_headers => $trim_headers,
 266                                     );
 267           exit 0;
 268      }
 269      my %seen_msg_ids;
 270      for my $record (@records) {
 271           $msg_num++;
 272           if ($skip_next) {
 273                $skip_next = 0;
 274                next;
 275           }
 276           $skip_next = 1 if $record->{type} eq 'html' and not $boring;
 277           push @log, handle_record($record,$ref,$msg_num,
 278                                    \%seen_msg_ids,
 279                                    trim_headers => $trim_headers,
 280                                    avatars => $avatars,
 281                                   );
 282      }
 283 }
 284
 285 @log = reverse @log if $reverse;
 286 $log = join("\n",@log);
 287
 288
 289 # All of the below should be turned into a template
 290
 291 my %maintainer = %{getmaintainers()};
 292 my %pkgsrc = %{getpkgsrc()};
 293
 294 my $indexentry;
 295 my $showseverity;
 296
 297 my $tpack;
 298 my $tmain;
 299
 300 my $dtime = strftime "%a, %e %b %Y %T UTC", gmtime;
 301
 302 unless (%status) {
 303     print $q->header(-type => "text/html",
 304                      -charset => 'utf-8',
 305                      (length $mtime)?(-last_modified => $mtime):(),
 306                     );
 307     print fill_in_template(template=>'cgi/no_such_bug',
 308                            variables => {modify_time => $dtime,
 309                                          bug_num     => $ref,
 310                                         },
 311                           );
 312     exit 0;
 313 }
 314
 315 #$|=1;
 316
 317
 318 my @packages = make_list($status{package});
 319
 320
 321 my %packages_affects;
 322 for my $p_a (qw(package affects)) {
 323     foreach my $pkg (make_list($status{$p_a})) {
 324         if ($pkg =~ /^src\:/) {
 325             my ($srcpkg) = $pkg =~ /^src:(.*)/;
 326             $packages_affects{$p_a}{$pkg} =
 327                {maintainer => exists($maintainer{$srcpkg}) ? $maintainer{$srcpkg} : '(unknown)',
 328                 source     => $srcpkg,
 329                 package    => $pkg,
 330                 is_source  => 1,
 331                };
 332         }
 333         else {
 334             $packages_affects{$p_a}{$pkg} =
 335                {maintainer => exists($maintainer{$pkg}) ? $maintainer{$pkg} : '(unknown)',
 336                 exists($pkgsrc{$pkg}) ? (source => $pkgsrc{$pkg}) : (),
 337                 package    => $pkg,
 338                };
 339         }
 340     }
 341 }
 342
 343 # fixup various bits of the status
 344 $status{tags_array} = [sort(make_list($status{tags}))];
 345 $status{date_text} = strftime('%a, %e %b %Y %T UTC', gmtime($status{date}));
 346 $status{mergedwith_array} = [make_list($status{mergedwith})];
 347
 348
 349 my $version_graph = '';
 350 if (@{$status{found_versions}} or @{$status{fixed_versions}}) {
 351      $version_graph = q(<a href=").
 352           html_escape(version_url(package => $status{package},
 353                                   found => $status{found_versions},
 354                                   fixed => $status{fixed_versions},
 355                                  )
 356                      ).
 357           q("><img alt="version graph" src=").
 358           html_escape(version_url(package => $status{package},
 359                                   found => $status{found_versions},
 360                                   fixed => $status{fixed_versions},
 361                                   width => 2,
 362                                   height => 2,
 363                                  )
 364                      ).
 365           qq{"></a>};
 366 }
 367
 368
 369
 370 my @blockedby= make_list($status{blockedby});
 371 $status{blockedby_array} = [];
 372 if (@blockedby && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 373     for my $b (@blockedby) {
 374         my %s = %{get_bug_status($b)};
 375         next if $s{"pending"} eq 'fixed' || length $s{done};
 376         push @{$status{blockedby_array}},{bug_num => $b, subject => $s{subject}, status => \%s};
 377    }
 378 }
 379
 380 my @blocks= make_list($status{blocks});
 381 $status{blocks_array} = [];
 382 if (@blocks && $status{"pending"} ne 'fixed' && ! length($status{done})) {
 383     for my $b (@blocks) {
 384         my %s = %{get_bug_status($b)};
 385         next if $s{"pending"} eq 'fixed' || length $s{done};
 386         push @{$status{blocks_array}}, {bug_num => $b, subject => $s{subject}, status => \%s};
 387     }
 388 }
 389
 390 if ($buglog !~ m#^\Q$gSpoolDir/db#) {
 391      $status{archived} = 1;
 392 }
 393
 394 my $descriptivehead = $indexentry;
 395
 396 print $q->header(-type => "text/html",
 397                  -charset => 'utf-8',
 398                  (length $mtime)?(-last_modified => $mtime):(),
 399                 );
 400
 401 print fill_in_template(template => 'cgi/bugreport',
 402                        variables => {status => \%status,
 403                                      package => $packages_affects{'package'},
 404                                      affects => $packages_affects{'affects'},
 405                                      log           => $log,
 406                                      bug_num       => $ref,
 407                                      version_graph => $version_graph,
 408                                      msg           => $msg,
 409                                      isstrongseverity => \&Debbugs::Status::isstrongseverity,
 410                                      html_escape   => \&Debbugs::CGI::html_escape,
 411                                      looks_like_number => \&Scalar::Util::looks_like_number,
 412                                      make_list        => \&Debbugs::Common::make_list,
 413                                     },
 414                        hole_var  => {'&package_links' => \&Debbugs::CGI::package_links,
 415                                      '&bug_links'     => \&Debbugs::CGI::bug_links,
 416                                      '&version_url'   => \&Debbugs::CGI::version_url,
 417                                      '&bug_url'       => \&Debbugs::CGI::bug_url,
 418                                      '&strftime'      => \&POSIX::strftime,
 419                                      '&maybelink'     => \&Debbugs::CGI::maybelink,
 420                                     },
 421                       );