bin/debbugs-loadsql

   1 #! /usr/bin/perl
   2 # debbugs-loadsql is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2012 by Don Armstrong <don@donarmstrong.com>.
   6
   7
   8 use warnings;
   9 use strict;
  10
  11 use Getopt::Long qw(:config no_ignore_case);
  12 use Pod::Usage;
  13
  14 =head1 NAME
  15
  16 debbugs-loadsql -- load debbugs sql database
  17
  18 =head1 SYNOPSIS
  19
  20 debbugs-loadsql [options] [subcommand]
  21
  22  Subcommands:
  23   bugs help versions configuration
  24   suites logs packages debinfo
  25  Options:
  26   --quick, -q only load changed things
  27   --progress Show progress bar
  28   --service, -s service name
  29   --sysconfdir, -c postgresql service config dir
  30   --spool-dir debbugs spool directory
  31   --debug, -d debugging level (Default 0)
  32   --help, -h display this help
  33   --man, -m display manual
  34
  35 =head1 SUBCOMMANDS
  36
  37 =head2 help
  38
  39 Display this manual
  40
  41 =head2 bugs
  42
  43 Add bugs (subject, number, etc) to the database
  44
  45    --preload create all bugs first, then add information
  46
  47 =head2 versions
  48
  49 Add version descendant information (which version is based on which version) to
  50 the database
  51
  52 =head2 maintainers
  53
  54 Add source maintainers to the BTS
  55
  56 =head2 configuration
  57
  58 Add debbugs configuration information (tags, severity, etc)
  59
  60 =head2 suites
  61
  62 Add suite information from ftp distribution
  63
  64   --ftpdists location of FTP mirror
  65
  66 =head2 logs
  67
  68 Add bug logs
  69
  70 =head2 packages
  71
  72 Add package information from the ftp archive
  73
  74   --ftpdists location of FTP mirror
  75   --suites Suite to operate on
  76
  77 =head2 debinfo
  78
  79 Add package information from a debinfo file
  80
  81   --null -0 names of debinfo files are null separated
  82
  83 =head1 OPTIONS
  84
  85 =over
  86
  87 =item B<--quick, -q>
  88
  89 Only load changed bugs
  90
  91 =item B<--progress>
  92
  93 Show progress bar (requires Term::ProgressBar)
  94
  95 =item B<--service,-s>
  96
  97 Postgreql service to use; defaults to debbugs
  98
  99 =item B<--sysconfdir,-c>
 100
 101 System configuration directory to use; if not set, defaults to the
 102 postgresql default. [Operates by setting PGSYSCONFDIR]
 103
 104 =item B<--spool-dir>
 105
 106 Debbugs spool directory; defaults to the value configured in the
 107 debbugs configuration file.
 108
 109 =item B<--verbose>
 110
 111 Output more information about what is happening. Probably not useful
 112 if you also set --progress.
 113
 114 =item B<--debug, -d>
 115
 116 Debug verbosity.
 117
 118 =item B<--help, -h>
 119
 120 Display brief useage information.
 121
 122 =item B<--man, -m>
 123
 124 Display this manual.
 125
 126 =back
 127
 128
 129 =cut
 130
 131
 132 use vars qw($DEBUG);
 133
 134 use Debbugs::Common (qw(checkpid lockpid get_hashname getparsedaddrs getbugcomponent make_list getsourcemaintainers),
 135                      qw(hash_slice open_compressed_file),);
 136 use Debbugs::Config qw(:config);
 137 use Debbugs::Status qw(read_bug split_status_fields);
 138 use Debbugs::Log;
 139 use Debbugs::DB;
 140 use Debbugs::DB::Load qw(:load_bug :load_package :load_suite);
 141 use DateTime;
 142 use File::stat;
 143 use File::Basename;
 144 use File::Spec;
 145 use IO::Dir;
 146 use IO::File;
 147 use IO::Uncompress::AnyUncompress;
 148 use Encode qw(decode_utf8);
 149 use List::MoreUtils qw(natatime);
 150
 151 my %options =
 152     (debug           => 0,
 153      help            => 0,
 154      man             => 0,
 155      verbose         => 0,
 156      quiet           => 0,
 157      quick           => 0,
 158      service         => $config{debbugs_db},
 159      progress        => 0,
 160     );
 161
 162 Getopt::Long::Configure('pass_through');
 163 GetOptions(\%options,
 164            'quick|q',
 165            'service|s=s',
 166            'sysconfdir|c=s',
 167            'progress!',
 168            'spool_dir|spool-dir=s',
 169            'verbose|v+',
 170            'quiet+',
 171            'debug|d+','help|h|?','man|m');
 172 Getopt::Long::Configure('default');
 173
 174 pod2usage() if $options{help};
 175 pod2usage({verbose=>2}) if $options{man};
 176
 177 $DEBUG = $options{debug};
 178
 179 my %subcommands =
 180     ('bugs' => {function => \&add_bugs,
 181                 arguments => {'preload' => 0},
 182                },
 183      'versions' => {function => \&add_versions,
 184                    },
 185      'debinfo' => {function => \&add_debinfo,
 186                    arguments => {'0|null' => 0},
 187                   },
 188      'maintainers' => {function => \&add_maintainers,
 189                       },
 190      'configuration' => {function => \&add_configuration,
 191                         },
 192      'suites' => {function => \&add_suite,
 193                   arguments => {'ftpdists=s' => 1,
 194                                },
 195                  },
 196      'logs' => {function => \&add_logs,
 197                },
 198      'packages' => {function => \&add_packages,
 199                     arguments => {'ftpdists=s' => 1,
 200                                   'suites=s@' => 0,
 201                                  },
 202                    },
 203      'help' => {function => sub {pod2usage({verbose => 2});}}
 204     );
 205
 206 my @USAGE_ERRORS;
 207 $options{verbose} = $options{verbose} - $options{quiet};
 208
 209 if ($options{progress}) {
 210     eval "use Term::ProgressBar";
 211     push @USAGE_ERRORS, "You asked for a progress bar, but Term::ProgressBar isn't installed" if $@;
 212 }
 213
 214
 215 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 216
 217 if (exists $options{sysconfdir}) {
 218     if (not defined $options{sysconfdir} or not length $options{sysconfdir}) {
 219         delete $ENV{PGSYSCONFDIR};
 220     } else {
 221         $ENV{PGSYSCONFDIR} = $options{sysconfdir};
 222     }
 223 }
 224
 225 if (exists $options{spool_dir} and defined $options{spool_dir}) {
 226     $config{spool_dir} = $options{spool_dir};
 227 }
 228
 229 my $prog_bar;
 230 if ($options{progress}) {
 231     $prog_bar = eval "Term::ProgressBar->new({count => 1,ETA=>q(linear)})";
 232     warn "Unable to initialize progress bar: $@" if not $prog_bar;
 233 }
 234
 235
 236 my ($subcommand) = shift @ARGV;
 237 if (not defined $subcommand) {
 238     $subcommand = 'help';
 239     print STDERR "You must provide a subcommand; displaying usage.\n";
 240     pod2usage();
 241 } elsif (not exists $subcommands{$subcommand}) {
 242     print STDERR "$subcommand is not a valid subcommand; displaying usage.\n";
 243     pod2usage();
 244 }
 245
 246 binmode(STDOUT,':encoding(UTF-8)');
 247 binmode(STDERR,':encoding(UTF-8)');
 248
 249 my $opts =
 250     handle_subcommand_arguments(\@ARGV,$subcommands{$subcommand}{arguments});
 251 $subcommands{$subcommand}{function}->(\%options,$opts,$prog_bar,\%config,\@ARGV);
 252
 253 sub add_bugs {
 254     my ($options,$opts,$p,$config,$argv) = @_;
 255     chdir($config->{spool_dir}) or
 256         die "chdir $config->{spool_dir} failed: $!";
 257
 258     my $verbose = $options->{debug};
 259
 260     my $initialdir = "db-h";
 261
 262     if (defined $argv->[0] and $argv->[0] eq "archive") {
 263         $initialdir = "archive";
 264     }
 265     my $s = db_connect($options);
 266
 267
 268     my $time = 0;
 269     my $start_time = time;
 270     my %tags;
 271     my %severities;
 272     my %queue;
 273
 274     if ($opts->{preload}) {
 275         my @bugs;
 276         walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 277                   undef,
 278                   'summary',
 279                   undef,
 280                   sub {
 281                     push @bugs,@_;
 282                   },
 283                   10000
 284                  );
 285         $s->resultset('Bug')->quick_insert_bugs(@bugs);
 286     }
 287     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 288               $p,
 289               'summary',
 290               $verbose,
 291               sub {
 292                 my @bugs = @_;
 293                 my @bugs_to_update;
 294                 if ($options{quick}) {
 295                   for my $bug (@bugs) {
 296                     my $stat = stat(getbugcomponent($bug,'summary',$initialdir));
 297                     if (not defined $stat) {
 298                       print STDERR "Unable to stat $bug $!\n";
 299                       next;
 300                     }
 301                     my $rs = $s->resultset('Bug')->search({id=>$bug})->single();
 302                     next if defined $rs and $stat->mtime <= $rs->last_modified()->epoch();
 303                     push @bugs_to_update, $bug;
 304                   }
 305                 } else {
 306                   @bugs_to_update = @bugs;
 307                 }
 308                 eval {
 309                   $s->txn_do(sub {
 310                                for my $bug (@bugs_to_update) {
 311                                  load_bug(db => $s,
 312                                           bug => $bug,
 313                                           tags => \%tags,
 314                                           severities => \%severities,
 315                                           queue => \%queue);
 316                                }
 317                              });
 318                 };
 319                 if ($@) {
 320                   die "failure while trying to load bug: $@";
 321                 }
 322               },
 323               50
 324              );
 325     handle_load_bug_queue(db => $s,
 326                           queue => \%queue);
 327 }
 328
 329 sub add_versions {
 330     my ($options,$opts,$p,$config,$argv) = @_;
 331
 332     my $s = db_connect($options);
 333
 334     my @files = @{$argv};
 335     $p->target(scalar @files) if $p;
 336     for my $file (@files) {
 337         my $fh = IO::File->new($file,'r') or
 338             die "Unable to open $file for reading: $!";
 339         my @versions;
 340         my %src_pkgs;
 341         while (<$fh>) {
 342             chomp;
 343             next unless length $_;
 344             if (/(\w[-+0-9a-z.]+) \(([^\(\) \t]+)\)/) {
 345                 push @versions, [$1,$2];
 346             }
 347         }
 348         close($fh);
 349         my $ancestor_sv;
 350         for my $i (reverse 0..($#versions)) {
 351             my $sp;
 352             if (not defined $src_pkgs{$versions[$i][0]}) {
 353                 $src_pkgs{$versions[$i][0]} =
 354                     $s->resultset('SrcPkg')->find_or_create({pkg => $versions[$i][0]});
 355             }
 356             $sp = $src_pkgs{$versions[$i][0]};
 357             # There's probably something wrong if the source package
 358             # doesn't exist, but we'll skip it for now
 359             next unless defined $sp;
 360             my $sv = $s->resultset('SrcVer')->find({src_pkg=>$sp->id(),
 361                                                     ver => $versions[$i][1],
 362                                                    });
 363             if (defined $ancestor_sv and defined $sv and not defined $sv->based_on()) {
 364                 $sv->update({based_on => $ancestor_sv->id()})
 365             }
 366             $ancestor_sv = $sv;
 367         }
 368         $p->update() if $p;
 369     }
 370     $p->remove() if $p;
 371 }
 372
 373 sub add_debinfo {
 374     my ($options,$opts,$p,$config,$argv) = @_;
 375
 376     my @files = @{$argv};
 377     if (not @files) {
 378        {
 379            local $/ = "\n";
 380            local $/ = "\0" if $opts->{0};
 381            while (<STDIN>) {
 382                s/\n$// unless $opts->{0};
 383                s/\0$// if $opts->{0};
 384                push @files, $_;
 385            }
 386        }
 387     }
 388     return unless @files;
 389     my $s = db_connect($options);
 390     my %cache;
 391     $p->target(scalar @files) if $p;
 392     my $it = natatime 100, @files;
 393     while (my @v = $it->()) {
 394         my @debinfos;
 395         for my $file (@v) {
 396             my $fh = IO::File->new($file,'r') or
 397                 die "Unable to open $file for reading: $!";
 398             my $f_stat = stat($file);
 399             my $ct_date = DateTime->from_epoch(epoch => $f_stat->ctime);
 400             while (<$fh>) {
 401                 chomp;
 402                 next unless length $_;
 403                 my ($binname, $binver, $binarch, $srcname, $srcver) = split;
 404                 # if $srcver is not defined, this is probably a broken
 405                 # .debinfo file [they were causing #686106, see commit
 406                 # 49c85ab8 in dak.] Basically, $binarch didn't get put into
 407                 # the file, so we'll fudge it from the filename.
 408                 if (not defined $srcver) {
 409                     ($srcname,$srcver) = ($binarch,$srcname);
 410                     ($binarch) = $file =~ /_([^\.]+)\.debinfo/;
 411                 }
 412                 push @debinfos,
 413                     [$binname,$binver,$binarch,$srcname,$srcver,$ct_date];
 414             }
 415         }
 416         $s->txn_do(
 417             sub {
 418                 for my $di (@debinfos) {
 419                     Debbugs::DB::Load::load_debinfo($s,@{$di}[0..5],\%cache);
 420                 }
 421             });
 422         $p->update($p->last_update()+@v) if $p;
 423     }
 424     $p->remove() if $p;
 425 }
 426
 427 sub add_maintainers {
 428     my ($options,$opts,$p,$config,$argv) = @_;
 429
 430     my $s = db_connect($options);
 431     my $maintainers = getsourcemaintainers();
 432     $p->target(2) if $p;
 433     ## get all of the maintainers, and add the missing ones
 434     my $maints = $s->resultset('Maintainer')->
 435         get_maintainers(values %{$maintainers});
 436     $p->update();
 437     my @svs = $s->resultset('SrcVer')->
 438         search({maintainer => undef
 439                },
 440               {join => 'src_pkg',
 441                group_by => 'me.src_pkg, src_pkg.pkg',
 442                result_class => 'DBIx::Class::ResultClass::HashRefInflator',
 443                columns => [qw(me.src_pkg src_pkg.pkg)],
 444               }
 445               )->all();
 446     $p->target(2+@svs) if $p;
 447     $p->update() if $p;
 448     for my $sv (@svs) {
 449         if (exists $maintainers->{$sv->{src_pkg}{pkg}}) {
 450             my $pkg = $sv->{src_pkg}{pkg};
 451             my $maint = $maints->
 452                {$maintainers->{$pkg}};
 453             $s->txn_do(sub {$s->resultset('SrcVer')->
 454                                 search({maintainer => undef,
 455                                         'src_pkg.pkg' => $pkg
 456                                        },
 457                                       {join => 'src_pkg'}
 458                                       )->update({maintainer => $maint})
 459                                   });
 460         }
 461         $p->update() if $p;
 462     }
 463     $p->remove() if $p;
 464 }
 465
 466 sub add_configuration {
 467     my ($options,$opts,$p,$config,$argv) = @_;
 468
 469     my $s = db_connect($options);
 470
 471     # tags
 472     # add all tags
 473     my %tags;
 474     for my $tag (@{$config{tags}}) {
 475         $tags{$tag} = 1;
 476         $s->resultset('Tag')->find_or_create({tag => $tag});
 477     }
 478     # mark obsolete tags
 479     for my $tag ($s->resultset('Tag')->search_rs()->all()) {
 480         next if exists $tags{$tag->tag};
 481         $tag->obsolete(1);
 482         $tag->update;
 483     }
 484
 485     # severities
 486     my %sev_names;
 487     my $order = -1;
 488     for my $sev_name (($config{default_severity},@{$config{severity_list}})) {
 489         # add all severitites
 490         my $sev = $s->resultset('Severity')->find_or_create({severity => $sev_name});
 491         # mark strong severities
 492         if (grep {$_ eq $sev_name} @{$config{strong_severities}}) {
 493             $sev->strong(1);
 494         }
 495         $sev->ordering($order);
 496         $sev->update();
 497         $order++;
 498         $sev_names{$sev_name} = 1;
 499     }
 500     # mark obsolete severities
 501     for my $sev ($s->resultset('Severity')->search_rs()->all()) {
 502         next if exists $sev_names{$sev->severity()};
 503         $sev->obsolete(1);
 504         $sev->update();
 505     }
 506 }
 507
 508 sub add_suite {
 509     my ($options,$opts,$p,$config,$argv) = @_;
 510     # suites
 511
 512     my $s = db_connect($options);
 513     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 514     my @dist_names =
 515         grep { $_ !~ /^\./ and
 516                -d $opts->{ftpdists}.'/'.$_ and
 517                not -l $opts->{ftpdists}.'/'.$_
 518            } $dist_dir->read;
 519     while (my $dist = shift @dist_names) {
 520         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 521         my ($dist_info,$package_files) =
 522             read_release_file($dist_dir.'/Release');
 523         load_suite($s,$dist_info);
 524     }
 525 }
 526
 527 sub add_logs {
 528     my ($options,$opts,$p,$config,$argv) = @_;
 529
 530     chdir($config->{spool_dir}) or
 531         die "chdir $config->{spool_dir} failed: $!";
 532
 533     my $verbose = $options->{debug};
 534
 535     my $initialdir = "db-h";
 536
 537     if (defined $argv->[0] and $argv->[0] eq "archive") {
 538         $initialdir = "archive";
 539     }
 540     my $s = db_connect($options);
 541
 542
 543     my $time = 0;
 544     my $start_time = time;
 545
 546     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 547               $p,
 548               'log',
 549               $verbose,
 550               sub {
 551                   my $bug = shift;
 552                   my $stat = stat(getbugcomponent($bug,'log',$initialdir));
 553                   if (not defined $stat) {
 554                       print STDERR "Unable to stat $bug $!\n";
 555                       next;
 556                   }
 557                   if ($options{quick}) {
 558                       my $rs = $s->resultset('Bug')->search({bug=>$bug})->single();
 559                       next if defined $rs and $stat->mtime <= $rs->last_modified()->epoch();
 560                   }
 561                   eval {
 562                       load_bug_log(db => $s,
 563                                    bug => $bug);
 564                   };
 565                   if ($@) {
 566                       die "failure while trying to load bug log $bug\n$@";
 567                   }
 568               });
 569 }
 570
 571 sub add_packages {
 572     my ($options,$opts,$p,$config,$argv) = @_;
 573
 574     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 575     my @dist_names =
 576         grep { $_ !~ /^\./ and
 577                -d $opts->{ftpdists}.'/'.$_ and
 578                not -l $opts->{ftpdists}.'/'.$_
 579            } $dist_dir->read;
 580     my %s_p;
 581     while (my $dist = shift @dist_names) {
 582         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 583         my ($dist_info,$package_files) =
 584             read_release_file($dist_dir.'/Release');
 585         $s_p{$dist_info->{Codename}} = $package_files;
 586     }
 587     my $tot = 0;
 588     for my $suite (keys %s_p) {
 589         for my $component (keys %{$s_p{$suite}}) {
 590             $tot += scalar keys %{$s_p{$suite}{$component}};
 591         }
 592     }
 593     $p->target($tot) if $p;
 594     my $i = 0;
 595     my $avg_pkgs = 0;
 596     my $tot_suites = scalar keys %s_p;
 597     my $done_suites=0;
 598     my $completed_pkgs=0;
 599     # parse packages files
 600     for my $suite (keys %s_p) {
 601         my @pkgs;
 602         for my $component (keys %{$s_p{$suite}}) {
 603             my @archs = keys %{$s_p{$suite}{$component}};
 604             if (grep {$_ eq 'source'} @archs) {
 605                 @archs = ('source',grep {$_ ne 'source'} @archs);
 606             }
 607             for my $arch (@archs) {
 608                 my $pfh =  open_compressed_file($s_p{$suite}{$component}{$arch}) or
 609                     die "Unable to open $s_p{$suite}{$component}{$arch} for reading: $!";
 610                 local $_;
 611                 local $/ = '';  # paragraph mode
 612                 while (<$pfh>) {
 613                     my %pkg;
 614                     for my $field (qw(Package Maintainer Version Source)) {
 615                         /^\Q$field\E: (.*)/m;
 616                         $pkg{$field} = $1;
 617                     }
 618                     next unless defined $pkg{Package} and
 619                         defined $pkg{Version};
 620                     push @pkgs,[$arch,$component,\%pkg];
 621                 }
 622             }
 623         }
 624         my $s = db_connect($options);
 625         if ($avg_pkgs==0) {
 626             $avg_pkgs = @pkgs;
 627         }
 628         $p->target($avg_pkgs*($tot_suites-$done_suites-1)+
 629                    $completed_pkgs+@pkgs) if $p;
 630         load_packages($s,
 631                       $suite,
 632                       \@pkgs,
 633                       $p);
 634         $avg_pkgs=($avg_pkgs*$done_suites + @pkgs)/($done_suites+1);
 635         $completed_pkgs += @pkgs;
 636         $done_suites++;
 637     }
 638     $p->remove() if $p;
 639 }
 640
 641 sub handle_subcommand_arguments {
 642     my ($argv,$args) = @_;
 643     my $subopt = {};
 644     Getopt::Long::GetOptionsFromArray($argv,
 645                               $subopt,
 646                               keys %{$args},
 647                              );
 648     my @usage_errors;
 649     for my $arg  (keys %{$args}) {
 650         next unless $args->{$arg};
 651         my $r_arg = $arg; # real argument name
 652         $r_arg =~ s/[=\|].+//g;
 653         if (not defined $subopt->{$r_arg}) {
 654             push @usage_errors, "You must give a $r_arg option";
 655         }
 656     }
 657     pod2usage(join("\n",@usage_errors)) if @usage_errors;
 658     return $subopt;
 659 }
 660
 661 sub get_lock{
 662     my ($subcommand,$config,$options) = @_;
 663     if (not lockpid($config->{spool_dir}.'/lock/debbugs-loadsql-$subcommand')) {
 664         if ($options->{quick}) {
 665             # If this is a quick run, just exit
 666             print STDERR "Another debbugs-loadsql is running; stopping\n" if $options->{verbose};
 667             exit 0;
 668         }
 669         print STDERR "Another debbugs-loadsql is running; stopping\n";
 670         exit 1;
 671     }
 672 }
 673
 674 sub db_connect {
 675     my ($options) = @_;
 676     # connect to the database; figure out how to handle errors
 677     # properly here.
 678     my $s = Debbugs::DB->connect($options->{service}) or
 679         die "Unable to connect to database: ";
 680 }
 681
 682 sub read_release_file {
 683     my ($file) = @_;
 684     # parse release
 685     my $rfh =  open_compressed_file($file) or
 686         die "Unable to open $file for reading: $!";
 687     my %dist_info;
 688     my $in_sha1;
 689     my %p_f;
 690     while (<$rfh>) {
 691         chomp;
 692         if (s/^(\S+):\s*//) {
 693             if ($1 eq 'SHA1'or $1 eq 'SHA256') {
 694                 $in_sha1 = 1;
 695                 next;
 696             }
 697             $dist_info{$1} = $_;
 698         } elsif ($in_sha1) {
 699             s/^\s//;
 700             my ($sha,$size,$f) = split /\s+/,$_;
 701             next unless $f =~ /(?:Packages|Sources)(?:\.gz|\.xz)$/;
 702             next unless $f =~ m{^([^/]+)/([^/]+)/([^/]+)$};
 703             my ($component,$arch,$package_source) = ($1,$2,$3);
 704             $arch =~ s/binary-//;
 705             next if exists $p_f{$component}{$arch};
 706             $p_f{$component}{$arch} = File::Spec->catfile(dirname($file),$f);
 707         }
 708     }
 709     return (\%dist_info,\%p_f);
 710 }
 711
 712 sub walk_bugs {
 713     my ($dirs,$p,$what,$verbose,$sub,$n) = @_;
 714     my @dirs = @{$dirs};
 715     my $tot_dirs = @dirs;
 716     my $done_dirs = 0;
 717     my $avg_subfiles = 0;
 718     my $completed_files = 0;
 719     $n //= 1;
 720     while (my $dir = shift @dirs) {
 721         printf "Doing dir %s ...\n", $dir if $verbose;
 722
 723         opendir(DIR, "$dir/.") or die "opendir $dir: $!";
 724         my @subdirs = readdir(DIR);
 725         closedir(DIR);
 726
 727         my @list = map { m/^(\d+)\.$what$/?($1):() } @subdirs;
 728         $tot_dirs -= @dirs;
 729         push @dirs, map { m/^(\d+)$/ && -d "$dir/$1"?("$dir/$1"):() } @subdirs;
 730         $tot_dirs += @dirs;
 731         if ($avg_subfiles == 0) {
 732             $avg_subfiles = @list;
 733         }
 734
 735         $p->target($avg_subfiles*($tot_dirs-$done_dirs)+$completed_files+@list) if $p;
 736         $avg_subfiles = ($avg_subfiles * $done_dirs + @list) / ($done_dirs+1);
 737         $done_dirs += 1;
 738
 739         my $it = natatime $n,@list;
 740         while (my @bugs = $it->()) {
 741           $sub->(@bugs);
 742           $completed_files += scalar @bugs;
 743           $p->update($completed_files) if $p;
 744           print "Up to $completed_files bugs...\n"
 745             if ($completed_files % 100 == 0 && $verbose);
 746         }
 747     }
 748     $p->remove() if $p;
 749 }
 750
 751
 752
 753 __END__