#! /usr/bin/perl
# vim: ts=4 sw=4 nowrap

# Generate some counts for the bugreports

use Getopt::Std;
require scanlib;
require bugcfg;
use strict;
use warnings;

my $Version		= "BugCount 1.1\nCopyright (C) Wichert Akkerman <wakkerma\@debian.org>\n";
my $statusfile		= "status";

sub ShowVersion() {
	print "$Version\n";
	exit 0;
}

sub ShowUsage() {
	print <<EOF;
Usage:
  $0 [-V] [-h] [-S file] [-C file]
Options:
  -V    show version
  -h    show some (hopefully) helpfull information
  -S    use different statusfile
EOF
	exit 0;
}

our ($opt_h,$opt_V,$opt_S);

getopts('VhS:');
ShowUsage if ($opt_h);
ShowVersion if ($opt_V);
$statusfile=$opt_S if ($opt_S);

scanlib::readstatus($statusfile);

my $total=0;		# total number of bugs
my $patchcount=0;	# Number of bugs that have a fix proposed
my $pendingcount=0;	# Number of bugs that will have a fix uploaded RSN
my $ignorecount=0;      # Number of bugs being ignored
my $worrycount=0;	# Number of bugs we're actually worried about
my $stablecount=0;	# Number of bugs affecting stable

for my $p (keys %scanlib::packagelist) {
	for my $nr (sort @{$scanlib::packagelist{$p}}) {
		$total++;
		$pendingcount++ if ($scanlib::bugs{$nr}->{'pending'});
		$patchcount++ if ($scanlib::bugs{$nr}->{'patch'});
		$ignorecount++ if ($scanlib::bugs{$nr}->{'sarge-ignore'} || $scanlib::bugs{$nr}->{'etch-ignore'});
		$worrycount++ if (scanlib::check_worry($scanlib::bugs{$nr}));
		$stablecount++ if (scanlib::check_worry_stable($scanlib::bugs{$nr}));
	}
}

printf("%d %d %d 0 %d 0 %d %d\n", $total, $pendingcount, $patchcount, $ignorecount, $worrycount, $stablecount);