#! /usr/bin/perl

# combine_results, is part of the gene search suite, and is released
# under the terms of the GPL version 2, or any later version, at your
# option. See the file README and COPYING for more information.

# Copyright 2006,2007 by Don Armstrong <don@donarmstrong.com>.


use warnings;
use strict;


use Getopt::Long;
use Pod::Usage;

=head1 NAME

  combine_results -- combines parsed result files; outputs to stdout.

=head1 SYNOPSIS

 combine_results parsed_results_1.txt [parsedresultfiles ...]

 Options:
  --debug, -d debugging level [default 0]
  --help, -h display this help
  --man, -m display manual

=head1 OPTIONS

=over

=item B<--debug, -d>

Debug verbosity. (Default 0)

=item B<--help, -h>

Display brief useage information.

=item B<--man, -m>

Display this manual.

=back

=head1 EXAMPLES

  combine_results foo_1.txt

Will pretty much do what you want

=cut



use vars qw($DEBUG);

BEGIN{
     $DEBUG = 0 unless defined $DEBUG;
}

use XML::Parser::Expat;
use IO::File;

# XXX parse config file

my %options = (debug    => 0,
	       help     => 0,
	       man      => 0,
	      );

GetOptions(\%options,'keyword|k=s','debug|d+','help|h|?','man|m');


pod2usage() if $options{help};
pod2usage({verbose=>2}) if $options{man};

$DEBUG = $options{debug};

# CSV columns
use constant {NAME        => 0,
	      REFSEQ      => 1,
	      LOCATION    => 2,
	      ALIAS       => 3,
	      FUNCTION    => 4,
	      DESCRIPTION => 5,
	      KEYWORD     => 6,
	      DBNAME      => 7,
	      FILENAME    => 8,
	     };

my @csv_fields = qw(name hits rzscore refseq location alias database terms description function);

my %genes;

for my $file_name (@ARGV) {
     my $file = new IO::File $file_name, 'r' or die "Unable to open file $file_name $!";
     while (<$file>) {
	  next if /^"Name"/;
	  my @gene = map {s/^\"//; s/\"$//; $_;} split /(?<=\")\,(?=\")/, $_;
	  $genes{$gene[NAME]}{name} = $gene[NAME];
	  $genes{$gene[NAME]}{database}{$gene[DBNAME]}++;
	  $genes{$gene[NAME]}{hits}++;
	  $genes{$gene[NAME]}{terms}{$gene[KEYWORD]}++;
	  add_unique_parts($genes{$gene[NAME]},'refseq',$gene[REFSEQ]);
	  add_if_better($genes{$gene[NAME]},'description',$gene[DESCRIPTION]);
	  add_if_better($genes{$gene[NAME]},'location',$gene[LOCATION]);
	  add_unique_parts($genes{$gene[NAME]},'function',split(/; /, $gene[FUNCTION]));
	  add_unique_parts($genes{$gene[NAME]},'alias', split(/; /, $gene[ALIAS]));
     }
}

print join(',',map {qq("$_")} @csv_fields),qq(\n);
for my $gene (keys %genes) {
     $genes{$gene}{rzscore} = scalar keys %{$genes{$gene}{terms}};
     next if $genes{$gene}{rzscore} == 1 and exists $genes{$gene}{terms}{antigen};
     $genes{$gene}{rzscore} -= 1 if exists $genes{$gene}{terms}{antigen};
     print STDOUT join (',',
			map {s/"//g; qq("$_")}
			map {
			     my $value = $_;
			     if (ref $value eq 'HASH') {
				  join('; ',map {qq($_:$$value{$_})} keys %$value);
			     }
			     elsif (ref $value eq 'ARRAY') {
				  join('; ', @$value);
			     }
			     else {
				  $value;
			     }
			} @{$genes{$gene}}{@csv_fields}
		       ), qq(\n);
}


sub add_unique_parts{
     my ($hr,$key,@values) = @_;
     if (not defined $$hr{key}) {
	  $$hr{$key} = [@values];
     }
     else {
	  my %temp_hash;
	  @temp_hash{@{$$hr{$key}}} = (1) x scalar @{$$hr{$key}};
	  $temp_hash{@values} = (1) x scalar @values;
	  $$hr{$key} = [keys %temp_hash];
     }
}

sub add_if_better{
     my ($hash, $key, $value) = @_;
     if (not defined $$hash{$key}) {
	  $$hash{$key} = $value;
     }
     elsif (length $$hash{$key} < length $value and $value !~ /^NO\s+(LOCATION|DESCRIPTION)+$/) {
	  $$hash{$key} = $value;
     }
}




__END__