bin/debbugs-loadsql

   1 #! /usr/bin/perl
   2 # debbugs-loadsql is part of debbugs, and is released
   3 # under the terms of the GPL version 2, or any later version, at your
   4 # option. See the file README and COPYING for more information.
   5 # Copyright 2012 by Don Armstrong <don@donarmstrong.com>.
   6
   7
   8 use warnings;
   9 use strict;
  10
  11 use Getopt::Long qw(:config no_ignore_case);
  12 use Pod::Usage;
  13
  14 =head1 NAME
  15
  16 debbugs-loadsql -- load debbugs sql database
  17
  18 =head1 SYNOPSIS
  19
  20 debbugs-loadsql [options] [subcommand]
  21
  22  Subcommands:
  23   bugs help versions configuration
  24   suites logs packages debinfo
  25  Options:
  26   --quick, -q only load changed things
  27   --progress Show progress bar
  28   --service, -s service name
  29   --sysconfdir, -c postgresql service config dir
  30   --spool-dir debbugs spool directory
  31   --debug, -d debugging level (Default 0)
  32   --help, -h display this help
  33   --man, -m display manual
  34
  35 =head1 SUBCOMMANDS
  36
  37 =head2 help
  38
  39 Display this manual
  40
  41 =head2 bugs
  42
  43 Add bugs (subject, number, etc) to the database
  44
  45    --preload create all bugs first, then add information
  46
  47 =head2 versions
  48
  49 Add version descendant information (which version is based on which version) to
  50 the database
  51
  52 =head2 maintainers
  53
  54 Add source maintainers to the BTS
  55
  56 =head2 configuration
  57
  58 Add debbugs configuration information (tags, severity, etc)
  59
  60 =head2 suites
  61
  62 Add suite information from ftp distribution
  63
  64   --ftpdists location of FTP mirror
  65
  66 =head2 logs
  67
  68 Add bug logs
  69
  70 =head2 packages
  71
  72 Add package information from the ftp archive
  73
  74   --ftpdists location of FTP mirror
  75   --suites Suite to operate on
  76
  77 =head2 debinfo
  78
  79 Add package information from a debinfo file
  80
  81   --null -0 names of debinfo files are null separated
  82
  83 =head1 OPTIONS
  84
  85 =over
  86
  87 =item B<--quick, -q>
  88
  89 Only load changed bugs
  90
  91 =item B<--progress>
  92
  93 Show progress bar (requires Term::ProgressBar)
  94
  95 =item B<--service,-s>
  96
  97 Postgreql service to use; defaults to debbugs
  98
  99 =item B<--sysconfdir,-c>
 100
 101 System configuration directory to use; if not set, defaults to the
 102 postgresql default. [Operates by setting PGSYSCONFDIR]
 103
 104 =item B<--spool-dir>
 105
 106 Debbugs spool directory; defaults to the value configured in the
 107 debbugs configuration file.
 108
 109 =item B<--verbose>
 110
 111 Output more information about what is happening. Probably not useful
 112 if you also set --progress.
 113
 114 =item B<--debug, -d>
 115
 116 Debug verbosity.
 117
 118 =item B<--help, -h>
 119
 120 Display brief useage information.
 121
 122 =item B<--man, -m>
 123
 124 Display this manual.
 125
 126 =back
 127
 128
 129 =cut
 130
 131
 132 use vars qw($DEBUG);
 133
 134 use Debbugs::Common (qw(checkpid lockpid get_hashname getparsedaddrs getbugcomponent make_list getsourcemaintainers),
 135                      qw(hash_slice open_compressed_file),);
 136 use Debbugs::Config qw(:config);
 137 use Debbugs::Status qw(read_bug split_status_fields);
 138 use Debbugs::Log;
 139 use Debbugs::DB;
 140 use Debbugs::DB::Load qw(:load_bug :load_package :load_suite);
 141 use DateTime;
 142 use File::stat;
 143 use File::Basename;
 144 use File::Spec;
 145 use IO::Dir;
 146 use IO::File;
 147 use IO::Uncompress::AnyUncompress;
 148 use Encode qw(decode_utf8);
 149 use List::MoreUtils qw(natatime);
 150
 151 my %options =
 152     (debug           => 0,
 153      help            => 0,
 154      man             => 0,
 155      verbose         => 0,
 156      quiet           => 0,
 157      quick           => 0,
 158      service         => $config{debbugs_db},
 159      progress        => 0,
 160     );
 161
 162 Getopt::Long::Configure('pass_through');
 163 GetOptions(\%options,
 164            'quick|q',
 165            'service|s=s',
 166            'sysconfdir|c=s',
 167            'progress!',
 168            'spool_dir|spool-dir=s',
 169            'verbose|v+',
 170            'quiet+',
 171            'debug|d+','help|h|?','man|m');
 172 Getopt::Long::Configure('default');
 173
 174 pod2usage() if $options{help};
 175 pod2usage({verbose=>2}) if $options{man};
 176
 177 $DEBUG = $options{debug};
 178
 179 my %subcommands =
 180     ('bugs' => {function => \&add_bugs,
 181                 arguments => {'preload' => 0},
 182                },
 183      'versions' => {function => \&add_versions,
 184                    },
 185      'debinfo' => {function => \&add_debinfo,
 186                    arguments => {'0|null' => 0},
 187                   },
 188      'maintainers' => {function => \&add_maintainers,
 189                       },
 190      'configuration' => {function => \&add_configuration,
 191                         },
 192      'suites' => {function => \&add_suite,
 193                   arguments => {'ftpdists=s' => 1,
 194                                },
 195                  },
 196      'logs' => {function => \&add_logs,
 197                },
 198      'packages' => {function => \&add_packages,
 199                     arguments => {'ftpdists=s' => 1,
 200                                   'suites=s@' => 0,
 201                                  },
 202                    },
 203      'help' => {function => sub {pod2usage({verbose => 2});}}
 204     );
 205
 206 my @USAGE_ERRORS;
 207 $options{verbose} = $options{verbose} - $options{quiet};
 208
 209 if ($options{progress}) {
 210     eval "use Term::ProgressBar";
 211     push @USAGE_ERRORS, "You asked for a progress bar, but Term::ProgressBar isn't installed" if $@;
 212 }
 213
 214
 215 pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;
 216
 217 if (exists $options{sysconfdir}) {
 218     if (not defined $options{sysconfdir} or not length $options{sysconfdir}) {
 219         delete $ENV{PGSYSCONFDIR};
 220     } else {
 221         $ENV{PGSYSCONFDIR} = $options{sysconfdir};
 222     }
 223 }
 224
 225 if (exists $options{spool_dir} and defined $options{spool_dir}) {
 226     $config{spool_dir} = $options{spool_dir};
 227 }
 228
 229 my $prog_bar;
 230 if ($options{progress}) {
 231     $prog_bar = eval "Term::ProgressBar->new({count => 1,ETA=>q(linear)})";
 232     warn "Unable to initialize progress bar: $@" if not $prog_bar;
 233 }
 234
 235
 236 my ($subcommand) = shift @ARGV;
 237 if (not defined $subcommand) {
 238     $subcommand = 'help';
 239     print STDERR "You must provide a subcommand; displaying usage.\n";
 240     pod2usage();
 241 } elsif (not exists $subcommands{$subcommand}) {
 242     print STDERR "$subcommand is not a valid subcommand; displaying usage.\n";
 243     pod2usage();
 244 }
 245
 246 binmode(STDOUT,':encoding(UTF-8)');
 247 binmode(STDERR,':encoding(UTF-8)');
 248
 249 my $opts =
 250     handle_subcommand_arguments(\@ARGV,$subcommands{$subcommand}{arguments});
 251 $subcommands{$subcommand}{function}->(\%options,$opts,$prog_bar,\%config,\@ARGV);
 252
 253 sub add_bugs {
 254     my ($options,$opts,$p,$config,$argv) = @_;
 255     chdir($config->{spool_dir}) or
 256         die "chdir $config->{spool_dir} failed: $!";
 257
 258     my $verbose = $options->{debug};
 259
 260     my $initialdir = "db-h";
 261
 262     if (defined $argv->[0] and $argv->[0] eq "archive") {
 263         $initialdir = "archive";
 264     }
 265     my $s = db_connect($options);
 266
 267
 268     my $time = 0;
 269     my $start_time = time;
 270     my %tags;
 271     my %severities;
 272     my %queue;
 273
 274     if ($opts->{preload}) {
 275         my @bugs;
 276         walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 277                   undef,
 278                   'summary',
 279                   undef,
 280                   sub {
 281                     push @bugs,@_;
 282                   },
 283                   10000
 284                  );
 285         $s->resultset('Bug')->quick_insert_bugs(@bugs);
 286     }
 287     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 288               $p,
 289               'summary',
 290               $verbose,
 291               sub {
 292                 my @bugs = @_;
 293                 my @bugs_to_update;
 294                 if ($options{quick}) {
 295                   for my $bug (@bugs) {
 296                     my $stat = stat(getbugcomponent($bug,'summary',$initialdir));
 297                     if (not defined $stat) {
 298                       print STDERR "Unable to stat $bug $!\n";
 299                       next;
 300                     }
 301                     my $rs = $s->resultset('Bug')->search({id=>$bug})->single();
 302                     next if defined $rs and $stat->mtime <= $rs->last_modified()->epoch();
 303                     push @bugs_to_update, $bug;
 304                   }
 305                 } else {
 306                   @bugs_to_update = @bugs;
 307                 }
 308                 eval {
 309                   $s->txn_do(sub {
 310                                for my $bug (@bugs_to_update) {
 311                                  load_bug(db => $s,
 312                                           bug => $bug,
 313                                           tags => \%tags,
 314                                           severities => \%severities,
 315                                           queue => \%queue);
 316                                }
 317                              });
 318                 };
 319                 if ($@) {
 320                   die "failure while trying to load bug: $@";
 321                 }
 322               },
 323               50
 324              );
 325     handle_load_bug_queue(db => $s,
 326                           queue => \%queue);
 327 }
 328
 329 sub add_versions {
 330     my ($options,$opts,$p,$config,$argv) = @_;
 331
 332     my $s = db_connect($options);
 333
 334     my @files = @{$argv};
 335     $p->target(scalar @files) if $p;
 336     for my $file (@files) {
 337         my $fh = IO::File->new($file,'r') or
 338             die "Unable to open $file for reading: $!";
 339         my @versions;
 340         my %src_pkgs;
 341         while (<$fh>) {
 342             chomp;
 343             next unless length $_;
 344             if (/(\w[-+0-9a-z.]+) \(([^\(\) \t]+)\)/) {
 345                 push @versions, [$1,$2];
 346             }
 347         }
 348         close($fh);
 349         my $ancestor_sv;
 350         for my $i (reverse 0..($#versions)) {
 351             my $sp;
 352             if (not defined $src_pkgs{$versions[$i][0]}) {
 353                 $src_pkgs{$versions[$i][0]} =
 354                     $s->resultset('SrcPkg')->
 355                     get_src_pkg_id($versions[$i][0]);
 356             }
 357             $sp = $src_pkgs{$versions[$i][0]};
 358             # There's probably something wrong if the source package
 359             # doesn't exist, but we'll skip it for now
 360             next unless defined $sp;
 361             my $sv = $s->resultset('SrcVer')->find({src_pkg=>$sp,
 362                                                     ver => $versions[$i][1],
 363                                                    });
 364             if (defined $ancestor_sv and defined $sv and not defined $sv->based_on()) {
 365                 $sv->update({based_on => $ancestor_sv})
 366             }
 367             $ancestor_sv = $sv->id();
 368         }
 369         $p->update() if $p;
 370     }
 371     $p->remove() if $p;
 372 }
 373
 374 sub add_debinfo {
 375     my ($options,$opts,$p,$config,$argv) = @_;
 376
 377     my @files = @{$argv};
 378     if (not @files) {
 379        {
 380            local $/ = "\n";
 381            local $/ = "\0" if $opts->{0};
 382            while (<STDIN>) {
 383                s/\n$// unless $opts->{0};
 384                s/\0$// if $opts->{0};
 385                push @files, $_;
 386            }
 387        }
 388     }
 389     return unless @files;
 390     my $s = db_connect($options);
 391     $p->target(scalar @files) if $p;
 392     my $it = natatime 100, @files;
 393     while (my @v = $it->()) {
 394         my %cache;
 395         my @debinfos;
 396         for my $file (@v) {
 397             my $fh = IO::File->new($file,'r') or
 398                 die "Unable to open $file for reading: $!";
 399             my $f_stat = stat($file);
 400             my $ct_date = DateTime->from_epoch(epoch => $f_stat->ctime);
 401             while (<$fh>) {
 402                 chomp;
 403                 next unless length $_;
 404                 my ($binname, $binver, $binarch, $srcname, $srcver) = split;
 405                 # if $srcver is not defined, this is probably a broken
 406                 # .debinfo file [they were causing #686106, see commit
 407                 # 49c85ab8 in dak.] Basically, $binarch didn't get put into
 408                 # the file, so we'll fudge it from the filename.
 409                 if (not defined $srcver) {
 410                     ($srcname,$srcver) = ($binarch,$srcname);
 411                     ($binarch) = $file =~ /_([^\.]+)\.debinfo/;
 412                 }
 413                 if (not defined $srcver) {
 414                     print STDERR "malformed debinfo (no srcver): $file\n";
 415                     next;
 416                 }
 417                 push @debinfos,
 418                     [$binname,$binver,$binarch,$srcname,$srcver,$ct_date];
 419             }
 420         }
 421         $s->txn_do(
 422             sub {
 423                 for my $di (@debinfos) {
 424                     Debbugs::DB::Load::load_debinfo($s,@{$di}[0..5],\%cache);
 425                 }
 426             });
 427         $p->update($p->last_update()+@v) if $p;
 428     }
 429     $p->remove() if $p;
 430 }
 431
 432 sub add_maintainers {
 433     my ($options,$opts,$p,$config,$argv) = @_;
 434
 435     my $s = db_connect($options);
 436     my $maintainers = getsourcemaintainers();
 437     $p->target(2) if $p;
 438     ## get all of the maintainers, and add the missing ones
 439     my $maints = $s->resultset('Maintainer')->
 440         get_maintainers(values %{$maintainers});
 441     $p->update();
 442     my @svs = $s->resultset('SrcVer')->
 443         search({maintainer => undef
 444                },
 445               {join => 'src_pkg',
 446                group_by => 'me.src_pkg, src_pkg.pkg',
 447                result_class => 'DBIx::Class::ResultClass::HashRefInflator',
 448                columns => [qw(me.src_pkg src_pkg.pkg)],
 449               }
 450               )->all();
 451     $p->target(2+@svs) if $p;
 452     $p->update() if $p;
 453     for my $sv (@svs) {
 454         if (exists $maintainers->{$sv->{src_pkg}{pkg}}) {
 455             my $pkg = $sv->{src_pkg}{pkg};
 456             my $maint = $maints->
 457                {$maintainers->{$pkg}};
 458             $s->txn_do(sub {$s->resultset('SrcVer')->
 459                                 search({maintainer => undef,
 460                                         'src_pkg.pkg' => $pkg
 461                                        },
 462                                       {join => 'src_pkg'}
 463                                       )->update({maintainer => $maint})
 464                                   });
 465         }
 466         $p->update() if $p;
 467     }
 468     $p->remove() if $p;
 469 }
 470
 471 sub add_configuration {
 472     my ($options,$opts,$p,$config,$argv) = @_;
 473
 474     my $s = db_connect($options);
 475
 476     # tags
 477     # add all tags
 478     my %tags;
 479     for my $tag (@{$config{tags}}) {
 480         $tags{$tag} = 1;
 481         $s->resultset('Tag')->find_or_create({tag => $tag});
 482     }
 483     # mark obsolete tags
 484     for my $tag ($s->resultset('Tag')->search_rs()->all()) {
 485         next if exists $tags{$tag->tag};
 486         $tag->obsolete(1);
 487         $tag->update;
 488     }
 489
 490     # severities
 491     my %sev_names;
 492     my $order = -1;
 493     for my $sev_name (($config{default_severity},@{$config{severity_list}})) {
 494         # add all severitites
 495         my $sev = $s->resultset('Severity')->find_or_create({severity => $sev_name});
 496         # mark strong severities
 497         if (grep {$_ eq $sev_name} @{$config{strong_severities}}) {
 498             $sev->strong(1);
 499         }
 500         $sev->ordering($order);
 501         $sev->update();
 502         $order++;
 503         $sev_names{$sev_name} = 1;
 504     }
 505     # mark obsolete severities
 506     for my $sev ($s->resultset('Severity')->search_rs()->all()) {
 507         next if exists $sev_names{$sev->severity()};
 508         $sev->obsolete(1);
 509         $sev->update();
 510     }
 511 }
 512
 513 sub add_suite {
 514     my ($options,$opts,$p,$config,$argv) = @_;
 515     # suites
 516
 517     my $s = db_connect($options);
 518     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 519     my @dist_names =
 520         grep { $_ !~ /^\./ and
 521                -d $opts->{ftpdists}.'/'.$_ and
 522                not -l $opts->{ftpdists}.'/'.$_
 523            } $dist_dir->read;
 524     while (my $dist = shift @dist_names) {
 525         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 526         my ($dist_info,$package_files) =
 527             read_release_file($dist_dir.'/Release');
 528         load_suite($s,$dist_info);
 529     }
 530 }
 531
 532 sub add_logs {
 533     my ($options,$opts,$p,$config,$argv) = @_;
 534
 535     chdir($config->{spool_dir}) or
 536         die "chdir $config->{spool_dir} failed: $!";
 537
 538     my $verbose = $options->{debug};
 539
 540     my $initialdir = "db-h";
 541
 542     if (defined $argv->[0] and $argv->[0] eq "archive") {
 543         $initialdir = "archive";
 544     }
 545     my $s = db_connect($options);
 546
 547
 548     my $time = 0;
 549     my $start_time = time;
 550
 551     walk_bugs([(@{$argv}?@{$argv} : $initialdir)],
 552               $p,
 553               'log',
 554               $verbose,
 555               sub {
 556                   my $bug = shift;
 557                   my $stat = stat(getbugcomponent($bug,'log',$initialdir));
 558                   if (not defined $stat) {
 559                       print STDERR "Unable to stat $bug $!\n";
 560                       next;
 561                   }
 562                   if ($options{quick}) {
 563                       my $rs = $s->resultset('Bug')->search({bug=>$bug})->single();
 564                       next if defined $rs and $stat->mtime <= $rs->last_modified()->epoch();
 565                   }
 566                   eval {
 567                       load_bug_log(db => $s,
 568                                    bug => $bug);
 569                   };
 570                   if ($@) {
 571                       die "failure while trying to load bug log $bug\n$@";
 572                   }
 573               });
 574 }
 575
 576 sub add_packages {
 577     my ($options,$opts,$p,$config,$argv) = @_;
 578
 579     my $dist_dir = IO::Dir->new($opts->{ftpdists});
 580     my @dist_names =
 581         grep { $_ !~ /^\./ and
 582                -d $opts->{ftpdists}.'/'.$_ and
 583                not -l $opts->{ftpdists}.'/'.$_
 584            } $dist_dir->read;
 585     my %s_p;
 586     while (my $dist = shift @dist_names) {
 587         my $dist_dir = $opts->{ftpdists}.'/'.$dist;
 588         my ($dist_info,$package_files) =
 589             read_release_file($dist_dir.'/Release');
 590         $s_p{$dist_info->{Codename}} = $package_files;
 591     }
 592     my $tot = 0;
 593     for my $suite (keys %s_p) {
 594         for my $component (keys %{$s_p{$suite}}) {
 595             $tot += scalar keys %{$s_p{$suite}{$component}};
 596         }
 597     }
 598     $p->target($tot) if $p;
 599     my $i = 0;
 600     my $avg_pkgs = 0;
 601     my $tot_suites = scalar keys %s_p;
 602     my $done_suites=0;
 603     my $completed_pkgs=0;
 604     # parse packages files
 605     for my $suite (keys %s_p) {
 606         my @pkgs;
 607         for my $component (keys %{$s_p{$suite}}) {
 608             my @archs = keys %{$s_p{$suite}{$component}};
 609             if (grep {$_ eq 'source'} @archs) {
 610                 @archs = ('source',grep {$_ ne 'source'} @archs);
 611             }
 612             for my $arch (@archs) {
 613                 my $pfh =  open_compressed_file($s_p{$suite}{$component}{$arch}) or
 614                     die "Unable to open $s_p{$suite}{$component}{$arch} for reading: $!";
 615                 local $_;
 616                 local $/ = '';  # paragraph mode
 617                 while (<$pfh>) {
 618                     my %pkg;
 619                     for my $field (qw(Package Maintainer Version Source)) {
 620                         /^\Q$field\E: (.*)/m;
 621                         $pkg{$field} = $1;
 622                     }
 623                     next unless defined $pkg{Package} and
 624                         defined $pkg{Version};
 625                     push @pkgs,[$arch,$component,\%pkg];
 626                 }
 627             }
 628         }
 629         my $s = db_connect($options);
 630         if ($avg_pkgs==0) {
 631             $avg_pkgs = @pkgs;
 632         }
 633         $p->target($avg_pkgs*($tot_suites-$done_suites-1)+
 634                    $completed_pkgs+@pkgs) if $p;
 635         load_packages($s,
 636                       $suite,
 637                       \@pkgs,
 638                       $p);
 639         $avg_pkgs=($avg_pkgs*$done_suites + @pkgs)/($done_suites+1);
 640         $completed_pkgs += @pkgs;
 641         $done_suites++;
 642     }
 643     $p->remove() if $p;
 644 }
 645
 646 sub handle_subcommand_arguments {
 647     my ($argv,$args) = @_;
 648     my $subopt = {};
 649     Getopt::Long::GetOptionsFromArray($argv,
 650                               $subopt,
 651                               keys %{$args},
 652                              );
 653     my @usage_errors;
 654     for my $arg  (keys %{$args}) {
 655         next unless $args->{$arg};
 656         my $r_arg = $arg; # real argument name
 657         $r_arg =~ s/[=\|].+//g;
 658         if (not defined $subopt->{$r_arg}) {
 659             push @usage_errors, "You must give a $r_arg option";
 660         }
 661     }
 662     pod2usage(join("\n",@usage_errors)) if @usage_errors;
 663     return $subopt;
 664 }
 665
 666 sub get_lock{
 667     my ($subcommand,$config,$options) = @_;
 668     if (not lockpid($config->{spool_dir}.'/lock/debbugs-loadsql-$subcommand')) {
 669         if ($options->{quick}) {
 670             # If this is a quick run, just exit
 671             print STDERR "Another debbugs-loadsql is running; stopping\n" if $options->{verbose};
 672             exit 0;
 673         }
 674         print STDERR "Another debbugs-loadsql is running; stopping\n";
 675         exit 1;
 676     }
 677 }
 678
 679 sub db_connect {
 680     my ($options) = @_;
 681     # connect to the database; figure out how to handle errors
 682     # properly here.
 683     my $s = Debbugs::DB->connect($options->{service}) or
 684         die "Unable to connect to database: ";
 685 }
 686
 687 sub read_release_file {
 688     my ($file) = @_;
 689     # parse release
 690     my $rfh =  open_compressed_file($file) or
 691         die "Unable to open $file for reading: $!";
 692     my %dist_info;
 693     my $in_sha1;
 694     my %p_f;
 695     while (<$rfh>) {
 696         chomp;
 697         if (s/^(\S+):\s*//) {
 698             if ($1 eq 'SHA1'or $1 eq 'SHA256') {
 699                 $in_sha1 = 1;
 700                 next;
 701             }
 702             $dist_info{$1} = $_;
 703         } elsif ($in_sha1) {
 704             s/^\s//;
 705             my ($sha,$size,$f) = split /\s+/,$_;
 706             next unless $f =~ /(?:Packages|Sources)(?:\.gz|\.xz)$/;
 707             next unless $f =~ m{^([^/]+)/([^/]+)/([^/]+)$};
 708             my ($component,$arch,$package_source) = ($1,$2,$3);
 709             $arch =~ s/binary-//;
 710             next if exists $p_f{$component}{$arch};
 711             $p_f{$component}{$arch} = File::Spec->catfile(dirname($file),$f);
 712         }
 713     }
 714     return (\%dist_info,\%p_f);
 715 }
 716
 717 sub walk_bugs {
 718     my ($dirs,$p,$what,$verbose,$sub,$n) = @_;
 719     my @dirs = @{$dirs};
 720     my $tot_dirs = @dirs;
 721     my $done_dirs = 0;
 722     my $avg_subfiles = 0;
 723     my $completed_files = 0;
 724     $n //= 1;
 725     while (my $dir = shift @dirs) {
 726         printf "Doing dir %s ...\n", $dir if $verbose;
 727
 728         opendir(DIR, "$dir/.") or die "opendir $dir: $!";
 729         my @subdirs = readdir(DIR);
 730         closedir(DIR);
 731
 732         my @list = map { m/^(\d+)\.$what$/?($1):() } @subdirs;
 733         $tot_dirs -= @dirs;
 734         push @dirs, map { m/^(\d+)$/ && -d "$dir/$1"?("$dir/$1"):() } @subdirs;
 735         $tot_dirs += @dirs;
 736         if ($avg_subfiles == 0) {
 737             $avg_subfiles = @list;
 738         }
 739
 740         $p->target($avg_subfiles*($tot_dirs-$done_dirs)+$completed_files+@list) if $p;
 741         $avg_subfiles = ($avg_subfiles * $done_dirs + @list) / ($done_dirs+1);
 742         $done_dirs += 1;
 743
 744         my $it = natatime $n,@list;
 745         while (my @bugs = $it->()) {
 746           $sub->(@bugs);
 747           $completed_files += scalar @bugs;
 748           $p->update($completed_files) if $p;
 749           print "Up to $completed_files bugs...\n"
 750             if ($completed_files % 100 == 0 && $verbose);
 751         }
 752     }
 753     $p->remove() if $p;
 754 }
 755
 756
 757
 758 __END__