Debbugs/Libravatar.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 # Copyright 2013 by Don Armstrong <don@donarmstrong.com>.
   5
   6 package Debbugs::Libravatar;
   7
   8 =head1 NAME
   9
  10 Debbugs::Libravatar -- Libravatar service handler (mod_perl)
  11
  12 =head1 SYNOPSIS
  13
  14 <Location /libravatar>
  15    SetHandler perl-script
  16    PerlResponseHandler Debbugs::Libravatar
  17 </Location>
  18
  19 =head1 DESCRIPTION
  20
  21 Debbugs::Libravatar is a libravatar service handler which will serve
  22 libravatar requests. It also contains utility routines which are used
  23 by the libravatar.cgi script for those who do not have mod_perl.
  24
  25 =head1 BUGS
  26
  27 None known.
  28
  29 =cut
  30
  31 use warnings;
  32 use strict;
  33 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  34 use Exporter qw(import);
  35
  36 use Debbugs::Config qw(:config);
  37 use Debbugs::Common qw(:lock);
  38 use Libravatar::URL;
  39 use CGI::Simple;
  40 use Debbugs::CGI qw(cgi_parameters);
  41 use Digest::MD5 qw(md5_hex);
  42 use File::Temp qw(tempfile);
  43 use File::LibMagic;
  44 use Cwd qw(abs_path);
  45
  46 use Carp;
  47
  48 BEGIN{
  49      ($VERSION) = q$Revision$ =~ /^Revision:\s+([^\s+])/;
  50      $DEBUG = 0 unless defined $DEBUG;
  51
  52      @EXPORT = ();
  53      %EXPORT_TAGS = (libravatar => [qw(retrieve_libravatar cache_location)]
  54                     );
  55      @EXPORT_OK = ();
  56      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  57      $EXPORT_TAGS{all} = [@EXPORT_OK];
  58 }
  59
  60
  61 =over
  62
  63 =item retrieve_libravatar
  64
  65      $cache_location = retrieve_libravatar(location => $cache_location,
  66                                            email => lc($param{email}),
  67                                           );
  68
  69 Returns the cache location where a specific avatar can be loaded. If
  70 there isn't a matching avatar, or there is an error, returns undef.
  71
  72
  73 =cut
  74
  75 sub retrieve_libravatar{
  76     my %type_mapping =
  77         (jpeg => 'jpg',
  78          png => 'png',
  79          gif => 'png',
  80          tiff => 'png',
  81          tif => 'png',
  82          pjpeg => 'jpg',
  83          jpg => 'jpg'
  84         );
  85     my %param = @_;
  86     my $cache_location = $param{location};
  87     my $timestamp;
  88     $cache_location =~ s/\.[^\.\/]+$//;
  89     # take out a lock on the cache location so that if another request
  90     # is made while we are serving this one, we don't do double work
  91     my ($fh,$lockfile,$errors) =
  92         simple_filelock($cache_location.'.lock',20,0.5);
  93     if (not $fh) {
  94         return undef;
  95     } else {
  96         # figure out if the cache is now valid; if it is, return the
  97         # cache location
  98         my $temp_location;
  99         ($temp_location, $timestamp) = cache_location(email => $param{email});
 100         if ($timestamp) {
 101             return ($temp_location,$timestamp);
 102         }
 103     }
 104     require LWP::UserAgent;
 105
 106     my $dest_type;
 107     eval {
 108         my $uri = libravatar_url(email => $param{email},
 109                                  default => 404,
 110                                  size => 80);
 111         my $ua = LWP::UserAgent->new(agent => 'Debbugs libravatar service (not Mozilla)',
 112                                     );
 113         $ua->from($config{maintainer});
 114         # if we don't get an avatar within 10 seconds, return so we
 115         # don't block forever
 116         $ua->timeout(10);
 117         # if the avatar is bigger than 30K, we don't want it either
 118         $ua->max_size(30*1024);
 119         my $r = $ua->get($uri);
 120         if (not $r->is_success()) {
 121             die "Not successful in request";
 122         }
 123         my $aborted = $r->header('Client-Aborted');
 124         # if we exceeded max size, I'm not sure if we'll be
 125         # successfull or not, but regardless, there will be a
 126         # Client-Aborted header. Stop here if that header is defined.
 127         die "Client aborted header" if defined $aborted;
 128         my $type = $r->header('Content-Type');
 129         # if there's no content type, or it's not one we like, we won't
 130         # bother going further
 131         die "No content type" if not defined $type;
 132         die "Wrong content type" if not $type =~ m{^image/([^/]+)$};
 133         $dest_type = $type_mapping{$1};
 134         die "No dest type" if not defined $dest_type;
 135         # undo any content encoding
 136         $r->decode() or die "Unable to decode content encoding";
 137         # ok, now we need to convert it from whatever it is into a
 138         # format that we actually like
 139         my ($temp_fh,$temp_fn) = tempfile() or
 140             die "Unable to create temporary file";
 141         eval {
 142             print {$temp_fh} $r->content() or
 143                 die "Unable to print to temp file";
 144             close ($temp_fh);
 145             ### resize all images to 80x80 and strip comments out of
 146             ### them. If convert has a bug, it would be possible for
 147             ### this to be an attack vector, but hopefully minimizing
 148             ### the size above, and requiring proper mime types will
 149             ### minimize that slightly. Doing this will at least make
 150             ### it harder for malicious web images to harm our users
 151             system('convert','-resize','80x80',
 152                    '-strip',
 153                    $temp_fn,
 154                    $cache_location.'.'.$dest_type) == 0 or
 155                        die "convert file failed";
 156             unlink($temp_fn);
 157         };
 158         if ($@) {
 159             unlink($cache_location.'.'.$dest_type) if -e $cache_location.'.'.$dest_type;
 160             unlink($temp_fn) if -e $temp_fn;
 161             die "Unable to convert image";
 162         }
 163     };
 164     if ($@) {
 165         # there was some kind of error; return undef and unlock the
 166         # lock
 167         simple_unlockfile($fh,$lockfile);
 168         return undef;
 169     }
 170     simple_unlockfile($fh,$lockfile);
 171     $timestamp = (stat($cache_location.'.'.$dest_type))[9];
 172     return ($cache_location.'.'.$dest_type,$timestamp);
 173 }
 174
 175 sub blocked_libravatar {
 176     my ($email,$md5sum) = @_;
 177     my $blocked = 0;
 178     for my $blocker (@{$config{libravatar_blacklist}||[]}) {
 179         for my $element ($email,$md5sum) {
 180             next unless defined $element;
 181             eval {
 182                 if ($element =~ /$blocker/) {
 183                     $blocked=1;
 184                 }
 185             };
 186         }
 187     }
 188     return $blocked;
 189 }
 190
 191 # Returns ($path, $timestamp)
 192 # - For blocked images, $path will be undef
 193 # - If $timestamp is 0 (and $path is not undef), the image should
 194 #   be re-fetched.
 195 sub cache_location {
 196     my %param = @_;
 197     my ($md5sum, $stem);
 198     if (exists $param{md5sum}) {
 199         $md5sum = $param{md5sum};
 200     }elsif (exists $param{email}) {
 201         $md5sum = md5_hex(lc($param{email}));
 202     } else {
 203         croak("cache_location must be called with one of md5sum or email");
 204     }
 205     return (undef, 0) if blocked_libravatar($param{email},$md5sum);
 206     $stem = $config{libravatar_cache_dir}.'/'.$md5sum;
 207     for my $ext ('.png', '.jpg', '') {
 208         my $path = $stem.$ext;
 209         if (-e $path) {
 210             my $timestamp = (time - (stat(_))[9] < 60*60) ? (stat(_))[9] : 0;
 211             return ($path, $timestamp);
 212         }
 213     }
 214     return ($stem, 0);
 215 }
 216
 217 ## the following is mod_perl specific
 218
 219 BEGIN{
 220     if (exists $ENV{MOD_PERL_API_VERSION}) {
 221         if ($ENV{MOD_PERL_API_VERSION} == 2) {
 222             require Apache2::RequestIO;
 223             require Apache2::RequestRec;
 224             require Apache2::RequestUtil;
 225             require Apache2::Const;
 226             require APR::Finfo;
 227             require APR::Const;
 228             APR::Const->import(-compile => qw(FINFO_NORM));
 229             Apache2::Const->import(-compile => qw(OK DECLINED FORBIDDEN NOT_FOUND HTTP_NOT_MODIFIED));
 230         } else {
 231             die "Unsupported mod perl api; mod_perl 2.0.0 or later is required";
 232         }
 233     }
 234 }
 235
 236 sub handler {
 237     die "Calling handler only makes sense if this is running under mod_perl" unless exists $ENV{MOD_PERL_API_VERSION};
 238     my $r = shift or Apache2::RequestUtil->request;
 239
 240     # we only want GET or HEAD requests
 241     unless ($r->method eq 'HEAD' or $r->method eq 'GET') {
 242         return Apache2::Const::DECLINED();
 243     }
 244     $r->headers_out->{"X-Powered-By"} = "Debbugs libravatar";
 245
 246     my $uri = $r->uri();
 247     # subtract out location
 248     my $location = $r->location();
 249     my ($email) = $uri =~ m/\Q$location\E\/?(.*)$/;
 250     if (not length $email) {
 251         return Apache2::Const::NOT_FOUND();
 252     }
 253     my $q = CGI::Simple->new();
 254     my %param = cgi_parameters(query => $q,
 255                                single => [qw(avatar)],
 256                                default => {avatar => 'yes',
 257                                           },
 258                               );
 259     if ($param{avatar} ne 'yes' or not defined $email or not length $email) {
 260         serve_cache_mod_perl('',$r);
 261         return Apache2::Const::DECLINED();
 262     }
 263     # figure out what the md5sum of the e-mail is.
 264     my ($cache_location, $timestamp) = cache_location(email => $email);
 265     # if we've got it, and it's less than one hour old, return it.
 266     if ($timestamp) {
 267         serve_cache_mod_perl($cache_location,$r);
 268         return Apache2::Const::DECLINED();
 269     }
 270     ($cache_location,$timestamp) =
 271         retrieve_libravatar(location => $cache_location,
 272                             email => $email,
 273                            );
 274     if (not defined $cache_location) {
 275         # failure, serve the default image
 276         serve_cache_mod_perl('',$r,$timestamp);
 277         return Apache2::Const::DECLINED();
 278     } else {
 279         serve_cache_mod_perl($cache_location,$r,$timestamp);
 280         return Apache2::Const::DECLINED();
 281     }
 282 }
 283
 284
 285
 286 our $magic;
 287
 288 sub serve_cache_mod_perl {
 289     my ($cache_location,$r,$timestamp) = @_;
 290     if (not defined $cache_location or not length $cache_location) {
 291         # serve the default image
 292         $cache_location = $config{libravatar_default_image};
 293     }
 294     $magic = File::LibMagic->new() if not defined $magic;
 295
 296     return Apache2::Const::DECLINED() if not defined $magic;
 297
 298     $r->content_type($magic->checktype_filename(abs_path($cache_location)));
 299
 300     $r->filename($cache_location);
 301     $r->path_info('');
 302     $r->finfo(APR::Finfo::stat($cache_location, APR::Const::FINFO_NORM(), $r->pool));
 303 }
 304
 305 =back
 306
 307 =cut
 308
 309 1;
 310
 311
 312 __END__