ddot.f

   1 *DECK DDOT
   2       DOUBLE PRECISION FUNCTION DDOT (N, DX, INCX, DY, INCY)
   3 C***BEGIN PROLOGUE  DDOT
   4 C***PURPOSE  Compute the inner product of two vectors.
   5 C***LIBRARY   SLATEC (BLAS)
   6 C***CATEGORY  D1A4
   7 C***TYPE      DOUBLE PRECISION (SDOT-S, DDOT-D, CDOTU-C)
   8 C***KEYWORDS  BLAS, INNER PRODUCT, LINEAR ALGEBRA, VECTOR
   9 C***AUTHOR  Lawson, C. L., (JPL)
  10 C           Hanson, R. J., (SNLA)
  11 C           Kincaid, D. R., (U. of Texas)
  12 C           Krogh, F. T., (JPL)
  13 C***DESCRIPTION
  14 C
  15 C                B L A S  Subprogram
  16 C    Description of Parameters
  17 C
  18 C     --Input--
  19 C        N  number of elements in input vector(s)
  20 C       DX  double precision vector with N elements
  21 C     INCX  storage spacing between elements of DX
  22 C       DY  double precision vector with N elements
  23 C     INCY  storage spacing between elements of DY
  24 C
  25 C     --Output--
  26 C     DDOT  double precision dot product (zero if N .LE. 0)
  27 C
  28 C     Returns the dot product of double precision DX and DY.
  29 C     DDOT = sum for I = 0 to N-1 of  DX(LX+I*INCX) * DY(LY+I*INCY),
  30 C     where LX = 1 if INCX .GE. 0, else LX = 1+(1-N)*INCX, and LY is
  31 C     defined in a similar way using INCY.
  32 C
  33 C***REFERENCES  C. L. Lawson, R. J. Hanson, D. R. Kincaid and F. T.
  34 C                 Krogh, Basic linear algebra subprograms for Fortran
  35 C                 usage, Algorithm No. 539, Transactions on Mathematical
  36 C                 Software 5, 3 (September 1979), pp. 308-323.
  37 C***ROUTINES CALLED  (NONE)
  38 C***REVISION HISTORY  (YYMMDD)
  39 C   791001  DATE WRITTEN
  40 C   890831  Modified array declarations.  (WRB)
  41 C   890831  REVISION DATE from Version 3.2
  42 C   891214  Prologue converted to Version 4.0 format.  (BAB)
  43 C   920310  Corrected definition of LX in DESCRIPTION.  (WRB)
  44 C   920501  Reformatted the REFERENCES section.  (WRB)
  45 C***END PROLOGUE  DDOT
  46       DOUBLE PRECISION DX(*), DY(*)
  47 C***FIRST EXECUTABLE STATEMENT  DDOT
  48       DDOT = 0.0D0
  49       DTEMP = 0.0D0
  50       IF (N .LE. 0) RETURN
  51       IF (INCX .EQ. INCY) IF (INCX-1) 5,20,60
  52 C
  53 C     Code for unequal or nonpositive increments.
  54 C
  55     5 IX = 1
  56       IY = 1
  57       IF (INCX .LT. 0) IX = (-N+1)*INCX + 1
  58       IF (INCY .LT. 0) IY = (-N+1)*INCY + 1
  59       DO 10 I = 1,N
  60         DDOT = DDOT + DX(IX)*DY(IY)
  61         IX = IX + INCX
  62         IY = IY + INCY
  63    10 CONTINUE
  64       RETURN
  65 C
  66 C     Code for both increments equal to 1.
  67 C
  68 C     Clean-up loop so remaining vector length is a multiple of 5.
  69 C
  70    20 M = MOD(N,5)
  71       IF (M .EQ. 0) GO TO 40
  72       DO 30 I = 1,M
  73          DDOT = DDOT + DX(I)*DY(I)
  74    30 CONTINUE
  75       IF (N .LT. 5) RETURN
  76    40 MP1 = M + 1
  77       DO  I = MP1,N,5
  78       DDOT = DDOT + DX(I)*DY(I) + DX(I+1)*DY(I+1) + DX(I+2)*DY(I+2) +
  79      1              DX(I+3)*DY(I+3) + DX(I+4)*DY(I+4)
  80       END DO
  81       RETURN
  82 C
  83 C     Code for equal, positive, non-unit increments.
  84 C
  85    60 NS = N*INCX
  86       DO 70 I = 1,NS,INCX
  87         DDOT = DDOT + DX(I)*DY(I)
  88    70 CONTINUE
  89       RETURN
  90       END