bin/debbugs-loadsql

   1 #! /usr/bin/perl
   2 # debbugs-loadsql is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2012 by Don Armstrong <don@donarmstrong.com>.
   6
   7
   8 use warnings;
   9 use strict;
  10
  11 use Getopt::Long qw(:config no_ignore_case);
  12 use Pod::Usage;
  13
  14 =head1 NAME
  15
  16 debbugs-loadsql -- load debbugs sql database
  17
  18 =head1 SYNOPSIS
  19
  20 debbugs-loadsql [options]
  21
  22  Options:
  23   --quick, -q only load changed bugs
  24   --progress Show progress bar
  25   --service, -s service name
  26   --sysconfdir, -c postgresql service config dir
  27   --spool-dir debbugs spool directory
  28   --debug, -d debugging level (Default 0)
  29   --help, -h display this help
  30   --man, -m display manual
  31
  32 =head1 SUBCOMMANDS
  33
  34 =head2 help
  35
  36 Display this manual
  37
  38 =head2 bugs
  39
  40 Add bugs
  41
  42 =head2 versions
  43
  44 Add versions
  45
  46 =head2 maintainers
  47
  48 Add source maintainers
  49
  50 =head1 OPTIONS
  51
  52 =over
  53
  54 =item B<--quick, -q>
  55
  56 Only load changed bugs
  57
  58 =item B<--progress>
  59
  60 Show progress bar (requires Term::ProgressBar)
  61
  62 =item B<--service,-s>
  63
  64 Postgreql service to use; defaults to debbugs
  65
  66 =item B<--sysconfdir,-c>
  67
  68 System configuration directory to use; if not set, defaults to the
  69 postgresql default. [Operates by setting PGSYSCONFDIR]
  70
  71 =item B<--spool-dir>
  72
  73 Debbugs spool directory; defaults to the value configured in the
  74 debbugs configuration file.
  75
  76 =item B<--verbose>
  77
  78 Output more information about what is happening. Probably not useful
  79 if you also set --progress.
  80
  81 =item B<--debug, -d>
  82
  83 Debug verbosity.
  84
  85 =item B<--help, -h>
  86
  87 Display brief useage information.
  88
  89 =item B<--man, -m>
  90
  91 Display this manual.
  92
  93 =back
  94
  95
  96 =cut
  97
  98
  99 use vars qw($DEBUG);
 100
 101 use Debbugs::Common qw(checkpid lockpid get_hashname getparsedaddrs getbugcomponent make_list getsourcemaintainers);
 102 use Debbugs::Config qw(:config);
 103 use Debbugs::Status qw(read_bug split_status_fields);
 104 use Debbugs::Log;
 105 use Debbugs::DB;
 106 use Debbugs::DB::Load qw(load_bug handle_load_bug_queue);
 107 use DateTime;
 108 use File::stat;
 109
 110
 111 my %options =
 112     (debug           => 0,
 113      help            => 0,
 114      man             => 0,
 115      verbose         => 0,
 116      quiet           => 0,
 117      quick           => 0,
 118      service         => $config{debbugs_db},
 119      progress        => 0,
 120     );
 121
 122 Getopt::Long::Configure('pass_through');
 123 GetOptions(\%options,
 124            'quick|q',
 125            'service|s=s',
 126            'sysconfdir|c=s',
 127            'progress!',
 128            'spool_dir|spool-dir=s',
 129            'verbose|v+',
 130            'quiet+',
 131            'debug|d+','help|h|?','man|m');
 132 Getopt::Long::Configure('default');
 133
 134 pod2usage() if $options{help};
 135 pod2usage({verbose=>2}) if $options{man};
 136
 137 $DEBUG = $options{debug};
 138
 139 my %subcommands =
 140     ('bugs' => {function => \&add_bugs,
 141                },
 142      'versions' => {function => \&add_versions,
 143                    },
 144      'debinfo' => {function => \&add_debinfo,
 145                   },
 146      'maintainers' => {function => \&add_maintainers,
 147                       },
 148      'configuration' => {function => \&add_configuration,
 149                         },
 150      'logs' => {function => \&add_logs,
 151                },
 152      'help' => {function => sub {pod2usage({verbose => 2});}}
 153     );
 154
 155 my @USAGE_ERRORS;
 156 $options{verbose} = $options{verbose} - $options{quiet};
 157
 158 if ($options{progress}) {
 159     eval "use Term::ProgressBar";
 160     push @USAGE_ERRORS, "You asked for a progress bar, but Term::ProgressBar isn't installed" if $@;
 161 }
 162
 163
 164 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 165
 166 if (exists $options{sysconfdir}) {
 167     if (not defined $options{sysconfdir} or not length $options{sysconfdir}) {
 168         delete $ENV{PGSYSCONFDIR};
 169     } else {
 170         $ENV{PGSYSCONFDIR} = $options{sysconfdir};
 171     }
 172 }
 173
 174 if (exists $options{spool_dir} and defined $options{spool_dir}) {
 175     $config{spool_dir} = $options{spool_dir};
 176 }
 177
 178 my $prog_bar;
 179 if ($options{progress}) {
 180     $prog_bar = eval "Term::ProgressBar->new({count => 1,ETA=>q(linear)})";
 181     warn "Unable to initialize progress bar: $@" if not $prog_bar;
 182 }
 183
 184
 185 my ($subcommand) = shift @ARGV;
 186 if (not defined $subcommand) {
 187     $subcommand = 'help';
 188     print STDERR "You must provide a subcommand; displaying usage.\n";
 189     pod2usage();
 190 } elsif (not exists $subcommands{$subcommand}) {
 191     print STDERR "$subcommand is not a valid subcommand; displaying usage.\n";
 192     pod2uage();
 193 }
 194
 195 my $opts =
 196     handle_subcommand_arguments(\@ARGV,$subcommands{$subcommand}{arguments});
 197 $subcommands{$subcommand}{function}->(\%options,$opts,$prog_bar,\%config,\@ARGV);
 198
 199 sub add_bugs {
 200     my ($options,$opts,$p,$config,$argv) = @_;
 201     chdir($config->{spool_dir}) or
 202         die "chdir $config->{spool_dir} failed: $!";
 203
 204     my $verbose = $options->{debug};
 205
 206     my $initialdir = "db-h";
 207
 208     if (defined $argv->[0] and $argv->[0] eq "archive") {
 209         $initialdir = "archive";
 210     }
 211     my $s = db_connect($options);
 212
 213
 214     my $time = 0;
 215     my $start_time = time;
 216
 217
 218     my @dirs = (@{$argv}?@{$argv} : $initialdir);
 219     my $cnt = 0;
 220     my %tags;
 221     my %severities;
 222     my %queue;
 223     my $tot_dirs = @{$argv}? @{$argv} : 0;
 224     my $done_dirs = 0;
 225     my $avg_subfiles = 0;
 226     my $completed_files = 0;
 227     while (my $dir = shift @dirs) {
 228         printf "Doing dir %s ...\n", $dir if $verbose;
 229
 230         opendir(DIR, "$dir/.") or die "opendir $dir: $!";
 231         my @subdirs = readdir(DIR);
 232         closedir(DIR);
 233
 234         my @list = map { m/^(\d+)\.summary$/?($1):() } @subdirs;
 235         $tot_dirs -= @dirs;
 236         push @dirs, map { m/^(\d+)$/ && -d "$dir/$1"?("$dir/$1"):() } @subdirs;
 237         $tot_dirs += @dirs;
 238         if ($avg_subfiles == 0) {
 239             $avg_subfiles = @list;
 240         }
 241
 242         $p->target($avg_subfiles*($tot_dirs-$done_dirs)+$completed_files+@list) if $p;
 243         $avg_subfiles = ($avg_subfiles * $done_dirs + @list) / ($done_dirs+1);
 244         $done_dirs += 1;
 245
 246         for my $bug (@list) {
 247             $completed_files++;
 248             $p->update($completed_files) if $p;
 249             print "Up to $cnt bugs...\n" if (++$cnt % 100 == 0 && $verbose);
 250             my $stat = stat(getbugcomponent($bug,'summary',$initialdir));
 251             if (not defined $stat) {
 252                 print STDERR "Unable to stat $bug $!\n";
 253                 next;
 254             }
 255             next if $stat->mtime < $time;
 256             my $data = read_bug(bug => $bug,
 257                                 location => $initialdir);
 258             eval {
 259                 load_bug(db => $s,
 260                          data => split_status_fields($data),
 261                          tags => \%tags,
 262                          severities => \%severities,
 263                          queue => \%queue);
 264             };
 265             if ($@) {
 266                 use Data::Dumper;
 267                 print STDERR Dumper($data) if $DEBUG;
 268                 die "failure while trying to load bug $bug\n$@";
 269             }
 270         }
 271     }
 272     $p->remove() if $p;
 273     handle_load_bug_queue(db => $s,
 274                           queue => \%queue);
 275 }
 276
 277 sub add_versions {
 278     my ($options,$opts,$p,$config,$argv) = @_;
 279
 280     my $s = db_connect($options);
 281
 282     my @files = @{$argv};
 283     $p->target(scalar @files) if $p;
 284     for my $file (@files) {
 285         my $fh = IO::File->new($file,'r') or
 286             die "Unable to open $file for reading: $!";
 287         my @versions;
 288         my %src_pkgs;
 289         while (<$fh>) {
 290             chomp;
 291             next unless length $_;
 292             if (/(\w[-+0-9a-z.]+) \(([^\(\) \t]+)\)/) {
 293                 push @versions, [$1,$2];
 294             }
 295         }
 296         close($fh);
 297         my $ancestor_sv;
 298         for my $i (reverse 0..($#versions)) {
 299             my $sp;
 300             if (not defined $src_pkgs{$versions[$i][0]}) {
 301                 $src_pkgs{$versions[$i][0]} =
 302                     $s->resultset('SrcPkg')->find_or_create({pkg => $versions[$i][0]});
 303             }
 304             $sp = $src_pkgs{$versions[$i][0]};
 305             # There's probably something wrong if the source package
 306             # doesn't exist, but we'll skip it for now
 307             next unless defined $sp;
 308             my $sv = $s->resultset('SrcVer')->find({src_pkg=>$sp->id(),
 309                                                     ver => $versions[$i][1],
 310                                                    });
 311             if (defined $ancestor_sv and defined $sv and not defined $sv->based_on()) {
 312                 $sv->update({based_on => $ancestor_sv->id()})
 313             }
 314             $ancestor_sv = $sv;
 315         }
 316         $p->update() if $p;
 317     }
 318     $p->remove() if $p;
 319 }
 320
 321 sub add_debinfo {
 322     my ($options,$opts,$p,$config,$argv) = @_;
 323
 324     my @files = @{$argv};
 325     return unless @files;
 326     my $s = db_connect($options);
 327     my %arch;
 328     $p->target(scalar @files) if $p;
 329     for my $file (@files) {
 330         my $fh = IO::File->new($file,'r') or
 331             die "Unable to open $file for reading: $!";
 332         my $f_stat = stat($file);
 333         while (<$fh>) {
 334             chomp;
 335             next unless length $_;
 336             my ($binname, $binver, $binarch, $srcname, $srcver) = split;
 337             # if $srcver is not defined, this is probably a broken
 338             # .debinfo file [they were causing #686106, see commit
 339             # 49c85ab8 in dak.] Basically, $binarch didn't get put into
 340             # the file, so we'll fudge it from the filename.
 341             if (not defined $srcver) {
 342                 ($srcname,$srcver) = ($binarch,$srcname);
 343                 ($binarch) = $file =~ /_([^\.]+)\.debinfo/;
 344             }
 345             my $sp = $s->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 346             my $sv = $s->resultset('SrcVer')->find_or_create({src_pkg =>$sp->id(),
 347                                                               ver => $srcver});
 348             my $arch;
 349             if (defined $arch{$binarch}) {
 350                 $arch = $arch{$binarch};
 351             } else {
 352                 $arch = $s->resultset('Arch')->find_or_create({arch => $binarch});
 353                 $arch{$binarch} = $arch;
 354             }
 355             my $bp = $s->resultset('BinPkg')->find_or_create({pkg => $binname});
 356             $s->resultset('BinVer')->find_or_create({bin_pkg => $bp->id(),
 357                                                      src_ver => $sv->id(),
 358                                                      arch    => $arch->id(),
 359                                                      ver        => $binver,
 360                                                     });
 361         }
 362         $p->update() if $p;
 363     }
 364     $p->remove() if $p;
 365 }
 366
 367 sub add_maintainers {
 368     my ($options,$opts,$p,$config,$argv) = @_;
 369
 370     my $s = db_connect($options);
 371     my $maintainers = getsourcemaintainers();
 372     $p->target(scalar keys %{$maintainers}) if $p;
 373     for my $pkg (keys %{$maintainers}) {
 374         my $maint = $maintainers->{$pkg};
 375         # see if a maintainer already exists; if so, we don't do
 376         # anything here
 377         my $maint_r = $s->resultset('Maintainer')->
 378             find({name => $maint});
 379         if (not defined $maint_r) {
 380             # get e-mail address of maintainer
 381             my $addr = getparsedaddrs($maint);
 382             my $e_mail = $addr->address();
 383             my $full_name = $addr->phrase();
 384             $full_name =~ s/^\"|\"$//g;
 385             $full_name =~ s/^\s+|\s+$//g;
 386             # find correspondent
 387             my $correspondent = $s->resultset('Correspondent')->
 388                 find_or_create({addr => $e_mail});
 389             if (length $full_name) {
 390                 my $c_full_name = $correspondent->find_or_create_related('correspondent_full_names',
 391                                                                         {full_name => $full_name}) if length $full_name;
 392                 $c_full_name->update({last_seen => 'NOW()'});
 393             }
 394             $maint_r =
 395                 $s->resultset('Maintainer')->
 396                 find_or_create({name => $maint,
 397                                 correspondent => $correspondent,
 398                                });
 399         }
 400         # add the maintainer to the source package for packages with
 401         # no maintainer
 402         $s->txn_do(sub {
 403                       $s->resultset('SrcPkg')->search({pkg => $pkg})->
 404                           search_related_rs('src_vers',{ maintainer => undef})->
 405                           update_all({maintainer => $maint_r->id()});
 406                   });
 407         $p->update() if $p;
 408     }
 409     $p->remove() if $p;
 410 }
 411
 412 sub add_configuration {
 413     my ($options,$opts,$p,$config,$argv) = @_;
 414 }
 415
 416 sub add_logs {
 417     my ($options,$opts,$p,$config,$argv) = @_;
 418 }
 419
 420 sub handle_subcommand_arguments {
 421     my ($argv,$args) = @_;
 422     my $subopt = {};
 423     Getopt::Long::GetOptionsFromArray($argv,
 424                               $subopt,
 425                               keys %{$args},
 426                              );
 427     my @usage_errors;
 428     for my $arg  (keys %{$args}) {
 429         next unless $args->{$arg};
 430         my $r_arg = $arg; # real argument name
 431         $r_arg =~ s/[=\|].+//g;
 432         if (not defined $subopt->{$r_arg}) {
 433             push @usage_errors, "You must give a $r_arg option";
 434         }
 435     }
 436     pod2usage(join("\n",@usage_errors)) if @usage_errors;
 437     return $subopt;
 438 }
 439
 440 sub get_lock{
 441     my ($subcommand,$config,$options) = @_;
 442     if (not lockpid($config->{spool_dir}.'/lock/debbugs-loadsql-$subcommand')) {
 443         if ($options->{quick}) {
 444             # If this is a quick run, just exit
 445             print STDERR "Another debbugs-loadsql is running; stopping\n" if $options->{verbose};
 446             exit 0;
 447         }
 448         print STDERR "Another debbugs-loadsql is running; stopping\n";
 449         exit 1;
 450     }
 451 }
 452
 453 sub db_connect {
 454     my ($options) = @_;
 455     # connect to the database; figure out how to handle errors
 456     # properly here.
 457     my $s = Debbugs::DB->connect('dbi:Pg:service='.$options->{service}) or
 458         die "Unable to connect to database: ";
 459 }
 460
 461
 462
 463 __END__