#!/usr/bin/env perl

# Copyright (C) 2007-2010 Martin A. Hansen.

# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

# http://www.gnu.org/copyleft/gpl.html


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> DESCRIPTION <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

# Trim sequence ends for residues with a low quality score.

# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


use warnings;
use strict;
use Maasha::Biopieces;
use Maasha::Fastq;


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


my ( $options, $in, $out, $record, $left, $right, $pos_l, $pos_r );

$options = Maasha::Biopieces::parse_options(
    [
        { long => 'min',  short => 'm', type => 'uint',   mandatory => 'no', default => 15,     allowed => undef,             disallowed => 0 },
        { long => 'trim', short => 't', type => 'string', mandatory => 'no', default => 'both', allowed => 'left,right,both', disallowed => undef },
    ]   
);

$right = 1 if $options->{ 'trim' } eq 'right';
$left  = 1 if $options->{ 'trim' } eq 'left';
$right = 1 if $options->{ 'trim' } eq 'both';
$left  = 1 if $options->{ 'trim' } eq 'both';

$in  = Maasha::Biopieces::read_stream( $options->{ "stream_in" } );
$out = Maasha::Biopieces::write_stream( $options->{ "stream_out" } );

while ( $record = Maasha::Biopieces::get_record( $in ) )
{
    if ( exists $record->{ 'SEQ' } and exists $record->{ 'SCORES' } )
    {
        if ( $right )
        {
            $pos_r = Maasha::Fastq::trim_right( $record->{ 'SCORES' }, $options->{ 'min' } );
        
            $record->{ 'SEQ' }       = substr $record->{ 'SEQ' }, 0, $pos_r + 1;
            $record->{ 'SCORES' }    = substr $record->{ 'SCORES' }, 0, $pos_r + 1; 
            $record->{ 'TRIM_RIGHT' } = $pos_r;
        }

        if ( $left )
        {
            $pos_l = Maasha::Fastq::trim_left( $record->{ 'SCORES' }, $options->{ 'min' } );
        
            $record->{ 'SEQ' }      = substr $record->{ 'SEQ' }, $pos_l;
            $record->{ 'SCORES' }   = substr $record->{ 'SCORES' }, $pos_l;
            $record->{ 'TRIM_LEFT' } = $pos_l;
        }

        $record->{ 'SEQ_LEN' } = length $record->{ 'SEQ' };
    }

    Maasha::Biopieces::put_record( $record, $out );
}

Maasha::Biopieces::close_stream( $in );
Maasha::Biopieces::close_stream( $out );


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


BEGIN
{
    Maasha::Biopieces::status_set();
}


END
{
    Maasha::Biopieces::status_log();
}


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


__END__