Debbugs/Log.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later
   3 # version at your option.
   4 # See the file README and COPYING for more information.
   5 #
   6 # [Other people have contributed to this file; their copyrights should
   7 # go here too.]
   8 # Copyright 2004 by Collin Watson <cjwatson@debian.org>
   9 # Copyright 2007 by Don Armstrong <don@donarmstrong.com>
  10
  11
  12 package Debbugs::Log;
  13
  14
  15 use warnings;
  16 use strict;
  17
  18 use vars qw($VERSION $DEBUG @EXPORT @EXPORT_OK %EXPORT_TAGS);
  19 use base qw(Exporter);
  20
  21 BEGIN {
  22     $VERSION = 1.00;
  23     $DEBUG = 0 unless defined $DEBUG;
  24
  25     @EXPORT = ();
  26     %EXPORT_TAGS = (write => [qw(write_log_records),
  27                              ],
  28                     read  => [qw(read_log_records),
  29                              ],
  30                     misc  => [qw(escape_log),
  31                              ],
  32                    );
  33     @EXPORT_OK = ();
  34     Exporter::export_ok_tags(qw(write read misc));
  35     $EXPORT_TAGS{all} = [@EXPORT_OK];
  36 }
  37
  38 use Carp;
  39
  40 use Debbugs::Common qw(getbuglocation getbugcomponent make_list);
  41 use Params::Validate qw(:types validate_with);
  42 use Encode qw(encode);
  43
  44 =head1 NAME
  45
  46 Debbugs::Log - an interface to debbugs .log files
  47
  48 =head1 DESCRIPTION
  49
  50 The Debbugs::Log module provides a convenient way for scripts to read and
  51 write the .log files used by debbugs to store the complete textual records
  52 of all bug transactions.
  53
  54 =head2 The .log File Format
  55
  56 .log files consist of a sequence of records, of one of the following four
  57 types. ^A, ^B, etc. represent those control characters.
  58
  59 =over 4
  60
  61 =item incoming-recv
  62
  63   ^G
  64   [mail]
  65   ^C
  66
  67 C<[mail]> must start with /^Received: \(at \S+\) by \S+;/, and is copied to
  68 the output.
  69
  70 =item autocheck
  71
  72 Auto-forwarded messages are recorded like this:
  73
  74   ^A
  75   [mail]
  76   ^C
  77
  78 C<[mail]> must contain /^X-Debian-Bugs(-\w+)?: This is an autoforward from
  79 \S+/. The first line matching that is removed; all lines in the message body
  80 that begin with 'X' will be copied to the output, minus the 'X'.
  81
  82 Nothing in debbugs actually generates this record type any more, but it may
  83 still be in old .logs at some sites.
  84
  85 =item recips
  86
  87   ^B
  88   [recip]^D[recip]^D[...] OR -t
  89   ^E
  90   [mail]
  91   ^C
  92
  93 Each [recip] is output after "Message sent"; C<-t> represents the same
  94 sendmail option, indicating that the recipients are taken from the headers
  95 of the message itself.
  96
  97 =item html
  98
  99   ^F
 100   [html]
 101   ^C
 102
 103 [html] is copied unescaped to the output. The record immediately following
 104 this one is considered "boring" and only shown in certain output modes.
 105
 106 (This is a design flaw in the log format, since it makes it difficult to
 107 change the HTML presentation later, or to present the data in an entirely
 108 different format.)
 109
 110 =back
 111
 112 No other types of records are permitted, and the file must end with a ^C
 113 line.
 114
 115 =cut
 116
 117 my %states = (
 118     1 => 'autocheck',
 119     2 => 'recips',
 120     3 => 'kill-end',
 121     5 => 'go',
 122     6 => 'html',
 123     7 => 'incoming-recv',
 124 );
 125
 126 =head2 Perl Record Representation
 127
 128 Each record is a hash. The C<type> field is C<incoming-recv>, C<autocheck>,
 129 C<recips>, or C<html> as above; C<text> contains text from C<[mail]> or
 130 C<[html]> as above; C<recips> is a reference to an array of recipients
 131 (strings), or undef for C<-t>.
 132
 133 =head1 FUNCTIONS
 134
 135 =over 4
 136
 137 =item new
 138
 139 Creates a new log reader based on a .log filehandle.
 140
 141       my $log = Debbugs::Log->new($logfh);
 142       my $log = Debbugs::Log->new(bug_num => $nnn);
 143       my $log = Debbugs::Log->new(logfh => $logfh);
 144
 145 Parameters
 146
 147 =over
 148
 149 =item bug_num -- bug number
 150
 151 =item logfh -- log filehandle
 152
 153 =item log_name -- name of log
 154
 155 =back
 156
 157 One of the above options must be passed.
 158
 159 =cut
 160
 161 sub new
 162 {
 163     my $this = shift;
 164     my %param;
 165     if (@_ == 1) {
 166          ($param{logfh}) = @_;
 167     }
 168     else {
 169          %param = validate_with(params => \@_,
 170                                 spec   => {bug_num => {type => SCALAR,
 171                                                        optional => 1,
 172                                                       },
 173                                            logfh   => {type => HANDLE,
 174                                                        optional => 1,
 175                                                       },
 176                                            log_name => {type => SCALAR,
 177                                                         optional => 1,
 178                                                        },
 179                                           }
 180                                );
 181     }
 182     if (grep({exists $param{$_} and defined $param{$_}} qw(bug_num logfh log_name)) ne 1) {
 183          croak "Exactly one of bug_num, logfh, or log_name must be passed and must be defined";
 184     }
 185
 186     my $class = ref($this) || $this;
 187     my $self = {};
 188     bless $self, $class;
 189
 190     if (exists $param{logfh}) {
 191          $self->{logfh} = $param{logfh}
 192     }
 193     elsif (exists $param{log_name}) {
 194          $self->{logfh} = IO::File->new($param{log_name},'r') or
 195               die "Unable to open bug log $param{log_name} for reading: $!";
 196     }
 197     elsif (exists $param{bug_num}) {
 198          my $location = getbuglocation($param{bug_num},'log');
 199          my $bug_log = getbugcomponent($param{bug_num},'log',$location);
 200          $self->{logfh} = IO::File->new($bug_log, 'r') or
 201               die "Unable to open bug log $bug_log for reading: $!";
 202     }
 203
 204     $self->{state} = 'kill-init';
 205     $self->{linenum} = 0;
 206     return $self;
 207 }
 208
 209 =item read_record
 210
 211 Reads and returns a single record from a log reader object. At end of file,
 212 returns undef. Throws exceptions using die(), so you may want to wrap this
 213 in an eval().
 214
 215 =cut
 216
 217 sub read_record
 218 {
 219     my $this = shift;
 220     my $logfh = $this->{logfh};
 221
 222     # This comes from bugreport.cgi, but is much simpler since it doesn't
 223     # worry about the details of output.
 224
 225     my $record = {};
 226
 227     while (defined (my $line = <$logfh>)) {
 228         chomp $line;
 229         ++$this->{linenum};
 230         if (length($line) == 1 and exists $states{ord($line)}) {
 231             # state transitions
 232             my $newstate = $states{ord($line)};
 233
 234             # disallowed transitions
 235             $_ = "$this->{state} $newstate";
 236             unless (/^(go|go-nox|html) kill-end$/ or
 237                     /^(kill-init|kill-end) (incoming-recv|autocheck|recips|html)$/ or
 238                     /^kill-body go$/) {
 239                 die "transition from $this->{state} to $newstate at $this->{linenum} disallowed";
 240             }
 241
 242             $this->{state} = $newstate;
 243
 244             if ($this->{state} =~ /^(autocheck|recips|html|incoming-recv)$/) {
 245                 $record->{type} = $this->{state};
 246             } elsif ($this->{state} eq 'kill-end') {
 247                 return $record;
 248             }
 249
 250             next;
 251         }
 252
 253         $_ = $line;
 254         if ($this->{state} eq 'incoming-recv') {
 255             my $pl = $_;
 256             unless (/^Received: \(at \S+\) by \S+;/) {
 257                 die "bad line '$pl' in state incoming-recv";
 258             }
 259             $this->{state} = 'go';
 260             $record->{text} .= "$_\n";
 261         } elsif ($this->{state} eq 'html') {
 262             $record->{text} .= "$_\n";
 263         } elsif ($this->{state} eq 'go') {
 264             s/^\030//;
 265             $record->{text} .= "$_\n";
 266         } elsif ($this->{state} eq 'go-nox') {
 267             $record->{text} .= "$_\n";
 268         } elsif ($this->{state} eq 'recips') {
 269             if (/^-t$/) {
 270                 undef $record->{recips};
 271             } else {
 272                 # preserve trailing null fields, e.g. #2298
 273                 $record->{recips} = [split /\04/, $_, -1];
 274             }
 275             $this->{state} = 'kill-body';
 276         } elsif ($this->{state} eq 'autocheck') {
 277             $record->{text} .= "$_\n";
 278             next if !/^X-Debian-Bugs(-\w+)?: This is an autoforward from (\S+)/;
 279             $this->{state} = 'autowait';
 280         } elsif ($this->{state} eq 'autowait') {
 281             $record->{text} .= "$_\n";
 282             next if !/^$/;
 283             $this->{state} = 'go-nox';
 284         } else {
 285             die "state $this->{state} at line $this->{linenum} ('$_')";
 286         }
 287     }
 288     die "state $this->{state} at end" unless $this->{state} eq 'kill-end';
 289
 290     if (keys %$record) {
 291         return $record;
 292     } else {
 293         return undef;
 294     }
 295 }
 296
 297 =item read_log_records
 298
 299 Takes a .log filehandle as input, and returns an array of all records in
 300 that file. Throws exceptions using die(), so you may want to wrap this in an
 301 eval().
 302
 303 Uses exactly the same options as Debbugs::Log::new
 304
 305 =cut
 306
 307 sub read_log_records
 308 {
 309     my %param;
 310     if (@_ == 1) {
 311          ($param{logfh}) = @_;
 312     }
 313     else {
 314          %param = validate_with(params => \@_,
 315                                 spec   => {bug_num => {type => SCALAR,
 316                                                        optional => 1,
 317                                                       },
 318                                            logfh   => {type => HANDLE,
 319                                                        optional => 1,
 320                                                       },
 321                                            log_name => {type => SCALAR,
 322                                                         optional => 1,
 323                                                        },
 324                                           }
 325                                );
 326     }
 327     if (grep({exists $param{$_} and defined $param{$_}} qw(bug_num logfh log_name)) ne 1) {
 328          croak "Exactly one of bug_num, logfh, or log_name must be passed and must be defined";
 329     }
 330
 331     my @records;
 332     my $reader = Debbugs::Log->new(%param);
 333     while (defined(my $record = $reader->read_record())) {
 334         push @records, $record;
 335     }
 336     return @records;
 337 }
 338
 339 =item write_log_records
 340
 341 Takes a filehandle and a list of records as input, and prints the .log
 342 format representation of those records to that filehandle.
 343
 344 =back
 345
 346 =cut
 347
 348 sub write_log_records
 349 {
 350     my %param = validate_with(params => \@_,
 351                               spec   => {bug_num => {type => SCALAR,
 352                                                      optional => 1,
 353                                                     },
 354                                          logfh   => {type => HANDLE,
 355                                                      optional => 1,
 356                                                     },
 357                                          log_name => {type => SCALAR,
 358                                                       optional => 1,
 359                                                      },
 360                                          records => {type => HASHREF|ARRAYREF,
 361                                                     },
 362                                         },
 363                              );
 364     if (grep({exists $param{$_} and defined $param{$_}} qw(bug_num logfh log_name)) ne 1) {
 365          croak "Exactly one of bug_num, logfh, or log_name must be passed and must be defined";
 366     }
 367     my $logfh;
 368     if (exists $param{logfh}) {
 369          $logfh = $param{logfh}
 370     }
 371     elsif (exists $param{log_name}) {
 372          $logfh = IO::File->new(">>$param{log_name}") or
 373               die "Unable to open bug log $param{log_name} for writing: $!";
 374     }
 375     elsif (exists $param{bug_num}) {
 376          my $location = getbuglocation($param{bug_num},'log');
 377          my $bug_log = getbugcomponent($param{bug_num},'log',$location);
 378          $logfh = IO::File->new($bug_log, 'r') or
 379               die "Unable to open bug log $bug_log for reading: $!";
 380     }
 381     my @records = make_list($param{records});
 382
 383     for my $record (@records) {
 384         my $type = $record->{type};
 385         croak "record type '$type' with no text field" unless defined $record->{text};
 386         my ($text) = escape_log($record->{text});
 387         if ($type eq 'autocheck') {
 388             print {$logfh} "\01\n$text\03\n" or
 389                 die "Unable to write to logfile: $!";
 390         } elsif ($type eq 'recips') {
 391             print {$logfh} "\02\n";
 392             my $recips = $record->{recips};
 393             if (defined $recips) {
 394                 croak "recips not undef or array"
 395                     unless ref($recips) eq 'ARRAY';
 396                 print {$logfh} join("\04", @$recips) . "\n" or
 397                     die "Unable to write to logfile: $!";
 398             } else {
 399                 print {$logfh} "-t\n" or
 400                     die "Unable to write to logfile: $!";
 401             }
 402             #$text =~ s/^([\01-\07\030])/\030$1/gm;
 403             print {$logfh} "\05\n$text\03\n" or
 404                 die "Unable to write to logfile: $!";
 405         } elsif ($type eq 'html') {
 406             print {$logfh} "\06\n$text\03\n" or
 407                 die "Unable to write to logfile: $!";
 408         } elsif ($type eq 'incoming-recv') {
 409             #$text =~ s/^([\01-\07\030])/\030$1/gm;
 410             print {$logfh} "\07\n$text\03\n" or
 411                 die "Unable to write to logfile: $!";
 412         } else {
 413             croak "unknown record type type '$type'";
 414         }
 415     }
 416
 417     1;
 418 }
 419
 420 =head2 escape_log
 421
 422      print {$log} escape_log(@log)
 423
 424 Applies the log escape regex to the passed logfile.
 425
 426 =cut
 427
 428 sub escape_log {
 429         my @log = @_;
 430         return map { eval {$_ = encode("utf8",$_,Encode::FB_CROAK)}; s/^([\01-\07\030])/\030$1/gm; $_ } @log;
 431 }
 432
 433
 434 =head1 CAVEATS
 435
 436 This module does none of the formatting that bugreport.cgi et al do. It's
 437 simply a means for extracting and rewriting raw records.
 438
 439 =cut
 440
 441 1;