Debbugs/Status.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # [Other people have contributed to this file; their copyrights should
   7 # go here too.]
   8 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>.
   9
  10 package Debbugs::Status;
  11
  12 =head1 NAME
  13
  14 Debbugs::Status -- Routines for dealing with summary and status files
  15
  16 =head1 SYNOPSIS
  17
  18 use Debbugs::Status;
  19
  20
  21 =head1 DESCRIPTION
  22
  23 This module is a replacement for the parts of errorlib.pl which write
  24 and read status and summary files.
  25
  26 It also contains generic routines for returning information about the
  27 status of a particular bug
  28
  29 =head1 FUNCTIONS
  30
  31 =cut
  32
  33 use warnings;
  34 use strict;
  35 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  36 use base qw(Exporter);
  37
  38 use Params::Validate qw(validate_with :types);
  39 use Debbugs::Common qw(:util :lock :quit :misc);
  40 use Debbugs::Config qw(:config);
  41 use Debbugs::MIME qw(decode_rfc1522 encode_rfc1522);
  42 use Debbugs::Packages qw(makesourceversions getversions get_versions binarytosource);
  43 use Debbugs::Versions;
  44 use Debbugs::Versions::Dpkg;
  45 use POSIX qw(ceil);
  46
  47 use List::Util qw(min max);
  48
  49
  50 BEGIN{
  51      $VERSION = 1.00;
  52      $DEBUG = 0 unless defined $DEBUG;
  53
  54      @EXPORT = ();
  55      %EXPORT_TAGS = (status => [qw(splitpackages get_bug_status buggy bug_archiveable),
  56                                 qw(isstrongseverity bug_presence),
  57                                ],
  58                      read   => [qw(readbug read_bug lockreadbug lockreadbugmerge)],
  59                      write  => [qw(writebug makestatus unlockwritebug)],
  60                      versions => [qw(addfoundversions addfixedversions),
  61                                   qw(removefoundversions removefixedversions)
  62                                  ],
  63                      hook     => [qw(bughook bughook_archive)],
  64                     );
  65      @EXPORT_OK = ();
  66      Exporter::export_ok_tags(qw(status read write versions hook));
  67      $EXPORT_TAGS{all} = [@EXPORT_OK];
  68 }
  69
  70
  71 =head2 readbug
  72
  73      readbug($bug_num,$location)
  74      readbug($bug_num)
  75
  76 Reads a summary file from the archive given a bug number and a bug
  77 location. Valid locations are those understood by L</getbugcomponent>
  78
  79 =cut
  80
  81
  82 my %fields = (originator     => 'submitter',
  83               date           => 'date',
  84               subject        => 'subject',
  85               msgid          => 'message-id',
  86               'package'      => 'package',
  87               keywords       => 'tags',
  88               done           => 'done',
  89               forwarded      => 'forwarded-to',
  90               mergedwith     => 'merged-with',
  91               severity       => 'severity',
  92               owner          => 'owner',
  93               found_versions => 'found-in',
  94               found_date     => 'found-date',
  95               fixed_versions => 'fixed-in',
  96               fixed_date     => 'fixed-date',
  97               blocks         => 'blocks',
  98               blockedby      => 'blocked-by',
  99               unarchived     => 'unarchived',
 100              );
 101
 102 # Fields which need to be RFC1522-decoded in format versions earlier than 3.
 103 my @rfc1522_fields = qw(originator subject done forwarded owner);
 104
 105 sub readbug {
 106      return read_bug(bug => $_[0],
 107                      (@_ > 1)?(location => $_[1]):()
 108                     );
 109 }
 110
 111 =head2 read_bug
 112
 113      read_bug(bug => $bug_num,
 114               location => 'archive',
 115              );
 116      read_bug(summary => 'path/to/bugnum.summary');
 117      read_bug($bug_num);
 118
 119 A more complete function than readbug; it enables you to pass a full
 120 path to the summary file instead of the bug number and/or location.
 121
 122 =head3 Options
 123
 124 =over
 125
 126 =item bug -- the bug number
 127
 128 =item location -- optional location which is passed to getbugcomponent
 129
 130 =item summary -- complete path to the .summary file which will be read
 131
 132 =back
 133
 134 One of C<bug> or C<summary> must be passed. This function will return
 135 undef on failure, and will die if improper arguments are passed.
 136
 137 =cut
 138
 139 sub read_bug{
 140     if (@_ == 1) {
 141          unshift @_, 'bug';
 142     }
 143     my %param = validate_with(params => \@_,
 144                               spec   => {bug => {type => SCALAR,
 145                                                  optional => 1,
 146                                                  # something really
 147                                                  # stupid passes
 148                                                  # negative bugnumbers
 149                                                  regex    => qr/^-?\d+/,
 150                                                 },
 151                                          location => {type => SCALAR|UNDEF,
 152                                                       optional => 1,
 153                                                      },
 154                                          summary  => {type => SCALAR,
 155                                                       optional => 1,
 156                                                      },
 157                                         },
 158                              );
 159     die "One of bug or summary must be passed to read_bug"
 160          if not exists $param{bug} and not exists $param{summary};
 161     my $status;
 162     my $log;
 163     my $location;
 164     if (not defined $param{summary}) {
 165          my $lref;
 166          ($lref,$location) = @param{qw(bug location)};
 167          if (not defined $location) {
 168               $location = getbuglocation($lref,'summary');
 169               return undef if not defined $location;
 170          }
 171          $status = getbugcomponent($lref, 'summary', $location);
 172          $log    = getbugcomponent($lref, 'log'    , $location);
 173          return undef unless defined $status;
 174     }
 175     else {
 176          $status = $param{summary};
 177          $log = $status;
 178          $log =~ s/\.summary$/.log/;
 179          ($location) = $status =~ m/(db-h|db|archive)/;
 180     }
 181     my $status_fh = new IO::File $status, 'r' or
 182          warn "Unable to open $status for reading: $!" and return undef;
 183
 184     my %data;
 185     my @lines;
 186     my $version = 2;
 187     local $_;
 188
 189     while (<$status_fh>) {
 190         chomp;
 191         push @lines, $_;
 192         $version = $1 if /^Format-Version: ([0-9]+)/i;
 193     }
 194
 195     # Version 3 is the latest format version currently supported.
 196     return undef if $version > 3;
 197
 198     my %namemap = reverse %fields;
 199     for my $line (@lines) {
 200         if ($line =~ /(\S+?): (.*)/) {
 201             my ($name, $value) = (lc $1, $2);
 202             $data{$namemap{$name}} = $value if exists $namemap{$name};
 203         }
 204     }
 205     for my $field (keys %fields) {
 206         $data{$field} = '' unless exists $data{$field};
 207     }
 208
 209     $data{severity} = $config{default_severity} if $data{severity} eq '';
 210     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 211          $data{$field} = [split ' ', $data{$field}];
 212     }
 213     for my $field (qw(found fixed)) {
 214          # create the found/fixed hashes which indicate when a
 215          # particular version was marked found or marked fixed.
 216          @{$data{$field}}{@{$data{"${field}_versions"}}} =
 217               (('') x (@{$data{"${field}_date"}} - @{$data{"${field}_versions"}}),
 218                @{$data{"${field}_date"}});
 219     }
 220
 221     if ($version < 3) {
 222         for my $field (@rfc1522_fields) {
 223             $data{$field} = decode_rfc1522($data{$field});
 224         }
 225     }
 226     # Add log last modified time
 227     $data{log_modified} = (stat($log))[9];
 228     $data{location} = $location;
 229
 230     return \%data;
 231 }
 232
 233 =head2 lockreadbug
 234
 235      lockreadbug($bug_num,$location)
 236
 237 Performs a filelock, then reads the bug; the bug is unlocked if the
 238 return is undefined, otherwise, you need to call unfilelock or
 239 unlockwritebug.
 240
 241 See readbug above for information on what this returns
 242
 243 =cut
 244
 245 sub lockreadbug {
 246     my ($lref, $location) = @_;
 247     &filelock("lock/$lref");
 248     my $data = read_bug(bug => $lref, location => $location);
 249     &unfilelock unless defined $data;
 250     return $data;
 251 }
 252
 253 =head2 lockreadbugmerge
 254
 255      my ($locks, $data) = lockreadbugmerge($bug_num,$location);
 256
 257 Performs a filelock, then reads the bug. If the bug is merged, locks
 258 the merge lock. Returns a list of the number of locks and the bug
 259 data.
 260
 261 =cut
 262
 263 sub lockreadbugmerge {
 264      my ($bug_num,$location) = @_;
 265      my $data = lockreadbug(@_);
 266      if (not defined $data) {
 267           return (0,undef);
 268      }
 269      if (not length $data->{mergedwith}) {
 270           return (1,$data);
 271      }
 272      unfilelock();
 273      filelock('lock/merge');
 274      $data = lockreadbug(@_);
 275      if (not defined $data) {
 276           unfilelock();
 277           return (0,undef);
 278      }
 279      return (2,$data);
 280 }
 281
 282
 283 my @v1fieldorder = qw(originator date subject msgid package
 284                       keywords done forwarded mergedwith severity);
 285
 286 =head2 makestatus
 287
 288      my $content = makestatus($status,$version)
 289      my $content = makestatus($status);
 290
 291 Creates the content for a status file based on the $status hashref
 292 passed.
 293
 294 Really only useful for writebug
 295
 296 Currently defaults to version 2 (non-encoded rfc1522 names) but will
 297 eventually default to version 3. If you care, you should specify a
 298 version.
 299
 300 =cut
 301
 302 sub makestatus {
 303     my ($data,$version) = @_;
 304     $version = 2 unless defined $version;
 305
 306     my $contents = '';
 307
 308     my %newdata = %$data;
 309     for my $field (qw(found fixed)) {
 310          if (exists $newdata{$field}) {
 311               $newdata{"${field}_date"} =
 312                    [map {$newdata{$field}{$_}||''} keys %{$newdata{$field}}];
 313          }
 314     }
 315
 316     for my $field (qw(found_versions fixed_versions found_date fixed_date)) {
 317          $newdata{$field} = join ' ', @{$newdata{$field}||[]};
 318     }
 319
 320     if ($version < 3) {
 321         for my $field (@rfc1522_fields) {
 322             $newdata{$field} = encode_rfc1522($newdata{$field});
 323         }
 324     }
 325
 326     if ($version == 1) {
 327         for my $field (@v1fieldorder) {
 328             if (exists $newdata{$field} and defined $newdata{$field}) {
 329                 $contents .= "$newdata{$field}\n";
 330             } else {
 331                 $contents .= "\n";
 332             }
 333         }
 334     } elsif ($version == 2 or $version == 3) {
 335         # Version 2 or 3. Add a file format version number for the sake of
 336         # further extensibility in the future.
 337         $contents .= "Format-Version: $version\n";
 338         for my $field (keys %fields) {
 339             if (exists $newdata{$field} and defined $newdata{$field}
 340                 and $newdata{$field} ne '') {
 341                 # Output field names in proper case, e.g. 'Merged-With'.
 342                 my $properfield = $fields{$field};
 343                 $properfield =~ s/(?:^|(?<=-))([a-z])/\u$1/g;
 344                 $contents .= "$properfield: $newdata{$field}\n";
 345             }
 346         }
 347     }
 348
 349     return $contents;
 350 }
 351
 352 =head2 writebug
 353
 354      writebug($bug_num,$status,$location,$minversion,$disablebughook)
 355
 356 Writes the bug status and summary files out.
 357
 358 Skips writting out a status file if minversion is 2
 359
 360 Does not call bughook if disablebughook is true.
 361
 362 =cut
 363
 364 sub writebug {
 365     my ($ref, $data, $location, $minversion, $disablebughook) = @_;
 366     my $change;
 367
 368     my %outputs = (1 => 'status', 2 => 'summary');
 369     for my $version (keys %outputs) {
 370         next if defined $minversion and $version < $minversion;
 371         my $status = getbugcomponent($ref, $outputs{$version}, $location);
 372         &quit("can't find location for $ref") unless defined $status;
 373         open(S,"> $status.new") || &quit("opening $status.new: $!");
 374         print(S makestatus($data, $version)) ||
 375             &quit("writing $status.new: $!");
 376         close(S) || &quit("closing $status.new: $!");
 377         if (-e $status) {
 378             $change = 'change';
 379         } else {
 380             $change = 'new';
 381         }
 382         rename("$status.new",$status) || &quit("installing new $status: $!");
 383     }
 384
 385     # $disablebughook is a bit of a hack to let format migration scripts use
 386     # this function rather than having to duplicate it themselves.
 387     &bughook($change,$ref,$data) unless $disablebughook;
 388 }
 389
 390 =head2 unlockwritebug
 391
 392      unlockwritebug($bug_num,$status,$location,$minversion,$disablebughook);
 393
 394 Writes a bug, then calls unfilelock; see writebug for what these
 395 options mean.
 396
 397 =cut
 398
 399 sub unlockwritebug {
 400     writebug(@_);
 401     &unfilelock;
 402 }
 403
 404 =head1 VERSIONS
 405
 406 The following functions are exported with the :versions tag
 407
 408 =head2 addfoundversions
 409
 410      addfoundversions($status,$package,$version,$isbinary);
 411
 412
 413
 414 =cut
 415
 416
 417 sub addfoundversions {
 418     my $data = shift;
 419     my $package = shift;
 420     my $version = shift;
 421     my $isbinary = shift;
 422     return unless defined $version;
 423     undef $package if $package =~ m[(?:\s|/)];
 424     my $source = $package;
 425
 426     if (defined $package and $isbinary) {
 427         my @srcinfo = binarytosource($package, $version, undef);
 428         if (@srcinfo) {
 429             # We know the source package(s). Use a fully-qualified version.
 430             addfoundversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 431             return;
 432         }
 433         # Otherwise, an unqualified version will have to do.
 434         undef $source;
 435     }
 436
 437     # Strip off various kinds of brain-damage.
 438     $version =~ s/;.*//;
 439     $version =~ s/ *\(.*\)//;
 440     $version =~ s/ +[A-Za-z].*//;
 441
 442     foreach my $ver (split /[,\s]+/, $version) {
 443         my $sver = defined($source) ? "$source/$ver" : '';
 444         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{found_versions}}) {
 445             push @{$data->{found_versions}}, defined($source) ? $sver : $ver;
 446         }
 447         @{$data->{fixed_versions}} =
 448             grep { $_ ne $ver and $_ ne $sver } @{$data->{fixed_versions}};
 449     }
 450 }
 451
 452 =head2 removefoundversions
 453
 454      removefoundversions($data,$package,$versiontoremove)
 455
 456 Removes found versions from $data
 457
 458 If a version is fully qualified (contains /) only versions matching
 459 exactly are removed. Otherwise, all versions matching the version
 460 number are removed.
 461
 462 Currently $package and $isbinary are entirely ignored, but accepted
 463 for backwards compatibilty.
 464
 465 =cut
 466
 467 sub removefoundversions {
 468     my $data = shift;
 469     my $package = shift;
 470     my $version = shift;
 471     my $isbinary = shift;
 472     return unless defined $version;
 473
 474     foreach my $ver (split /[,\s]+/, $version) {
 475          if ($ver =~ m{/}) {
 476               # fully qualified version
 477               @{$data->{found_versions}} =
 478                    grep {$_ ne $ver}
 479                         @{$data->{found_versions}};
 480          }
 481          else {
 482               # non qualified version; delete all matchers
 483               @{$data->{found_versions}} =
 484                    grep {$_ !~ m[(?:^|/)\Q$ver\E$]}
 485                         @{$data->{found_versions}};
 486          }
 487     }
 488 }
 489
 490
 491 sub addfixedversions {
 492     my $data = shift;
 493     my $package = shift;
 494     my $version = shift;
 495     my $isbinary = shift;
 496     return unless defined $version;
 497     undef $package if defined $package and $package =~ m[(?:\s|/)];
 498     my $source = $package;
 499
 500     if (defined $package and $isbinary) {
 501         my @srcinfo = binarytosource($package, $version, undef);
 502         if (@srcinfo) {
 503             # We know the source package(s). Use a fully-qualified version.
 504             addfixedversions($data, $_->[0], $_->[1], '') foreach @srcinfo;
 505             return;
 506         }
 507         # Otherwise, an unqualified version will have to do.
 508         undef $source;
 509     }
 510
 511     # Strip off various kinds of brain-damage.
 512     $version =~ s/;.*//;
 513     $version =~ s/ *\(.*\)//;
 514     $version =~ s/ +[A-Za-z].*//;
 515
 516     foreach my $ver (split /[,\s]+/, $version) {
 517         my $sver = defined($source) ? "$source/$ver" : '';
 518         unless (grep { $_ eq $ver or $_ eq $sver } @{$data->{fixed_versions}}) {
 519             push @{$data->{fixed_versions}}, defined($source) ? $sver : $ver;
 520         }
 521         @{$data->{found_versions}} =
 522             grep { $_ ne $ver and $_ ne $sver } @{$data->{found_versions}};
 523     }
 524 }
 525
 526 sub removefixedversions {
 527     my $data = shift;
 528     my $package = shift;
 529     my $version = shift;
 530     my $isbinary = shift;
 531     return unless defined $version;
 532
 533     foreach my $ver (split /[,\s]+/, $version) {
 534          if ($ver =~ m{/}) {
 535               # fully qualified version
 536               @{$data->{fixed_versions}} =
 537                    grep {$_ ne $ver}
 538                         @{$data->{fixed_versions}};
 539          }
 540          else {
 541               # non qualified version; delete all matchers
 542               @{$data->{fixed_versions}} =
 543                    grep {$_ !~ m[(?:^|/)\Q$ver\E$]}
 544                         @{$data->{fixed_versions}};
 545          }
 546     }
 547 }
 548
 549
 550
 551 =head2 splitpackages
 552
 553      splitpackages($pkgs)
 554
 555 Split a package string from the status file into a list of package names.
 556
 557 =cut
 558
 559 sub splitpackages {
 560     my $pkgs = shift;
 561     return unless defined $pkgs;
 562     return map lc, split /[ \t?,()]+/, $pkgs;
 563 }
 564
 565
 566 =head2 bug_archiveable
 567
 568      bug_archiveable(bug => $bug_num);
 569
 570 Options
 571
 572 =over
 573
 574 =item bug -- bug number (required)
 575
 576 =item status -- Status hashref returned by read_bug or get_bug_status (optional)
 577
 578 =item version -- Debbugs::Version information (optional)
 579
 580 =item days_until -- return days until the bug can be archived
 581
 582 =back
 583
 584 Returns 1 if the bug can be archived
 585 Returns 0 if the bug cannot be archived
 586
 587 If days_until is true, returns the number of days until the bug can be
 588 archived, -1 if it cannot be archived. 0 means that the bug can be
 589 archived the next time the archiver runs.
 590
 591 Returns undef on failure.
 592
 593 =cut
 594
 595 # This will eventually need to be fixed before we start using mod_perl
 596 our $version_cache = {};
 597 sub bug_archiveable{
 598      my %param = validate_with(params => \@_,
 599                                spec   => {bug => {type => SCALAR,
 600                                                   regex => qr/^\d+$/,
 601                                                  },
 602                                           status => {type => HASHREF,
 603                                                      optional => 1,
 604                                                     },
 605                                           days_until => {type => BOOLEAN,
 606                                                          default => 0,
 607                                                         },
 608                                           ignore_time => {type => BOOLEAN,
 609                                                           default => 0,
 610                                                          },
 611                                          },
 612                               );
 613      # This is what we return if the bug cannot be archived.
 614      my $cannot_archive = $param{days_until}?-1:0;
 615      # read the status information
 616      my $status = $param{status};
 617      if (not exists $param{status} or not defined $status) {
 618           $status = read_bug(bug=>$param{bug});
 619           if (not defined $status) {
 620                print STDERR "Cannot archive $param{bug} because it does not exist\n" if $DEBUG;
 621                return undef;
 622           }
 623      }
 624      # Bugs can be archived if they are
 625      # 1. Closed
 626      if (not defined $status->{done} or not length $status->{done}) {
 627           print STDERR "Cannot archive $param{bug} because it is not done\n" if $DEBUG;
 628           return $cannot_archive
 629      }
 630      # If we just are checking if the bug can be archived, we'll not even bother
 631      # checking the versioning information if the bug has been -done for less than 28 days.
 632      my $log_file = getbugcomponent($param{bug},'log');
 633      if (not defined $log_file) {
 634           print STDERR "Cannot archive $param{bug} because the log doesn't exist\n" if $DEBUG;
 635           return $cannot_archive;
 636      }
 637      my $max_log_age = max(map {$config{remove_age} - -M $_}
 638                            $log_file, map {my $log = getbugcomponent($_,'log');
 639                                            defined $log ? ($log) : ();
 640                                       }
 641                            split / /, $status->{mergedwith}
 642                        );
 643      if (not $param{days_until} and not $param{ignore_time}
 644          and $max_log_age > 0
 645         ) {
 646           print STDERR "Cannot archive $param{bug} because of time\n" if $DEBUG;
 647           return $cannot_archive;
 648      }
 649      # At this point, we have to get the versioning information for this bug.
 650      # We examine the set of distribution tags. If a bug has no distribution
 651      # tags set, we assume a default set, otherwise we use the tags the bug
 652      # has set.
 653
 654      # In cases where we are assuming a default set, if the severity
 655      # is strong, we use the strong severity default; otherwise, we
 656      # use the normal default.
 657
 658      # There must be fixed_versions for us to look at the versioning
 659      # information
 660      my $min_fixed_time = time;
 661      my $min_archive_days = 0;
 662      if (@{$status->{fixed_versions}}) {
 663           my %dist_tags;
 664           @dist_tags{@{$config{removal_distribution_tags}}} =
 665                (1) x @{$config{removal_distribution_tags}};
 666           my %dists;
 667           for my $tag (split ' ', ($status->{tags}||'')) {
 668                next unless exists $config{distribution_aliases}{$tag};
 669                next unless $dist_tags{$config{distribution_aliases}{$tag}};
 670                $dists{$config{distribution_aliases}{$tag}} = 1;
 671           }
 672           if (not keys %dists) {
 673                if (isstrongseverity($status->{severity})) {
 674                     @dists{@{$config{removal_strong_severity_default_distribution_tags}}} =
 675                          (1) x @{$config{removal_strong_severity_default_distribution_tags}};
 676                }
 677                else {
 678                     @dists{@{$config{removal_default_distribution_tags}}} =
 679                          (1) x @{$config{removal_default_distribution_tags}};
 680                }
 681           }
 682           my %source_versions;
 683           my @sourceversions = get_versions(package => $status->{package},
 684                                             dist => [keys %dists],
 685                                             source => 1,
 686                                            );
 687           @source_versions{@sourceversions} = (1) x @sourceversions;
 688           # If the bug has not been fixed in the versions actually
 689           # distributed, then it cannot be archived.
 690           if ('found' eq max_buggy(bug => $param{bug},
 691                                    sourceversions => [keys %source_versions],
 692                                    found          => $status->{found_versions},
 693                                    fixed          => $status->{fixed_versions},
 694                                    version_cache  => $version_cache,
 695                                    package        => $status->{package},
 696                                   )) {
 697                print STDERR "Cannot archive $param{bug} because it's found\n" if $DEBUG;
 698                return $cannot_archive;
 699           }
 700           # Since the bug has at least been fixed in the architectures
 701           # that matters, we check to see how long it has been fixed.
 702
 703           # If $param{ignore_time}, then we should ignore time.
 704           if ($param{ignore_time}) {
 705                return $param{days_until}?0:1;
 706           }
 707
 708           # To do this, we order the times from most recent to oldest;
 709           # when we come to the first found version, we stop.
 710           # If we run out of versions, we only report the time of the
 711           # last one.
 712           my %time_versions = get_versions(package => $status->{package},
 713                                            dist    => [keys %dists],
 714                                            source  => 1,
 715                                            time    => 1,
 716                                           );
 717           for my $version (sort {$time_versions{$b} <=> $time_versions{$a}} keys %time_versions) {
 718                my $buggy = buggy(bug => $param{bug},
 719                                  version        => $version,
 720                                  found          => $status->{found_versions},
 721                                  fixed          => $status->{fixed_versions},
 722                                  version_cache  => $version_cache,
 723                                  package        => $status->{package},
 724                                 );
 725                last if $buggy eq 'found';
 726                $min_fixed_time = min($time_versions{$version},$min_fixed_time);
 727           }
 728           $min_archive_days = max($min_archive_days,ceil($config{remove_age} - (time - $min_fixed_time)/(60*60*24)));
 729      }
 730      # If $param{ignore_time}, then we should ignore time.
 731      if ($param{ignore_time}) {
 732           return $param{days_until}?0:1;
 733      }
 734      # 6. at least 28 days have passed since the last action has occured or the bug was closed
 735      my $age = ceil($max_log_age);
 736      if ($age > 0 or $min_archive_days > 0) {
 737           print STDERR "Cannot archive $param{bug} because not enough days have passed\n" if $DEBUG;
 738           return $param{days_until}?max($age,$min_archive_days):0;
 739      }
 740      else {
 741           return $param{days_until}?0:1;
 742      }
 743 }
 744
 745
 746 =head2 get_bug_status
 747
 748      my $status = get_bug_status(bug => $nnn);
 749
 750      my $status = get_bug_status($bug_num)
 751
 752 =head3 Options
 753
 754 =over
 755
 756 =item bug -- scalar bug number
 757
 758 =item status -- optional hashref of bug status as returned by readbug
 759 (can be passed to avoid rereading the bug information)
 760
 761 =item bug_index -- optional tied index of bug status infomration;
 762 currently not correctly implemented.
 763
 764 =item version -- optional version(s) to check package status at
 765
 766 =item dist -- optional distribution(s) to check package status at
 767
 768 =item arch -- optional architecture(s) to check package status at
 769
 770 =item bugusertags -- optional hashref of bugusertags
 771
 772 =item sourceversion -- optional arrayref of source/version; overrides
 773 dist, arch, and version. [The entries in this array must be in the
 774 "source/version" format.] Eventually this can be used to for caching.
 775
 776 =back
 777
 778 Note: Currently the version information is cached; this needs to be
 779 changed before using this function in long lived programs.
 780
 781 =cut
 782
 783 sub get_bug_status {
 784      if (@_ == 1) {
 785           unshift @_, 'bug';
 786      }
 787      my %param = validate_with(params => \@_,
 788                                spec   => {bug       => {type => SCALAR,
 789                                                         regex => qr/^\d+$/,
 790                                                        },
 791                                           status    => {type => HASHREF,
 792                                                         optional => 1,
 793                                                        },
 794                                           bug_index => {type => OBJECT,
 795                                                         optional => 1,
 796                                                        },
 797                                           version   => {type => SCALAR|ARRAYREF,
 798                                                         optional => 1,
 799                                                        },
 800                                           dist       => {type => SCALAR|ARRAYREF,
 801                                                          optional => 1,
 802                                                         },
 803                                           arch       => {type => SCALAR|ARRAYREF,
 804                                                          optional => 1,
 805                                                         },
 806                                           bugusertags   => {type => HASHREF,
 807                                                             optional => 1,
 808                                                            },
 809                                           sourceversions => {type => ARRAYREF,
 810                                                              optional => 1,
 811                                                             },
 812                                          },
 813                               );
 814      my %status;
 815
 816      if (defined $param{bug_index} and
 817          exists $param{bug_index}{$param{bug}}) {
 818           %status = %{ $param{bug_index}{$param{bug}} };
 819           $status{pending} = $status{ status };
 820           $status{id} = $param{bug};
 821           return \%status;
 822      }
 823      if (defined $param{status}) {
 824           %status = %{$param{status}};
 825      }
 826      else {
 827           my $location = getbuglocation($param{bug}, 'summary');
 828           return {} if not defined $location or not length $location;
 829           %status = %{ readbug( $param{bug}, $location ) };
 830      }
 831      $status{id} = $param{bug};
 832
 833      if (defined $param{bugusertags}{$param{bug}}) {
 834           $status{keywords} = "" unless defined $status{keywords};
 835           $status{keywords} .= " " unless $status{keywords} eq "";
 836           $status{keywords} .= join(" ", @{$param{bugusertags}{$param{bug}}});
 837      }
 838      $status{tags} = $status{keywords};
 839      my %tags = map { $_ => 1 } split ' ', $status{tags};
 840
 841      $status{"package"} =~ s/\s*$//;
 842      $status{"package"} = 'unknown' if ($status{"package"} eq '');
 843      $status{"severity"} = 'normal' if ($status{"severity"} eq '');
 844
 845      $status{"pending"} = 'pending';
 846      $status{"pending"} = 'forwarded'       if (length($status{"forwarded"}));
 847      $status{"pending"} = 'pending-fixed'    if ($tags{pending});
 848      $status{"pending"} = 'fixed'           if ($tags{fixed});
 849
 850
 851      my $presence = bug_presence(map{(exists $param{$_})?($_,$param{$_}):()}
 852                                  qw(bug sourceversions arch dist version found fixed package)
 853                                 );
 854      if (defined $presence) {
 855           if ($presence eq 'fixed') {
 856                $status{pending} = 'done';
 857           }
 858           elsif ($presence eq 'absent') {
 859                $status{pending} = 'absent';
 860           }
 861      }
 862      return \%status;
 863 }
 864
 865 =head2 bug_presence
 866
 867      my $precence = bug_presence(bug => nnn,
 868                                  ...
 869                                 );
 870
 871 Returns 'found', 'absent', 'fixed' or undef based on whether the bug
 872 is found, absent, fixed, or no information is available in the
 873 distribution (dist) and/or architecture (arch) specified.
 874
 875
 876 =head3 Options
 877
 878 =over
 879
 880 =item bug -- scalar bug number
 881
 882 =item status -- optional hashref of bug status as returned by readbug
 883 (can be passed to avoid rereading the bug information)
 884
 885 =item bug_index -- optional tied index of bug status infomration;
 886 currently not correctly implemented.
 887
 888 =item version -- optional version to check package status at
 889
 890 =item dist -- optional distribution to check package status at
 891
 892 =item arch -- optional architecture to check package status at
 893
 894 =item sourceversion -- optional arrayref of source/version; overrides
 895 dist, arch, and version. [The entries in this array must be in the
 896 "source/version" format.] Eventually this can be used to for caching.
 897
 898 =back
 899
 900 =cut
 901
 902 sub bug_presence {
 903      my %param = validate_with(params => \@_,
 904                                spec   => {bug       => {type => SCALAR,
 905                                                         regex => qr/^\d+$/,
 906                                                        },
 907                                           status    => {type => HASHREF,
 908                                                         optional => 1,
 909                                                        },
 910                                           version   => {type => SCALAR|ARRAYREF,
 911                                                         optional => 1,
 912                                                        },
 913                                           dist       => {type => SCALAR|ARRAYREF,
 914                                                          optional => 1,
 915                                                         },
 916                                           arch       => {type => SCALAR|ARRAYREF,
 917                                                          optional => 1,
 918                                                         },
 919                                           sourceversions => {type => ARRAYREF,
 920                                                              optional => 1,
 921                                                             },
 922                                          },
 923                               );
 924      my %status;
 925      if (defined $param{status}) {
 926          %status = %{$param{status}};
 927      }
 928      else {
 929           my $location = getbuglocation($param{bug}, 'summary');
 930           return {} if not length $location;
 931           %status = %{ readbug( $param{bug}, $location ) };
 932      }
 933
 934      my @sourceversions;
 935      my $pseudo_desc = getpseudodesc();
 936      if (not exists $param{sourceversions}) {
 937           my %sourceversions;
 938           # pseudopackages do not have source versions by definition.
 939           if (exists $pseudo_desc->{$status{package}}) {
 940                # do nothing.
 941           }
 942           elsif (defined $param{version}) {
 943                foreach my $arch (make_list($param{arch})) {
 944                     for my $package (split /\s*,\s*/, $status{package}) {
 945                          my @temp = makesourceversions($package,
 946                                                        $arch,
 947                                                        make_list($param{version})
 948                                                       );
 949                          @sourceversions{@temp} = (1) x @temp;
 950                     }
 951                }
 952           } elsif (defined $param{dist}) {
 953                foreach my $arch (make_list($param{arch})) {
 954                     my @versions;
 955                     for my $package (split /\s*,\s*/, $status{package}) {
 956                          foreach my $dist (make_list($param{dist})) {
 957                               push @versions, getversions($package, $dist, $arch);
 958                          }
 959                          my @temp = makesourceversions($package,
 960                                                        $arch,
 961                                                        @versions
 962                                                       );
 963                          @sourceversions{@temp} = (1) x @temp;
 964                     }
 965                }
 966           }
 967
 968           # TODO: This should probably be handled further out for efficiency and
 969           # for more ease of distinguishing between pkg= and src= queries.
 970           # DLA: src= queries should just pass arch=source, and they'll be happy.
 971           @sourceversions = keys %sourceversions;
 972      }
 973      else {
 974           @sourceversions = @{$param{sourceversions}};
 975      }
 976      my $maxbuggy = 'undef';
 977      if (@sourceversions) {
 978           $maxbuggy = max_buggy(bug => $param{bug},
 979                                    sourceversions => \@sourceversions,
 980                                    found => $status{found_versions},
 981                                    fixed => $status{fixed_versions},
 982                                    package => $status{package},
 983                                    version_cache => $version_cache,
 984                                   );
 985      }
 986      elsif (defined $param{dist} and
 987             not exists $pseudo_desc->{$status{package}}) {
 988           return 'absent';
 989      }
 990      if (length($status{done}) and
 991          (not @sourceversions or not @{$status{fixed_versions}})) {
 992           return 'fixed';
 993      }
 994      return $maxbuggy;
 995 }
 996
 997
 998 =head2 max_buggy
 999
1000      max_buggy()
1001
1002 =head3 Options
1003
1004 =over
1005
1006 =item bug -- scalar bug number
1007
1008 =item sourceversion -- optional arrayref of source/version; overrides
1009 dist, arch, and version. [The entries in this array must be in the
1010 "source/version" format.] Eventually this can be used to for caching.
1011
1012 =back
1013
1014 Note: Currently the version information is cached; this needs to be
1015 changed before using this function in long lived programs.
1016
1017
1018 =cut
1019 sub max_buggy{
1020      my %param = validate_with(params => \@_,
1021                                spec   => {bug       => {type => SCALAR,
1022                                                         regex => qr/^\d+$/,
1023                                                        },
1024                                           sourceversions => {type => ARRAYREF,
1025                                                              default => [],
1026                                                             },
1027                                           found          => {type => ARRAYREF,
1028                                                              default => [],
1029                                                             },
1030                                           fixed          => {type => ARRAYREF,
1031                                                              default => [],
1032                                                             },
1033                                           package        => {type => SCALAR,
1034                                                             },
1035                                           version_cache  => {type => HASHREF,
1036                                                              default => {},
1037                                                             },
1038                                          },
1039                               );
1040      # Resolve bugginess states (we might be looking at multiple
1041      # architectures, say). Found wins, then fixed, then absent.
1042      my $maxbuggy = 'absent';
1043      for my $package (split /\s*,\s*/, $param{package}) {
1044           for my $version (@{$param{sourceversions}}) {
1045                my $buggy = buggy(bug => $param{bug},
1046                                  version => $version,
1047                                  found => $param{found},
1048                                  fixed => $param{fixed},
1049                                  version_cache => $param{version_cache},
1050                                  package => $package,
1051                                 );
1052                if ($buggy eq 'found') {
1053                     return 'found';
1054                } elsif ($buggy eq 'fixed') {
1055                     $maxbuggy = 'fixed';
1056                }
1057           }
1058      }
1059      return $maxbuggy;
1060 }
1061
1062
1063 =head2 buggy
1064
1065      buggy(bug => nnn,
1066            found => \@found,
1067            fixed => \@fixed,
1068            package => 'foo',
1069            version => '1.0',
1070           );
1071
1072 Returns the output of Debbugs::Versions::buggy for a particular
1073 package, version and found/fixed set. Automatically turns found, fixed
1074 and version into source/version strings.
1075
1076 Caching can be had by using the version_cache, but no attempt to check
1077 to see if the on disk information is more recent than the cache is
1078 made. [This will need to be fixed for long-lived processes.]
1079
1080 =cut
1081
1082 sub buggy {
1083      my %param = validate_with(params => \@_,
1084                                spec   => {bug => {type => SCALAR,
1085                                                   regex => qr/^\d+$/,
1086                                                  },
1087                                           found => {type => ARRAYREF,
1088                                                     default => [],
1089                                                    },
1090                                           fixed => {type => ARRAYREF,
1091                                                     default => [],
1092                                                    },
1093                                           version_cache => {type => HASHREF,
1094                                                             optional => 1,
1095                                                            },
1096                                           package => {type => SCALAR,
1097                                                      },
1098                                           version => {type => SCALAR,
1099                                                      },
1100                                          },
1101                               );
1102      my @found = @{$param{found}};
1103      my @fixed = @{$param{fixed}};
1104      if (grep {$_ !~ m{/}} (@{$param{found}}, @{$param{fixed}})) {
1105           # We have non-source version versions
1106           @found = makesourceversions($param{package},undef,
1107                                       @found
1108                                      );
1109           @fixed = makesourceversions($param{package},undef,
1110                                       @fixed
1111                                      );
1112      }
1113      if ($param{version} !~ m{/}) {
1114           my ($version) = makesourceversions($param{package},undef,
1115                                              $param{version}
1116                                             );
1117           $param{version} = $version if defined $version;
1118      }
1119      # Figure out which source packages we need
1120      my %sources;
1121      @sources{map {m{(.+)/}; $1} @found} = (1) x @found;
1122      @sources{map {m{(.+)/}; $1} @fixed} = (1) x @fixed;
1123      @sources{map {m{(.+)/}; $1} $param{version}} = 1 if
1124           $param{version} =~ m{/};
1125      my $version;
1126      if (not defined $param{version_cache} or
1127          not exists $param{version_cache}{join(',',sort keys %sources)}) {
1128           $version = Debbugs::Versions->new(\&Debbugs::Versions::Dpkg::vercmp);
1129           foreach my $source (keys %sources) {
1130                my $srchash = substr $source, 0, 1;
1131                my $version_fh = IO::File->new("$config{version_packages_dir}/$srchash/$source", 'r');
1132                if (not defined $version_fh) {
1133                     # We only want to warn if it's a package which actually has a maintainer
1134                     my $maints = getmaintainers();
1135                     next if not exists $maints->{$source};
1136                     warn "Bug $param{bug}: unable to open $config{version_packages_dir}/$srchash/$source: $!";
1137                     next;
1138                }
1139                $version->load($version_fh);
1140           }
1141           if (defined $param{version_cache}) {
1142                $param{version_cache}{join(',',sort keys %sources)} = $version;
1143           }
1144      }
1145      else {
1146           $version = $param{version_cache}{join(',',sort keys %sources)};
1147      }
1148      return $version->buggy($param{version},\@found,\@fixed);
1149 }
1150
1151 sub isstrongseverity {
1152     my $severity = shift;
1153     $severity = $config{default_severity} if
1154          not defined $severity or $severity eq '';
1155     return grep { $_ eq $severity } @{$config{strong_severities}};
1156 }
1157
1158
1159 =head1 PRIVATE FUNCTIONS
1160
1161 =cut
1162
1163 sub update_realtime {
1164         my ($file, %bugs) = @_;
1165
1166         # update realtime index.db
1167
1168         return () unless keys %bugs;
1169         my $idx_old = IO::File->new($file,'r')
1170              or die "Couldn't open ${file}: $!";
1171         my $idx_new = IO::File->new($file.'.new','w')
1172              or die "Couldn't open ${file}.new: $!";
1173
1174         my $min_bug = min(keys %bugs);
1175         my $line;
1176         my @line;
1177         my %changed_bugs;
1178         while($line = <$idx_old>) {
1179              @line = split /\s/, $line;
1180              # Two cases; replacing existing line or adding new line
1181              if (exists $bugs{$line[1]}) {
1182                   my $new = $bugs{$line[1]};
1183                   delete $bugs{$line[1]};
1184                   $min_bug = min(keys %bugs);
1185                   if ($new eq "NOCHANGE") {
1186                        print {$idx_new} $line;
1187                        $changed_bugs{$line[1]} = $line;
1188                   } elsif ($new eq "REMOVE") {
1189                        $changed_bugs{$line[1]} = $line;
1190                   } else {
1191                        print {$idx_new} $new;
1192                        $changed_bugs{$line[1]} = $line;
1193                   }
1194              }
1195              else {
1196                   while ($line[1] > $min_bug) {
1197                        print {$idx_new} $bugs{$min_bug};
1198                        delete $bugs{$min_bug};
1199                        last unless keys %bugs;
1200                        $min_bug = min(keys %bugs);
1201                   }
1202                   print {$idx_new} $line;
1203              }
1204              last unless keys %bugs;
1205         }
1206         print {$idx_new} map {$bugs{$_}} sort keys %bugs;
1207
1208         print {$idx_new} <$idx_old>;
1209
1210         close($idx_new);
1211         close($idx_old);
1212
1213         rename("$file.new", $file);
1214
1215         return %changed_bugs;
1216 }
1217
1218 sub bughook_archive {
1219         my @refs = @_;
1220         &filelock("debbugs.trace.lock");
1221         &appendfile("debbugs.trace","archive ".join(',',@refs)."\n");
1222         my %bugs = update_realtime("$config{spool_dir}/index.db.realtime",
1223                                    map{($_,'REMOVE')} @refs);
1224         update_realtime("$config{spool_dir}/index.archive.realtime",
1225                         %bugs);
1226         &unfilelock;
1227 }
1228
1229 sub bughook {
1230         my ( $type, %bugs_temp ) = @_;
1231         &filelock("debbugs.trace.lock");
1232
1233         my %bugs;
1234         for my $bug (keys %bugs_temp) {
1235              my $data = $bugs_temp{$bug};
1236              &appendfile("debbugs.trace","$type $bug\n",makestatus($data, 1));
1237
1238              my $whendone = "open";
1239              my $severity = $config{default_severity};
1240              (my $pkglist = $data->{package}) =~ s/[,\s]+/,/g;
1241              $pkglist =~ s/^,+//;
1242              $pkglist =~ s/,+$//;
1243              $whendone = "forwarded" if defined $data->{forwarded} and length $data->{forwarded};
1244              $whendone = "done" if defined $data->{done} and length $data->{done};
1245              $severity = $data->{severity} if length $data->{severity};
1246
1247              my $k = sprintf "%s %d %d %s [%s] %s %s\n",
1248                   $pkglist, $bug, $data->{date}, $whendone,
1249                        $data->{originator}, $severity, $data->{keywords};
1250              $bugs{$bug} = $k;
1251         }
1252         update_realtime("$config{spool_dir}/index.db.realtime", %bugs);
1253
1254         &unfilelock;
1255 }
1256
1257
1258 1;
1259
1260 __END__