scm/page-layout.scm

   1 ;;;; page-layout.scm -- page layout functions
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 (define (ly:modules-lookup modules sym)
   8   (let ((v (module-variable (car modules) sym)))
   9     (if (and v (variable-bound? v) (variable-ref v))
  10         (variable-ref v)
  11         (if (module? (cdr modules)) (ly:modules-lookup (cdr modules) sym)))))
  12
  13 (define (page-properties paper)
  14   (list (append `((linewidth . ,(ly:paper-get-number
  15                                  paper 'linewidth)))
  16                 (ly:paper-lookup paper 'text-font-defaults))))
  17
  18 (define-public (book-title paper scopes)
  19   "Generate book title from header strings."
  20
  21   (define (get sym)
  22     (let ((x (ly:modules-lookup scopes sym)))
  23       (if (and x (not (unspecified? x))) x "")))
  24
  25   (let ((props (page-properties paper)))
  26
  27     (interpret-markup
  28      paper props
  29      (markup
  30       #:column
  31       (#:override '(baseline-skip . 4)
  32       #:column
  33       (#:fill-line
  34        (#:normalsize (get 'dedication))
  35        #:fill-line
  36        (#:huge #:bigger #:bigger #:bigger #:bigger #:bold (get 'title))
  37        #:override '(baseline-skip . 3)
  38        #:column
  39        (#:fill-line
  40         (#:large #:bigger #:bigger #:bold (get 'subtitle))
  41         #:fill-line (#:bigger #:bigger #:bold (get 'subsubtitle)))
  42        #:override '(baseline-skip . 5)
  43        #:column ("")
  44        #:override '(baseline-skip . 2.5)
  45        #:column
  46        (#:fill-line
  47         (#:bigger (get 'poet) #:large #:bigger #:caps (get 'composer))
  48         #:fill-line (#:bigger (get 'texttranslator) #:bigger (get 'opus))
  49         #:fill-line
  50         (#:bigger (get 'meter) #:bigger (get 'arranger))
  51         ""
  52         #:fill-line (#:large #:bigger (get 'instrument))
  53         " "
  54         #:fill-line (#:large #:bigger #:caps (get 'piece) ""))))))))
  55
  56 (define-public (user-title paper markup)
  57   "Generate book title from header markup."
  58   (if (markup? markup)
  59       (let ((props (page-properties paper))
  60             (baseline-skip (chain-assoc-get 'baseline-skip props 2)) )
  61         (stack-lines DOWN 0 BASELINE-SKIP
  62                      (list (interpret-markup paper props markup))))))
  63
  64 (define-public (score-title paper scopes)
  65   "Generate score title from header strings."
  66
  67   (define (get sym)
  68     (let ((x (ly:modules-lookup scopes sym)))
  69       (if (and x (not (unspecified? x))) x "")))
  70
  71   (let ((props (page-properties paper)))
  72
  73     (interpret-markup
  74      paper props
  75      (markup
  76       #:column
  77       (#:override '(baseline-skip . 4)
  78       #:column
  79       (#:fill-line
  80        ("" (get 'opus))
  81        #:fill-line (#:large #:bigger #:caps (get 'piece) "")))))))
  82
  83 (define-public (make-header paper page-number)
  84   (let ((props (page-properties paper) ))
  85     (interpret-markup paper props
  86                       (markup #:fill-line
  87                               ("" #:bold (number->string page-number))))))
  88
  89 (define-public (make-footer paper page-number)
  90   (let ((props (page-properties paper)))
  91
  92     (interpret-markup paper props
  93                     (markup #:fill-line ("" (number->string page-number))))))
  94
  95
  96 (define TAGLINE
  97   (string-append "Engraved by LilyPond (version " (lilypond-version) ")"))
  98
  99 (define-public (make-tagline paper scopes)
 100   (let* ((props (page-properties paper))
 101          (tagline-var (ly:modules-lookup scopes 'tagline))
 102          (tagline (if (markup? tagline-var) tagline-var TAGLINE)))
 103
 104     (cond ((string? tagline)
 105            (if (not (equal? tagline ""))
 106                (interpret-markup paper props
 107                                  (markup #:fill-line (tagline "")))))
 108           ((markup? tagline) (interpret-markup paper props tagline)))))
 109
 110 (define-public (make-copyright paper scopes)
 111   (let ((props (page-properties paper))
 112         (copyright (ly:modules-lookup scopes 'copyright)))
 113
 114     (cond ((string? copyright)
 115            (if (not (equal? copyright ""))
 116                (interpret-markup paper props
 117                                  (markup #:fill-line (copyright "")))))
 118           ((markup? copyright) (interpret-markup paper props copyright)))))
 119
 120
 121 ;;; optimal page breaking
 122
 123 ;;; This is not optimal page breaking, this is optimal distribution of
 124 ;;; lines over pages; line breaks are a given.
 125
 126 ;;; TODO:
 127 ;;;    - user tweaking:
 128 ;;;       + \pagebreak, \nopagebreak
 129 ;;;       + #pages?
 130 ;;;    - short circut SCORE=-1 (dismiss path)
 131 ;;;    - density scoring
 132
 133
 134 (use-modules (oop goops describe))
 135
 136 (define-class <break-node> ()
 137   (prev #:init-value '() #:accessor node-prev #:init-keyword #:prev)
 138   (line #:init-value 'barf #:accessor node-line #:init-keyword #:line)
 139   (page #:init-value 0 #:accessor node-page #:init-keyword #:page)
 140   (score #:init-value 0 #:accessor node-score #:init-keyword #:score)
 141   (height #:init-value 0 #:accessor node-height #:init-keyword #:score))
 142
 143 (define INFINITY 1e9)
 144
 145 (define (line-number line)
 146   (if (null? line) 0
 147       (ly:paper-line-number line)))
 148
 149 (define (line-height line)
 150   (if (null? line) 0
 151       (ly:paper-line-height line)))
 152
 153 (define (node-line-number node)
 154   (if (null? node) 0
 155       (line-number (node-line node))))
 156
 157 (define (node-break-score node)
 158   (let ((line (node-line node)))
 159     (if (null? line) 0
 160         (ly:paper-line-break-score line))))
 161
 162 (define (make-node prev line page score)
 163   (make <break-node> #:prev prev #:line line #:page page #:score score))
 164
 165 (define MAX-CRAMP 0.05)
 166
 167 (define-public (ly:optimal-page-breaks lines book-height text-height
 168                                        first-diff last-diff)
 169
 170   ;; FIXME: may need some tweaking: square, cubic
 171   (define (height-score available used)
 172     (let* ((empty (- available used))
 173            (norm-empty (* empty (/ 100 available))))
 174       (if (< norm-empty 0)
 175           (if (> (* -1 (/ empty available)) MAX-CRAMP)
 176               ;; cannot fill more than MAX-CRAMP
 177               -1
 178               ;; overfull page is still worse by a power
 179               (* -1 norm-empty norm-empty norm-empty))
 180            (* norm-empty norm-empty))))
 181
 182   (define (page-height page-number page-count)
 183     (let ((h text-height))
 184       (if (= page-number 1)
 185           (set! h (+ h first-diff)))
 186       (if (= page-number page-count)
 187           ;;(> page-number (/ book-height text-height))
 188        (set! h (+ h last-diff)))
 189       h))
 190
 191   (define (cumulative-height lines)
 192     (apply + (map line-height lines)))
 193
 194   (define (get-path node)
 195     (if (null? node)
 196         '()
 197         (cons node (get-path (node-prev node)))))
 198
 199   (define (add-scores . lst)
 200     (if (null? (filter (lambda (x) (> 0 x)) lst))
 201         (apply + lst)
 202         -1))
 203
 204   (define (density-variance nodes)
 205     (define (sqr x) (* x x))
 206     (define (density node)
 207       (let ((p (page-height (node-page node) (node-page (car nodes))))
 208             (h (node-height node)))
 209         (if (and p h) (* (- p h) (/ h 100)) 0)))
 210     (let* ((densities (map density nodes))
 211            (mean (/ (apply + densities) (length densities)))
 212            (diff (map (lambda (x) (- x mean)) densities))
 213            (var (map sqr diff)))
 214       (if #f
 215           (begin
 216             (format (current-error-port) "\nDENSITIES")
 217             (map describe nodes)
 218             (format (current-error-port) "densities: ~S\n" densities)
 219             (format (current-error-port) "mean: ~S\n" mean)
 220             (format (current-error-port) "diff: ~S\n" diff)
 221             (format (current-error-port) "density-var: ~S\n" var)))
 222       (apply + var)))
 223
 224   (define (walk-paths best node lines nodes paths)
 225     (let* ((height (cumulative-height lines))
 226            (next-page (+ (if (null? paths) 0 (node-page (car paths))) 1))
 227            (page (page-height (node-page node) next-page)))
 228       (set! (node-height node) height)
 229       (let* ((break-score (node-break-score node))
 230              (density-score (if (null? paths) 0
 231                                 (* 0 (density-variance
 232                                       (get-path (car paths))))))
 233              (page-score (height-score page height))
 234              (this-score (add-scores page-score break-score density-score))
 235              (path-score (if (null? paths) 0 (node-score (car paths))))
 236              (score (add-scores path-score this-score)))
 237
 238         (if (and (>= score 0)
 239                  (not (null? lines))
 240                  (or (< score (node-score best))
 241                      (= (node-score best) -1)))
 242             (begin
 243               (set! (node-score best) score)
 244               (set! (node-page best) next-page)
 245               (set! (node-height best) height)
 246               (set! (node-prev best) node)))
 247
 248         (if (null? nodes)
 249             best
 250             (walk-paths best (car paths)
 251                         (cons (node-line node) lines)
 252                         (cdr nodes) (cdr paths))))))
 253
 254   (define (walk-lines lines nodes paths)
 255     (if (null? (cdr lines))
 256         paths
 257         (let* ((prev (node-prev (car nodes)))
 258                (this (make-node prev (car lines) 0 INFINITY))
 259                (next (make-node this (cadr lines) 0 0)))
 260           (let ((break (walk-paths this (car nodes) '() (cdr nodes) paths)))
 261             (walk-lines (cdr lines) (cons next nodes) (cons break paths))))))
 262
 263   (let* ((dummy (make-node '() '() 0 0))
 264          (this (make-node dummy (car lines) 0 0))
 265          (result (walk-lines lines (list this dummy) (list dummy)))
 266          (path (get-path (car result)))
 267          ;; CDR: junk dummy node
 268          (breaks (cdr (reverse (map node-line-number path)))))
 269
 270     (format (current-error-port) "ESTIMATE: ~S\n"
 271             (/ book-height text-height))
 272     (format (current-error-port) "breaks: ~S\n" breaks)
 273     (force-output (current-error-port))
 274     (list->vector breaks)))