scm/parser-ly-from-scheme.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 2004--2011  Nicolas Sceaux  <nicolas.sceaux@free.fr>
   4 ;;;;           Jan Nieuwenhuizen <janneke@gnu.org>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 (define-public (read-lily-expression chr port)
  20   "Read a lilypond music expression enclosed within @code{#@{} and @code{#@}}
  21 from @var{port} and return the corresponding Scheme music expression.
  22 @samp{$} and @samp{#} introduce immediate and normal Scheme forms."
  23   (let* ((closures '())
  24          (filename (port-filename port))
  25          (line (port-line port))
  26          (lily-string (call-with-output-string
  27                        (lambda (out)
  28                          (let ((copycat
  29                                 (make-soft-port
  30                                  (vector #f #f #f
  31                                          (lambda ()
  32                                            (let ((x (read-char port)))
  33                                              (write-char x out)
  34                                              x)) #f)
  35                                  "r")))
  36                            (do ((c (read-char port) (read-char port)))
  37                                ((and (char=? c #\#)
  38                                      (char=? (peek-char port) #\}))
  39                                 ;; we stop when #} is encountered
  40                                 (read-char port))
  41                              (write-char c out)
  42                              ;; a #scheme or $scheme expression
  43                              (if (or (char=? c #\#) (char=? c #\$))
  44                                  (let ((p (ftell out)))
  45                                    (set! closures
  46                                          (cons (cons p (read copycat))
  47                                                closures))))))))))
  48     `(let* ((clone
  49              (ly:parser-clone parser (list ,@(map (lambda (c)
  50                                                     `(cons ,(car c)
  51                                                            (lambda () ,(cdr c))))
  52                                                   (reverse! closures)))))
  53             (result (ly:parse-string-expression clone ,lily-string
  54                                                 ,filename
  55                                                 ,line)))
  56        (if (ly:parser-has-error? clone)
  57            (ly:parser-error parser (_ "error in #{ ... #}")))
  58        result)))
  59
  60 (read-hash-extend #\{ read-lily-expression)