#! /usr/bin/perl
# , and is released
# under the terms of the GPL version 2, or any later version, at your
# option. See the file README and COPYING for more information.
# Copyright 2011 by Don Armstrong <don@donarmstrong.com>.
# $Id: perl_script 1825 2011-01-02 01:53:43Z don $


use warnings;
use strict;

use Getopt::Long;
use Pod::Usage;

use Bio::DB::EUtilities;

use Encode qw(encode_utf8);
use Term::ANSIColor qw(:constants);
use Text::Wrap;


=head1 NAME

pubmed_search - 

=head1 SYNOPSIS

 pubmed_search [options] [searchterms]

 Options:
  --debug, -d debugging level (Default 0)
  --help, -h display this help
  --man, -m display manual

=head1 OPTIONS

=over

=item B<--debug, -d>

Debug verbosity. (Default 0)

=item B<--help, -h>

Display brief usage information.

=item B<--man, -m>

Display this manual.

=back

=head1 EXAMPLES


=cut


use vars qw($DEBUG);

my %options = (debug           => 0,
	       help            => 0,
	       man             => 0,
	       color           => 1,
	       org_mode        => 0,
	       );

GetOptions(\%options,
	   'color|c!',
	   'org_mode|org-mode',
	   'debug|d+','help|h|?','man|m');

pod2usage() if $options{help};
pod2usage({verbose=>2}) if $options{man};

$DEBUG = $options{debug};

my @USAGE_ERRORS;
if (not @ARGV) {
    push @USAGE_ERRORS,"You must pass something";
}

pod2usage(join("\n",@USAGE_ERRORS)) if @USAGE_ERRORS;


my $search = Bio::DB::EUtilities->new(-eutil => 'esearch',
				       -email => 'don@donarmstrong.com',
				       -db    => 'pubmed',
				       -term => join(' ',@ARGV),
				       -retmax => 1000,
				      );
my @ids = $search->get_ids();
if ($options{org_mode}) {
    print "* Pubmed search results for ".join(' ',@ARGV)." (".scalar(@ids).")\n";
    print "  + ";
}
print scalar(@ids)." results:\n";
exit 0 unless @ids;
my $esummary = Bio::DB::EUtilities->new(-eutil => 'efetch',
					-email => 'don@donarmstrong.com',
					-db    => 'pubmed',
					-id  => \@ids
				       );
use XML::LibXML;
my $xml = XML::LibXML->load_xml(string => $esummary->get_Response()->content());
for my $article ($xml->findnodes('PubmedArticleSet/PubmedArticle/MedlineCitation')) {
    # print $article->toString;
    my ($pmid) = $article->findnodes('./PMID');
    my ($title) = $article->findnodes('./Article/ArticleTitle');
    my ($abstract) = $article->findnodes('./Article/Abstract');
    if ($options{org_mode}) {
	print "** PMID: ";
    }
    print BOLD GREEN if $options{color};
    print $pmid->textContent();
    print ": ";
    print RESET if $options{color};
    print BOLD CYAN if $options{color};
    print encode_utf8($title->textContent())."\n";
    print RESET if $options{color};
    print BOLD MAGENTA if $options{color};
    if (defined $abstract) {
	if ($options{org_mode}) {
	    print "*** Abstract\n";
	}
	$abstract = $abstract->textContent();
	$abstract =~ s/^\s*//mg;
	$abstract =~ s/(.{,80})\s/$1\n/g;
	$abstract = encode_utf8($abstract);
	print wrap('','',$abstract);
	print "\n\n";
	print RESET if $options{color};
    }
}

__END__