stepmake/aclocal.m4

   1 dnl aclocal.m4   -*-shell-script-*-
   2 dnl StepMake subroutines for configure.in
   3
   4
   5 ### mostly interal macros
   6
   7 # Get full path of executable ($1)
   8 AC_DEFUN(STEPMAKE_GET_EXECUTABLE, [
   9     ## which doesn't work in ash, if /usr/bin/which isn't installed
  10     ## type -p doesn't work in ash
  11     ## command -v doesn't work in zsh
  12     ## command -v "$1" 2>&1
  13     ## this test should work in ash, bash, pdksh (ksh), zsh
  14     type -p $1 2>/dev/null | tail -n 1 | awk '{print $NF}'
  15 ])
  16
  17
  18 # Get version string from executable ($1)
  19 AC_DEFUN(STEPMAKE_GET_VERSION, [
  20     ## "$1" --version 2>&1 | grep -v '^$' | head -n 1 | awk '{print $NF}'
  21     ##
  22     ## ARG.
  23     ## Workaround for broken Debian gcc version string:
  24     ##     gcc (GCC) 3.1.1 20020606 (Debian prerelease)
  25     ##
  26     ## -V: Workaround for python
  27
  28     changequote(<<, >>)#dnl
  29
  30     ## Assume and hunt for dotted version multiplet.
  31     ## use eval trickery, because we cannot use multi-level $() instead of ``
  32     ## for compatibility reasons.
  33
  34     ## grab the first version number in  --version output.
  35     eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 |
  36                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  37                 head -n 1 |
  38                 tr ' ' '\n' |
  39                 sed 's/\([0-9][0-9]*\.[0-9][0-9.]*\).*/\1/g' |
  40                 grep -E '(^| )[0-9][0-9]*\.[0-9]' |
  41                 head -n 1\`\"
  42
  43     if test -z "$_ver"; then
  44         ## If empty, try date [fontforge]
  45         eval _ver=\"\`("$1" --version || "$1" -V) 2>&1 | grep '[0-9]\{6,8\}' \
  46             | head -n 1 \
  47             | sed -e 's/^[^.0-9]*//' -e 's/[^.0-9]*$//'\`\"
  48     fi
  49     echo "$_ver"
  50     changequote([, ])#dnl
  51 ])
  52
  53 # Calculate simplistic numeric version from version string ($1)
  54 # As yet, we have no need for something more elaborate.
  55 AC_DEFUN(STEPMAKE_NUMERIC_VERSION, [
  56     echo "$1" | awk -F. '
  57     {
  58       if ([$]3) {three = [$]3}
  59       else {three = 0}
  60     }
  61     {printf "%.0f\n", [$]1*1000000 + [$]2*1000 + three}'
  62 ])
  63
  64
  65 # Add item ($2) to list ($1, one of 'OPTIONAL', 'REQUIRED')
  66 AC_DEFUN(STEPMAKE_ADD_ENTRY, [
  67     eval "$1"=\"`eval echo \"'$'$1\" \"$2\"`\"
  68 ])
  69
  70 # Check if tested program ($2) was found ($1).
  71 # If not, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED').
  72 # We could abort here if a 'REQUIRED' program is not found
  73 AC_DEFUN(STEPMAKE_OPTIONAL_REQUIRED, [
  74     STEPMAKE_CHECK_SEARCH_RESULT($1)
  75     if test $? -ne 0; then
  76         STEPMAKE_ADD_ENTRY($3, $2)
  77         if test "$3" = "REQUIRED"; then
  78             command="echo ERROR: $2 not found"
  79             # abort configure process here?
  80         else
  81             command="- echo $2 not found"
  82         fi
  83         eval "$1"='$command'
  84         false
  85     else
  86         true
  87     fi
  88 ])
  89
  90
  91 # Return if tested proram ($1) was found (true) or not (false).
  92 AC_DEFUN(STEPMAKE_CHECK_SEARCH_RESULT, [
  93     r="`eval echo '$'"$1"`"
  94     if test -n "$r" -a "$r" != "error" -a "$r" != "no" && expr '`eval echo '$'"$1"`' : '.*\(echo\)' > /dev/null; then
  95         true
  96     else
  97         ##STEPMAKE_WARN(cannot find $2. $3)
  98         false
  99     fi
 100 ])
 101
 102
 103 # Check version of program ($1)
 104 # If version ($4: optional argument, supply if version cannot be
 105 # parsed using --version or -V ) is smaller than requested ($3), add
 106 # entry to missing-list ($2, one of 'OPTIONAL', 'REQUIRED').
 107 AC_DEFUN(STEPMAKE_CHECK_VERSION, [
 108     r="`eval echo '$'"$1"`"
 109     AC_MSG_CHECKING([$r version])
 110     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 111     if test -n "$4"; then
 112         ver="$4"
 113     else
 114         ver=`STEPMAKE_GET_VERSION($exe)`
 115     fi
 116     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 117     req=`STEPMAKE_NUMERIC_VERSION($3)`
 118     AC_MSG_RESULT([$ver])
 119     if test "$num" -lt "$req"; then
 120         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
 121     fi
 122     vervar="`echo $1 | tr '[a-z]' '[A-Z]'`_VERSION"
 123     eval `echo $vervar=$num`
 124 ##    AC_SUBST(`eval echo $vervar`)
 125 ])
 126
 127 # Check version of program ($1)
 128 # If version is greater than or equals unsupported ($3),
 129 # add entry to unsupported list ($2, 'UNSUPPORTED')
 130 AC_DEFUN(STEPMAKE_CHECK_VERSION_UNSUPPORTED, [
 131     r="`eval echo '$'"$1"`"
 132     AC_MSG_CHECKING([$r version])
 133     exe=`STEPMAKE_GET_EXECUTABLE($r)`
 134     ver=`STEPMAKE_GET_VERSION($exe)`
 135     num=`STEPMAKE_NUMERIC_VERSION($ver)`
 136     sup=`STEPMAKE_NUMERIC_VERSION($3)`
 137     AC_MSG_RESULT([$ver])
 138     if test "$num" -ge "$sup"; then
 139         STEPMAKE_ADD_ENTRY($2, ["$r < $3 (installed: $ver)"])
 140     fi
 141 ])
 142
 143 ### Macros to build configure.in
 144
 145
 146 AC_DEFUN(STEPMAKE_BIBTEX2HTML, [
 147     STEPMAKE_PROGS(BIBTEX2HTML, bibtex2html bib2html, $1)
 148     if test "$BIBTEX2HTML" = "bib2html"; then
 149         BIBTEX2HTML_FLAGS='$< $(@)'
 150     else
 151         BIBTEX2HTML_FLAGS='-o $(@D)/$(*F) $<'
 152     fi
 153     AC_SUBST(BIBTEX2HTML)
 154     AC_SUBST(BIBTEX2HTML_FLAGS)
 155 ])
 156
 157
 158 AC_DEFUN(STEPMAKE_BISON, [
 159     # ugh, automake: we want (and check for) bison
 160     AC_PROG_YACC
 161
 162     STEPMAKE_PROGS(BISON, bison, $1)
 163
 164     # urg.  should test functionality rather than version.
 165     if test "$BISON" = "bison" -a -n "$2"; then
 166         STEPMAKE_CHECK_VERSION(BISON, $1, $2)
 167     fi
 168 ])
 169
 170 AC_DEFUN(STEPMAKE_COMPILE_BEFORE, [
 171     # -O is necessary to get inlining
 172     CFLAGS=${CFLAGS-""}
 173     CXXFLAGS=${CXXFLAGS-$CFLAGS}
 174     LDFLAGS=${LDFLAGS-""}
 175     optimise_b=yes
 176     profile_b=no
 177     debug_b=yes
 178     pipe_b=yes
 179
 180     AC_ARG_ENABLE(debugging,
 181     [  --enable-debugging      compile with debugging info.  Default: on],
 182     [debug_b=$enableval])
 183
 184     AC_ARG_ENABLE(optimising,
 185     [  --enable-optimising     compile with optimising.  Default: on],
 186     [optimise_b=$enableval])
 187
 188     AC_ARG_ENABLE(profiling,
 189     [  --enable-profiling      compile with gprof support.  Default: off],
 190     [profile_b=$enableval])
 191
 192     AC_ARG_ENABLE(pipe,
 193     [  --enable-pipe           compile with -pipe.  Default: on],
 194     [pipe_b=$enableval])
 195
 196     if test "$optimise_b" = yes; then
 197         AC_DEFINE(NDEBUG)
 198         DEFINES="$DEFINES -DNDEBUG"
 199         OPTIMIZE=" -O2 -finline-functions"
 200     fi
 201
 202     if test $profile_b = yes; then
 203         EXTRA_LIBS="-pg"
 204         OPTIMIZE="$OPTIMIZE -pg"
 205     fi
 206
 207     if test $debug_b = yes; then
 208         OPTIMIZE="$OPTIMIZE -g"
 209     fi
 210 ])
 211
 212 AC_DEFUN(STEPMAKE_COMPILE, [
 213
 214     AC_REQUIRE([STEPMAKE_COMPILE_BEFORE])
 215     AC_REQUIRE([AC_PROG_CC])
 216
 217     STEPMAKE_OPTIONAL_REQUIRED(CC, cc, $1)
 218     LD='$(CC)'
 219     AC_SUBST(LD)
 220
 221     # If -pipe requested, test if it works and add to CFLAGS.
 222     if test "$pipe_b" = yes; then
 223         save_cflags="$CFLAGS"
 224         CFLAGS=" -pipe $CFLAGS";
 225         AC_CACHE_CHECK([whether compiler understands -pipe],
 226             [stepmake_cv_cflags_pipe],
 227             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[/* -pipe test */]])],
 228                 [stepmake_cv_cflags_pipe=yes],
 229                 [stepmake_cv_cflags_pipe=no]))
 230         CFLAGS=$save_cflags
 231         if test $stepmake_cv_cflags_pipe = yes; then
 232             OPTIMIZE="$OPTIMIZE -pipe"
 233         fi
 234     fi
 235
 236     CFLAGS="$CFLAGS $OPTIMIZE"
 237     CPPFLAGS=${CPPFLAGS-""}
 238
 239     AC_MSG_CHECKING([for IEEE-conformance compiler flags])
 240     save_cflags="$CFLAGS"
 241     case "$host" in
 242         alpha*-*-*)
 243             dnl should do compile test?
 244             AC_MSG_RESULT(-mieee)
 245             CFLAGS=" -mieee $CFLAGS"
 246             ;;
 247         *)
 248             AC_MSG_RESULT([none])
 249             ;;
 250     esac
 251
 252     AC_SUBST(cross_compiling)
 253     AC_SUBST(CFLAGS)
 254     AC_SUBST(CPPFLAGS)
 255     AC_SUBST(LDFLAGS)
 256     AC_SUBST(DEFINES)
 257     AC_SUBST(EXTRA_LIBS)
 258 ])
 259
 260 AC_DEFUN(STEPMAKE_CXX, [
 261     AC_PROG_CXX
 262     STEPMAKE_OPTIONAL_REQUIRED(CXX, c++, $1)
 263
 264     CXXFLAGS="$CXXFLAGS $OPTIMIZE"
 265     LD='$(CXX)'
 266
 267     AC_SUBST(CXX)
 268     AC_SUBST(CXXFLAGS)
 269     AC_SUBST(LD)
 270 ])
 271
 272
 273 AC_DEFUN(STEPMAKE_CXXTEMPLATE, [
 274     AC_CACHE_CHECK([whether explicit instantiation is needed],
 275         stepmake_cv_need_explicit_instantiation,
 276         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 277     template <class T> struct foo { static int baz; };
 278     template <class T> int foo<T>::baz = 1;
 279     ]], [[ return foo<int>::baz; ]])],[stepmake_cv_need_explicit_instantiation=no],[stepmake_cv_need_explicit_instantiation=yes]))
 280     if test x"$stepmake_cv_need_explicit_instantiation"x = x"yes"x; then
 281         AC_DEFINE(NEED_EXPLICIT_INSTANTIATION)
 282     fi
 283 ])
 284
 285
 286 AC_DEFUN(STEPMAKE_DATADIR, [
 287     if test "$datadir" = "\${prefix}/share"; then
 288             datadir='${prefix}/share'
 289     fi
 290     presome=${prefix}
 291     if test "$prefix" = "NONE"; then
 292         presome=${ac_default_prefix}
 293     fi
 294
 295     build_package_datadir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/share/$package
 296
 297     DATADIR=`echo ${datadir} | sed "s!\\\${datarootdir}!${prefix}/share!"`
 298     DATADIR=`echo ${DATADIR} | sed "s!\\\${prefix}!$presome!"`
 299     BUILD_PACKAGE_DATADIR=`echo ${build_package_datadir} | sed "s!\\\${prefix}!$presome!"`
 300
 301     AC_SUBST(datadir)
 302     AC_SUBST(datarootdir)
 303     AC_SUBST(build_package_datadir)
 304     AC_DEFINE_UNQUOTED(DATADIR, ["${DATADIR}"])
 305     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_DATADIR, ["${BUILD_PACKAGE_DATADIR}"])
 306 ])
 307
 308 ## ugh: cut & paste programming from datadir.
 309 AC_DEFUN(STEPMAKE_LIBDIR, [
 310
 311     if test "$libdir" = "\${exec_prefix}/lib"; then
 312         libdir='${exec_prefix}/lib'
 313     fi
 314     presome=$exec_prefix
 315     build_package_libdir=$ugh_ugh_autoconf250_builddir/out$CONFIGSUFFIX/lib/$package
 316
 317     LIBDIR=`echo ${libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 318     BUILD_PACKAGE_LIBDIR=`echo ${build_package_libdir} | sed "s!\\\${exec_prefix}!$presome!"`
 319
 320     AC_SUBST(libdir)
 321     AC_SUBST(build_package_libdir)
 322     AC_DEFINE_UNQUOTED(LIBDIR, ["${LIBDIR}"])
 323     AC_DEFINE_UNQUOTED(BUILD_PACKAGE_LIBDIR, ["${BUILD_PACKAGE_LIBDIR}"])
 324 ])
 325
 326
 327 AC_DEFUN(STEPMAKE_PREFIX_EXPAND_FIXUP, [
 328     # undo expanding of explicit --infodir=/usr/share
 329     # to ease install-time override with prefix=...
 330     strip=`echo $includedir | eval sed s@^$prefix@@`
 331     if test "$includedir" = "`eval echo $prefix$strip`"; then
 332             includedir='${prefix}'$strip''
 333     fi
 334     strip=`echo $libdir | eval sed s@^$exec_prefix@@`
 335     if test "$libdir" = "`eval echo $exec_prefix$strip`"; then
 336             libdir='${exec_prefix}'$strip''
 337     fi
 338     strip=`echo $infodir | eval sed s@^$datarootdir@@`
 339     if test "$infodir" = "`eval echo $datarootdir$strip`"; then
 340             infodir='${datarootdir}'$strip''
 341     fi
 342     strip=`echo $mandir | eval sed s@^$datarootdir@@`
 343     if test "$mandir" = "`eval echo $datarootdir$strip`"; then
 344             mandir='${datarootdir}'$strip''
 345     fi
 346 ])
 347
 348
 349 AC_DEFUN(STEPMAKE_END, [
 350     STEPMAKE_PREFIX_EXPAND_FIXUP
 351
 352     AC_SUBST(OPTIONAL)
 353     AC_SUBST(REQUIRED)
 354
 355     AC_CONFIG_FILES([$CONFIGFILE.make:config.make.in])
 356     AC_OUTPUT
 357
 358     if test -n "$OPTIONAL"; then
 359         echo
 360         echo "WARNING: Please consider installing optional programs: $OPTIONAL"
 361     fi
 362
 363     if test -n "$REQUIRED"; then
 364         echo
 365         echo "ERROR: Please install required programs: $REQUIRED"
 366     fi
 367
 368     if test -n "$UNSUPPORTED"; then
 369         echo
 370         echo "ERROR: Please use older version of programs: $UNSUPPORTED"
 371     fi
 372
 373     if test -n "$OPTIONAL$REQUIRED$UNSUPPORTED"; then
 374         echo
 375         echo "See INSTALL.txt for more information on how to build $PACKAGE_NAME"
 376         if test -f config.cache ; then
 377             echo "Remove config.cache before rerunning ./configure"
 378         fi
 379     fi
 380
 381     if test -n "$REQUIRED$UNSUPPORTED"; then
 382         rm -f $srcdir/GNUmakefile
 383         exit 1
 384     fi
 385
 386     # regular in-place build
 387     # test for srcdir_build = yes ?
 388     if test "$srcdir_build" = "yes"; then
 389         rm -f $srcdir/GNUmakefile
 390         cp $srcdir/GNUmakefile.in $srcdir/GNUmakefile
 391         chmod 444 $srcdir/GNUmakefile
 392     else
 393         if test -f $srcdir/GNUmakefile; then
 394             cat <<EOF
 395 Source directory already configured.  Please clean the source directory
 396
 397      make -C $srcdir distclean
 398
 399 and rerun configure.
 400 EOF
 401             exit 2
 402         fi
 403
 404         for d in 2 3 4 ; do
 405             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name GNUmakefile`; do
 406                 mkdir -p $(dirname $mf)
 407                 cat <<EOF | $PYTHON -  > $mf
 408 print 'depth=' + ('../' * ( $d-1 ) )
 409 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 410 print 'include \$(configure-srcdir)/$mf'
 411 print 'MODULE_INCLUDES += \$(src-dir)/\$(outbase)'
 412 EOF
 413             done
 414             for mf in `cd $srcdir ; find -maxdepth $d -mindepth $d -name '*.make' | grep -v config.make `; do
 415                 mkdir -p $(dirname $mf)
 416                 cat <<EOF | $PYTHON -  > $mf
 417 print 'include \$(depth)/config\$(if \$(conf),-\$(conf),).make'
 418 print 'include \$(configure-srcdir)/$mf'
 419 EOF
 420             done
 421         done
 422
 423
 424         cat <<EOF > GNUmakefile
 425 depth = ./
 426 include config\$(if \$(conf),-\$(conf),).make
 427 include \$(configure-srcdir)/GNUmakefile.in
 428 EOF
 429         AC_SUBST(VPATH)
 430     fi
 431 ])
 432
 433
 434 AC_DEFUN(STEPMAKE_FLEX, [
 435     # ugh, automake: we want (and check for) flex
 436     # AC_PROG_LEX
 437     # urg: automake 1.3: hope this doesn't break 1.2 ac_cv_pro_lex_root hack...
 438
 439     # AC_PROG_LEX()
 440     # ugh, ugh
 441     ac_cv_prog_lex_root=lex.yy
 442     STEPMAKE_PROGS(FLEX, flex, $1)
 443 ])
 444
 445
 446 AC_DEFUN(STEPMAKE_FLEXLEXER, [
 447     AC_CHECK_HEADERS([FlexLexer.h],[true],[false])
 448     if test $? -ne 0; then
 449         warn='FlexLexer.h (flex package)'
 450         STEPMAKE_ADD_ENTRY($1, $warn)
 451     fi
 452     # check for yyFlexLexer.yy_current_buffer,
 453     # in 2.5.4 <= flex < 2.5.29
 454     AC_CACHE_CHECK([for yyFlexLexer.yy_current_buffer],
 455         [stepmake_cv_flexlexer_yy_current_buffer],
 456         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 457 using namespace std;
 458 #include <FlexLexer.h>
 459 class yy_flex_lexer: public yyFlexLexer
 460 {
 461   public:
 462     yy_flex_lexer ()
 463     {
 464       yy_current_buffer = 0;
 465     }
 466 };
 467 ]])],
 468             [stepmake_cv_flexlexer_yy_current_buffer=yes],
 469             [stepmake_cv_flexlexer_yy_current_buffer=no]))
 470     if test $stepmake_cv_flexlexer_yy_current_buffer = yes; then
 471         AC_DEFINE(HAVE_FLEXLEXER_YY_CURRENT_BUFFER, 1, [Define to 1 if yyFlexLexer has yy_current_buffer.])
 472     fi
 473 ])
 474
 475
 476
 477 AC_DEFUN(STEPMAKE_FLEXLEXER_LOCATION, [
 478         AC_MSG_CHECKING([FlexLexer.h location])
 479
 480         # ugh.
 481         cat <<EOF > conftest.cc
 482 using namespace std;
 483 #include <FlexLexer.h>
 484 EOF
 485         FLEXLEXER_FILE=`eval $ac_cpp conftest.cc | \
 486           sed 's!# 1 "\(.*FlexLexer.h\)"!@FLEXLEXER@\1@@!g' | grep '@@' | \
 487           sed 's!.*@FLEXLEXER@\(.*\)@@.*$!\1!g' ` 1> /dev/null 2> /dev/null
 488         rm conftest.cc
 489         AC_SUBST(FLEXLEXER_FILE)
 490         AC_MSG_RESULT($FLEXLEXER_FILE)
 491 ])
 492
 493 AC_DEFUN(STEPMAKE_GCC, [
 494     if test "$GCC" = "yes"; then
 495         STEPMAKE_CHECK_VERSION(CC, $1, $2)
 496     else
 497         warn="$CC (Please install *GNU* cc)"
 498         STEPMAKE_ADD_ENTRY($1, $warn)
 499     fi
 500 ])
 501
 502 AC_DEFUN(STEPMAKE_GETTEXT, [
 503     presome=${prefix}
 504     if test "$prefix" = "NONE"; then
 505             presome=${ac_default_prefix}
 506     fi
 507     LOCALEDIR=`echo ${localedir} | sed "s!\\\${prefix}!$presome!"`
 508
 509     AC_SUBST(localedir)
 510     AC_DEFINE_UNQUOTED(LOCALEDIR, ["${LOCALEDIR}"])
 511     AC_CHECK_LIB(intl, gettext)
 512     AC_CHECK_FUNCS(gettext)
 513 ])
 514
 515
 516 AC_DEFUN(STEPMAKE_GUILE, [
 517     STEPMAKE_PATH_PROG(GUILE, guile, $1)
 518 ])
 519
 520
 521 #   STEPMAKE_GUILE_FLAGS --- set flags for compiling and linking with Guile
 522 #
 523 #   This macro runs the guile-config script, installed with Guile,
 524 #   to find out where Guile's header files and libraries are
 525 #   installed.  It sets two variables, marked for substitution, as
 526 #   by AC_SUBST.
 527 #
 528 #     GUILE_CFLAGS --- flags to pass to a C or C++ compiler to build
 529 #             code that uses Guile header files.  This is almost
 530 #             always just a -I flag.
 531 #
 532 #     GUILE_LDFLAGS --- flags to pass to the linker to link a
 533 #             program against Guile.  This includes -lguile for
 534 #             the Guile library itself, any libraries that Guile
 535 #             itself requires (like -lqthreads), and so on.  It may
 536 #             also include a -L flag to tell the compiler where to
 537 #             find the libraries.
 538
 539 AC_DEFUN([STEPMAKE_GUILE_FLAGS], [
 540     exe=`STEPMAKE_GET_EXECUTABLE($guile_config)`
 541     if test -x $exe; then
 542         AC_MSG_CHECKING([guile compile flags])
 543         GUILE_CFLAGS="`$guile_config compile`"
 544         AC_MSG_RESULT($GUILE_CFLAGS)
 545         AC_MSG_CHECKING([guile link flags])
 546         GUILE_LDFLAGS="`$guile_config link`"
 547         AC_MSG_RESULT($GUILE_LDFLAGS)
 548     fi
 549     AC_SUBST(GUILE_CFLAGS)
 550     AC_SUBST(GUILE_LDFLAGS)
 551 ])
 552
 553
 554 AC_DEFUN(STEPMAKE_GUILE_DEVEL, [
 555     ## First, let's just see if we can find Guile at all.
 556     test -n "$target_alias" && target_guile_config=$target_alias-guile-config
 557     test -n "$host_alias" && host_guile_config=$host_alias-guile-config
 558     AC_MSG_CHECKING([for guile-config])
 559     for guile_config in $GUILE_CONFIG $target_guile_config $host_guile_config $build_guile_config guile-config; do
 560         AC_MSG_RESULT([$guile_config])
 561         if ! $guile_config --version > /dev/null 2>&1 ; then
 562             AC_MSG_WARN([cannot execute $guile_config])
 563             AC_MSG_CHECKING([if we are cross compiling])
 564             GUILE_CONFIG='echo no guile-config'
 565         else
 566             GUILE_CONFIG=$guile_config
 567             break
 568         fi
 569     done
 570     STEPMAKE_OPTIONAL_REQUIRED(GUILE_CONFIG, $guile_config, $1)
 571     if test $? -ne 0; then
 572         STEPMAKE_ADD_ENTRY($1, 'guile-config (guile-devel, guile-dev or libguile-dev package)')
 573     fi
 574
 575     STEPMAKE_CHECK_SEARCH_RESULT(GUILE_CONFIG)
 576     # urg.  should test functionality rather than version.
 577     if test $? -eq 0 -a -n "$2"; then
 578         STEPMAKE_CHECK_VERSION(GUILE_CONFIG, $1, $2)
 579     fi
 580
 581     AC_SUBST(GUILE_CONFIG)
 582
 583     guile_version="$ver"
 584     changequote(<<, >>)#dnl
 585     GUILE_MAJOR_VERSION=`expr $guile_version : '\([0-9]*\)'`
 586     GUILE_MINOR_VERSION=`expr $guile_version : '[0-9]*\.\([0-9]*\)'`
 587     GUILE_PATCH_LEVEL=`expr $guile_version : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
 588     changequote([, ])#dnl
 589     STEPMAKE_GUILE_FLAGS
 590     save_CPPFLAGS="$CPPFLAGS"
 591     save_LIBS="$LIBS"
 592     CPPFLAGS="$GUILE_CFLAGS $CPPFLAGS"
 593     LIBS="$GUILE_LDFLAGS $LIBS"
 594     AC_CHECK_HEADERS([libguile.h])
 595     AC_CHECK_LIB(guile, scm_boot_guile)
 596     AC_CHECK_FUNCS(scm_boot_guile,,libguile_b=no)
 597     if test "$libguile_b" = "no"; then
 598             warn='libguile (libguile-dev, guile-devel or guile-dev
 599    package).'
 600             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 601     fi
 602     CPPFLAGS="$save_CPPFLAGS"
 603     LIBS="$save_LIBS"
 604     AC_DEFINE_UNQUOTED(GUILE_MAJOR_VERSION, $GUILE_MAJOR_VERSION)
 605     AC_DEFINE_UNQUOTED(GUILE_MINOR_VERSION, $GUILE_MINOR_VERSION)
 606     AC_DEFINE_UNQUOTED(GUILE_PATCH_LEVEL, $GUILE_PATCH_LEVEL)
 607 ])
 608
 609
 610 AC_DEFUN(STEPMAKE_DLOPEN, [
 611     AC_CHECK_LIB(dl, dlopen)
 612     AC_CHECK_FUNCS(dlopen)
 613 ])
 614
 615 AC_DEFUN(STEPMAKE_GXX, [
 616     if test "$GXX" = "yes"; then
 617         STEPMAKE_CHECK_VERSION(CXX, $1, $2)
 618     else
 619         warn="$CXX (Please install *GNU* c++)"
 620         STEPMAKE_ADD_ENTRY($1, $warn)
 621     fi
 622 ])
 623
 624
 625 AC_DEFUN(STEPMAKE_INIT, [
 626
 627     . $srcdir/VERSION
 628     FULL_VERSION=$MAJOR_VERSION.$MINOR_VERSION.$PATCH_LEVEL
 629     MICRO_VERSION=$PATCH_LEVEL
 630     TOPLEVEL_VERSION=$FULL_VERSION
 631     if test x$MY_PATCH_LEVEL != x; then
 632         FULL_VERSION=$FULL_VERSION.$MY_PATCH_LEVEL
 633     fi
 634     VERSION=$FULL_VERSION
 635     export MAJOR_VERSION MINOR_VERSION PATCH_LEVEL
 636     # urg: don't "fix" this: irix doesn't know about [:lower:] and [:upper:]
 637     changequote(<<, >>)#dnl
 638     PACKAGE=`echo $PACKAGE_NAME | tr '[a-z]' '[A-Z]'`
 639     package=`echo $PACKAGE_NAME | tr '[A-Z]' '[a-z]'`
 640     changequote([, ])#dnl
 641
 642     # No versioning on directory names of sub-packages
 643     # urg, urg
 644     stepmake=${datadir}/stepmake
 645     presome=${prefix}
 646     if test "$prefix" = "NONE"; then
 647             presome=${ac_default_prefix}
 648     fi
 649     stepmake=`echo ${stepmake} | sed "s!\\\${prefix}!$presome!"`
 650
 651     # urg, how is this supposed to work?
 652     if test "$program_prefix" = "NONE"; then
 653           program_prefix=
 654     fi
 655     if test "$program_suffix" = "NONE"; then
 656           program_suffix=
 657     fi
 658
 659     AC_MSG_CHECKING(Package)
 660     if test "$PACKAGE" = "STEPMAKE"; then
 661         AC_MSG_RESULT(Stepmake package!)
 662
 663         AC_MSG_CHECKING(builddir)
 664
 665         ugh_ugh_autoconf250_builddir="`pwd`"
 666
 667         if test "$srcdir" = "."; then
 668             srcdir_build=yes
 669         else
 670             srcdir_build=no
 671             package_builddir="`dirname $ugh_ugh_autoconf250_builddir`"
 672             package_srcdir="`dirname  $srcdir`"
 673         fi
 674         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 675
 676         (cd stepmake 2>/dev/null || mkdir stepmake)
 677         (cd stepmake; rm -f bin; ln -s ../$srcdir/bin .)
 678         stepmake=stepmake
 679     else
 680         AC_MSG_RESULT($PACKAGE)
 681
 682         AC_MSG_CHECKING(builddir)
 683         ugh_ugh_autoconf250_builddir="`pwd`"
 684
 685         here_dir=$(cd . && pwd)
 686         full_src_dir=$(cd $srcdir && pwd)
 687
 688         if test "$full_src_dir" = "$here_dir"; then
 689             srcdir_build=yes
 690         else
 691             srcdir_build=no
 692         fi
 693         AC_MSG_RESULT($ugh_ugh_autoconf250_builddir)
 694
 695         AC_MSG_CHECKING(for stepmake)
 696         # Check for installed stepmake
 697         if test -d $stepmake; then
 698             AC_MSG_RESULT($stepmake)
 699         else
 700             stepmake="`cd $srcdir/stepmake; pwd`"
 701             AC_MSG_RESULT([$srcdir/stepmake  ($datadir/stepmake not found)])
 702         fi
 703     fi
 704
 705     AC_SUBST(ugh_ugh_autoconf250_builddir)
 706
 707     # Use absolute directory for non-srcdir builds, so that build
 708     # dir can be moved.
 709     if test "$srcdir_build" = "no" ;  then
 710         srcdir="`cd $srcdir; pwd`"
 711     fi
 712
 713     AC_SUBST(srcdir)
 714     AC_SUBST(stepmake)
 715     AC_SUBST(package)
 716     AC_SUBST(PACKAGE)
 717     AC_SUBST(PACKAGE_NAME)
 718     AC_SUBST(VERSION)
 719     AC_SUBST(MAJOR_VERSION)
 720     AC_SUBST(MINOR_VERSION)
 721     AC_SUBST(MICRO_VERSION)
 722
 723     # stepmake nonstandard names
 724     AC_SUBST(PATCH_LEVEL)
 725     AC_SUBST(TOPLEVEL_VERSION)
 726
 727     # We don't need the upper case variant,
 728     # so stick to macros are uppercase convention.
 729     # AC_DEFINE_UNQUOTED(package, ["${package}"])
 730     # AC_DEFINE_UNQUOTED(PACKAGE, ["${PACKAGE}"])
 731     AC_DEFINE_UNQUOTED(PACKAGE, ["${package}"])
 732     AC_DEFINE_UNQUOTED(PACKAGE_NAME, ["${PACKAGE_NAME}"])
 733     AC_DEFINE_UNQUOTED(TOPLEVEL_VERSION, ["${FULL_VERSION}"])
 734
 735     if test -z "$package_depth"; then
 736         package_depth="."
 737     else
 738         package_depth="../$package_depth"
 739     fi
 740     export package_depth
 741     AC_SUBST(package_depth)
 742
 743     AUTOGENERATE="This file was automatically generated by configure"
 744     AC_SUBST(AUTOGENERATE)
 745
 746     CONFIGSUFFIX=
 747     AC_ARG_ENABLE(config,
 748     [  --enable-config=CONF    put settings in config-CONF.make and config-CONF.h;
 749                             do `make conf=CONF' to get output in ./out-CONF],
 750     [CONFIGURATION=$enableval])
 751
 752     ##'`#
 753
 754     test -n "$CONFIGURATION" && CONFIGSUFFIX="-$CONFIGURATION"
 755     CONFIGFILE=config$CONFIGSUFFIX
 756     AC_SUBST(CONFIGSUFFIX)
 757
 758     AC_CANONICAL_HOST
 759     STEPMAKE_PROGS(MAKE, gmake make, REQUIRED)
 760     STEPMAKE_PROGS(FIND, find, REQUIRED)
 761
 762     STEPMAKE_PROGS(TAR, tar, REQUIRED)
 763
 764     if test "$(echo 2)" != "2" ||
 765         test "x`uname`" = "xHP-UX"; then
 766         AC_PATH_PROG(KSH, ksh, /bin/ksh)
 767         AC_PATH_PROG(BASH, bash, $KSH)
 768         STEPMAKE_WARN(avoiding buggy /bin/sh)
 769         AC_PATH_PROG(SHELL, bash, $KSH)
 770     else
 771         SHELL=/bin/sh
 772         AC_PATH_PROG(BASH, bash, $SHELL)
 773     fi
 774     AC_SUBST(SHELL)
 775
 776     STEPMAKE_PYTHON(REQUIRED, 1.5)
 777
 778     if expr "$MAKE" : '.*\(echo\)' >/dev/null; then
 779         $MAKE -v 2> /dev/null | grep GNU > /dev/null
 780         if test "$?" = 1; then
 781             warn='make (Please install *GNU* make)'
 782             # STEPMAKE_WARN($warn)
 783             STEPMAKE_ADD_ENTRY(REQUIRED, $warn)
 784         fi
 785     fi
 786
 787     ROOTSEP=':'
 788     DIRSEP='/'
 789     PATHSEP=':'
 790     LN=ln
 791     LN_S='ln -s'
 792     ZIP="zip -r -9"
 793
 794     AC_SUBST(program_prefix)
 795     AC_SUBST(program_suffix)
 796     AC_SUBST(ZIP)
 797     AC_SUBST(LN)
 798     AC_SUBST(LN_S)
 799     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
 800     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
 801     AC_SUBST(DIRSEP)
 802     AC_SUBST(PATHSEP)
 803     AC_SUBST(ROOTSEP)
 804
 805     STEPMAKE_DATADIR
 806     STEPMAKE_LIBDIR
 807 ])
 808
 809
 810 AC_DEFUN(STEPMAKE_LIB, [
 811     STEPMAKE_PROGS(AR, ar, $1)
 812     AC_PROG_RANLIB
 813     STEPMAKE_OPTIONAL_REQUIRED(RANLIB, ranlib, $1)
 814 ])
 815
 816
 817 AC_DEFUN(STEPMAKE_LIBTOOL, [
 818     # libtool.info ...
 819     # **Never** try to set library version numbers so that they correspond
 820     # to the release number of your package.  This is an abuse that only
 821     # fosters misunderstanding of the purpose of library versions.
 822
 823     REVISION=$PATCH_LEVEL
 824     # CURRENT=$MINOR_VERSION
 825     CURRENT=`expr $MINOR_VERSION + 1`
 826     # AGE=`expr $MAJOR_VERSION + 1`
 827     AGE=$MAJOR_VERSION
 828     AC_SUBST(CURRENT)
 829     AC_SUBST(REVISION)
 830     AC_SUBST(AGE)
 831 ])
 832
 833
 834 AC_DEFUN(STEPMAKE_LOCALE, [
 835     lang=English
 836     ALL_LINGUAS="en nl"
 837
 838     # with/enable ??
 839     AC_ARG_WITH(localedir,
 840     [  --with-localedir=DIR    location of locales.  Default: PREFIX/share/locale ],
 841     localedir=$with_localedir,
 842     localedir='${prefix}/share/locale')
 843
 844     AC_ARG_WITH(lang,
 845     [  --with-lang=LANG        use LANG as language to emit messages],
 846     language=$with_lang,
 847     language=English)
 848
 849     AC_MSG_CHECKING(language)
 850     case "$language" in
 851       En* | en* | Am* | am* | US* | us*)
 852             lang=English;;
 853       NL | nl | Du* | du* | Ned* | ned*)
 854             lang=Dutch;;
 855       "")
 856             lang=English;;
 857       *)
 858             lang=unknown;;
 859     esac
 860     AC_MSG_RESULT($lang)
 861
 862     if test "$lang" = "unknown" ; then
 863         STEPMAKE_WARN($language not supported; available are: $ALL_LINGUAS)
 864     fi
 865
 866 ])
 867
 868
 869 AC_DEFUN(STEPMAKE_MAKEINFO, [
 870     STEPMAKE_PROGS(MAKEINFO, makeinfo, $1)
 871 ])
 872
 873
 874 AC_DEFUN(STEPMAKE_MAN, [
 875     STEPMAKE_PROGS(GROFF, groff ditroff, $1)
 876     AC_SUBST(GROFF)
 877     STEPMAKE_PROGS(TROFF, troff, $1)
 878     AC_SUBST(TROFF)
 879     STEPMAKE_PROGS(TBL, tbl, $1)
 880     AC_SUBST(TBL)
 881 ])
 882
 883
 884 AC_DEFUN(STEPMAKE_MSGFMT, [
 885     STEPMAKE_PROGS(MSGFMT, msgfmt, $1)
 886 ])
 887
 888
 889 # Check for program ($2), set full path result to ($1).
 890 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 891 AC_DEFUN(STEPMAKE_PATH_PROG, [
 892     AC_CHECK_PROGS($1, $2, no)
 893     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 894     if test $? -eq 0; then
 895         AC_PATH_PROG($1, $2)
 896         if test -n "$4"; then
 897             STEPMAKE_CHECK_VERSION($1, $3, $4)
 898         fi
 899     fi
 900 ])
 901
 902
 903 # Check for program in set of names ($2), set result to ($1) .
 904 # If missing, add entry to missing-list ($3, one of 'OPTIONAL', 'REQUIRED')
 905 # If exists, and a minimal version ($4) is required
 906 AC_DEFUN(STEPMAKE_PROGS, [
 907     AC_CHECK_PROGS($1, $2, no)
 908     STEPMAKE_OPTIONAL_REQUIRED($1, $2, $3)
 909     if test $? -eq 0 -a -n "$4"; then
 910         STEPMAKE_CHECK_VERSION($1, $3, $4)
 911     fi
 912 ])
 913
 914
 915 AC_DEFUN(STEPMAKE_PERL, [
 916     STEPMAKE_PATH_PROG(PERL, perl, $1)
 917 ])
 918
 919
 920 AC_DEFUN(STEPMAKE_PYTHON, [
 921     unset pv
 922     AC_MSG_CHECKING([for python])
 923     for python in $PYTHON python python2 python2.4 python2.3 python2.2 python2.1 python2.0; do
 924         AC_MSG_RESULT([$python])
 925         if ! $python -V > /dev/null 2>&1 ; then
 926             #AC_MSG_WARN([cannot execute $python])
 927             PYTHON='echo no python'
 928         else
 929             unset pv
 930             STEPMAKE_CHECK_VERSION(python, pv, $2)
 931             if test -z "$pv"; then
 932                 PYTHON=$python
 933                 break
 934             fi
 935         fi
 936     done
 937     if test -n "$pv"; then
 938         STEPMAKE_ADD_ENTRY($1, $pv)
 939     fi
 940     # clear cached value since arg 2 might point us to a new binary
 941     unset ac_cv_path_PYTHON
 942
 943     AC_PATH_PROG(PYTHON, $PYTHON)
 944     AC_SUBST(PYTHON)
 945 ])
 946
 947 AC_DEFUN(STEPMAKE_PYTHON_DEVEL, [
 948     AC_ARG_WITH(python-include,
 949         [  --with-python-include=DIR
 950                           location of the python include dir],[
 951             if test "$withval" = "yes" -o "$withval" = "no"; then
 952                 AC_MSG_WARN(Usage: --with-python-include=includedir)
 953             else
 954                 PYTHON_CFLAGS="-I${withval}"
 955             fi
 956             ])
 957
 958     AC_ARG_WITH(python-lib,
 959         [  --with-python-lib=NAME  name of the python lib],[
 960             if test "$withval" = "yes" -o "$withval" = "no"; then
 961                 AC_MSG_WARN(Usage: --with-python-lib=name)
 962             else
 963                 LDFLAGS="$LDFLAGS -l${withval}"
 964             fi
 965             ])
 966
 967     AC_CHECK_PROGS(PYTHON_CONFIG, python-config, no)
 968
 969     if test -z "$PYTHON_CFLAGS" -a "$PYTHON_CONFIG" != "no"; then
 970         # Clean out junk: http://bugs.python.org/issue3290
 971         # Python headers may need some -f* flags, leave them in.
 972         # We want the sed commands to look like 's/-[WDOm][[:alnum:][:punct:]][[:alnum:][:punct:]]*//g' and 's/-arch [^[:space:]]*//g', but automake eats brackets.
 973         PYTHON_CFLAGS=`$PYTHON_CONFIG --cflags | sed -e 's/-[[WDOm]][[[:alnum:][:punct:]]][[[:alnum:][:punct:]]]*//g' | sed -e 's/-arch @<:@^@<:@:space:@:>@@:>@*//g'`
 974         PYTHON_LDFLAGS=`$PYTHON_CONFIG --ldflags`
 975     fi
 976
 977     if test -z "$PYTHON_CFLAGS" -a "$cross_compiling" = "no"; then
 978         changequote(<<, >>)#dnl
 979         # alternatively, for python >= 2.0
 980         # 'import sys, distutils.sysconfig; sys.stdout.write (distutils.sysconfig.get_python_inc ())'
 981         PYTHON_INCLUDE=`$PYTHON -c 'import sys; sys.stdout.write ("%s/include/python%s" % (sys.prefix, sys.version[:3]))'`
 982         PYTHON_CFLAGS="-I$PYTHON_INCLUDE"
 983         changequote([, ])#dnl
 984     fi
 985
 986     if test -z "$PYTHON_HEADER"; then
 987         CPPFLAGS="$PYTHON_CFLAGS $CPPFLAGS"
 988         AC_CHECK_HEADERS([Python.h],[PYTHON_HEADER=yes])
 989     fi
 990
 991     if test -z "$PYTHON_HEADER"; then
 992         warn="Python.h (python-devel, python-dev or libpython-dev package)"
 993         STEPMAKE_ADD_ENTRY($1, $warn)
 994     fi
 995 ])
 996
 997
 998
 999 AC_DEFUN(STEPMAKE_STL_DATA_METHOD, [
1000     AC_CACHE_CHECK([for stl.data () method],
1001         [stepmake_cv_stl_data_method],
1002         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1003 #include <vector>
1004 using namespace std;
1005 vector <int> v;
1006 void *p = v.data ();
1007 ]])],
1008             [stepmake_cv_stl_data_method=yes],
1009             [stepmake_cv_stl_data_method=no]))
1010     if test $stepmake_cv_stl_data_method = yes; then
1011         AC_DEFINE(HAVE_STL_DATA_METHOD, 1, [define if stl classes have data () method])
1012     fi
1013 ])
1014
1015
1016 AC_DEFUN(STEPMAKE_TEXMF_DIRS, [
1017     # ugh
1018     STEPMAKE_PROGS(KPSEWHICH, kpsewhich, OPTIONAL)
1019 ])
1020
1021 AC_DEFUN(STEPMAKE_TEXMF, [
1022     STEPMAKE_PROGS(METAFONT, mf-nowin mf mfw mfont, $1)
1023     STEPMAKE_PROGS(METAPOST, mpost, $1)
1024
1025     AC_MSG_CHECKING(for working metafont mode)
1026     modelist='ljfour lj4 lj3 lj2 ljet laserjet'
1027     for MFMODE in $modelist; do
1028         $METAFONT -progname=mf "\mode:=$MFMODE; mode_setup; end." > /dev/null 2>&1
1029         if test -f mfput.tfm; then
1030             break;
1031         fi
1032     done
1033     AC_MSG_RESULT($MFMODE)
1034
1035     rm -f mfput.*
1036
1037     AC_SUBST(MFMODE)
1038 ])
1039
1040
1041 AC_DEFUN(STEPMAKE_WARN, [
1042     AC_MSG_WARN($1)
1043     warn_b=yes
1044 ])
1045
1046
1047 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1048 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1049 dnl also defines GSTUFF_PKG_ERRORS on error
1050 AC_DEFUN(PKG_CHECK_MODULES, [
1051   succeeded=no
1052
1053   if test -z "$PKG_CONFIG"; then
1054     AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1055   fi
1056
1057   if test "$PKG_CONFIG" = "no" ; then
1058      echo "*** The pkg-config script could not be found. Make sure it is"
1059      echo "*** in your path, or set the PKG_CONFIG environment variable"
1060      echo "*** to the full path to pkg-config."
1061      echo "*** Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config."
1062   else
1063      PKG_CONFIG_MIN_VERSION=0.9.0
1064      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1065         AC_MSG_CHECKING(for $2)
1066
1067         if $PKG_CONFIG --exists "$2" ; then
1068             AC_MSG_RESULT(yes)
1069             succeeded=yes
1070
1071             AC_MSG_CHECKING($1_CFLAGS)
1072             $1_CFLAGS=`$PKG_CONFIG --cflags "$2"`
1073             AC_MSG_RESULT($$1_CFLAGS)
1074
1075             AC_MSG_CHECKING($1_LIBS)
1076             $1_LIBS=`$PKG_CONFIG --libs "$2"`
1077             AC_MSG_RESULT($$1_LIBS)
1078         else
1079             $1_CFLAGS=""
1080             $1_LIBS=""
1081             ## If we have a custom action on failure, don't print errors, but
1082             ## do set a variable so people can do so.
1083             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1084             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1085         fi
1086
1087         AC_SUBST($1_CFLAGS)
1088         AC_SUBST($1_LIBS)
1089      fi
1090   fi
1091
1092   if test $succeeded = yes; then
1093      ifelse([$3], , :, [$3])
1094   else
1095      ifelse([$4], , AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.]), [$4])
1096   fi
1097 ])
1098
1099 AC_DEFUN(STEPMAKE_FREETYPE2, [
1100     PKG_CHECK_MODULES(FREETYPE2, $1 >= $3, have_freetype2=yes, true)
1101     if test "$have_freetype2" = yes; then
1102         AC_DEFINE(HAVE_FREETYPE2)
1103         save_CPPFLAGS="$CPPFLAGS"
1104         save_LIBS="$LIBS"
1105         CPPFLAGS="$FREETYPE2_CFLAGS $CPPFLAGS"
1106         LIBS="$FREETYPE2_LIBS $LIBS"
1107         AC_SUBST(FREETYPE2_CFLAGS)
1108         AC_SUBST(FREETYPE2_LIBS)
1109         CPPFLAGS="$save_CPPFLAGS"
1110         LIBS="$save_LIBS"
1111     else
1112         # UGR
1113         #r="lib$1-dev or $1-devel"
1114         r="libfreetype6-dev or freetype?-devel"
1115         ver="`pkg-config --modversion $1`"
1116         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1117     fi
1118 ])
1119
1120 AC_DEFUN(STEPMAKE_PANGO, [
1121     PKG_CHECK_MODULES(PANGO, $1 >= $3, have_pango16=yes, true)
1122     if test "$have_pango16" = yes ; then
1123         AC_DEFINE(HAVE_PANGO16)
1124         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1125         save_CPPFLAGS="$CPPFLAGS"
1126         save_LIBS="$LIBS"
1127         CPPFLAGS="$PANGO_CFLAGS $CPPFLAGS"
1128         LIBS="$PANGO_LIBS $LIBS"
1129         AC_CHECK_HEADERS([pango/pangofc-fontmap.h])
1130         AC_CHECK_FUNCS([pango_fc_font_map_add_decoder_find_func])
1131         AC_SUBST(PANGO_CFLAGS)
1132         AC_SUBST(PANGO_LIBS)
1133         CPPFLAGS="$save_CPPFLAGS"
1134         LIBS="$save_LIBS"
1135     else
1136         # UGR
1137         #r="lib$1-dev or $1-devel"
1138         r="libpango1.0-dev or pango1.0-devel"
1139         ver="`pkg-config --modversion $1`"
1140         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1141     fi
1142 ])
1143
1144 AC_DEFUN(STEPMAKE_PANGO_FT2, [
1145     PKG_CHECK_MODULES(PANGO_FT2, $1 >= $3, have_pangoft2=yes, true)
1146     if test "$have_pangoft2" = yes ; then
1147         AC_DEFINE(HAVE_PANGO16)
1148         AC_DEFINE(HAVE_PANGO_FT2)
1149         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1150         save_CPPFLAGS="$CPPFLAGS"
1151         save_LIBS="$LIBS"
1152         CPPFLAGS="$CPPFLAGS $PANGO_FT2_CFLAGS"
1153         LIBS="$PANGO_FT2_LIBS $LIBS"
1154         AC_CHECK_HEADERS([pango/pangoft2.h])
1155         AC_CHECK_FUNCS([pango_ft2_font_map_create_context])
1156         AC_SUBST(PANGO_FT2_CFLAGS)
1157         AC_SUBST(PANGO_FT2_LIBS)
1158         CPPFLAGS="$save_CPPFLAGS"
1159         LIBS="$save_LIBS"
1160     else
1161         # UGR
1162         #r="lib$1-dev or $1-devel"e
1163         r="libpango1.0-dev or pango?-devel"
1164         ver="`pkg-config --modversion $1`"
1165         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1166     fi
1167 ])
1168
1169 AC_DEFUN(STEPMAKE_FONTCONFIG, [
1170     PKG_CHECK_MODULES(FONTCONFIG, $1 >= $3, have_fontconfig=yes, true)
1171     if test "$have_fontconfig" = yes ; then
1172         AC_DEFINE(HAVE_FONTCONFIG)
1173         # Do not pollute user-CPPFLAGS with configure-CPPFLAGS
1174         save_CPPFLAGS="$CPPFLAGS"
1175         save_LIBS="$LIBS"
1176         CPPFLAGS="$FONTCONFIG_CFLAGS $CPPFLAGS"
1177         LIBS="$FONTCONFIG_LIBS $LIBS"
1178         AC_SUBST(FONTCONFIG_CFLAGS)
1179         AC_SUBST(FONTCONFIG_LIBS)
1180         CPPFLAGS="$save_CPPFLAGS"
1181         LIBS="$save_LIBS"
1182     else
1183         r="lib$1-dev or $1-devel"
1184         ver="`pkg-config --modversion $1`"
1185         STEPMAKE_ADD_ENTRY($2, ["$r >= $3 (installed: $ver)"])
1186     fi
1187 ])
1188
1189 AC_DEFUN(STEPMAKE_WINDOWS, [
1190     AC_CYGWIN
1191     AC_MINGW32
1192
1193     if test "$CYGWIN" = "yes"; then
1194         LN_S='cp -r' # Cygwin symbolic links do not work for native apps.
1195         program_suffix=.exe
1196         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1197     elif test "$MINGW32" = "yes"; then
1198         LN='cp -r'
1199         LN_S='cp -r'
1200         program_suffix=.exe
1201         INSTALL="\$(SHELL) \$(stepdir)/../bin/install-dot-exe.sh -c"
1202         PATHSEP=';'
1203     fi
1204
1205     AC_SUBST(LN)
1206     AC_SUBST(LN_S)
1207     AC_DEFINE_UNQUOTED(DIRSEP, ['${DIRSEP}'])
1208     AC_DEFINE_UNQUOTED(PATHSEP, ['${PATHSEP}'])
1209     AC_SUBST(DIRSEP)
1210     AC_SUBST(PATHSEP)
1211     AC_SUBST(program_suffix)
1212
1213     AC_MSG_CHECKING([for some flavor of Windows])
1214     if test "$CYGWIN$MINGW32" = "nono"; then
1215         PLATFORM_WINDOWS=no
1216     else
1217         PLATFORM_WINDOWS=yes
1218     fi
1219     AC_MSG_RESULT([$PLATFORM_WINDOWS])
1220     AC_SUBST(PLATFORM_WINDOWS)
1221     STEPMAKE_PROGS(WINDRES, $target-windres windres, x)
1222     AC_SUBST(WINDRES)
1223 ])