scm/output-ps.scm

   1 ;;;; output-ps.scm -- implement Scheme output routines for PostScript
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c)  1998--2004 Jan Nieuwenhuizen <janneke@gnu.org>
   6 ;;;;                 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   7
   8 ;;;; Note: currently misused as testbed for titles with markup, see
   9 ;;;;       input/test/title-markup.ly
  10 ;;;;
  11 ;;;; TODO:
  12 ;;;;   * papersize in header
  13 ;;;;   * special characters, encoding.
  14 ;;;;     + implement encoding switch (switches?  input/output??),
  15 ;;;;     + move encoding definitions to ENCODING.ps files, or
  16 ;;;;     + find out which program's PS(?) encoding code we can use?
  17 ;;;;   * text setting, kerning.
  18 ;;;;   * document output-interface
  19
  20 (debug-enable 'backtrace)
  21
  22 (define-module (scm output-ps)
  23   #:re-export (quote)
  24   #:export (define-fonts
  25              unknown
  26              output-paper-def
  27              output-scopes
  28              select-font
  29              blank
  30              dot
  31              beam
  32              bracket
  33              dashed-slur
  34              char
  35              dashed-line
  36              zigzag-line
  37              symmetric-x-triangle
  38              ez-ball
  39              comment
  40              end-output
  41              experimental-on
  42              repeat-slash
  43              header-end
  44              header
  45              placebox
  46              bezier-sandwich
  47              start-system
  48              stop-system
  49              stop-last-system
  50              horizontal-line
  51              filledbox
  52              round-filled-box
  53              text
  54              tuplet
  55              polygon
  56              draw-line
  57              between-system-string
  58              define-origin
  59              no-origin
  60              start-page
  61              stop-page
  62              )
  63 )
  64 (use-modules (guile)
  65              (ice-9 regex)
  66              (srfi srfi-13)
  67              (lily))
  68
  69 ;;; Global vars
  70 ;; alist containing fontname -> fontcommand assoc (both strings)
  71 (define page-count 0)
  72 (define page-number 0)
  73 (define font-name-alist '())
  74
  75 ;; /lilypondpaperoutputscale 1.75729901757299 def
  76 ;;/lily-output-units 2.83464  def  %% milimeter
  77 ;;/output-scale lilypondpaperoutputscale lily-output-units mul def
  78 ;;
  79 ;; output-scale = 1.75729901757299 * 2.83464 = 4.9813100871731003736
  80
  81 (define OUTPUT-SCALE 4.98)
  82 (define TOP-MARGIN 0)
  83
  84 ;;; helper functions, not part of output interface
  85 (define (escape-parentheses s)
  86   (regexp-substitute/global #f "(^|[^\\])([\\(\\)])" s 'pre 1 "\\" 2 'post))
  87
  88 (define (offset-add a b)
  89   (cons (+ (car a) (car b))
  90         (+ (cdr a) (cdr b))))
  91
  92 ;; WIP
  93 (define font-encoding-alist
  94   '(("ecrm12" . "ISOLatin1Encoding")
  95     ("ecmb12" . "ISOLatin1Encoding")))
  96
  97 (define (ps-encoding text)
  98   (escape-parentheses text))
  99
 100 ;; FIXME: lily-def
 101 (define (ps-string-def prefix key val)
 102   (string-append "/" prefix (symbol->string key) " ("
 103                  (escape-parentheses val)
 104                  ") def\n"))
 105
 106 (define (ps-number-def prefix key val)
 107   (let ((s (if (integer? val)
 108                (ly:number->string val)
 109                (ly:number->string (exact->inexact val)))))
 110     (string-append "/" prefix (symbol->string key) " " s " def\n")))
 111
 112 (define (tex-font? fontname)
 113   (equal? (substring fontname 0 2) "cm"))
 114
 115
 116 ;;;
 117 ;;; Lily output interface, PostScript implementation --- cleanup and docme
 118 ;;;
 119
 120 ;;; Output-interface functions
 121 (define (beam width slope thick blot)
 122   (string-append
 123    (ly:numbers->string (list slope width thick blot)) " draw_beam" ))
 124
 125 ;; two beziers
 126 (define (bezier-sandwich l thick)
 127   (string-append
 128    (string-join (map ly:number-pair->string l) " ")
 129    " "
 130    (ly:number->string thick)
 131    " draw_bezier_sandwich"))
 132
 133 (define (bracket arch_angle arch_width arch_height  height arch_thick thick)
 134   (string-append
 135    (ly:numbers->string
 136     (list arch_angle arch_width arch_height height arch_thick thick))
 137    " draw_bracket"))
 138
 139 (define (char i)
 140   (string-append
 141    "(\\" (ly:inexact->string i 8) ") show" ))
 142
 143 (define (comment s)
 144   (string-append "% " s "\n"))
 145
 146 (define (dashed-line thick on off dx dy)
 147   (string-append
 148    (ly:number->string dx)
 149    " "
 150    (ly:number->string dy)
 151    " "
 152    (ly:number->string thick)
 153    " [ "
 154    (ly:number->string on)
 155    " "
 156    (ly:number->string off)
 157    " ] 0 draw_dashed_line"))
 158
 159 ;; what the heck is this interface ?
 160 (define (dashed-slur thick dash l)
 161   (string-append
 162    (string-join (map ly:number-pair->string l) " ")
 163    " "
 164    (ly:number->string thick)
 165    " [ "
 166    (ly:number->string dash)
 167    " "
 168    ;;UGH.  10 ?
 169    (ly:number->string (* 10 thick))
 170    " ] 0 draw_dashed_slur"))
 171
 172 (define (define-fonts internal-external-name-mag-pairs)
 173
 174   (define (fontname->designsize fontname)
 175     (let ((i (string-index fontname char-numeric?)))
 176       (string->number (substring fontname i))))
 177
 178   (define (define-font command fontname scaling)
 179     (string-append
 180      "/" command " { /" fontname " findfont "
 181      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
 182
 183   (define (reencode-font raw encoding command)
 184     (string-append
 185      raw " " encoding " /" command " reencode-font\n"
 186      "/" command "{ /" command " findfont 1 scalefont } bind def\n"))
 187
 188   ;; frobnicate NAME to jibe with external definitions.
 189   (define (possibly-mangle-fontname fontname)
 190     (cond
 191      ((tex-font? fontname)
 192       ;; FIXME: we need proper Fontmap for CM fonts, like so:
 193       ;; /CMR10 (cmr10.pfb);
 194       ;; (string-upcase fontname)
 195       (string-append fontname ".pfb"))
 196      ((or (equal? (substring fontname 0 4) "feta")
 197           (equal? (substring fontname 0 4) "parm"))
 198       (regexp-substitute/global
 199        #f "(feta|parmesan)([a-z-]*)([0-9]+)"
 200        fontname 'pre "GNU-LilyPond-" 1 2 "-" 3 'post))
 201      (else fontname)))
 202
 203   ;;  (define (font-load-command name-mag command)
 204   (define (font-load-command lst)
 205     (let* ((key-name-size (car lst))
 206            (value (cdr lst))
 207            (value-name-size (car value))
 208            (command (cdr value))
 209            (fontname (car value-name-size))
 210            (mangled (possibly-mangle-fontname fontname))
 211            (encoding (assoc-get fontname font-encoding-alist))
 212            (designsize (fontname->designsize fontname))
 213            (fontsize (cdr value-name-size))
 214            (scaling (* fontsize designsize)))
 215
 216       (if
 217        #f
 218        (begin
 219          (newline)
 220          (format (current-error-port) "key-name-size ~S\n" key-name-size)
 221          (format (current-error-port) "value ~S\n" value)
 222          (format (current-error-port) "value-name-size ~S\n" value-name-size)
 223          (format (current-error-port) "command ~S\n" command)
 224          (format (current-error-port) "designsize ~S\n" designsize)
 225          (format (current-error-port) "fontname ~S\n" fontname)
 226          (format (current-error-port) "mangled ~S\n" mangled)
 227          (format (current-error-port) "fontsize ~S\n" fontsize)
 228          (format (current-error-port) "scaling ~S\n" scaling)))
 229
 230       (if encoding
 231           ;; FIXME: should rather tag encoded font
 232           (let ((raw (string-append command "-raw")))
 233             (string-append
 234              (define-font raw mangled scaling)
 235              (reencode-font raw encoding command)))
 236           (define-font command mangled scaling))))
 237
 238   (define (ps-encoded-fontswitch name-mag-pair)
 239     (let* ((key (car name-mag-pair))
 240            (value (cdr name-mag-pair))
 241            (fontname (car value))
 242            (scaling (cdr value)))
 243       (cons key (cons value
 244                       (string-append
 245                        "lilyfont" fontname "-" (ly:number->string scaling))))))
 246
 247   (set! font-name-alist
 248         (map ps-encoded-fontswitch internal-external-name-mag-pairs))
 249   (apply string-append (map font-load-command font-name-alist)))
 250
 251 (define (define-origin file line col) "")
 252
 253 (define (dot x y radius)
 254   (string-append
 255    " "
 256    (ly:numbers->string
 257     (list x y radius)) " draw_dot"))
 258
 259 (define (draw-line thick x1 y1 x2 y2)
 260   (string-append
 261    "1 setlinecap 1 setlinejoin "
 262    (ly:number->string thick) " setlinewidth "
 263    (ly:number->string x1) " "
 264    (ly:number->string y1) " moveto "
 265    (ly:number->string x2) " "
 266    (ly:number->string y2) " lineto stroke"))
 267
 268 (define (end-output)
 269   "\nend-lilypond-output\n")
 270
 271 (define (ez-ball ch letter-col ball-col)
 272   (string-append
 273    " (" ch ") "
 274    (ly:numbers->string (list letter-col ball-col))
 275    " /Helvetica-Bold " ;; ugh
 276    " draw_ez_ball"))
 277
 278 (define (filledbox breapth width depth height)
 279   (string-append (ly:numbers->string (list breapth width depth height))
 280                  " draw_box"))
 281
 282 (define (fontify name-mag-pair exp)
 283
 284   (define (select-font name-mag-pair)
 285     (let ((c (assoc name-mag-pair font-name-alist)))
 286
 287       (if c
 288           (string-append (cddr c) " setfont ")
 289           (begin
 290             (ly:warn
 291              (format "Programming error: No such font: ~S" name-mag-pair))
 292             ""))))
 293
 294   (string-append (select-font name-mag-pair) exp))
 295
 296 (define (header creator time-stamp page-count-)
 297   (set! page-count page-count-)
 298   (set! page-number 0)
 299   (string-append
 300    "%!PS-Adobe-3.0\n"
 301    "%%Creator: " creator " " time-stamp "\n"
 302    "%%Pages: " (number->string page-count) "\n"
 303    "%%PageOrder: Ascend\n"
 304    ;; FIXME: TODO get from paper
 305    ;; "%%DocumentPaperSizes: a6\n"
 306    ;;(string-append "GNU LilyPond (" (lilypond-version) "), ")
 307    ;;      (strftime "%c" (localtime (current-time))))
 308    ;; FIXME: duplicated in every backend
 309    (ps-string-def
 310     "lilypond" 'tagline
 311     (string-append "Engraved by LilyPond (version " (lilypond-version) ")"))))
 312
 313 (define (header-end)
 314   (string-append
 315    (ly:gulp-file "lilyponddefs.ps")
 316    (ly:gulp-file "music-drawing-routines.ps")))
 317
 318 (define (horizontal-line x1 x2 th)
 319   (draw-line th x1  0 x2 0))
 320
 321 (define (lily-def key val)
 322   (let ((prefix "lilypondpaper"))
 323     (if (string=?
 324          (substring key 0 (min (string-length prefix) (string-length key)))
 325          prefix)
 326         (string-append "/" key " {" val "} bind def\n")
 327         (string-append "/" key " (" val ") def\n"))))
 328
 329 (define (no-origin) "")
 330
 331 ;; FIXME: duplictates output-scopes, duplicated in other backends
 332 ;; FIXME: silly interface name
 333 (define (output-paper-def pd)
 334   (let ((prefix "lilypondpaper"))
 335
 336     (define (scope-entry->string key var)
 337       (let ((val (variable-ref var)))
 338         (cond
 339          ((string? val) (ps-string-def prefix key val))
 340          ((number? val) (ps-number-def prefix key val))
 341          (else ""))))
 342
 343     (apply
 344      string-append
 345      (module-map scope-entry->string (ly:output-def-scope pd)))))
 346
 347 ;; FIXME: duplicated in other output backends
 348 ;; FIXME: silly interface name
 349 (define (output-scopes paper scopes fields basename)
 350   (let ((prefix "lilypond"))
 351
 352     ;; FIXME: duplicates output-paper's scope-entry->string, mostly
 353     (define (scope-entry->string key var)
 354       (if (variable-bound? var)
 355           (let ((val (variable-ref var)))
 356             (if (and (memq key fields) (string? val))
 357                 (header-to-file basename key val))
 358             (cond
 359              ((string? val) (ps-string-def prefix key val))
 360              ((number? val) (ps-number-def prefix key val))
 361              (else "")))
 362           ""))
 363
 364     (define (output-scope scope)
 365       (apply string-append (module-map scope-entry->string scope)))
 366
 367     (string-append (apply string-append (map output-scope scopes)))))
 368
 369 ;; hmm, looks like recursing call is always last statement, does guile
 370 ;; think so too?
 371 (define (output-stencil port expr offset)
 372   (if (pair? expr)
 373       (let ((head (car expr)))
 374         (cond
 375          ((ly:input-location? head)
 376           (display (apply define-origin (ly:input-location head)) port)
 377           (output-stencil port (cadr expr) offset))
 378          ((eq? head 'no-origin)
 379           (display (expression->string head) port)
 380           (output-stencil port (cadr expr) offset))
 381          ((eq? head 'translate-stencil)
 382           (output-stencil port (caddr expr) (offset-add offset (cadr expr))))
 383          ((eq? head 'combine-stencil)
 384           (output-stencil port (cadr expr) offset)
 385           (output-stencil port (caddr expr) offset))
 386          (else
 387           (display (placebox (car offset) (cdr offset)
 388                              (expression->string expr)) port))))))
 389
 390 (define (placebox x y s)
 391   (string-append
 392    (ly:number->string x) " " (ly:number->string y) " { " s " } place-box\n"))
 393
 394 (define (polygon points blotdiameter)
 395   (string-append
 396    " "
 397    (ly:numbers->string points)
 398    (ly:number->string (/ (length points) 2))
 399    (ly:number->string blotdiameter)
 400    " draw_polygon"))
 401
 402 (define (repeat-slash wid slope thick)
 403   (string-append
 404    (ly:numbers->string (list wid slope thick))
 405    " draw_repeat_slash"))
 406
 407 (define (round-filled-box x y width height blotdiam)
 408    (string-append
 409     (ly:numbers->string
 410      (list x y width height blotdiam)) " draw_round_box"))
 411
 412 (define (new-start-system origin dim)
 413   (string-append
 414    "\n" (ly:number-pair->string origin) " start-system\n"
 415    "{\n"
 416    "set-ps-scale-to-lily-scale\n"))
 417
 418 (define (stem breapth width depth height)
 419   (string-append
 420    (ly:numbers->string (list breapth width depth height))
 421    " draw_box" ))
 422
 423 (define (stop-system)
 424   "} stop-system\n")
 425
 426 (define stop-last-system stop-system)
 427
 428 (define (symmetric-x-triangle thick w h)
 429   (string-append
 430    (ly:numbers->string (list h w thick))
 431    " draw_symmetric_x_triangle"))
 432
 433 (define (text s)
 434 ;;  (string-append "(" (escape-parentheses s) ") show "))
 435   (string-append "(" (ps-encoding s) ") show"))
 436
 437 (define (unknown)
 438   "\n unknown\n")
 439
 440 (define (zigzag-line centre? zzw zzh thick dx dy)
 441   (string-append
 442     (if centre? "true" "false")
 443     " "
 444     (ly:number->string zzw)
 445     " "
 446     (ly:number->string zzh)
 447     " "
 448     (ly:number->string thick)
 449     " 0 0 "
 450     (ly:number->string dx)
 451     " "
 452     (ly:number->string dy)
 453     " draw_zigzag_line"))
 454
 455 (define (start-page)
 456   (set! page-number (+ page-number 1))
 457   (string-append
 458    "%%Page: " (number->string page-number) " " (number->string page-count) "\n"
 459   "start-page\n"))
 460
 461 (define (stop-page last?)
 462   (if last?
 463       "\nstop-last-page\n"
 464       "\nstop-page\n"))