Debbugs/CGI/Bugreport.pm

   1 # This module is part of debbugs, and is released
   2 # under the terms of the GPL version 2, or any later version. See the
   3 # file README and COPYING for more information.
   4 #
   5 # [Other people have contributed to this file; their copyrights should
   6 # be listed here too.]
   7 # Copyright 2008 by Don Armstrong <don@donarmstrong.com>.
   8
   9
  10 package Debbugs::CGI::Bugreport;
  11
  12 =head1 NAME
  13
  14 Debbugs::CGI::Bugreport -- specific routines for the bugreport cgi script
  15
  16 =head1 SYNOPSIS
  17
  18
  19 =head1 DESCRIPTION
  20
  21
  22 =head1 BUGS
  23
  24 None known.
  25
  26 =cut
  27
  28 use warnings;
  29 use strict;
  30 use vars qw($VERSION $DEBUG %EXPORT_TAGS @EXPORT_OK @EXPORT);
  31 use base qw(Exporter);
  32
  33 use IO::Scalar;
  34 use Params::Validate qw(validate_with :types);
  35 use Digest::MD5 qw(md5_hex);
  36 use Debbugs::Mail qw(get_addresses :reply);
  37 use Debbugs::MIME qw(decode_rfc1522 create_mime_message);
  38 use Debbugs::CGI qw(:url :html :util);
  39 use Debbugs::Common qw(globify_scalar english_join);
  40 use Debbugs::UTF8;
  41 use Debbugs::Config qw(:config);
  42 use POSIX qw(strftime);
  43 use Encode qw(decode_utf8 encode_utf8);
  44 use URI::Escape qw(uri_escape_utf8);
  45 use Scalar::Util qw(blessed);
  46 use File::Temp;
  47
  48 BEGIN{
  49      ($VERSION) = q$Revision: 494 $ =~ /^Revision:\s+([^\s+])/;
  50      $DEBUG = 0 unless defined $DEBUG;
  51
  52      @EXPORT = ();
  53      %EXPORT_TAGS = ();
  54      @EXPORT_OK = (qw(display_entity handle_record handle_email_message));
  55      Exporter::export_ok_tags(keys %EXPORT_TAGS);
  56      $EXPORT_TAGS{all} = [@EXPORT_OK];
  57 }
  58
  59
  60
  61 =head2 display_entity
  62
  63      display_entity(entity      => $entity,
  64                     bug_num     => $ref,
  65                     outer       => 1,
  66                     msg_num     => $msg_num,
  67                     attachments => \@attachments,
  68                     output      => \$output);
  69
  70
  71 =over
  72
  73 =item entity -- MIME::Parser entity
  74
  75 =item bug_num -- Bug number
  76
  77 =item outer -- Whether this is the outer entity; defaults to 1
  78
  79 =item msg_num -- message number in the log
  80
  81 =item attachments -- arrayref of attachments
  82
  83 =item output -- scalar reference for output
  84
  85 =back
  86
  87 =cut
  88
  89 sub display_entity {
  90     my %param = validate_with(params => \@_,
  91                               spec   => {entity      => {type => OBJECT,
  92                                                         },
  93                                          bug_num     => {type => SCALAR,
  94                                                          regex => qr/^\d+$/,
  95                                                         },
  96                                          outer       => {type => BOOLEAN,
  97                                                          default => 1,
  98                                                         },
  99                                          msg_num     => {type => SCALAR,
 100                                                         },
 101                                          attachments => {type => ARRAYREF,
 102                                                          default => [],
 103                                                         },
 104                                          output      => {type => SCALARREF|HANDLE,
 105                                                          default => \*STDOUT,
 106                                                         },
 107                                          terse       => {type => BOOLEAN,
 108                                                          default => 0,
 109                                                         },
 110                                          msg         => {type => SCALAR,
 111                                                          optional => 1,
 112                                                         },
 113                                          att         => {type => SCALAR,
 114                                                          optional => 1,
 115                                                         },
 116                                          trim_headers => {type => BOOLEAN,
 117                                                           default => 1,
 118                                                          },
 119                                          avatars => {type => BOOLEAN,
 120                                                      default => 1,
 121                                                     },
 122                                         }
 123                              );
 124
 125     my $output = globify_scalar($param{output});
 126     my $entity = $param{entity};
 127     my $ref = $param{bug_num};
 128     my $top = $param{outer};
 129     my $xmessage = $param{msg_num};
 130     my $attachments = $param{attachments};
 131
 132     my $head = $entity->head;
 133     my $disposition = $head->mime_attr('content-disposition');
 134     $disposition = 'inline' if not defined $disposition or $disposition eq '';
 135     my $type = $entity->effective_type;
 136     my $filename = $entity->head->recommended_filename;
 137     $filename = '' unless defined $filename;
 138     $filename = decode_rfc1522($filename);
 139
 140     if ($param{outer} and
 141         not $param{terse} and
 142         not exists $param{att}) {
 143          print {$output} "<div class=\"headers\">\n";
 144          if ($param{trim_headers}) {
 145               my @headers;
 146               foreach (qw(From To Cc Subject Date)) {
 147                    my $head_field = $head->get($_);
 148                    next unless defined $head_field and $head_field ne '';
 149                    chomp $head_field;
 150                    if ($_ eq 'From' and $param{avatars}) {
 151                        my $libravatar_url = __libravatar_url(decode_rfc1522($head_field));
 152                        if (defined $libravatar_url and length $libravatar_url) {
 153                            push @headers,q(<img src=").html_escape($libravatar_url).qq(" alt="">\n);
 154                        }
 155                    }
 156                    push @headers, qq(<div class="header"><span class="headerfield">$_:</span> ) . html_escape(decode_rfc1522($head_field))."</div>\n";
 157               }
 158               print {$output} join(qq(), @headers);
 159          } else {
 160               print {$output} "<pre>".html_escape(decode_rfc1522($entity->head->stringify))."</pre>\n";
 161          }
 162          print {$output} "</div>\n";
 163     }
 164
 165     if (not (($param{outer} and $type =~ m{^text(?:/plain)?(?:;|$)})
 166              or $type =~ m{^multipart/}
 167             )) {
 168         push @$attachments, $param{entity};
 169         # output this attachment
 170         if (exists $param{att} and
 171             $param{att} == $#$attachments) {
 172             my $head = $entity->head;
 173             chomp(my $type = $entity->effective_type);
 174             my $body = $entity->stringify_body;
 175             # this attachment has its own content type, so we must not
 176             # try to convert it to UTF-8 or do anything funky.
 177             binmode($output,':raw');
 178             print {$output} "Content-Type: $type";
 179             my ($charset) = $head->get('Content-Type:') =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 180             print {$output} qq(; charset="$charset") if defined $charset;
 181             print {$output} "\n";
 182             if ($filename ne '') {
 183                 my $qf = $filename;
 184                 $qf =~ s/"/\\"/g;
 185                 $qf =~ s[.*/][];
 186                 print {$output} qq{Content-Disposition: inline; filename="$qf"\n};
 187             }
 188             print {$output} "\n";
 189             my $decoder = MIME::Decoder->new($head->mime_encoding);
 190             $decoder->decode(IO::Scalar->new(\$body), $output);
 191             # we don't reset the layers here, because it makes no
 192             # sense to add anything to the output handle after this
 193             # point.
 194             return(1);
 195         }
 196         elsif (not exists $param{att}) {
 197              my @dlargs = (msg=>$xmessage, att=>$#$attachments);
 198              push @dlargs, (filename=>$filename) if $filename ne '';
 199              my $printname = $filename;
 200              $printname = 'Message part ' . ($#$attachments + 1) if $filename eq '';
 201              print {$output} '<pre class="mime">[<a href="' .
 202                   html_escape(bug_links(bug => $ref,
 203                                         links_only => 1,
 204                                         options => {@dlargs})
 205                              ) . qq{">$printname</a> } .
 206                                   "($type, $disposition)]</pre>\n";
 207         }
 208     }
 209
 210     return 0 if not $param{outer} and $disposition eq 'attachment' and not exists $param{att};
 211     return 0 unless (($type =~ m[^text/?] and
 212                       $type !~ m[^text/(?:html|enriched)(?:;|$)]) or
 213                      $type =~ m[^application/pgp(?:;|$)] or
 214                      $entity->parts);
 215
 216     if ($entity->is_multipart) {
 217         my @parts = $entity->parts;
 218         foreach my $part (@parts) {
 219             my $raw_output =
 220                 display_entity(entity => $part,
 221                                bug_num => $ref,
 222                                outer => 0,
 223                                msg_num => $xmessage,
 224                                output => $output,
 225                                attachments => $attachments,
 226                                terse => $param{terse},
 227                                exists $param{msg}?(msg=>$param{msg}):(),
 228                                exists $param{att}?(att=>$param{att}):(),
 229                                exists $param{avatars}?(avatars=>$param{avatars}):(),
 230                               );
 231             if ($raw_output) {
 232                 return $raw_output;
 233             }
 234             # print {$output} "\n";
 235         }
 236     } elsif ($entity->parts) {
 237         # We must be dealing with a nested message.
 238          if (not exists $param{att}) {
 239               print {$output} "<blockquote>\n";
 240          }
 241         my @parts = $entity->parts;
 242         foreach my $part (@parts) {
 243             display_entity(entity => $part,
 244                            bug_num => $ref,
 245                            outer => 1,
 246                            msg_num => $xmessage,
 247                            output => $output,
 248                            attachments => $attachments,
 249                            terse => $param{terse},
 250                            exists $param{msg}?(msg=>$param{msg}):(),
 251                            exists $param{att}?(att=>$param{att}):(),
 252                            exists $param{avatars}?(avatars=>$param{avatars}):(),
 253                           );
 254             # print {$output} "\n";
 255         }
 256          if (not exists $param{att}) {
 257               print {$output} "</blockquote>\n";
 258          }
 259     } elsif (not $param{terse}) {
 260          my $content_type = $entity->head->get('Content-Type:') || "text/html";
 261          my ($charset) = $content_type =~ m/charset\s*=\s*\"?([\w-]+)\"?/i;
 262          my $body = $entity->bodyhandle->as_string;
 263          $body = convert_to_utf8($body,$charset//'utf8');
 264          $body = html_escape($body);
 265          # Attempt to deal with format=flowed
 266          if ($content_type =~ m/format\s*=\s*\"?flowed\"?/i) {
 267               $body =~ s{^\ }{}mgo;
 268               # we ignore the other things that you can do with
 269               # flowed e-mails cause they don't really matter.
 270          }
 271          # Add links to URLs
 272          # We don't html escape here because we escape above;
 273          # wierd terminators are because of that
 274          $body =~ s{((?:ftp|http|https|svn|ftps|rsync)://[\S~-]+?/?) # Url
 275                     ((?:\&gt\;)?[)]?(?:'|\&\#39\;|\&quot\;)?[:.\,]?(?:\s|$)) # terminators
 276               }{<a href=\"$1\">$1</a>$2}gox;
 277          # Add links to bug closures
 278          $body =~ s[((?:closes|see):\s* # start of closed/referenced bugs
 279                         (?:bug)?\#?\s?\d+\s? # first bug
 280                         (?:,?\s*(?:bug)?\#?\s?\d+)* # additional bugs
 281                     (?:\s|\n|\)|\]|\}|\.|\,|$)) # ends with a space, newline, end of string, or ); fixes #747267
 282                   ]
 283                    [my $temp = $1;
 284                     $temp =~ s{(\d+)}
 285                               {bug_links(bug=>$1)}ge;
 286                     $temp;]gxie;
 287          if (defined $config{cve_tracker} and
 288              length $config{cve_tracker}
 289             ) {
 290              # Add links to CVE vulnerabilities (closes #568464)
 291              $body =~ s{(^|\s|[\(\[])(CVE-\d{4}-\d{4,})(\s|[,.-\[\]\)]|$)}
 292                        {$1<a href="http://$config{cve_tracker}$2">$2</a>$3}gxm;
 293          }
 294          if (not exists $param{att}) {
 295               print {$output} qq(<pre class="message">$body</pre>\n);
 296          }
 297     }
 298     return 0;
 299 }
 300
 301
 302 =head2 handle_email_message
 303
 304      handle_email_message($record->{text},
 305                           ref        => $bug_number,
 306                           msg_num => $msg_number,
 307                          );
 308
 309 Returns a decoded e-mail message and displays entities/attachments as
 310 appropriate.
 311
 312
 313 =cut
 314
 315 sub handle_email_message{
 316      my ($email,%param) = @_;
 317
 318      my $output;
 319      my $output_fh = globify_scalar(\$output);
 320      my $entity;
 321      my $tempdir;
 322      if (not blessed $email) {
 323          my $parser = MIME::Parser->new();
 324          # Because we are using memory, not tempfiles, there's no need to
 325          # clean up here like in Debbugs::MIME
 326          # this will be cleaned up once it goes out of scope
 327          $tempdir = File::Temp->newdir();
 328          $parser->output_under($tempdir->dirname());
 329          $entity = $parser->parse_data( $email);
 330      } else {
 331          $entity = $email
 332      }
 333      my @attachments = ();
 334      my $raw_output =
 335          display_entity(entity  => $entity,
 336                         bug_num => $param{ref},
 337                         outer   => 1,
 338                         msg_num => $param{msg_num},
 339                         output => $output_fh,
 340                         attachments => \@attachments,
 341                         terse       => $param{terse},
 342                         exists $param{msg}?(msg=>$param{msg}):(),
 343                         exists $param{att}?(att=>$param{att}):(),
 344                         exists $param{trim_headers}?(trim_headers=>$param{trim_headers}):(),
 345                         exists $param{avatars}?(avatars=>$param{avatars}):(),
 346                        );
 347      return $raw_output?$output:decode_utf8($output);
 348 }
 349
 350 =head2 handle_record
 351
 352      push @log, handle_record($record,$ref,$msg_num);
 353
 354 Deals with a record in a bug log as returned by
 355 L<Debbugs::Log::read_log_records>; returns the log information that
 356 should be output to the browser.
 357
 358 =cut
 359
 360 sub handle_record{
 361      my ($record,$bug_number,$msg_number,$seen_msg_ids,%param) = @_;
 362
 363      # output needs to have the is_utf8 flag on to avoid double
 364      # encoding
 365      my $output = decode_utf8('');
 366      local $_ = $record->{type};
 367      if (/html/) {
 368          # $record->{text} is not in perl's internal encoding; convert it
 369          my $text = decode_rfc1522(decode_utf8($record->{text}));
 370           my ($time) = $text =~ /<!--\s+time:(\d+)\s+-->/;
 371           my $class = $text =~ /^<strong>(?:Acknowledgement|Reply|Information|Report|Notification)/m ? 'infmessage':'msgreceived';
 372           $output .= $text;
 373           # Link to forwarded http:// urls in the midst of the report
 374           # (even though these links already exist at the top)
 375           $output =~ s,((?:ftp|http|https)://[\S~-]+?/?)((?:[\)\'\:\.\,]|\&\#39;|\&quot\;)?
 376                            (?:\s|\.<|$)),<a href=\"$1\">$1</a>$2,gxo;
 377           # Add links to the cloned bugs
 378           $output =~ s{(Bug )(\d+)( cloned as bugs? )(\d+)(?:\-(\d+)|)}{$1.bug_links(bug=>$2).$3.bug_links(bug=>(defined $5)?[$4..$5]:$4)}eo;
 379           # Add links to merged bugs
 380           $output =~ s{(?<=Merged )([\d\s]+)(?=\.)}{join(' ',map {bug_links(bug=>$_)} (split /\s+/, $1))}eo;
 381           # Add links to blocked bugs
 382           $output =~ s{(?<=Blocking bugs)(?:( of )(\d+))?( (?:added|set to|removed):\s+)([\d\s\,]+)}
 383                       {(defined $2?$1.bug_links(bug=>$2):'').$3.
 384                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+/, $4)])}eo;
 385           $output =~ s{((?:[Aa]dded|[Rr]emoved)\ blocking\ bug(?:\(s\))?)(?:(\ of\ )(\d+))?(:?\s+)
 386                        (\d+(?:,\s+\d+)*(?:\,?\s+and\s+\d+)?)}
 387                       {$1.(defined $3?$2.bug_links(bug=>$3):'').$4.
 388                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}xeo;
 389           $output =~ s{([Aa]dded|[Rr]emoved)( indication that bug )(\d+)( blocks )([\d\s\,]+)}
 390                       {$1.$2.(bug_links(bug=>$3)).$4.
 391                            english_join([map {bug_links(bug=>$_)} (split /\,?\s+(?:and\s+)?/, $5)])}eo;
 392           # Add links to reassigned packages
 393           $output =~ s{(Bug\sreassigned\sfrom\spackage\s(?:[\`']|\&\#39;))([^']+?)((?:'|\&\#39;|\&quot\;)
 394                                \sto\s(?:[\`']|\&\#39;|\&quot\;))([^']+?)((?:'|\&\#39;|\&quot\;))}
 395           {$1.q(<a href=").html_escape(package_links(package=>$2)).qq(">$2</a>).$3.
 396                q(<a href=").html_escape(package_links(package=>$4)).qq(">$4</a>).$5}exo;
 397           if (defined $time) {
 398                $output .= ' ('.strftime('%a, %d %b %Y %T GMT',gmtime($time)).') ';
 399           }
 400           $output .= '<a href="' .
 401                html_escape(bug_links(bug => $bug_number,
 402                                      options => {msg => ($msg_number+1)},
 403                                      links_only => 1,
 404                                     )
 405                           ) . '">Full text</a> and <a href="' .
 406                                html_escape(bug_links(bug => $bug_number,
 407                                                      options => {msg => ($msg_number+1),
 408                                                                  mbox => 'yes'},
 409                                                      links_only => 1)
 410                                           ) . '">rfc822 format</a> available.';
 411
 412           $output = qq(<div class="$class"><hr>\n<a name="$msg_number"></a>\n) . $output . "</div>\n";
 413      }
 414      elsif (/recips/) {
 415           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 416           if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 417                return ();
 418           }
 419           elsif (defined $msg_id) {
 420                $$seen_msg_ids{$msg_id} = 1;
 421           }
 422           $output .= qq(<hr><p class="msgreceived"><a name="$msg_number"></a>\n);
 423           $output .= 'View this message in <a href="' . html_escape(bug_links(bug=>$bug_number, links_only => 1, options=>{msg=>$msg_number, mbox=>'yes'})) . '">rfc822 format</a></p>';
 424           $output .= handle_email_message($record->{text},
 425                                           ref     => $bug_number,
 426                                           msg_num => $msg_number,
 427                                           %param,
 428                                          );
 429      }
 430      elsif (/autocheck/) {
 431           # Do nothing
 432      }
 433      elsif (/incoming-recv/) {
 434           my ($msg_id) = $record->{text} =~ /^Message-Id:\s+<(.+)>/im;
 435           if (defined $msg_id and exists $$seen_msg_ids{$msg_id}) {
 436                return ();
 437           }
 438           elsif (defined $msg_id) {
 439                $$seen_msg_ids{$msg_id} = 1;
 440           }
 441           # Incomming Mail Message
 442           my ($received,$hostname) = $record->{text} =~ m/Received: \(at (\S+)\) by (\S+)\;/;
 443           $output .= qq|<hr><p class="msgreceived"><a name="$msg_number"></a><a name="msg$msg_number"></a><a href="#$msg_number">Message #$msg_number</a> received at |.
 444                html_escape("$received\@$hostname") .
 445                     q| (<a href="| . html_escape(bug_links(bug => $bug_number, links_only => 1, options => {msg=>$msg_number})) . '">full text</a>'.
 446                          q|, <a href="| . html_escape(bug_links(bug => $bug_number,
 447                                                                 links_only => 1,
 448                                                                 options => {msg=>$msg_number,
 449                                                                             mbox=>'yes'}
 450                                                                )
 451                                                      ) .'">mbox</a>, ';
 452           my $parser = MIME::Parser->new();
 453
 454           # this will be cleaned up once it goes out of scope
 455           my $tempdir = File::Temp->newdir();
 456           $parser->output_under($tempdir->dirname());
 457           my $entity = $parser->parse_data($record->{text});
 458           my $r_l = reply_headers($entity);
 459           $output .= q(<a href=").
 460               html_escape('mailto:'.$bug_number.'@'.$config{email_domain}.'?'.
 461                           join('&',map {defined $r_l->{$_}?$_.'='.uri_escape_utf8($r_l->{$_}):()} keys %{$r_l})).
 462                               qq(">reply</a>);
 463
 464           $output .= ')'.":</p>\n";
 465           $output .= handle_email_message($entity,
 466                                           ref     => $bug_number,
 467                                           msg_num => $msg_number,
 468                                           %param,
 469                                          );
 470      }
 471      else {
 472           die "Unknown record type $_";
 473      }
 474      return $output;
 475 }
 476
 477
 478 sub __libravatar_url {
 479     my ($email) = @_;
 480     if (not defined $config{libravatar_uri} or not length $config{libravatar_uri}) {
 481         return undef;
 482     }
 483     ($email) = grep {/\@/} get_addresses($email);
 484     return $config{libravatar_uri}.uri_escape_utf8($email.($config{libravatar_uri_options}//''));
 485 }
 486
 487
 488 1;
 489
 490
 491 __END__
 492
 493
 494
 495
 496
 497