Debbugs/CGI/Bugreport.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 #
   5 # [Other people have contributed to this file; their copyrights should
   6 # be listed here too.]
   7 # Copyright 2008 by Don Armstrong <don@donarmstrong.com>.
   8
   9
  10 package Debbugs::CGI::Bugreport;
  11
  12 =head1 NAME
  13
  14 Debbugs::CGI::Bugreport -- specific routines for the bugreport cgi script
  15
  16 =head1 SYNOPSIS
  17
  18
  19 =head1 DESCRIPTION
  20
  21
  22 =head1 BUGS
  23
  24 None known.
  25
  26 =cut
  27
  28 use warnings;
  29 use strict;
  30 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  31 use Exporter qw(import);
  32
  33 use IO::Scalar;
  34 use Params::Validate qw(validate_with :types);
  35 use Digest::MD5 qw(md5_hex);
  36 use Debbugs::Mail qw(get_addresses :reply);
  37 use Debbugs::MIME qw(decode_rfc1522 create_mime_message);
  38 use Debbugs::CGI qw(:url :html :util);
  39 use Debbugs::Common qw(globify_scalar english_join);
  40 use Debbugs::UTF8;
  41 use Debbugs::Config qw(:config);
  42 use Debbugs::Log qw(:read);
  43 use POSIX qw(strftime);
  44 use Encode qw(decode_utf8 encode_utf8);
  45 use URI::Escape qw(uri_escape_utf8);
  46 use Scalar::Util qw(blessed);
  47 use File::Temp;
  48
  49 BEGIN{
  50      ($VERSION) = q$Revision: 494 $ =~ /^Revision:\s+([^\s+])/;
  51      $DEBUG = 0 unless defined $DEBUG;
  52
  53      @EXPORT = ();
  54      %EXPORT_TAGS = ();
  55      @EXPORT_OK = (qw(display_entity handle_record handle_email_message));
  56      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  57      $EXPORT_TAGS{all} = [@EXPORT_OK];
  58 }
  59
  60
  61
  62 =head2 display_entity
  63
  64      display_entity(entity      => $entity,
  65                     bug_num     => $ref,
  66                     outer       => 1,
  67                     msg_num     => $msg_num,
  68                     attachments => \@attachments,
  69                     output      => \$output);
  70
  71
  72 =over
  73
  74 =item entity -- MIME::Parser entity
  75
  76 =item bug_num -- Bug number
  77
  78 =item outer -- Whether this is the outer entity; defaults to 1
  79
  80 =item msg_num -- message number in the log
  81
  82 =item attachments -- arrayref of attachments
  83
  84 =item output -- scalar reference for output
  85
  86 =back
  87
  88 =cut
  89
  90 sub display_entity {
  91     my %param = validate_with(params => \@_,
  92                               spec   => {entity      => {type => OBJECT,
  93                                                         },
  94                                          bug_num     => {type => SCALAR,
  95                                                          regex => qr/^\d+$/,
  96                                                         },
  97                                          outer       => {type => BOOLEAN,
  98                                                          default => 1,
  99                                                         },
 100                                          msg_num     => {type => SCALAR,
 101                                                         },
 102                                          attachments => {type => ARRAYREF,
 103                                                          default => [],
 104                                                         },
 105                                          output      => {type => SCALARREF|HANDLE,
 106                                                          default => \*STDOUT,
 107                                                         },
 108                                          terse       => {type => BOOLEAN,
 109                                                          default => 0,
 110                                                         },
 111                                          msg         => {type => SCALAR,
 112                                                          optional => 1,
 113                                                         },
 114                                          att         => {type => SCALAR,
 115                                                          optional => 1,
 116                                                         },
 117                                          trim_headers => {type => BOOLEAN,
 118                                                           default => 1,
 119                                                          },
 120                                          avatars => {type => BOOLEAN,
 121                                                      default => 1,
 122                                                     },
 123                                         }
 124                              );
 125
 126     my $output = globify_scalar($param{output});
 127     my $entity = $param{entity};
 128     my $ref = $param{bug_num};
 129     my $top = $param{outer};
 130     my $xmessage = $param{msg_num};
 131     my $attachments = $param{attachments};
 132
 133     my $head = $entity->head;
 134     my $disposition = $head->mime_attr('content-disposition');
 135     $disposition = 'inline' if not defined $disposition or $disposition eq '';
 136     my $type = $entity->effective_type;
 137     my $filename = $entity->head->recommended_filename;
 138     $filename = '' unless defined $filename;
 139     $filename = decode_rfc1522($filename);
 140
 141     if ($param{outer} and
 142         not $param{terse} and
 143         not exists $param{att}) {
 144          print {$output} "<div class=\"headers\">\n";
 145          if ($param{trim_headers}) {
 146               my @headers;
 147               foreach (qw(From To Cc Subject Date)) {
 148                    my $head_field = $head->get($_);
 149                    next unless defined $head_field and $head_field ne '';
 150                    chomp $head_field;
 151                    if ($_ eq 'From' and $param{avatars}) {
 152                        my $libravatar_url = __libravatar_url(decode_rfc1522($head_field));
 153                        if (defined $libravatar_url and length $libravatar_url) {
 154                            push @headers,q(<img src=").html_escape($libravatar_url).qq(" alt="">\n);
 155                        }
 156                    }
 157                    push @headers, qq(<div class="header"><span class="headerfield">$_:</span> ) . html_escape(decode_rfc1522($head_field))."</div>\n";
 158               }
 159               print {$output} join(qq(), @headers);
 160          } else {
 161               print {$output} "<pre>".html_escape(decode_rfc1522($entity->head->stringify))."</pre>\n";
 162          }
 163          print {$output} "</div>\n";
 164     }
 165
 166     if (not (($param{outer} and $type =~ m{^text(?:/plain)?(?:;|$)})
 167              or $type =~ m{^multipart/}
 168             )) {
 169         push @$attachments, $param{entity};
 170         # output this attachment
 171         if (exists $param{att} and
 172             $param{att} == $#$attachments) {
 173             my $head = $entity->head;
 174             chomp(my $type = $entity->effective_type);
 175             my $body = $entity->stringify_body;
 176             # this attachment has its own content type, so we must not
 177             # try to convert it to UTF-8 or do anything funky.
 178             binmode($output,':raw');
 179             print {$output} "Content-Type: $type";
 180             my ($charset) = $head->get('Content-Type:') =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 181             print {$output} qq(; charset="$charset") if defined $charset;
 182             print {$output} "\n";
 183             if ($filename ne '') {
 184                 my $qf = $filename;
 185                 $qf =~ s/"/\\"/g;
 186                 $qf =~ s[.*/][];
 187                 print {$output} qq{Content-Disposition: inline; filename="$qf"\n};
 188             }
 189             print {$output} "\n";
 190             my $decoder = MIME::Decoder->new($head->mime_encoding);
 191             $decoder->decode(IO::Scalar->new(\$body), $output);
 192             # we don't reset the layers here, because it makes no
 193             # sense to add anything to the output handle after this
 194             # point.
 195             return(1);
 196         }
 197         elsif (not exists $param{att}) {
 198              my @dlargs = (msg=>$xmessage, att=>$#$attachments);
 199              push @dlargs, (filename=>$filename) if $filename ne '';
 200              my $printname = $filename;
 201              $printname = 'Message part ' . ($#$attachments + 1) if $filename eq '';
 202              print {$output} '<pre class="mime">[<a href="' .
 203                   html_escape(bug_links(bug => $ref,
 204                                         links_only => 1,
 205                                         options => {@dlargs})
 206                              ) . qq{">$printname</a> } .
 207                                   "($type, $disposition)]</pre>\n";
 208         }
 209     }
 210
 211     return 0 if not $param{outer} and $disposition eq 'attachment' and not exists $param{att};
 212     return 0 unless (($type =~ m[^text/?] and
 213                       $type !~ m[^text/(?:html|enriched)(?:;|$)]) or
 214                      $type =~ m[^application/pgp(?:;|$)] or
 215                      $entity->parts);
 216
 217     if ($entity->is_multipart) {
 218         my @parts = $entity->parts;
 219         foreach my $part (@parts) {
 220             my $raw_output =
 221                 display_entity(entity => $part,
 222                                bug_num => $ref,
 223                                outer => 0,
 224                                msg_num => $xmessage,
 225                                output => $output,
 226                                attachments => $attachments,
 227                                terse => $param{terse},
 228                                exists $param{msg}?(msg=>$param{msg}):(),
 229                                exists $param{att}?(att=>$param{att}):(),
 230                                exists $param{avatars}?(avatars=>$param{avatars}):(),
 231                               );
 232             if ($raw_output) {
 233                 return $raw_output;
 234             }
 235             # print {$output} "\n";
 236         }
 237     } elsif ($entity->parts) {
 238         # We must be dealing with a nested message.
 239          if (not exists $param{att}) {
 240               print {$output} "<blockquote>\n";
 241          }
 242         my @parts = $entity->parts;
 243         foreach my $part (@parts) {
 244             display_entity(entity => $part,
 245                            bug_num => $ref,
 246                            outer => 1,
 247                            msg_num => $xmessage,
 248                            output => $output,
 249                            attachments => $attachments,
 250                            terse => $param{terse},
 251                            exists $param{msg}?(msg=>$param{msg}):(),
 252                            exists $param{att}?(att=>$param{att}):(),
 253                            exists $param{avatars}?(avatars=>$param{avatars}):(),
 254                           );
 255             # print {$output} "\n";
 256         }
 257          if (not exists $param{att}) {
 258               print {$output} "</blockquote>\n";
 259          }
 260     } elsif (not $param{terse}) {
 261          my $content_type = $entity->head->get('Content-Type:') || "text/html";
 262          my ($charset) = $content_type =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 263          my $body = $entity->bodyhandle->as_string;
 264          $body = convert_to_utf8($body,$charset//'utf8');
 265          $body = html_escape($body);
 266          # Attempt to deal with format=flowed
 267          if ($content_type =~ m/format\s*=\s*\"?flowed\"?/i) {
 268               $body =~ s{^\ }{}mgo;
 269               # we ignore the other things that you can do with
 270               # flowed e-mails cause they don't really matter.
 271          }
 272          # Add links to URLs
 273          # We don't html escape here because we escape above;
 274          # wierd terminators are because of that
 275          $body =~ s{((?:ftp|http|https|svn|ftps|rsync)://[\S~-]+?/?) # Url
 276                     ((?:\&gt\;)?[)]?(?:'|\&\#39\;|\&quot\;)?[:.\,]?(?:\s|$)) # terminators
 277               }{<a href=\"$1\">$1</a>$2}gox;
 278          # Add links to bug closures
 279          $body =~ s[((?:closes|see):\s* # start of closed/referenced bugs
 280                         (?:bug)?\#?\s?\d+\s? # first bug
 281                         (?:,?\s*(?:bug)?\#?\s?\d+)* # additional bugs
 282                     (?:\s|\n|\)|\]|\}|\.|\,|$)) # ends with a space, newline, end of string, or ); fixes #747267
 283                   ]
 284                    [my $temp = $1;
 285                     $temp =~ s{(\d+)}
 286                               {bug_links(bug=>$1)}ge;
 287                     $temp;]gxie;
 288          if (defined $config{cve_tracker} and
 289              length $config{cve_tracker}
 290             ) {
 291              # Add links to CVE vulnerabilities (closes #568464)
 292              $body =~ s{(^|\s|[\(\[])(CVE-\d{4}-\d{4,})(\s|[,.-\[\]\)]|$)}
 293                        {$1<a href="http://$config{cve_tracker}$2">$2</a>$3}gxm;
 294          }
 295          if (not exists $param{att}) {
 296               print {$output} qq(<pre class="message">$body</pre>\n);
 297          }
 298     }
 299     return 0;
 300 }
 301
 302
 303 =head2 handle_email_message
 304
 305      handle_email_message($record->{text},
 306                           ref        => $bug_number,
 307                           msg_num => $msg_number,
 308                          );
 309
 310 Returns a decoded e-mail message and displays entities/attachments as
 311 appropriate.
 312
 313
 314 =cut
 315
 316 sub handle_email_message{
 317      my ($record,%param) = @_;
 318
 319      my $output;
 320      my $output_fh = globify_scalar(\$output);
 321      my $entity;
 322      my $tempdir;
 323      if (not blessed $record) {
 324          my $parser = MIME::Parser->new();
 325          # this will be cleaned up once it goes out of scope
 326          $tempdir = File::Temp->newdir();
 327          $parser->output_under($tempdir->dirname());
 328          if ($record->{inner_file}) {
 329              $entity = $parser->parse($record->{fh}) or
 330                  die "Unable to parse entity";
 331          } else {
 332              $entity = $parser->parse_data($record->{text}) or
 333                  die "Unable to parse entity";
 334          }
 335      } else {
 336          $entity = $record;
 337      }
 338      my @attachments = ();
 339      my $raw_output =
 340          display_entity(entity  => $entity,
 341                         bug_num => $param{ref},
 342                         outer   => 1,
 343                         msg_num => $param{msg_num},
 344                         output => $output_fh,
 345                         attachments => \@attachments,
 346                         terse       => $param{terse},
 347                         exists $param{msg}?(msg=>$param{msg}):(),
 348                         exists $param{att}?(att=>$param{att}):(),
 349                         exists $param{trim_headers}?(trim_headers=>$param{trim_headers}):(),
 350                         exists $param{avatars}?(avatars=>$param{avatars}):(),
 351                        );
 352      return $raw_output?$output:decode_utf8($output);
 353 }
 354
 355 =head2 handle_record
 356
 357      push @log, handle_record($record,$ref,$msg_num);
 358
 359 Deals with a record in a bug log as returned by
 360 L<Debbugs::Log::read_log_records>; returns the log information that
 361 should be output to the browser.
 362
 363 =cut
 364
 365 sub handle_record{
 366      my ($record,$bug_number,$msg_number,$seen_msg_ids,%param) = @_;
 367
 368      # output needs to have the is_utf8 flag on to avoid double
 369      # encoding
 370      my $output = decode_utf8('');
 371      local $_ = $record->{type};
 372      if (/html/) {
 373          # $record->{text} is not in perl's internal encoding; convert it
 374          my $text = decode_rfc1522(decode_utf8(record_text($record)));
 375           my ($time) = $text =~ /<!--\s+time:(\d+)\s+-->/;
 376           my $class = $text =~ /^<strong>(?:Acknowledgement|Reply|Information|Report|Notification)/m ? 'infmessage':'msgreceived';
 377           $output .= $text;
 378           # Link to forwarded http:// urls in the midst of the report
 379           # (even though these links already exist at the top)
 380           $output =~ s,((?:ftp|http|https)://[\S~-]+?/?)((?:[\)\'\:\.\,]|\&\#39;|\&quot\;)?
 381                            (?:\s|\.<|$)),<a href=\"$1\">$1</a>$2,gxo;
 382           # Add links to the cloned bugs
 383           $output =~ s{(Bug )(\d+)( cloned as bugs? )(\d+)(?:\-(\d+)|)}{$1.bug_links(bug=>$2).$3.bug_links(bug=>(defined $5)?[$4..$5]:$4)}eo;
 384           # Add links to merged bugs
 385           $output =~ s{(?<=Merged )([\d\s]+)(?=\.)}{join(' ',map {bug_links(bug=>$_)} (split /\s+/, $1))}eo;
 386           # Add links to blocked bugs
 387           $output =~ s{(?<=Blocking bugs)(?:( of )(\d+))?( (?:added|set to|removed):\s+)([\d\s\,]+)}
 388                       {(defined $2?$1.bug_links(bug=>$2):'').$3.
 389                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+/, $4)])}eo;
 390           $output =~ s{((?:[Aa]dded|[Rr]emoved)\ blocking\ bug(?:\(s\))?)(?:(\ of\ )(\d+))?(:?\s+)
 391                        (\d+(?:,\s+\d+)*(?:\,?\s+and\s+\d+)?)}
 392                       {$1.(defined $3?$2.bug_links(bug=>$3):'').$4.
 393                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}xeo;
 394           $output =~ s{([Aa]dded|[Rr]emoved)( indication that bug )(\d+)( blocks )([\d\s\,]+)}
 395                       {$1.$2.(bug_links(bug=>$3)).$4.
 396                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}eo;
 397           # Add links to reassigned packages
 398           $output =~ s{($config{bug}\sreassigned\sfrom\spackage\s(?:[\`']|\&\#39;))([^']+?)((?:'|\&\#39;|\&quot\;)
 399                                \sto\s(?:[\`']|\&\#39;|\&quot\;))([^']+?)((?:'|\&\#39;|\&quot\;))}
 400           {$1.package_links(package=>$2).$3.
 401                package_links(package=>$4).$5}exo;
 402           if (defined $time) {
 403                $output .= ' ('.strftime('%a, %d %b %Y %T GMT',gmtime($time)).') ';
 404           }
 405           $output .= '<a href="' .
 406                html_escape(bug_links(bug => $bug_number,
 407                                      options => {msg => ($msg_number+1)},
 408                                      links_only => 1,
 409                                     )
 410                           ) . '">Full text</a> and <a href="' .
 411                                html_escape(bug_links(bug => $bug_number,
 412                                                      options => {msg => ($msg_number+1),
 413                                                                  mbox => 'yes'},
 414                                                      links_only => 1)
 415                                           ) . '">rfc822 format</a> available.';
 416
 417           $output = qq(<div class="$class"><hr>\n<a name="$msg_number"></a>\n) . $output . "</div>\n";
 418      }
 419      elsif (/recips/) {
 420          my ($msg_id) = record_regex($record,qr/^Message-Id:\s+<(.+)>/i);
 421          if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 422                return ();
 423           }
 424           elsif (defined $msg_id) {
 425                $$seen_msg_ids{$msg_id} = 1;
 426           }
 427           $output .= qq(<hr><p class="msgreceived"><a name="$msg_number"></a>\n);
 428           $output .= 'View this message in <a href="' . html_escape(bug_links(bug=>$bug_number, links_only => 1, options=>{msg=>$msg_number, mbox=>'yes'})) . '">rfc822 format</a></p>';
 429           $output .= handle_email_message($record,
 430                                           ref     => $bug_number,
 431                                           msg_num => $msg_number,
 432                                           %param,
 433                                          );
 434      }
 435      elsif (/autocheck/) {
 436           # Do nothing
 437      }
 438      elsif (/incoming-recv/) {
 439          my ($msg_id) = record_regex($record,qr/^Message-Id:\s+<(.+)>/i);
 440           if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 441                return ();
 442           }
 443           elsif (defined $msg_id) {
 444                $$seen_msg_ids{$msg_id} = 1;
 445           }
 446           # Incomming Mail Message
 447           my ($received,$hostname) = record_regex($record,qr/Received: \(at (\S+)\) by (\S+)\;/o);
 448           $output .= qq|<hr><p class="msgreceived"><a name="$msg_number"></a><a name="msg$msg_number"></a><a href="#$msg_number">Message #$msg_number</a> received at |.
 449                html_escape("$received\@$hostname") .
 450                     q| (<a href="| . html_escape(bug_links(bug => $bug_number, links_only => 1, options => {msg=>$msg_number})) . '">full text</a>'.
 451                          q|, <a href="| . html_escape(bug_links(bug => $bug_number,
 452                                                                 links_only => 1,
 453                                                                 options => {msg=>$msg_number,
 454                                                                             mbox=>'yes'}
 455                                                                )
 456                                                      ) .'">mbox</a>, ';
 457           my $parser = MIME::Parser->new();
 458
 459           # this will be cleaned up once it goes out of scope
 460           my $tempdir = File::Temp->newdir();
 461           $parser->output_under($tempdir->dirname());
 462          my $entity;
 463          if ($record->{inner_file}) {
 464              $entity = $parser->parse($record->{fh});
 465          } else {
 466              $entity = $parser->parse_data($record->{text});
 467          }
 468           my $r_l = reply_headers($entity);
 469           $output .= q(<a href=").
 470               html_escape('mailto:'.$bug_number.'@'.$config{email_domain}.'?'.
 471                           join('&',map {defined $r_l->{$_}?$_.'='.uri_escape_utf8($r_l->{$_}):()} keys %{$r_l})).
 472                               qq(">reply</a>);
 473
 474           $output .= ')'.":</p>\n";
 475           $output .= handle_email_message($entity,
 476                                           ref     => $bug_number,
 477                                           msg_num => $msg_number,
 478                                           %param,
 479                                          );
 480      }
 481      else {
 482           die "Unknown record type $_";
 483      }
 484      return $output;
 485 }
 486
 487
 488 sub __libravatar_url {
 489     my ($email) = @_;
 490     if (not defined $config{libravatar_uri} or not length $config{libravatar_uri}) {
 491         return undef;
 492     }
 493     ($email) = grep {/\@/} get_addresses($email);
 494     return $config{libravatar_uri}.uri_escape_utf8($email.($config{libravatar_uri_options}//''));
 495 }
 496
 497
 498 1;
 499
 500
 501 __END__
 502
 503
 504
 505
 506
 507