bin/debbugs-loadsql

   1 #! /usr/bin/perl
   2 # debbugs-loadsql is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2012 by Don Armstrong <don@donarmstrong.com>.
   6
   7
   8 use warnings;
   9 use strict;
  10
  11 use Getopt::Long qw(:config no_ignore_case);
  12 use Pod::Usage;
  13
  14 =head1 NAME
  15
  16 debbugs-loadsql -- load debbugs sql database
  17
  18 =head1 SYNOPSIS
  19
  20 debbugs-loadsql [options] [subcommand]
  21
  22  Subcommands:
  23   bugs help versions configuration
  24   suites logs packages debinfo
  25  Options:
  26   --quick, -q only load changed things
  27   --progress Show progress bar
  28   --service, -s service name
  29   --sysconfdir, -c postgresql service config dir
  30   --spool-dir debbugs spool directory
  31   --debug, -d debugging level (Default 0)
  32   --help, -h display this help
  33   --man, -m display manual
  34
  35 =head1 SUBCOMMANDS
  36
  37 =head2 help
  38
  39 Display this manual
  40
  41 =head2 bugs
  42
  43 Add bugs (subject, number, etc) to the database
  44
  45    --preload create all bugs first, then add information
  46
  47 =head2 versions
  48
  49 Add version descendant information (which version is based on which version) to
  50 the database
  51
  52 =head2 maintainers
  53
  54 Add source maintainers to the BTS
  55
  56 =head2 configuration
  57
  58 Add debbugs configuration information (tags, severity, etc)
  59
  60 =head2 suites
  61
  62 Add suite information from ftp distribution
  63
  64   --ftpdists location of FTP mirror
  65
  66 =head2 logs
  67
  68 Add bug logs
  69
  70 =head2 packages
  71
  72 Add package information from the ftp archive
  73
  74   --ftpdists location of FTP mirror
  75   --suites Suite to operate on
  76
  77 =head2 debinfo
  78
  79 Add package information from a debinfo file
  80
  81   --null -0 names of debinfo files are null separated
  82
  83 =head1 OPTIONS
  84
  85 =over
  86
  87 =item B<--quick, -q>
  88
  89 Only load changed bugs
  90
  91 =item B<--progress>
  92
  93 Show progress bar (requires Term::ProgressBar)
  94
  95 =item B<--service,-s>
  96
  97 Postgreql service to use; defaults to debbugs
  98
  99 =item B<--sysconfdir,-c>
 100
 101 System configuration directory to use; if not set, defaults to the
 102 postgresql default. [Operates by setting PGSYSCONFDIR]
 103
 104 =item B<--spool-dir>
 105
 106 Debbugs spool directory; defaults to the value configured in the
 107 debbugs configuration file.
 108
 109 =item B<--verbose>
 110
 111 Output more information about what is happening. Probably not useful
 112 if you also set --progress.
 113
 114 =item B<--debug, -d>
 115
 116 Debug verbosity.
 117
 118 =item B<--help, -h>
 119
 120 Display brief useage information.
 121
 122 =item B<--man, -m>
 123
 124 Display this manual.
 125
 126 =back
 127
 128
 129 =cut
 130
 131
 132 use vars qw($DEBUG);
 133
 134 use Debbugs::Common (qw(checkpid lockpid get_hashname getparsedaddrs getbugcomponent make_list getsourcemaintainers),
 135                      qw(hash_slice open_compressed_file),);
 136 use Debbugs::Config qw(:config);
 137 use Debbugs::Status qw(read_bug split_status_fields);
 138 use Debbugs::Log;
 139 use Debbugs::DB;
 140 use Debbugs::DB::Load qw(:load_bug :load_package :load_suite);
 141 use DateTime;
 142 use File::stat;
 143 use File::Basename;
 144 use File::Spec;
 145 use IO::Dir;
 146 use IO::File;
 147 use IO::Uncompress::AnyUncompress;
 148 use Encode qw(decode_utf8);
 149 use List::MoreUtils qw(natatime);
 150
 151 my %options =
 152     (debug           => 0,
 153      help            => 0,
 154      man             => 0,
 155      verbose         => 0,
 156      quiet           => 0,
 157      quick           => 0,
 158      service         => $config{debbugs_db},
 159      progress        => 0,
 160     );
 161
 162 Getopt::Long::Configure('pass_through');
 163 GetOptions(\%options,
 164            'quick|q',
 165            'service|s=s',
 166            'sysconfdir|c=s',
 167            'progress!',
 168            'spool_dir|spool-dir=s',
 169            'verbose|v+',
 170            'quiet+',
 171            'debug|d+','help|h|?','man|m');
 172 Getopt::Long::Configure('default');
 173
 174 pod2usage() if $options{help};
 175 pod2usage({verbose=>2}) if $options{man};
 176
 177 $DEBUG = $options{debug};
 178
 179 my %subcommands =
 180     ('bugs' => {function => \&add_bugs,
 181                 arguments => {'preload' => 0},
 182                },
 183      'versions' => {function => \&add_versions,
 184                    },
 185      'debinfo' => {function => \&add_debinfo,
 186                    arguments => {'0|null' => 0},
 187                   },
 188      'maintainers' => {function => \&add_maintainers,
 189                       },
 190      'configuration' => {function => \&add_configuration,
 191                         },
 192      'suites' => {function => \&add_suite,
 193                   arguments => {'ftpdists=s' => 1,
 194                                },
 195                  },
 196      'logs' => {function => \&add_logs,
 197                },
 198      'packages' => {function => \&add_packages,
 199                     arguments => {'ftpdists=s' => 1,
 200                                   'suites=s@' => 0,
 201                                  },
 202                    },
 203      'help' => {function => sub {pod2usage({verbose => 2});}}
 204     );
 205
 206 my @USAGE_ERRORS;
 207 $options{verbose} = $options{verbose} - $options{quiet};
 208
 209 if ($options{progress}) {
 210     eval "use Term::ProgressBar";
 211     push @USAGE_ERRORS, "You asked for a progress bar, but Term::ProgressBar isn't installed" if $@;
 212 }
 213
 214
 215 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 216
 217 if (exists $options{sysconfdir}) {
 218     if (not defined $options{sysconfdir} or not length $options{sysconfdir}) {
 219         delete $ENV{PGSYSCONFDIR};
 220     } else {
 221         $ENV{PGSYSCONFDIR} = $options{sysconfdir};
 222     }
 223 }
 224
 225 if (exists $options{spool_dir} and defined $options{spool_dir}) {
 226     $config{spool_dir} = $options{spool_dir};
 227 }
 228
 229 my $prog_bar;
 230 if ($options{progress}) {
 231     $prog_bar = eval "Term::ProgressBar->new({count => 1,ETA=>q(linear)})";
 232     warn "Unable to initialize progress bar: $@" if not $prog_bar;
 233 }
 234
 235
 236 my ($subcommand) = shift @ARGV;
 237 if (not defined $subcommand) {
 238     $subcommand = 'help';
 239     print STDERR "You must provide a subcommand; displaying usage.\n";
 240     pod2usage();
 241 } elsif (not exists $subcommands{$subcommand}) {
 242     print STDERR "$subcommand is not a valid subcommand; displaying usage.\n";
 243     pod2usage();
 244 }
 245
 246 binmode(STDOUT,':encoding(UTF-8)');
 247 binmode(STDERR,':encoding(UTF-8)');
 248
 249 my $opts =
 250     handle_subcommand_arguments(\@ARGV,$subcommands{$subcommand}{arguments});
 251 $subcommands{$subcommand}{function}->(\%options,$opts,$prog_bar,\%config,\@ARGV);
 252
 253 sub add_bugs {
 254     my ($options,$opts,$p,$config,$argv) = @_;
 255     chdir($config->{spool_dir}) or
 256         die "chdir $config->{spool_dir} failed: $!";
 257
 258     my $verbose = $options->{debug};
 259
 260     my $initialdir = "db-h";
 261
 262     if (defined $argv->[0] and $argv->[0] eq "archive") {
 263         $initialdir = "archive";
 264     }
 265     my $s = db_connect($options);
 266
 267
 268     my $time = 0;
 269     my $start_time = time;
 270     my %tags;
 271     my %severities;
 272     my %queue;
 273
 274     if ($opts->{preload}) {
 275         my @bugs;
 276         walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 277                   undef,
 278                   'summary',
 279                   undef,
 280                   sub {
 281                     push @bugs,@_;
 282                   },
 283                   10000
 284                  );
 285         $s->resultset('Bug')->quick_insert_bugs(@bugs);
 286     }
 287     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 288               $p,
 289               'summary',
 290               $verbose,
 291               sub {
 292                 my @bugs = @_;
 293                 my @bugs_to_update;
 294                 if ($options{quick}) {
 295                   for my $bug (@bugs) {
 296                     my $stat = stat(getbugcomponent($bug,'summary',$initialdir));
 297                     if (not defined $stat) {
 298                       print STDERR "Unable to stat $bug $!\n";
 299                       next;
 300                     }
 301                     my $rs = $s->resultset('Bug')->search({id=>$bug})->single();
 302                     next if defined $rs and $stat->mtime < $rs->last_modified()->epoch();
 303                     push @bugs_to_update, $bug;
 304                   }
 305                 } else {
 306                   @bugs_to_update = @bugs;
 307                 }
 308                 eval {
 309                   $s->txn_do(sub {
 310                                for my $bug (@bugs) {
 311                                  load_bug(db => $s,
 312                                           bug => $bug,
 313                                           tags => \%tags,
 314                                           severities => \%severities,
 315                                           queue => \%queue);
 316                                }
 317                              });
 318                 };
 319                 if ($@) {
 320                   die "failure while trying to load bug: $@";
 321                 }
 322               },
 323               50
 324              );
 325     handle_load_bug_queue(db => $s,
 326                           queue => \%queue);
 327 }
 328
 329 sub add_versions {
 330     my ($options,$opts,$p,$config,$argv) = @_;
 331
 332     my $s = db_connect($options);
 333
 334     my @files = @{$argv};
 335     $p->target(scalar @files) if $p;
 336     for my $file (@files) {
 337         my $fh = IO::File->new($file,'r') or
 338             die "Unable to open $file for reading: $!";
 339         my @versions;
 340         my %src_pkgs;
 341         while (<$fh>) {
 342             chomp;
 343             next unless length $_;
 344             if (/(\w[-+0-9a-z.]+) \(([^\(\) \t]+)\)/) {
 345                 push @versions, [$1,$2];
 346             }
 347         }
 348         close($fh);
 349         my $ancestor_sv;
 350         for my $i (reverse 0..($#versions)) {
 351             my $sp;
 352             if (not defined $src_pkgs{$versions[$i][0]}) {
 353                 $src_pkgs{$versions[$i][0]} =
 354                     $s->resultset('SrcPkg')->find_or_create({pkg => $versions[$i][0]});
 355             }
 356             $sp = $src_pkgs{$versions[$i][0]};
 357             # There's probably something wrong if the source package
 358             # doesn't exist, but we'll skip it for now
 359             next unless defined $sp;
 360             my $sv = $s->resultset('SrcVer')->find({src_pkg=>$sp->id(),
 361                                                     ver => $versions[$i][1],
 362                                                    });
 363             if (defined $ancestor_sv and defined $sv and not defined $sv->based_on()) {
 364                 $sv->update({based_on => $ancestor_sv->id()})
 365             }
 366             $ancestor_sv = $sv;
 367         }
 368         $p->update() if $p;
 369     }
 370     $p->remove() if $p;
 371 }
 372
 373 sub add_debinfo {
 374     my ($options,$opts,$p,$config,$argv) = @_;
 375
 376     my @files = @{$argv};
 377     if (not @files) {
 378        {
 379            if ($opts->{0}) {
 380                local $/ = "\0";
 381            }
 382            while (<STDIN>) {
 383                push @files, $_;
 384            }
 385        }
 386     }
 387     return unless @files;
 388     my $s = db_connect($options);
 389     my %arch;
 390     $p->target(scalar @files) if $p;
 391     for my $file (@files) {
 392         my $fh = IO::File->new($file,'r') or
 393             die "Unable to open $file for reading: $!";
 394         my $f_stat = stat($file);
 395         while (<$fh>) {
 396             chomp;
 397             next unless length $_;
 398             my ($binname, $binver, $binarch, $srcname, $srcver) = split;
 399             # if $srcver is not defined, this is probably a broken
 400             # .debinfo file [they were causing #686106, see commit
 401             # 49c85ab8 in dak.] Basically, $binarch didn't get put into
 402             # the file, so we'll fudge it from the filename.
 403             if (not defined $srcver) {
 404                 ($srcname,$srcver) = ($binarch,$srcname);
 405                 ($binarch) = $file =~ /_([^\.]+)\.debinfo/;
 406             }
 407             my $sp = $s->resultset('SrcPkg')->find_or_create({pkg => $srcname});
 408             # update the creation date if the data we have is earlier
 409             my $ct_date = DateTime->from_epoch(epoch => $f_stat->ctime);
 410             if ($ct_date < $sp->creation) {
 411                 $sp->creation($ct_date);
 412                 $sp->last_modified(DateTime->now);
 413                 $sp->update;
 414             }
 415             my $sv = $s->resultset('SrcVer')->find_or_create({src_pkg =>$sp->id(),
 416                                                               ver => $srcver});
 417             if (not defined $sv->upload_date() or $ct_date < $sv->upload_date()) {
 418                 $sv->upload_date($ct_date);
 419                 $sv->update;
 420             }
 421             my $arch;
 422             if (defined $arch{$binarch}) {
 423                 $arch = $arch{$binarch};
 424             } else {
 425                 $arch = $s->resultset('Arch')->find_or_create({arch => $binarch});
 426                 $arch{$binarch} = $arch;
 427             }
 428             my $bp = $s->resultset('BinPkg')->find_or_create({pkg => $binname});
 429             $s->resultset('BinVer')->find_or_create({bin_pkg => $bp->id(),
 430                                                      src_ver => $sv->id(),
 431                                                      arch    => $arch->id(),
 432                                                      ver        => $binver,
 433                                                     });
 434         }
 435         $p->update() if $p;
 436     }
 437     $p->remove() if $p;
 438 }
 439
 440 sub add_maintainers {
 441     my ($options,$opts,$p,$config,$argv) = @_;
 442
 443     my $s = db_connect($options);
 444     my $maintainers = getsourcemaintainers();
 445     $p->target(2) if $p;
 446     ## get all of the maintainers, and add the missing ones
 447     my $maints = $s->resultset('Maintainer')->
 448         get_maintainers(values %{$maintainers});
 449     $p->update();
 450     my @svs = $s->resultset('SrcVer')->
 451         search({maintainer => undef
 452                },
 453               {join => 'src_pkg',
 454                group_by => 'me.src_pkg, src_pkg.pkg',
 455                result_class => 'DBIx::Class::ResultClass::HashRefInflator',
 456                columns => [qw(me.src_pkg src_pkg.pkg)],
 457               }
 458               )->all();
 459     $p->target(2+@svs) if $p;
 460     $p->update() if $p;
 461     for my $sv (@svs) {
 462         if (exists $maintainers->{$sv->{src_pkg}{pkg}}) {
 463             my $pkg = $sv->{src_pkg}{pkg};
 464             my $maint = $maints->
 465                {$maintainers->{$pkg}};
 466             $s->txn_do(sub {$s->resultset('SrcVer')->
 467                                 search({maintainer => undef,
 468                                         'src_pkg.pkg' => $pkg
 469                                        },
 470                                       {join => 'src_pkg'}
 471                                       )->update({maintainer => $maint})
 472                                   });
 473         }
 474         $p->update() if $p;
 475     }
 476     $p->remove() if $p;
 477 }
 478
 479 sub add_configuration {
 480     my ($options,$opts,$p,$config,$argv) = @_;
 481
 482     my $s = db_connect($options);
 483
 484     # tags
 485     # add all tags
 486     my %tags;
 487     for my $tag (@{$config{tags}}) {
 488         $tags{$tag} = 1;
 489         $s->resultset('Tag')->find_or_create({tag => $tag});
 490     }
 491     # mark obsolete tags
 492     for my $tag ($s->resultset('Tag')->search_rs()->all()) {
 493         next if exists $tags{$tag->tag};
 494         $tag->obsolete(1);
 495         $tag->update;
 496     }
 497
 498     # severities
 499     my %sev_names;
 500     my $order = -1;
 501     for my $sev_name (($config{default_severity},@{$config{severity_list}})) {
 502         # add all severitites
 503         my $sev = $s->resultset('Severity')->find_or_create({severity => $sev_name});
 504         # mark strong severities
 505         if (grep {$_ eq $sev_name} @{$config{strong_severities}}) {
 506             $sev->strong(1);
 507         }
 508         $sev->ordering($order);
 509         $sev->update();
 510         $order++;
 511         $sev_names{$sev_name} = 1;
 512     }
 513     # mark obsolete severities
 514     for my $sev ($s->resultset('Severity')->search_rs()->all()) {
 515         next if exists $sev_names{$sev->severity()};
 516         $sev->obsolete(1);
 517         $sev->update();
 518     }
 519 }
 520
 521 sub add_suite {
 522     my ($options,$opts,$p,$config,$argv) = @_;
 523     # suites
 524
 525     my $s = db_connect($options);
 526     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 527     my @dist_names =
 528         grep { $_ !~ /^\./ and
 529                -d $opts->{ftpdists}.'/'.$_ and
 530                not -l $opts->{ftpdists}.'/'.$_
 531            } $dist_dir->read;
 532     while (my $dist = shift @dist_names) {
 533         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 534         my ($dist_info,$package_files) =
 535             read_release_file($dist_dir.'/Release');
 536         load_suite($s,$dist_info);
 537     }
 538 }
 539
 540 sub add_logs {
 541     my ($options,$opts,$p,$config,$argv) = @_;
 542
 543     chdir($config->{spool_dir}) or
 544         die "chdir $config->{spool_dir} failed: $!";
 545
 546     my $verbose = $options->{debug};
 547
 548     my $initialdir = "db-h";
 549
 550     if (defined $argv->[0] and $argv->[0] eq "archive") {
 551         $initialdir = "archive";
 552     }
 553     my $s = db_connect($options);
 554
 555
 556     my $time = 0;
 557     my $start_time = time;
 558
 559     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 560               $p,
 561               'log',
 562               $verbose,
 563               sub {
 564                   my $bug = shift;
 565                   my $stat = stat(getbugcomponent($bug,'log',$initialdir));
 566                   if (not defined $stat) {
 567                       print STDERR "Unable to stat $bug $!\n";
 568                       next;
 569                   }
 570                   if ($options{quick}) {
 571                       my $rs = $s->resultset('Bug')->search({bug=>$bug})->single();
 572                       next if defined $rs and $stat->mtime < $rs->last_modified()->epoch();
 573                   }
 574                   eval {
 575                       load_bug_log(db => $s,
 576                                    bug => $bug);
 577                   };
 578                   if ($@) {
 579                       die "failure while trying to load bug log $bug\n$@";
 580                   }
 581               });
 582 }
 583
 584 sub add_packages {
 585     my ($options,$opts,$p,$config,$argv) = @_;
 586
 587     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 588     my @dist_names =
 589         grep { $_ !~ /^\./ and
 590                -d $opts->{ftpdists}.'/'.$_ and
 591                not -l $opts->{ftpdists}.'/'.$_
 592            } $dist_dir->read;
 593     my %s_p;
 594     while (my $dist = shift @dist_names) {
 595         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 596         my ($dist_info,$package_files) =
 597             read_release_file($dist_dir.'/Release');
 598         $s_p{$dist_info->{Codename}} = $package_files;
 599     }
 600     my $tot = 0;
 601     for my $suite (keys %s_p) {
 602         for my $component (keys %{$s_p{$suite}}) {
 603             $tot += scalar keys %{$s_p{$suite}{$component}};
 604         }
 605     }
 606     $p->target($tot) if $p;
 607     my $i = 0;
 608     my $avg_pkgs = 0;
 609     my $tot_suites = scalar keys %s_p;
 610     my $done_suites=0;
 611     my $completed_pkgs=0;
 612     # parse packages files
 613     for my $suite (keys %s_p) {
 614         my @pkgs;
 615         for my $component (keys %{$s_p{$suite}}) {
 616             my @archs = keys %{$s_p{$suite}{$component}};
 617             if (grep {$_ eq 'source'} @archs) {
 618                 @archs = ('source',grep {$_ ne 'source'} @archs);
 619             }
 620             for my $arch (@archs) {
 621                 my $pfh =  open_compressed_file($s_p{$suite}{$component}{$arch}) or
 622                     die "Unable to open $s_p{$suite}{$component}{$arch} for reading: $!";
 623                 local $_;
 624                 local $/ = '';  # paragraph mode
 625                 while (<$pfh>) {
 626                     my %pkg;
 627                     for my $field (qw(Package Maintainer Version Source)) {
 628                         /^\Q$field\E: (.*)/m;
 629                         $pkg{$field} = $1;
 630                     }
 631                     next unless defined $pkg{Package} and
 632                         defined $pkg{Version};
 633                     push @pkgs,[$arch,$component,\%pkg];
 634                 }
 635             }
 636         }
 637         my $s = db_connect($options);
 638         if ($avg_pkgs==0) {
 639             $avg_pkgs = @pkgs;
 640         }
 641         $p->target($avg_pkgs*($tot_suites-$done_suites-1)+
 642                    $completed_pkgs+@pkgs) if $p;
 643         load_packages($s,
 644                       $suite,
 645                       \@pkgs,
 646                       $p);
 647         $avg_pkgs=($avg_pkgs*$done_suites + @pkgs)/($done_suites+1);
 648         $completed_pkgs += @pkgs;
 649         $done_suites++;
 650     }
 651     $p->remove() if $p;
 652 }
 653
 654 sub handle_subcommand_arguments {
 655     my ($argv,$args) = @_;
 656     my $subopt = {};
 657     Getopt::Long::GetOptionsFromArray($argv,
 658                               $subopt,
 659                               keys %{$args},
 660                              );
 661     my @usage_errors;
 662     for my $arg  (keys %{$args}) {
 663         next unless $args->{$arg};
 664         my $r_arg = $arg; # real argument name
 665         $r_arg =~ s/[=\|].+//g;
 666         if (not defined $subopt->{$r_arg}) {
 667             push @usage_errors, "You must give a $r_arg option";
 668         }
 669     }
 670     pod2usage(join("\n",@usage_errors)) if @usage_errors;
 671     return $subopt;
 672 }
 673
 674 sub get_lock{
 675     my ($subcommand,$config,$options) = @_;
 676     if (not lockpid($config->{spool_dir}.'/lock/debbugs-loadsql-$subcommand')) {
 677         if ($options->{quick}) {
 678             # If this is a quick run, just exit
 679             print STDERR "Another debbugs-loadsql is running; stopping\n" if $options->{verbose};
 680             exit 0;
 681         }
 682         print STDERR "Another debbugs-loadsql is running; stopping\n";
 683         exit 1;
 684     }
 685 }
 686
 687 sub db_connect {
 688     my ($options) = @_;
 689     # connect to the database; figure out how to handle errors
 690     # properly here.
 691     my $s = Debbugs::DB->connect($options->{service}) or
 692         die "Unable to connect to database: ";
 693 }
 694
 695 sub read_release_file {
 696     my ($file) = @_;
 697     # parse release
 698     my $rfh =  open_compressed_file($file) or
 699         die "Unable to open $file for reading: $!";
 700     my %dist_info;
 701     my $in_sha1;
 702     my %p_f;
 703     while (<$rfh>) {
 704         chomp;
 705         if (s/^(\S+):\s*//) {
 706             if ($1 eq 'SHA1'or $1 eq 'SHA256') {
 707                 $in_sha1 = 1;
 708                 next;
 709             }
 710             $dist_info{$1} = $_;
 711         } elsif ($in_sha1) {
 712             s/^\s//;
 713             my ($sha,$size,$f) = split /\s+/,$_;
 714             next unless $f =~ /(?:Packages|Sources)(?:\.gz|\.xz)$/;
 715             next unless $f =~ m{^([^/]+)/([^/]+)/([^/]+)$};
 716             my ($component,$arch,$package_source) = ($1,$2,$3);
 717             $arch =~ s/binary-//;
 718             next if exists $p_f{$component}{$arch};
 719             $p_f{$component}{$arch} = File::Spec->catfile(dirname($file),$f);
 720         }
 721     }
 722     return (\%dist_info,\%p_f);
 723 }
 724
 725 sub walk_bugs {
 726     my ($dirs,$p,$what,$verbose,$sub,$n) = @_;
 727     my @dirs = @{$dirs};
 728     my $tot_dirs = @dirs;
 729     my $done_dirs = 0;
 730     my $avg_subfiles = 0;
 731     my $completed_files = 0;
 732     $n //= 1;
 733     while (my $dir = shift @dirs) {
 734         printf "Doing dir %s ...\n", $dir if $verbose;
 735
 736         opendir(DIR, "$dir/.") or die "opendir $dir: $!";
 737         my @subdirs = readdir(DIR);
 738         closedir(DIR);
 739
 740         my @list = map { m/^(\d+)\.$what$/?($1):() } @subdirs;
 741         $tot_dirs -= @dirs;
 742         push @dirs, map { m/^(\d+)$/ && -d "$dir/$1"?("$dir/$1"):() } @subdirs;
 743         $tot_dirs += @dirs;
 744         if ($avg_subfiles == 0) {
 745             $avg_subfiles = @list;
 746         }
 747
 748         $p->target($avg_subfiles*($tot_dirs-$done_dirs)+$completed_files+@list) if $p;
 749         $avg_subfiles = ($avg_subfiles * $done_dirs + @list) / ($done_dirs+1);
 750         $done_dirs += 1;
 751
 752         my $it = natatime $n,@list;
 753         while (my @bugs = $it->()) {
 754           $sub->(@bugs);
 755           $completed_files += scalar @bugs;
 756           $p->update($completed_files) if $p;
 757           print "Up to $completed_files bugs...\n"
 758             if ($completed_files % 100 == 0 && $verbose);
 759         }
 760     }
 761     $p->remove() if $p;
 762 }
 763
 764
 765
 766 __END__