Debbugs/Status.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # [Other people have contributed to this file; their copyrights should
   7 # go here too.]
   8 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   9
  10 package Debbugs::Status;
  11
  12 =head1 NAME
  13
  14 Debbugs::Status -- Routines for dealing with summary and status files
  15
  16 =head1 SYNOPSIS
  17
  18 use Debbugs::Status;
  19
  20
  21 =head1 DESCRIPTION
  22
  23 This module is a replacement for the parts of errorlib.pl which write
  24 and read status and summary files.
  25
  26 It also contains generic routines for returning information about the
  27 status of a particular bug
  28
  29 =head1 FUNCTIONS
  30
  31 =cut
  32
  33 use warnings;
  34 use strict;
  35 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  36 use base qw(Exporter);
  37
  38 use Params::Validate qw(validate_with :types);
  39 use Debbugs::Common qw(:util :lock :quit :misc);
  40 use Debbugs::Config qw(:config);
  41 use Debbugs::MIME qw(decode_rfc1522 encode_rfc1522);
  42 use Debbugs::Packages qw(makesourceversions getversions get_versions binarytosource);
  43 use Debbugs::Versions;
  44 use Debbugs::Versions::Dpkg;
  45 use POSIX qw(ceil);
  46
  47 use List::Util qw(min max);
  48
  49
  50 BEGIN{
  51      $VERSION = 1.00;
  52      $DEBUG = 0 unless defined $DEBUG;
  53
  54      @EXPORT = ();
  55      %EXPORT_TAGS = (status => [qw(splitpackages get_bug_status buggy bug_archiveable),
  56                                 qw(isstrongseverity bug_presence),
  57                                ],
  58                      read   => [qw(readbug read_bug lockreadbug lockreadbugmerge)],
  59                      write  => [qw(writebug makestatus unlockwritebug)],
  60                      versions => [qw(addfoundversions addfixedversions),
  61                                   qw(removefoundversions removefixedversions)
  62                                  ],
  63                      hook     => [qw(bughook bughook_archive)],
  64                     );
  65      @EXPORT_OK = ();
  66      Exporter::export_ok_tags(qw(status read write versions hook));
  67      $EXPORT_TAGS{all} = [@EXPORT_OK];
  68 }
  69
  70
  71 =head2 readbug
  72
  73      readbug($bug_num,$location)
  74      readbug($bug_num)
  75
  76 Reads a summary file from the archive given a bug number and a bug
  77 location. Valid locations are those understood by L</getbugcomponent>
  78
  79 =cut
  80
  81
  82 my %fields = (originator     => 'submitter',
  83               date           => 'date',
  84               subject        => 'subject',
  85               msgid          => 'message-id',
  86               'package'      => 'package',
  87               keywords       => 'tags',
  88               done           => 'done',
  89               forwarded      => 'forwarded-to',
  90               mergedwith     => 'merged-with',
  91               severity       => 'severity',
  92               owner          => 'owner',
  93               found_versions => 'found-in',
  94               found_date     => 'found-date',
  95               fixed_versions => 'fixed-in',
  96               fixed_date     => 'fixed-date',
  97               blocks         => 'blocks',
  98               blockedby      => 'blocked-by',
  99               unarchived     => 'unarchived',
 100              );
 101
 102 # Fields which need to be RFC1522-decoded in format versions earlier than 3.
 103 my @rfc1522_fields = qw(originator subject done forwarded owner);
 104
 105 sub readbug {
 106      return read_bug(bug => $_[0],
 107                      (@_ > 1)?(location => $_[1]):()
 108                     );
 109 }
 110
 111 =head2 read_bug
 112
 113      read_bug(bug => $bug_num,
 114               location => 'archive',
 115              );
 116      read_bug(summary => 'path/to/bugnum.summary');
 117      read_bug($bug_num);
 118
 119 A more complete function than readbug; it enables you to pass a full
 120 path to the summary file instead of the bug number and/or location.
 121
 122 =head3 Options
 123
 124 =over
 125
 126 =item bug -- the bug number
 127
 128 =item location -- optional location which is passed to getbugcomponent
 129
 130 =item summary -- complete path to the .summary file which will be read
 131
 132 =back
 133
 134 One of C<bug> or C<summary> must be passed. This function will return
 135 undef on failure, and will die if improper arguments are passed.
 136
 137 =cut
 138
 139 sub read_bug{
 140     if (@_ == 1) {
 141          unshift @_, 'bug';
 142     }
 143     my %param = validate_with(params => \@_,
 144                               spec   => {bug => {type => SCALAR,
 145                                                  optional => 1,
 146                                                  # something really
 147                                                  # stupid passes
 148                                                  # negative bugnumbers
 149                                                  regex    => qr/^-?\d+/,
 150                                                 },
 151                                          location => {type => SCALAR|UNDEF,
 152                                                       optional => 1,
 153                                                      },
 154                                          summary  => {type => SCALAR,
 155                                                       optional => 1,
 156                                                      },
 157                                         },
 158                              );
 159     die "One of bug or summary must be passed to read_bug"
 160          if not exists $param{bug} and not exists $param{summary};
 161     my $status;
 162     my $log;
 163     my $location;
 164     if (not defined $param{summary}) {
 165          my $lref;
 166          ($lref,$location) = @param{qw(bug location)};
 167          if (not defined $location) {
 168               $location = getbuglocation($lref,'summary');
 169               return undef if not defined $location;
 170          }
 171          $status = getbugcomponent($lref, 'summary', $location);
 172          $log    = getbugcomponent($lref, 'log'    , $location);
 173          return undef unless defined $status;
 174     }
 175     else {
 176          $status = $param{summary};
 177          $log = $status;
 178          $log =~ s/\.summary$/.log/;
 179          ($location) = $status =~ m/(db-h|db|archive)/;
 180     }
 181     my $status_fh = new IO::File $status, 'r' or
 182          warn "Unable to open $status for reading: $!" and return undef;
 183
 184     my %data;
 185     my @lines;
 186     my $version = 2;
 187     local $_;
 188
 189     while (<$status_fh>) {
 190         chomp;
 191         push @lines, $_;
 192         $version = $1 if /^Format-Version: ([0-9]+)/i;
 193     }
 194
 195     # Version 3 is the latest format version currently supported.
 196     return undef if $version > 3;
 197
 198     my %namemap = reverse %fields;
 199     for my $line (@lines) {
 200         if ($line =~ /(\S+?): (.*)/) {
 201             my ($name, $value) = (lc $1, $2);
 202             $data{$namemap{$name}} = $value if exists $namemap{$name};
 203         }
 204     }
 205     for my $field (keys %fields) {
 206         $data{$field} = '' unless exists $data{$field};
 207     }
 208
 209     $data{severity} = $config{default_severity} if $data{severity} eq '';
 210     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 211          $data{$field} = [split ' ', $data{$field}];
 212     }
 213     for my $field (qw(found fixed)) {
 214          # create the found/fixed hashes which indicate when a
 215          # particular version was marked found or marked fixed.
 216          @{$data{$field}}{@{$data{"${field}_versions"}}} =
 217               (('') x (@{$data{"${field}_date"}} - @{$data{"${field}_versions"}}),
 218                @{$data{"${field}_date"}});
 219     }
 220
 221     if ($version < 3) {
 222         for my $field (@rfc1522_fields) {
 223             $data{$field} = decode_rfc1522($data{$field});
 224         }
 225     }
 226     # Add log last modified time
 227     $data{log_modified} = (stat($log))[9];
 228     $data{location} = $location;
 229
 230     return \%data;
 231 }
 232
 233 =head2 lockreadbug
 234
 235      lockreadbug($bug_num,$location)
 236
 237 Performs a filelock, then reads the bug; the bug is unlocked if the
 238 return is undefined, otherwise, you need to call unfilelock or
 239 unlockwritebug.
 240
 241 See readbug above for information on what this returns
 242
 243 =cut
 244
 245 sub lockreadbug {
 246     my ($lref, $location) = @_;
 247     &filelock("lock/$lref");
 248     my $data = read_bug(bug => $lref, location => $location);
 249     &unfilelock unless defined $data;
 250     return $data;
 251 }
 252
 253 =head2 lockreadbugmerge
 254
 255      my ($locks, $data) = lockreadbugmerge($bug_num,$location);
 256
 257 Performs a filelock, then reads the bug. If the bug is merged, locks
 258 the merge lock. Returns a list of the number of locks and the bug
 259 data.
 260
 261 =cut
 262
 263 sub lockreadbugmerge {
 264      my ($bug_num,$location) = @_;
 265      my $data = lockreadbug(@_);
 266      if (not defined $data) {
 267           return (0,undef);
 268      }
 269      if (not length $data->{mergedwith}) {
 270           return (1,$data);
 271      }
 272      unfilelock();
 273      filelock('lock/merge');
 274      $data = lockreadbug(@_);
 275      if (not defined $data) {
 276           unfilelock();
 277           return (0,undef);
 278      }
 279      return (2,$data);
 280 }
 281
 282
 283 my @v1fieldorder = qw(originator date subject msgid package
 284                       keywords done forwarded mergedwith severity);
 285
 286 =head2 makestatus
 287
 288      my $content = makestatus($status,$version)
 289      my $content = makestatus($status);
 290
 291 Creates the content for a status file based on the $status hashref
 292 passed.
 293
 294 Really only useful for writebug
 295
 296 Currently defaults to version 2 (non-encoded rfc1522 names) but will
 297 eventually default to version 3. If you care, you should specify a
 298 version.
 299
 300 =cut
 301
 302 sub makestatus {
 303     my ($data,$version) = @_;
 304     $version = 2 unless defined $version;
 305
 306     my $contents = '';
 307
 308     my %newdata = %$data;
 309     for my $field (qw(found fixed)) {
 310          if (exists $newdata{$field}) {
 311               $newdata{"${field}_date"} =
 312                    [map {$newdata{$field}{$_}||''} keys %{$newdata{$field}}];
 313          }
 314     }
 315
 316     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 317          $newdata{$field} = join ' ', @{$newdata{$field}||[]};
 318     }
 319
 320     if ($version < 3) {
 321         for my $field (@rfc1522_fields) {
 322             $newdata{$field} = encode_rfc1522($newdata{$field});
 323         }
 324     }
 325
 326     if ($version == 1) {
 327         for my $field (@v1fieldorder) {
 328             if (exists $newdata{$field} and defined $newdata{$field}) {
 329                 $contents .= "$newdata{$field}\n";
 330             } else {
 331                 $contents .= "\n";
 332             }
 333         }
 334     } elsif ($version == 2 or $version == 3) {
 335         # Version 2 or 3. Add a file format version number for the sake of
 336         # further extensibility in the future.
 337         $contents .= "Format-Version: $version\n";
 338         for my $field (keys %fields) {
 339             if (exists $newdata{$field} and defined $newdata{$field}
 340                 and $newdata{$field} ne '') {
 341                 # Output field names in proper case, e.g. 'Merged-With'.
 342                 my $properfield = $fields{$field};
 343                 $properfield =~ s/(?:^|(?<=-))([a-z])/\u$1/g;
 344                 $contents .= "$properfield: $newdata{$field}\n";
 345             }
 346         }
 347     }
 348
 349     return $contents;
 350 }
 351
 352 =head2 writebug
 353
 354      writebug($bug_num,$status,$location,$minversion,$disablebughook)
 355
 356 Writes the bug status and summary files out.
 357
 358 Skips writting out a status file if minversion is 2
 359
 360 Does not call bughook if disablebughook is true.
 361
 362 =cut
 363
 364 sub writebug {
 365     my ($ref, $data, $location, $minversion, $disablebughook) = @_;
 366     my $change;
 367
 368     my %outputs = (1 => 'status', 2 => 'summary');
 369     for my $version (keys %outputs) {
 370         next if defined $minversion and $version < $minversion;
 371         my $status = getbugcomponent($ref, $outputs{$version}, $location);
 372         &quit("can't find location for $ref") unless defined $status;
 373         open(S,"> $status.new") || &quit("opening $status.new: $!");
 374         print(S makestatus($data, $version)) ||
 375             &quit("writing $status.new: $!");
 376         close(S) || &quit("closing $status.new: $!");
 377         if (-e $status) {
 378             $change = 'change';
 379         } else {
 380             $change = 'new';
 381         }
 382         rename("$status.new",$status) || &quit("installing new $status: $!");
 383     }
 384
 385     # $disablebughook is a bit of a hack to let format migration scripts use
 386     # this function rather than having to duplicate it themselves.
 387     &bughook($change,$ref,$data) unless $disablebughook;
 388 }
 389
 390 =head2 unlockwritebug
 391
 392      unlockwritebug($bug_num,$status,$location,$minversion,$disablebughook);
 393
 394 Writes a bug, then calls unfilelock; see writebug for what these
 395 options mean.
 396
 397 =cut
 398
 399 sub unlockwritebug {
 400     writebug(@_);
 401     &unfilelock;
 402 }
 403
 404 =head1 VERSIONS
 405
 406 The following functions are exported with the :versions tag
 407
 408 =head2 addfoundversions
 409
 410      addfoundversions($status,$package,$version,$isbinary);
 411
 412
 413
 414 =cut
 415
 416
 417 sub addfoundversions {
 418     my $data = shift;
 419     my $package = shift;
 420     my $version = shift;
 421     my $isbinary = shift;
 422     return unless defined $version;
 423     undef $package if $package =~ m[(?:\s|/)];
 424     my $source = $package;
 425
 426     if (defined $package and $isbinary) {
 427         my @srcinfo = binarytosource($package, $version, undef);
 428         if (@srcinfo) {
 429             # We know the source package(s). Use a fully-qualified version.
 430             addfoundversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 431             return;
 432         }
 433         # Otherwise, an unqualified version will have to do.
 434         undef $source;
 435     }
 436
 437     # Strip off various kinds of brain-damage.
 438     $version =~ s/;.*//;
 439     $version =~ s/ *\(.*\)//;
 440     $version =~ s/ +[A-Za-z].*//;
 441
 442     foreach my $ver (split /[,\s]+/, $version) {
 443         my $sver = defined($source) ? "$source/$ver" : '';
 444         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{found_versions}}) {
 445             push @{$data->{found_versions}}, defined($source) ? $sver : $ver;
 446         }
 447         @{$data->{fixed_versions}} =
 448             grep { $_ ne $ver and $_ ne $sver } @{$data->{fixed_versions}};
 449     }
 450 }
 451
 452 =head2 removefoundversions
 453
 454      removefoundversions($data,$package,$versiontoremove)
 455
 456 Removes found versions from $data
 457
 458 If a version is fully qualified (contains /) only versions matching
 459 exactly are removed. Otherwise, all versions matching the version
 460 number are removed.
 461
 462 Currently $package and $isbinary are entirely ignored, but accepted
 463 for backwards compatibilty.
 464
 465 =cut
 466
 467 sub removefoundversions {
 468     my $data = shift;
 469     my $package = shift;
 470     my $version = shift;
 471     my $isbinary = shift;
 472     return unless defined $version;
 473
 474     foreach my $ver (split /[,\s]+/, $version) {
 475          if ($ver =~ m{/}) {
 476               # fully qualified version
 477               @{$data->{found_versions}} =
 478                    grep {$_ ne $ver}
 479                         @{$data->{found_versions}};
 480          }
 481          else {
 482               # non qualified version; delete all matchers
 483               @{$data->{found_versions}} =
 484                    grep {$_ !~ m[(?:^|/)\Q$ver\E$]}
 485                         @{$data->{found_versions}};
 486          }
 487     }
 488 }
 489
 490
 491 sub addfixedversions {
 492     my $data = shift;
 493     my $package = shift;
 494     my $version = shift;
 495     my $isbinary = shift;
 496     return unless defined $version;
 497     undef $package if defined $package and $package =~ m[(?:\s|/)];
 498     my $source = $package;
 499
 500     if (defined $package and $isbinary) {
 501         my @srcinfo = binarytosource($package, $version, undef);
 502         if (@srcinfo) {
 503             # We know the source package(s). Use a fully-qualified version.
 504             addfixedversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 505             return;
 506         }
 507         # Otherwise, an unqualified version will have to do.
 508         undef $source;
 509     }
 510
 511     # Strip off various kinds of brain-damage.
 512     $version =~ s/;.*//;
 513     $version =~ s/ *\(.*\)//;
 514     $version =~ s/ +[A-Za-z].*//;
 515
 516     foreach my $ver (split /[,\s]+/, $version) {
 517         my $sver = defined($source) ? "$source/$ver" : '';
 518         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{fixed_versions}}) {
 519             push @{$data->{fixed_versions}}, defined($source) ? $sver : $ver;
 520         }
 521         @{$data->{found_versions}} =
 522             grep { $_ ne $ver and $_ ne $sver } @{$data->{found_versions}};
 523     }
 524 }
 525
 526 sub removefixedversions {
 527     my $data = shift;
 528     my $package = shift;
 529     my $version = shift;
 530     my $isbinary = shift;
 531     return unless defined $version;
 532     undef $package if $package =~ m[(?:\s|/)];
 533     my $source = $package;
 534
 535     if (defined $package and $isbinary) {
 536         my @srcinfo = binarytosource($package, $version, undef);
 537         if (@srcinfo) {
 538             # We know the source package(s). Use a fully-qualified version.
 539             removefixedversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 540             return;
 541         }
 542         # Otherwise, an unqualified version will have to do.
 543         undef $source;
 544     }
 545
 546     foreach my $ver (split /[,\s]+/, $version) {
 547         my $sver = defined($source) ? "$source/$ver" : '';
 548         @{$data->{fixed_versions}} =
 549             grep { $_ ne $ver and $_ ne $sver } @{$data->{fixed_versions}};
 550     }
 551 }
 552
 553
 554
 555 =head2 splitpackages
 556
 557      splitpackages($pkgs)
 558
 559 Split a package string from the status file into a list of package names.
 560
 561 =cut
 562
 563 sub splitpackages {
 564     my $pkgs = shift;
 565     return unless defined $pkgs;
 566     return map lc, split /[ \t?,()]+/, $pkgs;
 567 }
 568
 569
 570 =head2 bug_archiveable
 571
 572      bug_archiveable(bug => $bug_num);
 573
 574 Options
 575
 576 =over
 577
 578 =item bug -- bug number (required)
 579
 580 =item status -- Status hashref returned by read_bug or get_bug_status (optional)
 581
 582 =item version -- Debbugs::Version information (optional)
 583
 584 =item days_until -- return days until the bug can be archived
 585
 586 =back
 587
 588 Returns 1 if the bug can be archived
 589 Returns 0 if the bug cannot be archived
 590
 591 If days_until is true, returns the number of days until the bug can be
 592 archived, -1 if it cannot be archived. 0 means that the bug can be
 593 archived the next time the archiver runs.
 594
 595 Returns undef on failure.
 596
 597 =cut
 598
 599 # This will eventually need to be fixed before we start using mod_perl
 600 our $version_cache = {};
 601 sub bug_archiveable{
 602      my %param = validate_with(params => \@_,
 603                                spec   => {bug => {type => SCALAR,
 604                                                   regex => qr/^\d+$/,
 605                                                  },
 606                                           status => {type => HASHREF,
 607                                                      optional => 1,
 608                                                     },
 609                                           days_until => {type => BOOLEAN,
 610                                                          default => 0,
 611                                                         },
 612                                           ignore_time => {type => BOOLEAN,
 613                                                           default => 0,
 614                                                          },
 615                                          },
 616                               );
 617      # This is what we return if the bug cannot be archived.
 618      my $cannot_archive = $param{days_until}?-1:0;
 619      # read the status information
 620      my $status = $param{status};
 621      if (not exists $param{status} or not defined $status) {
 622           $status = read_bug(bug=>$param{bug});
 623           return undef if not defined $status;
 624      }
 625      # Bugs can be archived if they are
 626      # 1. Closed
 627      return $cannot_archive if not defined $status->{done} or not length $status->{done};
 628      # If we just are checking if the bug can be archived, we'll not even bother
 629      # checking the versioning information if the bug has been -done for less than 28 days.
 630      my $log_file = getbugcomponent($param{bug},'log');
 631      if (not defined $log_file) {
 632           print STDERR "Cannot archive $param{bug} because the log doesn't exists\n" if $DEBUG;
 633      }
 634      if (not $param{days_until} and not $param{ignore_time}
 635          and $config{remove_age} >
 636          -M $log_file
 637         ) {
 638           print STDERR "Cannot archive $param{bug} because of time\n" if $DEBUG;
 639           return $cannot_archive;
 640      }
 641      # At this point, we have to get the versioning information for this bug.
 642      # We examine the set of distribution tags. If a bug has no distribution
 643      # tags set, we assume a default set, otherwise we use the tags the bug
 644      # has set.
 645
 646      # There must be fixed_versions for us to look at the versioning
 647      # information
 648      my $min_fixed_time = time;
 649      my $min_archive_days = 0;
 650      if (@{$status->{fixed_versions}}) {
 651           my %dist_tags;
 652           @dist_tags{@{$config{removal_distribution_tags}}} =
 653                (1) x @{$config{removal_distribution_tags}};
 654           my %dists;
 655           @dists{@{$config{removal_default_distribution_tags}}} =
 656                (1) x @{$config{removal_default_distribution_tags}};
 657           for my $tag (split ' ', ($status->{tags}||'')) {
 658                next unless $dist_tags{$tag};
 659                $dists{$tag} = 1;
 660           }
 661           my %source_versions;
 662           my @sourceversions = get_versions(package => $status->{package},
 663                                             dist => [keys %dists],
 664                                             source => 1,
 665                                            );
 666           @source_versions{@sourceversions} = (1) x @sourceversions;
 667           # If the bug has not been fixed in the versions actually
 668           # distributed, then it cannot be archived.
 669           if ('found' eq max_buggy(bug => $param{bug},
 670                                    sourceversions => [keys %source_versions],
 671                                    found          => $status->{found_versions},
 672                                    fixed          => $status->{fixed_versions},
 673                                    version_cache  => $version_cache,
 674                                    package        => $status->{package},
 675                                   )) {
 676                print STDERR "Cannot archive $param{bug} because it's found\n" if $DEBUG;
 677                return $cannot_archive;
 678           }
 679           # Since the bug has at least been fixed in the architectures
 680           # that matters, we check to see how long it has been fixed.
 681
 682           # If $param{ignore_time}, then we should ignore time.
 683           if ($param{ignore_time}) {
 684                return $param{days_until}?0:1;
 685           }
 686
 687           # To do this, we order the times from most recent to oldest;
 688           # when we come to the first found version, we stop.
 689           # If we run out of versions, we only report the time of the
 690           # last one.
 691           my %time_versions = get_versions(package => $status->{package},
 692                                            dist    => [keys %dists],
 693                                            source  => 1,
 694                                            time    => 1,
 695                                           );
 696           for my $version (sort {$time_versions{$b} <=> $time_versions{$a}} keys %time_versions) {
 697                my $buggy = buggy(bug => $param{bug},
 698                                  version        => $version,
 699                                  found          => $status->{found_versions},
 700                                  fixed          => $status->{fixed_versions},
 701                                  version_cache  => $version_cache,
 702                                  package        => $status->{package},
 703                                 );
 704                last if $buggy eq 'found';
 705                $min_fixed_time = min($time_versions{$version},$min_fixed_time);
 706           }
 707           $min_archive_days = max($min_archive_days,ceil($config{remove_age} - (time - $min_fixed_time)/(60*60*24)));
 708      }
 709      # If $param{ignore_time}, then we should ignore time.
 710      if ($param{ignore_time}) {
 711           return $param{days_until}?0:1;
 712      }
 713      # 6. at least 28 days have passed since the last action has occured or the bug was closed
 714      my $age = ceil(max(map {$config{remove_age} - -M $log_file}
 715                         $param{bug}, split / /, $status->{mergedwith}
 716                        )
 717                    );
 718      if ($age > 0 or $min_archive_days > 0) {
 719           return $param{days_until}?max($age,$min_archive_days):0;
 720      }
 721      else {
 722           return $param{days_until}?0:1;
 723      }
 724 }
 725
 726
 727 =head2 get_bug_status
 728
 729      my $status = get_bug_status(bug => $nnn);
 730
 731      my $status = get_bug_status($bug_num)
 732
 733 =head3 Options
 734
 735 =over
 736
 737 =item bug -- scalar bug number
 738
 739 =item status -- optional hashref of bug status as returned by readbug
 740 (can be passed to avoid rereading the bug information)
 741
 742 =item bug_index -- optional tied index of bug status infomration;
 743 currently not correctly implemented.
 744
 745 =item version -- optional version(s) to check package status at
 746
 747 =item dist -- optional distribution(s) to check package status at
 748
 749 =item arch -- optional architecture(s) to check package status at
 750
 751 =item bugusertags -- optional hashref of bugusertags
 752
 753 =item sourceversion -- optional arrayref of source/version; overrides
 754 dist, arch, and version. [The entries in this array must be in the
 755 "source/version" format.] Eventually this can be used to for caching.
 756
 757 =back
 758
 759 Note: Currently the version information is cached; this needs to be
 760 changed before using this function in long lived programs.
 761
 762 =cut
 763
 764 sub get_bug_status {
 765      if (@_ == 1) {
 766           unshift @_, 'bug';
 767      }
 768      my %param = validate_with(params => \@_,
 769                                spec   => {bug       => {type => SCALAR,
 770                                                         regex => qr/^\d+$/,
 771                                                        },
 772                                           status    => {type => HASHREF,
 773                                                         optional => 1,
 774                                                        },
 775                                           bug_index => {type => OBJECT,
 776                                                         optional => 1,
 777                                                        },
 778                                           version   => {type => SCALAR|ARRAYREF,
 779                                                         optional => 1,
 780                                                        },
 781                                           dist       => {type => SCALAR|ARRAYREF,
 782                                                          optional => 1,
 783                                                         },
 784                                           arch       => {type => SCALAR|ARRAYREF,
 785                                                          optional => 1,
 786                                                         },
 787                                           bugusertags   => {type => HASHREF,
 788                                                             optional => 1,
 789                                                            },
 790                                           sourceversions => {type => ARRAYREF,
 791                                                              optional => 1,
 792                                                             },
 793                                          },
 794                               );
 795      my %status;
 796
 797      if (defined $param{bug_index} and
 798          exists $param{bug_index}{$param{bug}}) {
 799           %status = %{ $param{bug_index}{$param{bug}} };
 800           $status{pending} = $status{ status };
 801           $status{id} = $param{bug};
 802           return \%status;
 803      }
 804      if (defined $param{status}) {
 805           %status = %{$param{status}};
 806      }
 807      else {
 808           my $location = getbuglocation($param{bug}, 'summary');
 809           return {} if not defined $location or not length $location;
 810           %status = %{ readbug( $param{bug}, $location ) };
 811      }
 812      $status{id} = $param{bug};
 813
 814      if (defined $param{bugusertags}{$param{bug}}) {
 815           $status{keywords} = "" unless defined $status{keywords};
 816           $status{keywords} .= " " unless $status{keywords} eq "";
 817           $status{keywords} .= join(" ", @{$param{bugusertags}{$param{bug}}});
 818      }
 819      $status{tags} = $status{keywords};
 820      my %tags = map { $_ => 1 } split ' ', $status{tags};
 821
 822      $status{"package"} =~ s/\s*$//;
 823      $status{"package"} = 'unknown' if ($status{"package"} eq '');
 824      $status{"severity"} = 'normal' if ($status{"severity"} eq '');
 825
 826      $status{"pending"} = 'pending';
 827      $status{"pending"} = 'forwarded'       if (length($status{"forwarded"}));
 828      $status{"pending"} = 'pending-fixed'    if ($tags{pending});
 829      $status{"pending"} = 'fixed'           if ($tags{fixed});
 830
 831
 832      my $presence = bug_presence(map{(exists $param{$_})?($_,$param{$_}):()}
 833                                  qw(bug sourceversions arch dist version found fixed package)
 834                                 );
 835      if (defined $presence) {
 836           if ($presence eq 'fixed') {
 837                $status{pending} = 'done';
 838           }
 839           elsif ($presence eq 'absent') {
 840                $status{pending} = 'absent';
 841           }
 842      }
 843      return \%status;
 844 }
 845
 846 =head2 bug_presence
 847
 848      my $precence = bug_presence(bug => nnn,
 849                                  ...
 850                                 );
 851
 852 Returns 'found', 'absent', 'fixed' or undef based on whether the bug
 853 is found, absent, fixed, or no information is available in the
 854 distribution (dist) and/or architecture (arch) specified.
 855
 856
 857 =head3 Options
 858
 859 =over
 860
 861 =item bug -- scalar bug number
 862
 863 =item status -- optional hashref of bug status as returned by readbug
 864 (can be passed to avoid rereading the bug information)
 865
 866 =item bug_index -- optional tied index of bug status infomration;
 867 currently not correctly implemented.
 868
 869 =item version -- optional version to check package status at
 870
 871 =item dist -- optional distribution to check package status at
 872
 873 =item arch -- optional architecture to check package status at
 874
 875 =item sourceversion -- optional arrayref of source/version; overrides
 876 dist, arch, and version. [The entries in this array must be in the
 877 "source/version" format.] Eventually this can be used to for caching.
 878
 879 =back
 880
 881 =cut
 882
 883 sub bug_presence {
 884      my %param = validate_with(params => \@_,
 885                                spec   => {bug       => {type => SCALAR,
 886                                                         regex => qr/^\d+$/,
 887                                                        },
 888                                           status    => {type => HASHREF,
 889                                                         optional => 1,
 890                                                        },
 891                                           version   => {type => SCALAR|ARRAYREF,
 892                                                         optional => 1,
 893                                                        },
 894                                           dist       => {type => SCALAR|ARRAYREF,
 895                                                          optional => 1,
 896                                                         },
 897                                           arch       => {type => SCALAR|ARRAYREF,
 898                                                          optional => 1,
 899                                                         },
 900                                           sourceversions => {type => ARRAYREF,
 901                                                              optional => 1,
 902                                                             },
 903                                          },
 904                               );
 905      my %status;
 906      if (defined $param{status}) {
 907          %status = %{$param{status}};
 908      }
 909      else {
 910           my $location = getbuglocation($param{bug}, 'summary');
 911           return {} if not length $location;
 912           %status = %{ readbug( $param{bug}, $location ) };
 913      }
 914
 915      my @sourceversions;
 916      my $pseudo_desc = getpseudodesc();
 917      if (not exists $param{sourceversions}) {
 918           my %sourceversions;
 919           # pseudopackages do not have source versions by definition.
 920           if (exists $pseudo_desc->{$status{package}}) {
 921                # do nothing.
 922           }
 923           elsif (defined $param{version}) {
 924                foreach my $arch (make_list($param{arch})) {
 925                     for my $package (split /\s*,\s*/, $status{package}) {
 926                          my @temp = makesourceversions($package,
 927                                                        $arch,
 928                                                        make_list($param{version})
 929                                                       );
 930                          @sourceversions{@temp} = (1) x @temp;
 931                     }
 932                }
 933           } elsif (defined $param{dist}) {
 934                foreach my $arch (make_list($param{arch})) {
 935                     my @versions;
 936                     for my $package (split /\s*,\s*/, $status{package}) {
 937                          foreach my $dist (make_list($param{dist})) {
 938                               push @versions, getversions($package, $dist, $arch);
 939                          }
 940                          my @temp = makesourceversions($package,
 941                                                        $arch,
 942                                                        @versions
 943                                                       );
 944                          @sourceversions{@temp} = (1) x @temp;
 945                     }
 946                }
 947           }
 948
 949           # TODO: This should probably be handled further out for efficiency and
 950           # for more ease of distinguishing between pkg= and src= queries.
 951           # DLA: src= queries should just pass arch=source, and they'll be happy.
 952           @sourceversions = keys %sourceversions;
 953      }
 954      else {
 955           @sourceversions = @{$param{sourceversions}};
 956      }
 957      my $maxbuggy = 'undef';
 958      if (@sourceversions) {
 959           $maxbuggy = max_buggy(bug => $param{bug},
 960                                    sourceversions => \@sourceversions,
 961                                    found => $status{found_versions},
 962                                    fixed => $status{fixed_versions},
 963                                    package => $status{package},
 964                                    version_cache => $version_cache,
 965                                   );
 966      }
 967      elsif (defined $param{dist}) {
 968           return 'absent';
 969      }
 970      if (length($status{done}) and
 971          (not @sourceversions or not @{$status{fixed_versions}})) {
 972           return 'fixed';
 973      }
 974      return $maxbuggy;
 975 }
 976
 977
 978 =head2 max_buggy
 979
 980      max_buggy()
 981
 982 =head3 Options
 983
 984 =over
 985
 986 =item bug -- scalar bug number
 987
 988 =item sourceversion -- optional arrayref of source/version; overrides
 989 dist, arch, and version. [The entries in this array must be in the
 990 "source/version" format.] Eventually this can be used to for caching.
 991
 992 =back
 993
 994 Note: Currently the version information is cached; this needs to be
 995 changed before using this function in long lived programs.
 996
 997
 998 =cut
 999 sub max_buggy{
1000      my %param = validate_with(params => \@_,
1001                                spec   => {bug       => {type => SCALAR,
1002                                                         regex => qr/^\d+$/,
1003                                                        },
1004                                           sourceversions => {type => ARRAYREF,
1005                                                              default => [],
1006                                                             },
1007                                           found          => {type => ARRAYREF,
1008                                                              default => [],
1009                                                             },
1010                                           fixed          => {type => ARRAYREF,
1011                                                              default => [],
1012                                                             },
1013                                           package        => {type => SCALAR,
1014                                                             },
1015                                           version_cache  => {type => HASHREF,
1016                                                              default => {},
1017                                                             },
1018                                          },
1019                               );
1020      # Resolve bugginess states (we might be looking at multiple
1021      # architectures, say). Found wins, then fixed, then absent.
1022      my $maxbuggy = 'absent';
1023      for my $package (split /\s*,\s*/, $param{package}) {
1024           for my $version (@{$param{sourceversions}}) {
1025                my $buggy = buggy(bug => $param{bug},
1026                                  version => $version,
1027                                  found => $param{found},
1028                                  fixed => $param{fixed},
1029                                  version_cache => $param{version_cache},
1030                                  package => $package,
1031                                 );
1032                if ($buggy eq 'found') {
1033                     return 'found';
1034                } elsif ($buggy eq 'fixed') {
1035                     $maxbuggy = 'fixed';
1036                }
1037           }
1038      }
1039      return $maxbuggy;
1040 }
1041
1042
1043 =head2 buggy
1044
1045      buggy(bug => nnn,
1046            found => \@found,
1047            fixed => \@fixed,
1048            package => 'foo',
1049            version => '1.0',
1050           );
1051
1052 Returns the output of Debbugs::Versions::buggy for a particular
1053 package, version and found/fixed set. Automatically turns found, fixed
1054 and version into source/version strings.
1055
1056 Caching can be had by using the version_cache, but no attempt to check
1057 to see if the on disk information is more recent than the cache is
1058 made. [This will need to be fixed for long-lived processes.]
1059
1060 =cut
1061
1062 sub buggy {
1063      my %param = validate_with(params => \@_,
1064                                spec   => {bug => {type => SCALAR,
1065                                                   regex => qr/^\d+$/,
1066                                                  },
1067                                           found => {type => ARRAYREF,
1068                                                     default => [],
1069                                                    },
1070                                           fixed => {type => ARRAYREF,
1071                                                     default => [],
1072                                                    },
1073                                           version_cache => {type => HASHREF,
1074                                                             optional => 1,
1075                                                            },
1076                                           package => {type => SCALAR,
1077                                                      },
1078                                           version => {type => SCALAR,
1079                                                      },
1080                                          },
1081                               );
1082      my @found = @{$param{found}};
1083      my @fixed = @{$param{fixed}};
1084      if (grep {$_ !~ m{/}} (@{$param{found}}, @{$param{fixed}})) {
1085           # We have non-source version versions
1086           @found = makesourceversions($param{package},undef,
1087                                       @found
1088                                      );
1089           @fixed = makesourceversions($param{package},undef,
1090                                       @fixed
1091                                      );
1092      }
1093      if ($param{version} !~ m{/}) {
1094           my ($version) = makesourceversions($param{package},undef,
1095                                              $param{version}
1096                                             );
1097           $param{version} = $version if defined $version;
1098      }
1099      # Figure out which source packages we need
1100      my %sources;
1101      @sources{map {m{(.+)/}; $1} @found} = (1) x @found;
1102      @sources{map {m{(.+)/}; $1} @fixed} = (1) x @fixed;
1103      @sources{map {m{(.+)/}; $1} $param{version}} = 1 if
1104           $param{version} =~ m{/};
1105      my $version;
1106      if (not defined $param{version_cache} or
1107          not exists $param{version_cache}{join(',',sort keys %sources)}) {
1108           $version = Debbugs::Versions->new(\&Debbugs::Versions::Dpkg::vercmp);
1109           foreach my $source (keys %sources) {
1110                my $srchash = substr $source, 0, 1;
1111                my $version_fh = IO::File->new("$config{version_packages_dir}/$srchash/$source", 'r');
1112                if (not defined $version_fh) {
1113                     # We only want to warn if it's a package which actually has a maintainer
1114                     my $maints = getmaintainers();
1115                     next if not exists $maints->{$source};
1116                     warn "Unable to open $config{version_packages_dir}/$srchash/$source: $!";
1117                     next;
1118                }
1119                $version->load($version_fh);
1120           }
1121           if (defined $param{version_cache}) {
1122                $param{version_cache}{join(',',sort keys %sources)} = $version;
1123           }
1124      }
1125      else {
1126           $version = $param{version_cache}{join(',',sort keys %sources)};
1127      }
1128      return $version->buggy($param{version},\@found,\@fixed);
1129 }
1130
1131 sub isstrongseverity {
1132     my $severity = shift;
1133     $severity = $config{default_severity} if
1134          not defined $severity or $severity eq '';
1135     return grep { $_ eq $severity } @{$config{strong_severities}};
1136 }
1137
1138
1139 =head1 PRIVATE FUNCTIONS
1140
1141 =cut
1142
1143 sub update_realtime {
1144         my ($file, %bugs) = @_;
1145
1146         # update realtime index.db
1147
1148         return () unless keys %bugs;
1149         my $idx_old = IO::File->new($file,'r')
1150              or die "Couldn't open ${file}: $!";
1151         my $idx_new = IO::File->new($file.'.new','w')
1152              or die "Couldn't open ${file}.new: $!";
1153
1154         my $min_bug = min(keys %bugs);
1155         my $line;
1156         my @line;
1157         my %changed_bugs;
1158         while($line = <$idx_old>) {
1159              @line = split /\s/, $line;
1160              # Two cases; replacing existing line or adding new line
1161              if (exists $bugs{$line[1]}) {
1162                   my $new = $bugs{$line[1]};
1163                   delete $bugs{$line[1]};
1164                   $min_bug = min(keys %bugs);
1165                   if ($new eq "NOCHANGE") {
1166                        print {$idx_new} $line;
1167                        $changed_bugs{$line[1]} = $line;
1168                   } elsif ($new eq "REMOVE") {
1169                        $changed_bugs{$line[1]} = $line;
1170                   } else {
1171                        print {$idx_new} $new;
1172                        $changed_bugs{$line[1]} = $line;
1173                   }
1174              }
1175              else {
1176                   while ($line[1] > $min_bug) {
1177                        print {$idx_new} $bugs{$min_bug};
1178                        delete $bugs{$min_bug};
1179                        last unless keys %bugs;
1180                        $min_bug = min(keys %bugs);
1181                   }
1182                   print {$idx_new} $line;
1183              }
1184              last unless keys %bugs;
1185         }
1186         print {$idx_new} map {$bugs{$_}} sort keys %bugs;
1187
1188         print {$idx_new} <$idx_old>;
1189
1190         close($idx_new);
1191         close($idx_old);
1192
1193         rename("$file.new", $file);
1194
1195         return %changed_bugs;
1196 }
1197
1198 sub bughook_archive {
1199         my @refs = @_;
1200         &filelock("debbugs.trace.lock");
1201         &appendfile("debbugs.trace","archive ".join(',',@refs)."\n");
1202         my %bugs = update_realtime("$config{spool_dir}/index.db.realtime",
1203                                    map{($_,'REMOVE')} @refs);
1204         update_realtime("$config{spool_dir}/index.archive.realtime",
1205                         %bugs);
1206         &unfilelock;
1207 }
1208
1209 sub bughook {
1210         my ( $type, %bugs_temp ) = @_;
1211         &filelock("debbugs.trace.lock");
1212
1213         my %bugs;
1214         for my $bug (keys %bugs_temp) {
1215              my $data = $bugs_temp{$bug};
1216              &appendfile("debbugs.trace","$type $bug\n",makestatus($data, 1));
1217
1218              my $whendone = "open";
1219              my $severity = $config{default_severity};
1220              (my $pkglist = $data->{package}) =~ s/[,\s]+/,/g;
1221              $pkglist =~ s/^,+//;
1222              $pkglist =~ s/,+$//;
1223              $whendone = "forwarded" if defined $data->{forwarded} and length $data->{forwarded};
1224              $whendone = "done" if defined $data->{done} and length $data->{done};
1225              $severity = $data->{severity} if length $data->{severity};
1226
1227              my $k = sprintf "%s %d %d %s [%s] %s %s\n",
1228                   $pkglist, $bug, $data->{date}, $whendone,
1229                        $data->{originator}, $severity, $data->{keywords};
1230              $bugs{$bug} = $k;
1231         }
1232         update_realtime("$config{spool_dir}/index.db.realtime", %bugs);
1233
1234         &unfilelock;
1235 }
1236
1237
1238 1;
1239
1240 __END__