Debbugs/Status.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # [Other people have contributed to this file; their copyrights should
   7 # go here too.]
   8 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   9
  10 package Debbugs::Status;
  11
  12 =head1 NAME
  13
  14 Debbugs::Status -- Routines for dealing with summary and status files
  15
  16 =head1 SYNOPSIS
  17
  18 use Debbugs::Status;
  19
  20
  21 =head1 DESCRIPTION
  22
  23 This module is a replacement for the parts of errorlib.pl which write
  24 and read status and summary files.
  25
  26 It also contains generic routines for returning information about the
  27 status of a particular bug
  28
  29 =head1 FUNCTIONS
  30
  31 =cut
  32
  33 use warnings;
  34 use strict;
  35 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  36 use base qw(Exporter);
  37
  38 use Params::Validate qw(validate_with :types);
  39 use Debbugs::Common qw(:util :lock :quit :misc);
  40 use Debbugs::Config qw(:config);
  41 use Debbugs::MIME qw(decode_rfc1522 encode_rfc1522);
  42 use Debbugs::Packages qw(makesourceversions getversions get_versions binarytosource);
  43 use Debbugs::Versions;
  44 use Debbugs::Versions::Dpkg;
  45 use POSIX qw(ceil);
  46
  47 use List::Util qw(min max);
  48
  49
  50 BEGIN{
  51      $VERSION = 1.00;
  52      $DEBUG = 0 unless defined $DEBUG;
  53
  54      @EXPORT = ();
  55      %EXPORT_TAGS = (status => [qw(splitpackages get_bug_status buggy bug_archiveable),
  56                                 qw(isstrongseverity bug_presence),
  57                                ],
  58                      read   => [qw(readbug read_bug lockreadbug lockreadbugmerge)],
  59                      write  => [qw(writebug makestatus unlockwritebug)],
  60                      versions => [qw(addfoundversions addfixedversions),
  61                                   qw(removefoundversions removefixedversions)
  62                                  ],
  63                      hook     => [qw(bughook bughook_archive)],
  64                     );
  65      @EXPORT_OK = ();
  66      Exporter::export_ok_tags(qw(status read write versions hook));
  67      $EXPORT_TAGS{all} = [@EXPORT_OK];
  68 }
  69
  70
  71 =head2 readbug
  72
  73      readbug($bug_num,$location)
  74      readbug($bug_num)
  75
  76 Reads a summary file from the archive given a bug number and a bug
  77 location. Valid locations are those understood by L</getbugcomponent>
  78
  79 =cut
  80
  81
  82 my %fields = (originator     => 'submitter',
  83               date           => 'date',
  84               subject        => 'subject',
  85               msgid          => 'message-id',
  86               'package'      => 'package',
  87               keywords       => 'tags',
  88               done           => 'done',
  89               forwarded      => 'forwarded-to',
  90               mergedwith     => 'merged-with',
  91               severity       => 'severity',
  92               owner          => 'owner',
  93               found_versions => 'found-in',
  94               found_date     => 'found-date',
  95               fixed_versions => 'fixed-in',
  96               fixed_date     => 'fixed-date',
  97               blocks         => 'blocks',
  98               blockedby      => 'blocked-by',
  99               unarchived     => 'unarchived',
 100              );
 101
 102 # Fields which need to be RFC1522-decoded in format versions earlier than 3.
 103 my @rfc1522_fields = qw(originator subject done forwarded owner);
 104
 105 sub readbug {
 106      return read_bug(bug => $_[0],
 107                      (@_ > 1)?(location => $_[1]):()
 108                     );
 109 }
 110
 111 =head2 read_bug
 112
 113      read_bug(bug => $bug_num,
 114               location => 'archive',
 115              );
 116      read_bug(summary => 'path/to/bugnum.summary');
 117      read_bug($bug_num);
 118
 119 A more complete function than readbug; it enables you to pass a full
 120 path to the summary file instead of the bug number and/or location.
 121
 122 =head3 Options
 123
 124 =over
 125
 126 =item bug -- the bug number
 127
 128 =item location -- optional location which is passed to getbugcomponent
 129
 130 =item summary -- complete path to the .summary file which will be read
 131
 132 =back
 133
 134 One of C<bug> or C<summary> must be passed. This function will return
 135 undef on failure, and will die if improper arguments are passed.
 136
 137 =cut
 138
 139 sub read_bug{
 140     if (@_ == 1) {
 141          unshift @_, 'bug';
 142     }
 143     my %param = validate_with(params => \@_,
 144                               spec   => {bug => {type => SCALAR,
 145                                                  optional => 1,
 146                                                  # something really
 147                                                  # stupid passes
 148                                                  # negative bugnumbers
 149                                                  regex    => qr/^-?\d+/,
 150                                                 },
 151                                          location => {type => SCALAR|UNDEF,
 152                                                       optional => 1,
 153                                                      },
 154                                          summary  => {type => SCALAR,
 155                                                       optional => 1,
 156                                                      },
 157                                         },
 158                              );
 159     die "One of bug or summary must be passed to read_bug"
 160          if not exists $param{bug} and not exists $param{summary};
 161     my $status;
 162     my $log;
 163     my $location;
 164     if (not defined $param{summary}) {
 165          my $lref;
 166          ($lref,$location) = @param{qw(bug location)};
 167          if (not defined $location) {
 168               $location = getbuglocation($lref,'summary');
 169               return undef if not defined $location;
 170          }
 171          $status = getbugcomponent($lref, 'summary', $location);
 172          $log    = getbugcomponent($lref, 'log'    , $location);
 173          return undef unless defined $status;
 174     }
 175     else {
 176          $status = $param{summary};
 177          $log = $status;
 178          $log =~ s/\.summary$/.log/;
 179          ($location) = $status =~ m/(db-h|db|archive)/;
 180     }
 181     my $status_fh = new IO::File $status, 'r' or
 182          warn "Unable to open $status for reading: $!" and return undef;
 183
 184     my %data;
 185     my @lines;
 186     my $version = 2;
 187     local $_;
 188
 189     while (<$status_fh>) {
 190         chomp;
 191         push @lines, $_;
 192         $version = $1 if /^Format-Version: ([0-9]+)/i;
 193     }
 194
 195     # Version 3 is the latest format version currently supported.
 196     return undef if $version > 3;
 197
 198     my %namemap = reverse %fields;
 199     for my $line (@lines) {
 200         if ($line =~ /(\S+?): (.*)/) {
 201             my ($name, $value) = (lc $1, $2);
 202             $data{$namemap{$name}} = $value if exists $namemap{$name};
 203         }
 204     }
 205     for my $field (keys %fields) {
 206         $data{$field} = '' unless exists $data{$field};
 207     }
 208
 209     $data{severity} = $config{default_severity} if $data{severity} eq '';
 210     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 211          $data{$field} = [split ' ', $data{$field}];
 212     }
 213     for my $field (qw(found fixed)) {
 214          # create the found/fixed hashes which indicate when a
 215          # particular version was marked found or marked fixed.
 216          @{$data{$field}}{@{$data{"${field}_versions"}}} =
 217               (('') x (@{$data{"${field}_date"}} - @{$data{"${field}_versions"}}),
 218                @{$data{"${field}_date"}});
 219     }
 220
 221     if ($version < 3) {
 222         for my $field (@rfc1522_fields) {
 223             $data{$field} = decode_rfc1522($data{$field});
 224         }
 225     }
 226     # Add log last modified time
 227     $data{log_modified} = (stat($log))[9];
 228     $data{location} = $location;
 229
 230     return \%data;
 231 }
 232
 233 =head2 lockreadbug
 234
 235      lockreadbug($bug_num,$location)
 236
 237 Performs a filelock, then reads the bug; the bug is unlocked if the
 238 return is undefined, otherwise, you need to call unfilelock or
 239 unlockwritebug.
 240
 241 See readbug above for information on what this returns
 242
 243 =cut
 244
 245 sub lockreadbug {
 246     my ($lref, $location) = @_;
 247     &filelock("lock/$lref");
 248     my $data = read_bug(bug => $lref, location => $location);
 249     &unfilelock unless defined $data;
 250     return $data;
 251 }
 252
 253 =head2 lockreadbugmerge
 254
 255      my ($locks, $data) = lockreadbugmerge($bug_num,$location);
 256
 257 Performs a filelock, then reads the bug. If the bug is merged, locks
 258 the merge lock. Returns a list of the number of locks and the bug
 259 data.
 260
 261 =cut
 262
 263 sub lockreadbugmerge {
 264      my ($bug_num,$location) = @_;
 265      my $data = lockreadbug(@_);
 266      if (not defined $data) {
 267           return (0,undef);
 268      }
 269      if (not length $data->{mergedwith}) {
 270           return (1,$data);
 271      }
 272      unfilelock();
 273      filelock('lock/merge');
 274      $data = lockreadbug(@_);
 275      if (not defined $data) {
 276           unfilelock();
 277           return (0,undef);
 278      }
 279      return (2,$data);
 280 }
 281
 282
 283 my @v1fieldorder = qw(originator date subject msgid package
 284                       keywords done forwarded mergedwith severity);
 285
 286 =head2 makestatus
 287
 288      my $content = makestatus($status,$version)
 289      my $content = makestatus($status);
 290
 291 Creates the content for a status file based on the $status hashref
 292 passed.
 293
 294 Really only useful for writebug
 295
 296 Currently defaults to version 2 (non-encoded rfc1522 names) but will
 297 eventually default to version 3. If you care, you should specify a
 298 version.
 299
 300 =cut
 301
 302 sub makestatus {
 303     my ($data,$version) = @_;
 304     $version = 2 unless defined $version;
 305
 306     my $contents = '';
 307
 308     my %newdata = %$data;
 309     for my $field (qw(found fixed)) {
 310          if (exists $newdata{$field}) {
 311               $newdata{"${field}_date"} =
 312                    [map {$newdata{$field}{$_}||''} keys %{$newdata{$field}}];
 313          }
 314     }
 315
 316     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 317          $newdata{$field} = join ' ', @{$newdata{$field}||[]};
 318     }
 319
 320     if ($version < 3) {
 321         for my $field (@rfc1522_fields) {
 322             $newdata{$field} = encode_rfc1522($newdata{$field});
 323         }
 324     }
 325
 326     if ($version == 1) {
 327         for my $field (@v1fieldorder) {
 328             if (exists $newdata{$field} and defined $newdata{$field}) {
 329                 $contents .= "$newdata{$field}\n";
 330             } else {
 331                 $contents .= "\n";
 332             }
 333         }
 334     } elsif ($version == 2 or $version == 3) {
 335         # Version 2 or 3. Add a file format version number for the sake of
 336         # further extensibility in the future.
 337         $contents .= "Format-Version: $version\n";
 338         for my $field (keys %fields) {
 339             if (exists $newdata{$field} and defined $newdata{$field}
 340                 and $newdata{$field} ne '') {
 341                 # Output field names in proper case, e.g. 'Merged-With'.
 342                 my $properfield = $fields{$field};
 343                 $properfield =~ s/(?:^|(?<=-))([a-z])/\u$1/g;
 344                 $contents .= "$properfield: $newdata{$field}\n";
 345             }
 346         }
 347     }
 348
 349     return $contents;
 350 }
 351
 352 =head2 writebug
 353
 354      writebug($bug_num,$status,$location,$minversion,$disablebughook)
 355
 356 Writes the bug status and summary files out.
 357
 358 Skips writting out a status file if minversion is 2
 359
 360 Does not call bughook if disablebughook is true.
 361
 362 =cut
 363
 364 sub writebug {
 365     my ($ref, $data, $location, $minversion, $disablebughook) = @_;
 366     my $change;
 367
 368     my %outputs = (1 => 'status', 2 => 'summary');
 369     for my $version (keys %outputs) {
 370         next if defined $minversion and $version < $minversion;
 371         my $status = getbugcomponent($ref, $outputs{$version}, $location);
 372         &quit("can't find location for $ref") unless defined $status;
 373         open(S,"> $status.new") || &quit("opening $status.new: $!");
 374         print(S makestatus($data, $version)) ||
 375             &quit("writing $status.new: $!");
 376         close(S) || &quit("closing $status.new: $!");
 377         if (-e $status) {
 378             $change = 'change';
 379         } else {
 380             $change = 'new';
 381         }
 382         rename("$status.new",$status) || &quit("installing new $status: $!");
 383     }
 384
 385     # $disablebughook is a bit of a hack to let format migration scripts use
 386     # this function rather than having to duplicate it themselves.
 387     &bughook($change,$ref,$data) unless $disablebughook;
 388 }
 389
 390 =head2 unlockwritebug
 391
 392      unlockwritebug($bug_num,$status,$location,$minversion,$disablebughook);
 393
 394 Writes a bug, then calls unfilelock; see writebug for what these
 395 options mean.
 396
 397 =cut
 398
 399 sub unlockwritebug {
 400     writebug(@_);
 401     &unfilelock;
 402 }
 403
 404 =head1 VERSIONS
 405
 406 The following functions are exported with the :versions tag
 407
 408 =head2 addfoundversions
 409
 410      addfoundversions($status,$package,$version,$isbinary);
 411
 412
 413
 414 =cut
 415
 416
 417 sub addfoundversions {
 418     my $data = shift;
 419     my $package = shift;
 420     my $version = shift;
 421     my $isbinary = shift;
 422     return unless defined $version;
 423     undef $package if $package =~ m[(?:\s|/)];
 424     my $source = $package;
 425
 426     if (defined $package and $isbinary) {
 427         my @srcinfo = binarytosource($package, $version, undef);
 428         if (@srcinfo) {
 429             # We know the source package(s). Use a fully-qualified version.
 430             addfoundversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 431             return;
 432         }
 433         # Otherwise, an unqualified version will have to do.
 434         undef $source;
 435     }
 436
 437     # Strip off various kinds of brain-damage.
 438     $version =~ s/;.*//;
 439     $version =~ s/ *\(.*\)//;
 440     $version =~ s/ +[A-Za-z].*//;
 441
 442     foreach my $ver (split /[,\s]+/, $version) {
 443         my $sver = defined($source) ? "$source/$ver" : '';
 444         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{found_versions}}) {
 445             push @{$data->{found_versions}}, defined($source) ? $sver : $ver;
 446         }
 447         @{$data->{fixed_versions}} =
 448             grep { $_ ne $ver and $_ ne $sver } @{$data->{fixed_versions}};
 449     }
 450 }
 451
 452 =head2 removefoundversions
 453
 454      removefoundversions($data,$package,$versiontoremove)
 455
 456 Removes found versions from $data
 457
 458 If a version is fully qualified (contains /) only versions matching
 459 exactly are removed. Otherwise, all versions matching the version
 460 number are removed.
 461
 462 Currently $package and $isbinary are entirely ignored, but accepted
 463 for backwards compatibilty.
 464
 465 =cut
 466
 467 sub removefoundversions {
 468     my $data = shift;
 469     my $package = shift;
 470     my $version = shift;
 471     my $isbinary = shift;
 472     return unless defined $version;
 473
 474     foreach my $ver (split /[,\s]+/, $version) {
 475          if ($ver =~ m{/}) {
 476               # fully qualified version
 477               @{$data->{found_versions}} =
 478                    grep {$_ ne $ver}
 479                         @{$data->{found_versions}};
 480          }
 481          else {
 482               # non qualified version; delete all matchers
 483               @{$data->{found_versions}} =
 484                    grep {$_ !~ m[(?:^|/)\Q$ver\E$]}
 485                         @{$data->{found_versions}};
 486          }
 487     }
 488 }
 489
 490
 491 sub addfixedversions {
 492     my $data = shift;
 493     my $package = shift;
 494     my $version = shift;
 495     my $isbinary = shift;
 496     return unless defined $version;
 497     undef $package if defined $package and $package =~ m[(?:\s|/)];
 498     my $source = $package;
 499
 500     if (defined $package and $isbinary) {
 501         my @srcinfo = binarytosource($package, $version, undef);
 502         if (@srcinfo) {
 503             # We know the source package(s). Use a fully-qualified version.
 504             addfixedversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 505             return;
 506         }
 507         # Otherwise, an unqualified version will have to do.
 508         undef $source;
 509     }
 510
 511     # Strip off various kinds of brain-damage.
 512     $version =~ s/;.*//;
 513     $version =~ s/ *\(.*\)//;
 514     $version =~ s/ +[A-Za-z].*//;
 515
 516     foreach my $ver (split /[,\s]+/, $version) {
 517         my $sver = defined($source) ? "$source/$ver" : '';
 518         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{fixed_versions}}) {
 519             push @{$data->{fixed_versions}}, defined($source) ? $sver : $ver;
 520         }
 521         @{$data->{found_versions}} =
 522             grep { $_ ne $ver and $_ ne $sver } @{$data->{found_versions}};
 523     }
 524 }
 525
 526 sub removefixedversions {
 527     my $data = shift;
 528     my $package = shift;
 529     my $version = shift;
 530     my $isbinary = shift;
 531     return unless defined $version;
 532     undef $package if $package =~ m[(?:\s|/)];
 533     my $source = $package;
 534
 535     if (defined $package and $isbinary) {
 536         my @srcinfo = binarytosource($package, $version, undef);
 537         if (@srcinfo) {
 538             # We know the source package(s). Use a fully-qualified version.
 539             removefixedversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 540             return;
 541         }
 542         # Otherwise, an unqualified version will have to do.
 543         undef $source;
 544     }
 545
 546     foreach my $ver (split /[,\s]+/, $version) {
 547         my $sver = defined($source) ? "$source/$ver" : '';
 548         @{$data->{fixed_versions}} =
 549             grep { $_ ne $ver and $_ ne $sver } @{$data->{fixed_versions}};
 550     }
 551 }
 552
 553
 554
 555 =head2 splitpackages
 556
 557      splitpackages($pkgs)
 558
 559 Split a package string from the status file into a list of package names.
 560
 561 =cut
 562
 563 sub splitpackages {
 564     my $pkgs = shift;
 565     return unless defined $pkgs;
 566     return map lc, split /[ \t?,()]+/, $pkgs;
 567 }
 568
 569
 570 =head2 bug_archiveable
 571
 572      bug_archiveable(bug => $bug_num);
 573
 574 Options
 575
 576 =over
 577
 578 =item bug -- bug number (required)
 579
 580 =item status -- Status hashref returned by read_bug or get_bug_status (optional)
 581
 582 =item version -- Debbugs::Version information (optional)
 583
 584 =item days_until -- return days until the bug can be archived
 585
 586 =back
 587
 588 Returns 1 if the bug can be archived
 589 Returns 0 if the bug cannot be archived
 590
 591 If days_until is true, returns the number of days until the bug can be
 592 archived, -1 if it cannot be archived. 0 means that the bug can be
 593 archived the next time the archiver runs.
 594
 595 Returns undef on failure.
 596
 597 =cut
 598
 599 # This will eventually need to be fixed before we start using mod_perl
 600 our $version_cache = {};
 601 sub bug_archiveable{
 602      my %param = validate_with(params => \@_,
 603                                spec   => {bug => {type => SCALAR,
 604                                                   regex => qr/^\d+$/,
 605                                                  },
 606                                           status => {type => HASHREF,
 607                                                      optional => 1,
 608                                                     },
 609                                           days_until => {type => BOOLEAN,
 610                                                          default => 0,
 611                                                         },
 612                                           ignore_time => {type => BOOLEAN,
 613                                                           default => 0,
 614                                                          },
 615                                          },
 616                               );
 617      # This is what we return if the bug cannot be archived.
 618      my $cannot_archive = $param{days_until}?-1:0;
 619      # read the status information
 620      my $status = $param{status};
 621      if (not exists $param{status} or not defined $status) {
 622           $status = read_bug(bug=>$param{bug});
 623           return undef if not defined $status;
 624      }
 625      # Bugs can be archived if they are
 626      # 1. Closed
 627      return $cannot_archive if not defined $status->{done} or not length $status->{done};
 628      # If we just are checking if the bug can be archived, we'll not even bother
 629      # checking the versioning information if the bug has been -done for less than 28 days.
 630      if (not $param{days_until} and not $param{ignore_time}
 631          and $config{remove_age} >
 632          -M getbugcomponent($param{bug},'log')
 633         ) {
 634           return $cannot_archive;
 635      }
 636      # At this point, we have to get the versioning information for this bug.
 637      # We examine the set of distribution tags. If a bug has no distribution
 638      # tags set, we assume a default set, otherwise we use the tags the bug
 639      # has set.
 640
 641      # There must be fixed_versions for us to look at the versioning
 642      # information
 643      my $min_fixed_time = time;
 644      my $min_archive_days = 0;
 645      if (@{$status->{fixed_versions}}) {
 646           my %dist_tags;
 647           @dist_tags{@{$config{removal_distribution_tags}}} =
 648                (1) x @{$config{removal_distribution_tags}};
 649           my %dists;
 650           @dists{@{$config{removal_default_distribution_tags}}} =
 651                (1) x @{$config{removal_default_distribution_tags}};
 652           for my $tag (split ' ', ($status->{tags}||'')) {
 653                next unless $dist_tags{$tag};
 654                $dists{$tag} = 1;
 655           }
 656           my %source_versions;
 657           my @sourceversions = get_versions(package => $status->{package},
 658                                             dist => [keys %dists],
 659                                             source => 1,
 660                                            );
 661           @source_versions{@sourceversions} = (1) x @sourceversions;
 662           # If the bug has not been fixed in the versions actually
 663           # distributed, then it cannot be archived.
 664           if ('found' eq max_buggy(bug => $param{bug},
 665                                    sourceversions => [keys %source_versions],
 666                                    found          => $status->{found_versions},
 667                                    fixed          => $status->{fixed_versions},
 668                                    version_cache  => $version_cache,
 669                                    package        => $status->{package},
 670                                   )) {
 671                return $cannot_archive;
 672           }
 673           # Since the bug has at least been fixed in the architectures
 674           # that matters, we check to see how long it has been fixed.
 675
 676           # If $param{ignore_time}, then we should ignore time.
 677           if ($param{ignore_time}) {
 678                return $param{days_until}?0:1;
 679           }
 680
 681           # To do this, we order the times from most recent to oldest;
 682           # when we come to the first found version, we stop.
 683           # If we run out of versions, we only report the time of the
 684           # last one.
 685           my %time_versions = get_versions(package => $status->{package},
 686                                            dist    => [keys %dists],
 687                                            source  => 1,
 688                                            time    => 1,
 689                                           );
 690           for my $version (sort {$time_versions{$b} <=> $time_versions{$a}} keys %time_versions) {
 691                my $buggy = buggy(bug => $param{bug},
 692                                  version        => $version,
 693                                  found          => $status->{found_versions},
 694                                  fixed          => $status->{fixed_versions},
 695                                  version_cache  => $version_cache,
 696                                  package        => $status->{package},
 697                                 );
 698                last if $buggy eq 'found';
 699                $min_fixed_time = min($time_versions{$version},$min_fixed_time);
 700           }
 701           $min_archive_days = max($min_archive_days,ceil((time - $min_fixed_time)/(60*60*24)));
 702      }
 703      # If $param{ignore_time}, then we should ignore time.
 704      if ($param{ignore_time}) {
 705           return $param{days_until}?0:1;
 706      }
 707      # 6. at least 28 days have passed since the last action has occured or the bug was closed
 708      my $age = ceil($config{remove_age} - -M getbugcomponent($param{bug},'log'));
 709      if ($age > 0 or $min_archive_days > 0) {
 710           return $param{days_until}?max($age,$min_archive_days):0;
 711      }
 712      else {
 713           return $param{days_until}?0:1;
 714      }
 715 }
 716
 717
 718 =head2 get_bug_status
 719
 720      my $status = get_bug_status(bug => $nnn);
 721
 722      my $status = get_bug_status($bug_num)
 723
 724 =head3 Options
 725
 726 =over
 727
 728 =item bug -- scalar bug number
 729
 730 =item status -- optional hashref of bug status as returned by readbug
 731 (can be passed to avoid rereading the bug information)
 732
 733 =item bug_index -- optional tied index of bug status infomration;
 734 currently not correctly implemented.
 735
 736 =item version -- optional version(s) to check package status at
 737
 738 =item dist -- optional distribution(s) to check package status at
 739
 740 =item arch -- optional architecture(s) to check package status at
 741
 742 =item usertags -- optional hashref of usertags
 743
 744 =item sourceversion -- optional arrayref of source/version; overrides
 745 dist, arch, and version. [The entries in this array must be in the
 746 "source/version" format.] Eventually this can be used to for caching.
 747
 748 =back
 749
 750 Note: Currently the version information is cached; this needs to be
 751 changed before using this function in long lived programs.
 752
 753 =cut
 754
 755 sub get_bug_status {
 756      if (@_ == 1) {
 757           unshift @_, 'bug';
 758      }
 759      my %param = validate_with(params => \@_,
 760                                spec   => {bug       => {type => SCALAR,
 761                                                         regex => qr/^\d+$/,
 762                                                        },
 763                                           status    => {type => HASHREF,
 764                                                         optional => 1,
 765                                                        },
 766                                           bug_index => {type => OBJECT,
 767                                                         optional => 1,
 768                                                        },
 769                                           version   => {type => SCALAR|ARRAYREF,
 770                                                         optional => 1,
 771                                                        },
 772                                           dist       => {type => SCALAR|ARRAYREF,
 773                                                          optional => 1,
 774                                                         },
 775                                           arch       => {type => SCALAR|ARRAYREF,
 776                                                          optional => 1,
 777                                                         },
 778                                           usertags   => {type => HASHREF,
 779                                                          optional => 1,
 780                                                         },
 781                                           sourceversions => {type => ARRAYREF,
 782                                                              optional => 1,
 783                                                             },
 784                                          },
 785                               );
 786      my %status;
 787
 788      if (defined $param{bug_index} and
 789          exists $param{bug_index}{$param{bug}}) {
 790           %status = %{ $param{bug_index}{$param{bug}} };
 791           $status{pending} = $status{ status };
 792           $status{id} = $param{bug};
 793           return \%status;
 794      }
 795      if (defined $param{status}) {
 796           %status = %{$param{status}};
 797      }
 798      else {
 799           my $location = getbuglocation($param{bug}, 'summary');
 800           return {} if not length $location;
 801           %status = %{ readbug( $param{bug}, $location ) };
 802      }
 803      $status{id} = $param{bug};
 804
 805      if (defined $param{usertags}{$param{bug}}) {
 806           $status{keywords} = "" unless defined $status{keywords};
 807           $status{keywords} .= " " unless $status{keywords} eq "";
 808           $status{keywords} .= join(" ", @{$param{usertags}{$param{bug}}});
 809      }
 810      $status{tags} = $status{keywords};
 811      my %tags = map { $_ => 1 } split ' ', $status{tags};
 812
 813      $status{"package"} =~ s/\s*$//;
 814      $status{"package"} = 'unknown' if ($status{"package"} eq '');
 815      $status{"severity"} = 'normal' if ($status{"severity"} eq '');
 816
 817      $status{"pending"} = 'pending';
 818      $status{"pending"} = 'forwarded'       if (length($status{"forwarded"}));
 819      $status{"pending"} = 'pending-fixed'    if ($tags{pending});
 820      $status{"pending"} = 'fixed'           if ($tags{fixed});
 821
 822
 823      my $presence = bug_presence(map{(exists $param{$_})?($_,$param{$_}):()}
 824                                  qw(bug sourceversions arch dist version found fixed package)
 825                                 );
 826      if (defined $presence) {
 827           if ($presence eq 'fixed') {
 828                $status{pending} = 'done';
 829           }
 830           elsif ($presence eq 'absent') {
 831                $status{pending} = 'absent';
 832           }
 833      }
 834      return \%status;
 835 }
 836
 837 =head2 bug_presence
 838
 839      my $precence = bug_presence(bug => nnn,
 840                                  ...
 841                                 );
 842
 843 Returns 'found', 'absent', 'fixed' or undef based on whether the bug
 844 is found, absent, fixed, or no information is available in the
 845 distribution (dist) and/or architecture (arch) specified.
 846
 847
 848 =head3 Options
 849
 850 =over
 851
 852 =item bug -- scalar bug number
 853
 854 =item status -- optional hashref of bug status as returned by readbug
 855 (can be passed to avoid rereading the bug information)
 856
 857 =item bug_index -- optional tied index of bug status infomration;
 858 currently not correctly implemented.
 859
 860 =item version -- optional version to check package status at
 861
 862 =item dist -- optional distribution to check package status at
 863
 864 =item arch -- optional architecture to check package status at
 865
 866 =item sourceversion -- optional arrayref of source/version; overrides
 867 dist, arch, and version. [The entries in this array must be in the
 868 "source/version" format.] Eventually this can be used to for caching.
 869
 870 =back
 871
 872 =cut
 873
 874 sub bug_presence {
 875      my %param = validate_with(params => \@_,
 876                                spec   => {bug       => {type => SCALAR,
 877                                                         regex => qr/^\d+$/,
 878                                                        },
 879                                           status    => {type => HASHREF,
 880                                                         optional => 1,
 881                                                        },
 882                                           version   => {type => SCALAR|ARRAYREF,
 883                                                         optional => 1,
 884                                                        },
 885                                           dist       => {type => SCALAR|ARRAYREF,
 886                                                          optional => 1,
 887                                                         },
 888                                           arch       => {type => SCALAR|ARRAYREF,
 889                                                          optional => 1,
 890                                                         },
 891                                           sourceversions => {type => ARRAYREF,
 892                                                              optional => 1,
 893                                                             },
 894                                          },
 895                               );
 896      my %status;
 897      if (defined $param{status}) {
 898          %status = %{$param{status}};
 899      }
 900      else {
 901           my $location = getbuglocation($param{bug}, 'summary');
 902           return {} if not length $location;
 903           %status = %{ readbug( $param{bug}, $location ) };
 904      }
 905
 906      my @sourceversions;
 907      if (not exists $param{sourceversions}) {
 908           my %sourceversions;
 909           if (defined $param{version}) {
 910                foreach my $arch (make_list($param{arch})) {
 911                     my @temp = makesourceversions($status{package},
 912                                                   $arch,
 913                                                   make_list($param{version})
 914                                                  );
 915                     @sourceversions{@temp} = (1) x @temp;
 916                }
 917           } elsif (defined $param{dist}) {
 918                foreach my $arch (make_list($param{arch})) {
 919                     my @versions;
 920                     foreach my $dist (make_list($param{dist})) {
 921                          push @versions, getversions($status{package}, $dist, $arch);
 922                     }
 923                     my @temp = makesourceversions($status{package},
 924                                                   $arch,
 925                                                   @versions
 926                                                  );
 927                     @sourceversions{@temp} = (1) x @temp;
 928                }
 929           }
 930
 931           # TODO: This should probably be handled further out for efficiency and
 932           # for more ease of distinguishing between pkg= and src= queries.
 933           @sourceversions = keys %sourceversions;
 934      }
 935      else {
 936           @sourceversions = @{$param{sourceversions}};
 937      }
 938      my $maxbuggy = 'undef';
 939      if (@sourceversions) {
 940           $maxbuggy = max_buggy(bug => $param{bug},
 941                                    sourceversions => \@sourceversions,
 942                                    found => $status{found_versions},
 943                                    fixed => $status{fixed_versions},
 944                                    package => $status{package},
 945                                    version_cache => $version_cache,
 946                                   );
 947      }
 948      elsif (defined $param{dist}) {
 949           return 'absent';
 950      }
 951      if (length($status{done}) and
 952          (not @sourceversions or not @{$status{fixed_versions}})) {
 953           return 'fixed';
 954      }
 955      return $maxbuggy;
 956 }
 957
 958
 959 =head2 max_buggy
 960
 961      max_buggy()
 962
 963 =head3 Options
 964
 965 =over
 966
 967 =item bug -- scalar bug number
 968
 969 =item sourceversion -- optional arrayref of source/version; overrides
 970 dist, arch, and version. [The entries in this array must be in the
 971 "source/version" format.] Eventually this can be used to for caching.
 972
 973 =back
 974
 975 Note: Currently the version information is cached; this needs to be
 976 changed before using this function in long lived programs.
 977
 978
 979 =cut
 980 sub max_buggy{
 981      my %param = validate_with(params => \@_,
 982                                spec   => {bug       => {type => SCALAR,
 983                                                         regex => qr/^\d+$/,
 984                                                        },
 985                                           sourceversions => {type => ARRAYREF,
 986                                                              default => [],
 987                                                             },
 988                                           found          => {type => ARRAYREF,
 989                                                              default => [],
 990                                                             },
 991                                           fixed          => {type => ARRAYREF,
 992                                                              default => [],
 993                                                             },
 994                                           package        => {type => SCALAR,
 995                                                             },
 996                                           version_cache  => {type => HASHREF,
 997                                                              default => {},
 998                                                             },
 999                                          },
1000                               );
1001      # Resolve bugginess states (we might be looking at multiple
1002      # architectures, say). Found wins, then fixed, then absent.
1003      my $maxbuggy = 'absent';
1004      for my $version (@{$param{sourceversions}}) {
1005           my $buggy = buggy(bug => $param{bug},
1006                             version => $version,
1007                             found => $param{found},
1008                             fixed => $param{fixed},
1009                             version_cache => $param{version_cache},
1010                             package => $param{package},
1011                            );
1012           if ($buggy eq 'found') {
1013                return 'found';
1014           } elsif ($buggy eq 'fixed') {
1015                $maxbuggy = 'fixed';
1016           }
1017      }
1018      return $maxbuggy;
1019 }
1020
1021
1022 =head2 buggy
1023
1024      buggy(bug => nnn,
1025            found => \@found,
1026            fixed => \@fixed,
1027            package => 'foo',
1028            version => '1.0',
1029           );
1030
1031 Returns the output of Debbugs::Versions::buggy for a particular
1032 package, version and found/fixed set. Automatically turns found, fixed
1033 and version into source/version strings.
1034
1035 Caching can be had by using the version_cache, but no attempt to check
1036 to see if the on disk information is more recent than the cache is
1037 made. [This will need to be fixed for long-lived processes.]
1038
1039 =cut
1040
1041 sub buggy {
1042      my %param = validate_with(params => \@_,
1043                                spec   => {bug => {type => SCALAR,
1044                                                   regex => qr/^\d+$/,
1045                                                  },
1046                                           found => {type => ARRAYREF,
1047                                                     default => [],
1048                                                    },
1049                                           fixed => {type => ARRAYREF,
1050                                                     default => [],
1051                                                    },
1052                                           version_cache => {type => HASHREF,
1053                                                             optional => 1,
1054                                                            },
1055                                           package => {type => SCALAR,
1056                                                      },
1057                                           version => {type => SCALAR,
1058                                                      },
1059                                          },
1060                               );
1061      my @found = @{$param{found}};
1062      my @fixed = @{$param{fixed}};
1063      if (grep {$_ !~ m{/}} (@{$param{found}}, @{$param{fixed}})) {
1064           # We have non-source version versions
1065           @found = makesourceversions($param{package},undef,
1066                                       @found
1067                                      );
1068           @fixed = makesourceversions($param{package},undef,
1069                                       @fixed
1070                                      );
1071      }
1072      if ($param{version} !~ m{/}) {
1073           $param{version} = makesourceversions($param{package},undef,
1074                                                $param{version}
1075                                               );
1076      }
1077      # Figure out which source packages we need
1078      my %sources;
1079      @sources{map {m{(.+)/}; $1} @found} = (1) x @found;
1080      @sources{map {m{(.+)/}; $1} @fixed} = (1) x @fixed;
1081      @sources{map {m{(.+)/}; $1} $param{version}} = 1;
1082      my $version;
1083      if (not defined $param{version_cache} or
1084          not exists $param{version_cache}{join(',',sort keys %sources)}) {
1085           $version = Debbugs::Versions->new(\&Debbugs::Versions::Dpkg::vercmp);
1086           foreach my $source (keys %sources) {
1087                my $srchash = substr $source, 0, 1;
1088                my $version_fh = new IO::File "$config{version_packages_dir}/$srchash/$source", 'r' or
1089                     warn "Unable to open $config{version_packages_dir}/$srchash/$source: $!" and next;
1090                $version->load($version_fh);
1091           }
1092           if (defined $param{version_cache}) {
1093                $param{version_cache}{join(',',sort keys %sources)} = $version;
1094           }
1095      }
1096      else {
1097           $version = $param{version_cache}{join(',',sort keys %sources)};
1098      }
1099      return $version->buggy($param{version},\@found,\@fixed);
1100 }
1101
1102 sub isstrongseverity {
1103     my $severity = shift;
1104     $severity = $config{default_severity} if $severity eq '';
1105     return grep { $_ eq $severity } @{$config{strong_severities}};
1106 }
1107
1108
1109 =head1 PRIVATE FUNCTIONS
1110
1111 =cut
1112
1113 sub update_realtime {
1114         my ($file, %bugs) = @_;
1115
1116         # update realtime index.db
1117
1118         open(IDXDB, "<$file") or die "Couldn't open $file";
1119         open(IDXNEW, ">$file.new");
1120
1121         my $min_bug = min(keys %bugs);
1122         my $line;
1123         my @line;
1124         my %changed_bugs;
1125         while($line = <IDXDB>) {
1126              @line = split /\s/, $line;
1127              last unless (keys %bugs) > 0;
1128              # Two cases; replacing existing line or adding new line
1129              if (exists $bugs{$line[1]}) {
1130                   my $new = $bugs{$line[1]};
1131                   delete $bugs{$line[1]};
1132                   $min_bug = min(keys %bugs);
1133                   if ($new eq "NOCHANGE") {
1134                        print IDXNEW $line;
1135                        $changed_bugs{$line[1]} = $line;
1136                   } elsif ($new eq "REMOVE") {
1137                        $changed_bugs{$line[1]} = $line;
1138                   } else {
1139                        print IDXNEW $new;
1140                        $changed_bugs{$line[1]} = $line;
1141                   }
1142              }
1143              elsif ($line[1] > $min_bug) {
1144                   print IDXNEW $bugs{$min_bug};
1145                   delete $bugs{$min_bug};
1146                   $min_bug = min(keys %bugs);
1147                   $changed_bugs{$line[1]} = '';
1148              }
1149         }
1150
1151         print IDXNEW while(<IDXDB>);
1152
1153         close(IDXNEW);
1154         close(IDXDB);
1155
1156         rename("$file.new", $file);
1157
1158         return %changed_bugs;
1159 }
1160
1161 sub bughook_archive {
1162         my @refs = @_;
1163         &filelock("debbugs.trace.lock");
1164         &appendfile("debbugs.trace","archive ".join(',',@refs)."\n");
1165         my %bugs = update_realtime("$config{spool_dir}/index.db.realtime",
1166                                    map{($_,'REMOVE')} @refs);
1167         update_realtime("$config{spool_dir}/index.archive.realtime",
1168                         %bugs);
1169         &unfilelock;
1170 }
1171
1172 sub bughook {
1173         my ( $type, %bugs_temp ) = @_;
1174         &filelock("debbugs.trace.lock");
1175
1176         my %bugs;
1177         for my $bug (keys %bugs_temp) {
1178              my $data = $bugs_temp{$bug};
1179              &appendfile("debbugs.trace","$type $bug\n",makestatus($data, 1));
1180
1181              my $whendone = "open";
1182              my $severity = $config{default_severity};
1183              (my $pkglist = $data->{package}) =~ s/[,\s]+/,/g;
1184              $pkglist =~ s/^,+//;
1185              $pkglist =~ s/,+$//;
1186              $whendone = "forwarded" if defined $data->{forwarded} and length $data->{forwarded};
1187              $whendone = "done" if defined $data->{done} and length $data->{done};
1188              $severity = $data->{severity} if length $data->{severity};
1189
1190              my $k = sprintf "%s %d %d %s [%s] %s %s\n",
1191                   $pkglist, $bug, $data->{date}, $whendone,
1192                        $data->{originator}, $severity, $data->{keywords};
1193              $bugs{$bug} = $k;
1194         }
1195         update_realtime("$config{spool_dir}/index.db.realtime", %bugs);
1196
1197         &unfilelock;
1198 }
1199
1200
1201 1;
1202
1203 __END__