#!/usr/bin/env perl

# Copyright (C) 2007-2009 Martin A. Hansen.

# This program is free software; you can redistribute it and/or
# modify it under the terms of the GNU General Public License
# as published by the Free Software Foundation; either version 2
# of the License, or (at your option) any later version.

# This program is distributed in the hope that it will be useful,
# but WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
# GNU General Public License for more details.

# You should have received a copy of the GNU General Public License
# along with this program; if not, write to the Free Software
# Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301, USA.

# http://www.gnu.org/copyleft/gpl.html


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>> DESCRIPTION <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<

# Use BWA to map sequences in the stream against a specified genome or index.

# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


use warnings;
use strict;
use Data::Dumper;
use Maasha::Biopieces;
use Maasha::Common;
use Maasha::Fastq;
use Maasha::SAM;


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


my ( $options, $in, $out, $index, $tmp_dir, $tmp_fq, $tmp_sai, $tmp_sam, $fh_in, $fh_out, $record, $entry, $line, @fields, $type, @args, $arg );

$options = Maasha::Biopieces::parse_options(
    [
        { long => 'genome',      short => 'g', type => 'genome', mandatory => 'no', default => undef, allowed => undef,     disallowed => undef },
        { long => 'index_name',  short => 'i', type => 'string', mandatory => 'no', default => undef, allowed => undef,     disallowed => undef },
        { long => 'mismatches',  short => 'm', type => 'uint',   mandatory => 'no', default => 0,     allowed => "0,1,2,3", disallowed => undef },
        { long => 'max_hits',    short => 'h', type => 'uint',   mandatory => 'no', default => undef, allowed => undef,     disallowed => 0     },
        { long => 'cpus',        short => 'c', type => 'uint',   mandatory => 'no', default => 1,     allowed => undef,     disallowed => 0     },
    ]   
);

Maasha::Common::error( qq(both --index_name and --genome specified) ) if     $options->{ "genome" } and     $options->{ "index_name" };
Maasha::Common::error( qq(no --index_name or --genome specified) )    if not $options->{ "genome" } and not $options->{ "index_name" };

$in  = Maasha::Biopieces::read_stream( $options->{ "stream_in" } );
$out = Maasha::Biopieces::write_stream( $options->{ "stream_out" } );

if ( defined $options->{ 'genome' } ) {
    $index = "$ENV{ 'BP_DATA' }/genomes/$options->{ 'genome' }/bowtie/$options->{ 'genome' }";
} elsif (defined $options->{ 'index_name' } ) {
    $index = $options->{ 'index_name' };
}

$tmp_dir = Maasha::Biopieces::get_tmpdir();
$tmp_fq  = "$tmp_dir/bwa.fq";
$tmp_sai = "$tmp_dir/bwa.fq.sai";
$tmp_sam = "$tmp_dir/bwa.fq.sam";

$fh_out = Maasha::Filesys::file_write_open( $tmp_fq );

while ( $record = Maasha::Biopieces::get_record( $in ) ) 
{
    if ( $entry = Maasha::Fastq::biopiece2fastq( $record ) ) {
        Maasha::Fastq::put_entry( $entry, $fh_out );
    }

    Maasha::Biopieces::put_record( $record, $out );
}

close $fh_out;

push @args, "-t $options->{ 'cpus' }";
push @args, "-R $options->{ 'max_hits' }" if $options->{ 'max_hits' };

$arg = join " ", @args;

if ( $options->{ 'verbose' } )
{
    print STDERR qq(Running: bwa aln $arg $index $tmp_fq > $tmp_sai\n);
    Maasha::Common::run( "bwa", "aln $arg $index $tmp_fq > $tmp_sai" );
    print STDERR qq(Running: bwa samse $index $tmp_sai $tmp_fq > $tmp_sam\n);
    Maasha::Common::run( "bwa", "samse $index $tmp_sai $tmp_fq > $tmp_sam" )
}
else
{
    Maasha::Common::run( "bwa", "aln $arg $index $tmp_fq       > $tmp_sai 2> /dev/null" );
    Maasha::Common::run( "bwa", "samse $index $tmp_sai $tmp_fq > $tmp_sam 2> /dev/null" );
}

$fh_in = Maasha::Filesys::file_read_open( $tmp_sam );

while ( $entry = Maasha::SAM::get_entry( $fh_in ) )
{
    if ( $record = Maasha::SAM::sam2biopiece( $entry ) ) {
        Maasha::Biopieces::put_record( $record, $out );
    }
}

close $fh_in;

unlink $tmp_fq;
unlink $tmp_sai;
unlink $tmp_sam;

Maasha::Biopieces::close_stream( $in );
Maasha::Biopieces::close_stream( $out );


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


BEGIN
{
    Maasha::Biopieces::status_set();
}


END
{
    Maasha::Biopieces::status_log();
}


# >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>><<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<


__END__