scm/output-lib.scm

   1 ;;;; This file is part of LilyPond, the GNU music typesetter.
   2 ;;;;
   3 ;;;; Copyright (C) 1998--2011 Jan Nieuwenhuizen <janneke@gnu.org>
   4 ;;;; Han-Wen Nienhuys <hanwen@xs4all.nl>
   5 ;;;;
   6 ;;;; LilyPond is free software: you can redistribute it and/or modify
   7 ;;;; it under the terms of the GNU General Public License as published by
   8 ;;;; the Free Software Foundation, either version 3 of the License, or
   9 ;;;; (at your option) any later version.
  10 ;;;;
  11 ;;;; LilyPond is distributed in the hope that it will be useful,
  12 ;;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 ;;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 ;;;; GNU General Public License for more details.
  15 ;;;;
  16 ;;;; You should have received a copy of the GNU General Public License
  17 ;;;; along with LilyPond.  If not, see <http://www.gnu.org/licenses/>.
  18
  19
  20 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  21 ;; general
  22
  23 (define-public (grob::has-interface grob iface)
  24   (memq iface (ly:grob-interfaces grob)))
  25
  26 (define-public (grob::is-live? grob)
  27   (pair? (ly:grob-basic-properties grob)))
  28
  29 (define-public (make-stencil-boxer thickness padding callback)
  30   "Return function that adds a box around the grob passed as argument."
  31   (lambda (grob)
  32     (box-stencil (callback grob) thickness padding)))
  33
  34 (define-public (make-stencil-circler thickness padding callback)
  35   "Return function that adds a circle around the grob passed as argument."
  36   (lambda (grob)
  37     (circle-stencil (callback grob) thickness padding)))
  38
  39 (define-public (print-circled-text-callback grob)
  40   (grob-interpret-markup grob (make-circle-markup
  41                                (ly:grob-property grob 'text))))
  42
  43 (define-public (event-cause grob)
  44   (let ((cause (ly:grob-property  grob 'cause)))
  45
  46     (cond
  47      ((ly:stream-event? cause) cause)
  48      ((ly:grob? cause) (event-cause cause))
  49      (else #f))))
  50
  51 (define-public (grob-interpret-markup grob text)
  52   (let* ((layout (ly:grob-layout grob))
  53          (defs (ly:output-def-lookup layout 'text-font-defaults))
  54          (props (ly:grob-alist-chain grob defs)))
  55
  56     (ly:text-interface::interpret-markup layout props text)))
  57
  58
  59 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  60 ;; note heads
  61
  62 (define-public (stem::calc-duration-log grob)
  63   (ly:duration-log
  64    (ly:event-property (event-cause grob) 'duration)))
  65
  66 (define-public (note-head::calc-duration-log grob)
  67   (min 2
  68        (ly:duration-log
  69         (ly:event-property (event-cause grob) 'duration))))
  70
  71 (define-public (dots::calc-dot-count grob)
  72   (ly:duration-dot-count
  73    (ly:event-property (event-cause grob) 'duration)))
  74
  75 (define-public (dots::calc-staff-position grob)
  76   (let* ((head (ly:grob-parent grob Y))
  77          (log (ly:grob-property head 'duration-log)))
  78
  79     (cond
  80      ((or (not (grob::has-interface head 'rest-interface))
  81           (not (integer? log))) 0)
  82      ((= log 7) 4)
  83      ((> log 4) 3)
  84      ((= log 0) -1)
  85      ((= log 1) 1)
  86      ((= log -1) 1)
  87      (else 0))))
  88
  89 ;; Kept separate from note-head::calc-glyph-name to allow use by
  90 ;; markup commands \note and \note-by-number
  91 (define-public (select-head-glyph style log)
  92   "Select a note head glyph string based on note head style @var{style}
  93 and duration-log @var{log}."
  94   (case style
  95     ;; "default" style is directly handled in note-head.cc as a
  96     ;; special case (HW says, mainly for performance reasons).
  97     ;; Therefore, style "default" does not appear in this case
  98     ;; statement.  -- jr
  99     ((xcircle) "2xcircle")
 100     ((harmonic) "0harmonic")
 101     ((harmonic-black) "2harmonic")
 102     ((harmonic-mixed) (if (<= log 1) "0harmonic"
 103                           "2harmonic"))
 104     ((baroque)
 105      ;; Oops, I actually would not call this "baroque", but, for
 106      ;; backwards compatibility to 1.4, this is supposed to take
 107      ;; brevis, longa and maxima from the neo-mensural font and all
 108      ;; other note heads from the default font.  -- jr
 109      (if (< log 0)
 110          (string-append (number->string log) "neomensural")
 111          (number->string log)))
 112     ((altdefault)
 113      ;; Like default, but brevis is drawn with double vertical lines
 114      (if (= log -1)
 115          (string-append (number->string log) "double")
 116          (number->string log)))
 117     ((mensural)
 118      (string-append (number->string log) (symbol->string style)))
 119     ((petrucci)
 120      (if (< log 0)
 121          (string-append (number->string log) "mensural")
 122          (string-append (number->string log) (symbol->string style))))
 123     ((blackpetrucci)
 124      (if (< log 0)
 125          (string-append (number->string log) "blackmensural")
 126          (string-append (number->string log) (symbol->string style))))
 127     ((semipetrucci)
 128      (if (< log 0)
 129          (string-append (number->string log) "semimensural")
 130          (string-append (number->string log) "petrucci")))
 131     ((neomensural)
 132      (string-append (number->string log) (symbol->string style)))
 133     (else
 134      (if (string-match "vaticana*|hufnagel*|medicaea*" (symbol->string style))
 135          (symbol->string style)
 136          (string-append (number->string (max 0 log))
 137                         (symbol->string style))))))
 138
 139 (define-public (note-head::calc-glyph-name grob)
 140   (let ((style (ly:grob-property grob 'style))
 141         (log (min 2 (ly:grob-property grob 'duration-log))))
 142
 143     (select-head-glyph style log)))
 144
 145 (define-public (note-head::brew-ez-stencil grob)
 146   (let* ((log (ly:grob-property grob 'duration-log))
 147          (pitch (ly:event-property (event-cause grob) 'pitch))
 148          (pitch-index (ly:pitch-notename pitch))
 149          (note-names (ly:grob-property grob 'note-names))
 150          (pitch-string (if (and (vector? note-names)
 151                                 (> (vector-length note-names) pitch-index))
 152                            (vector-ref note-names pitch-index)
 153                            (string
 154                             (integer->char
 155                              (+ (modulo (+ pitch-index 2) 7)
 156                                 (char->integer #\A))))))
 157          (staff-space (ly:staff-symbol-staff-space grob))
 158          (line-thickness (ly:staff-symbol-line-thickness grob))
 159          (stem (ly:grob-object grob 'stem))
 160          (stem-thickness (* (if (ly:grob? stem)
 161                                 (ly:grob-property stem 'thickness)
 162                                 1.3)
 163                             line-thickness))
 164          (radius (/ (+ staff-space line-thickness) 2))
 165          (letter (markup #:center-align #:vcenter pitch-string))
 166          (filled-circle (markup #:draw-circle radius 0 #t)))
 167
 168     (ly:stencil-translate-axis
 169      (grob-interpret-markup
 170       grob
 171       (if (>= log 2)
 172           (make-combine-markup
 173            filled-circle
 174            (make-with-color-markup white letter))
 175           (make-combine-markup
 176            (make-combine-markup
 177             filled-circle
 178             (make-with-color-markup white (make-draw-circle-markup
 179                                            (- radius stem-thickness) 0 #t)))
 180            letter)))
 181      radius X)))
 182
 183 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 184 ;; clipping
 185
 186 (define-public (make-rhythmic-location bar-num num den)
 187   (cons
 188    bar-num (ly:make-moment num den)))
 189
 190 (define-public (rhythmic-location? a)
 191   (and (pair? a)
 192        (integer? (car a))
 193        (ly:moment? (cdr a))))
 194
 195 (define-public (make-graceless-rhythmic-location loc)
 196   (make-rhythmic-location
 197    (car loc)
 198    (ly:moment-main-numerator (rhythmic-location-measure-position loc))
 199    (ly:moment-main-denominator (rhythmic-location-measure-position loc))))
 200
 201 (define-public rhythmic-location-measure-position cdr)
 202 (define-public rhythmic-location-bar-number car)
 203
 204 (define-public (rhythmic-location<? a b)
 205   (cond
 206    ((< (car a) (car b)) #t)
 207    ((> (car a) (car b)) #f)
 208    (else
 209     (ly:moment<? (cdr a) (cdr b)))))
 210
 211 (define-public (rhythmic-location<=? a b)
 212   (not (rhythmic-location<? b a)))
 213 (define-public (rhythmic-location>=? a b)
 214   (rhythmic-location<? a b))
 215 (define-public (rhythmic-location>? a b)
 216   (rhythmic-location<? b a))
 217
 218 (define-public (rhythmic-location=? a b)
 219   (and (rhythmic-location<=? a b)
 220        (rhythmic-location<=? b a)))
 221
 222 (define-public (rhythmic-location->file-string a)
 223   (ly:format "~a.~a.~a"
 224              (car a)
 225              (ly:moment-main-numerator (cdr a))
 226              (ly:moment-main-denominator (cdr a))))
 227
 228 (define-public (rhythmic-location->string a)
 229   (ly:format "bar ~a ~a"
 230              (car a)
 231              (ly:moment->string (cdr a))))
 232
 233 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 234 ;; break visibility
 235
 236 (define-public all-visible             #(#t #t #t))
 237 (define-public begin-of-line-invisible #(#t #t #f))
 238 (define-public center-invisible        #(#t #f #t))
 239 (define-public end-of-line-invisible   #(#f #t #t))
 240 (define-public begin-of-line-visible   #(#f #f #t))
 241 (define-public center-visible          #(#f #t #f))
 242 (define-public end-of-line-visible     #(#t #f #f))
 243 (define-public all-invisible           #(#f #f #f))
 244 (define-public (inherit-x-parent-visibility grob)
 245   (let ((parent (ly:grob-parent grob X)))
 246     (ly:grob-property parent 'break-visibility all-invisible)))
 247 (define-public (inherit-y-parent-visibility grob)
 248   (let ((parent (ly:grob-parent grob X)))
 249     (ly:grob-property parent 'break-visibility)))
 250
 251
 252 (define-public spanbar-begin-of-line-invisible #(#t #f #f))
 253
 254
 255 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 256 ;; Bar lines.
 257
 258 ;;
 259 ;; How should a  bar line behave at a break?
 260 (define bar-glyph-alist
 261   '((":|:" . (":|" . "|:"))
 262     (":|.|:" . (":|" . "|:"))
 263     (":|.:" . (":|" . "|:"))
 264     ("||:" . ("||" . "|:"))
 265     ("dashed" . ("dashed" . '()))
 266     ("|" . ("|" . ()))
 267     ("||:" . ("||" . "|:"))
 268     ("|s" . (() . "|"))
 269     ("|:" . ("|" . "|:"))
 270     ("|." . ("|." . ()))
 271
 272     ;; hmm... should we end with a bar line here?
 273     (".|" . ("|" . ".|"))
 274     (":|" . (":|" . ()))
 275     ("||" . ("||" . ()))
 276     (".|." . (".|." . ()))
 277     ("|.|" . ("|.|" . ()))
 278     ("" . ("" . ""))
 279     (":" . (":" . ""))
 280     ("." . ("." . ()))
 281     ("'" . ("'" . ()))
 282     ("empty" . (() . ()))
 283     ("brace" . (() . "brace"))
 284     ("bracket" . (() . "bracket"))
 285
 286     ;; segno bar lines
 287     ("S" . ("||" . "S"))
 288     ("|S" . ("|" . "S"))
 289     ("S|" . ("S" . ()))
 290     (":|S" . (":|" . "S"))
 291     (":|S." . (":|S" . ()))
 292     ("S|:" . ("S" . "|:"))
 293     (".S|:" . ("|" . "S|:"))
 294     (":|S|:" . (":|" . "S|:"))
 295     (":|S.|:" . (":|S" . "|:"))))
 296
 297 (define-public (bar-line::calc-glyph-name grob)
 298   (let* ((glyph (ly:grob-property grob 'glyph))
 299          (dir (ly:item-break-dir grob))
 300          (result (assoc-get glyph bar-glyph-alist))
 301          (glyph-name (if (= dir CENTER)
 302                          glyph
 303                          (if (and result
 304                                   (string? (index-cell result dir)))
 305                              (index-cell result dir)
 306                              #f))))
 307     glyph-name))
 308
 309 (define-public (bar-line::calc-break-visibility grob)
 310   (let* ((glyph (ly:grob-property grob 'glyph))
 311          (result (assoc-get glyph bar-glyph-alist)))
 312
 313     (if result
 314         (vector (string? (car result)) #t (string? (cdr result)))
 315         all-invisible)))
 316
 317 (define-public (shift-right-at-line-begin g)
 318   "Shift an item to the right, but only at the start of the line."
 319   (if (and (ly:item? g)
 320            (equal? (ly:item-break-dir g) RIGHT))
 321       (ly:grob-translate-axis! g 3.5 X)))
 322
 323
 324 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 325 ;; Tuplets
 326
 327 (define-public (tuplet-number::calc-direction grob)
 328   (ly:tuplet-bracket::calc-direction (ly:grob-object grob 'bracket)))
 329
 330 (define-public (tuplet-number::calc-denominator-text grob)
 331   (number->string (ly:event-property (event-cause grob) 'denominator)))
 332
 333 (define-public (tuplet-number::calc-fraction-text grob)
 334   (let ((ev (event-cause grob)))
 335
 336     (format #f "~a:~a"
 337             (ly:event-property ev 'denominator)
 338             (ly:event-property ev 'numerator))))
 339
 340 ;; a formatter function, which is simply a wrapper around an existing
 341 ;; tuplet formatter function. It takes the value returned by the given
 342 ;; function and appends a note of given length.
 343 (define-public ((tuplet-number::append-note-wrapper function note) grob)
 344   (let ((txt (if function (function grob) #f)))
 345
 346     (if txt
 347         (markup txt #:fontsize -5 #:note note UP)
 348         (markup #:fontsize -5 #:note note UP))))
 349
 350 ;; Print a tuplet denominator with a different number than the one derived from
 351 ;; the actual tuplet fraction
 352 (define-public ((tuplet-number::non-default-tuplet-denominator-text denominator)
 353                 grob)
 354   (number->string (if denominator
 355                       denominator
 356                       (ly:event-property (event-cause grob) 'denominator))))
 357
 358 ;; Print a tuplet fraction with different numbers than the ones derived from
 359 ;; the actual tuplet fraction
 360 (define-public ((tuplet-number::non-default-tuplet-fraction-text
 361                  denominator numerator) grob)
 362   (let* ((ev (event-cause grob))
 363          (den (if denominator denominator (ly:event-property ev 'denominator)))
 364          (num (if numerator numerator (ly:event-property ev 'numerator))))
 365
 366     (format #f "~a:~a" den num)))
 367
 368 ;; Print a tuplet fraction with note durations appended to the numerator and the
 369 ;; denominator
 370 (define-public ((tuplet-number::fraction-with-notes
 371                  denominatornote numeratornote) grob)
 372   (let* ((ev (event-cause grob))
 373          (denominator (ly:event-property ev 'denominator))
 374          (numerator (ly:event-property ev 'numerator)))
 375
 376     ((tuplet-number::non-default-fraction-with-notes
 377       denominator denominatornote numerator numeratornote) grob)))
 378
 379 ;; Print a tuplet fraction with note durations appended to the numerator and the
 380 ;; denominator
 381 (define-public ((tuplet-number::non-default-fraction-with-notes
 382                  denominator denominatornote numerator numeratornote) grob)
 383   (let* ((ev (event-cause grob))
 384          (den (if denominator denominator (ly:event-property ev 'denominator)))
 385          (num (if numerator numerator (ly:event-property ev 'numerator))))
 386
 387     (make-concat-markup (list
 388                          (make-simple-markup (format #f "~a" den))
 389                          (markup #:fontsize -5 #:note denominatornote UP)
 390                          (make-simple-markup " : ")
 391                          (make-simple-markup (format #f "~a" num))
 392                          (markup #:fontsize -5 #:note numeratornote UP)))))
 393
 394
 395 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 396 ;; Color
 397
 398 (define-public (color? x)
 399   (and (list? x)
 400        (= 3 (length x))
 401        (apply eq? #t (map number? x))
 402        (apply eq? #t (map (lambda (y) (<= 0 y 1)) x))))
 403
 404 (define-public (rgb-color r g b) (list r g b))
 405
 406 ; predefined colors
 407 (define-public black       '(0.0 0.0 0.0))
 408 (define-public white       '(1.0 1.0 1.0))
 409 (define-public red         '(1.0 0.0 0.0))
 410 (define-public green       '(0.0 1.0 0.0))
 411 (define-public blue        '(0.0 0.0 1.0))
 412 (define-public cyan        '(0.0 1.0 1.0))
 413 (define-public magenta     '(1.0 0.0 1.0))
 414 (define-public yellow      '(1.0 1.0 0.0))
 415
 416 (define-public grey        '(0.5 0.5 0.5))
 417 (define-public darkred     '(0.5 0.0 0.0))
 418 (define-public darkgreen   '(0.0 0.5 0.0))
 419 (define-public darkblue    '(0.0 0.0 0.5))
 420 (define-public darkcyan    '(0.0 0.5 0.5))
 421 (define-public darkmagenta '(0.5 0.0 0.5))
 422 (define-public darkyellow  '(0.5 0.5 0.0))
 423
 424
 425 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 426 ;; key signature
 427
 428 (define-public (key-signature-interface::alteration-position step alter
 429                                                              c0-position)
 430   ;; TODO: memoize - this is mostly constant.
 431
 432   ;; fes, ges, as and bes typeset in lower octave
 433   (define FLAT_TOP_PITCH 2)
 434
 435   ;; ais and bis typeset in lower octave
 436   (define SHARP_TOP_PITCH 4)
 437
 438   (if (pair? step)
 439       (+ (cdr step) (* (car step) 7) c0-position)
 440       (let* ((from-bottom-pos (modulo (+ 4 49 c0-position) 7))
 441              (p step)
 442              (c0 (- from-bottom-pos 4)))
 443
 444         (if
 445          (or (and (< alter 0)
 446                   (or (> p FLAT_TOP_PITCH) (> (+ p c0) 4)) (> (+ p c0) 1))
 447              (and (> alter 0)
 448                   (or (> p SHARP_TOP_PITCH) (> (+ p c0) 5)) (> (+ p c0) 2)))
 449
 450          ;; Typeset below c_position
 451          (set! p (- p 7)))
 452
 453         ;; Provide for the four cases in which there's a glitch
 454         ;; it's a hack, but probably not worth
 455         ;; the effort of finding a nicer solution.
 456         ;; --dl.
 457         (cond
 458          ((and (= c0 2) (= p 3) (> alter 0))
 459           (set! p (- p 7)))
 460          ((and (= c0 -3) (= p -1) (> alter 0))
 461           (set! p (+ p 7)))
 462          ((and (= c0 -4) (= p -1) (< alter 0))
 463           (set! p (+ p 7)))
 464          ((and (= c0 -2) (= p -3) (< alter 0))
 465           (set! p (+ p 7))))
 466
 467         (+ c0 p))))
 468
 469
 470 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 471 ;; accidentals
 472
 473 (define-public (accidental-interface::calc-alteration grob)
 474   (ly:pitch-alteration (ly:event-property (event-cause grob) 'pitch)))
 475
 476 (define-public cancellation-glyph-name-alist
 477   '((0 . "accidentals.natural")))
 478
 479 (define-public standard-alteration-glyph-name-alist
 480   '(
 481     ;; ordered for optimal performance.
 482     (0 . "accidentals.natural")
 483     (-1/2 . "accidentals.flat")
 484     (1/2 . "accidentals.sharp")
 485
 486     (1 . "accidentals.doublesharp")
 487     (-1 . "accidentals.flatflat")
 488
 489     (3/4 . "accidentals.sharp.slashslash.stemstemstem")
 490     (1/4 . "accidentals.sharp.slashslash.stem")
 491     (-1/4 . "accidentals.mirroredflat")
 492     (-3/4 . "accidentals.mirroredflat.flat")))
 493
 494 ;; FIXME: standard vs default, alteration-FOO vs FOO-alteration
 495 (define-public alteration-default-glyph-name-alist
 496   standard-alteration-glyph-name-alist)
 497
 498 (define-public makam-alteration-glyph-name-alist
 499   '((1 . "accidentals.doublesharp")
 500     (8/9 . "accidentals.sharp.slashslashslash.stemstem")
 501     (5/9 . "accidentals.sharp.slashslashslash.stem")
 502     (4/9 . "accidentals.sharp")
 503     (1/9 . "accidentals.sharp.slashslash.stem")
 504     (0 . "accidentals.natural")
 505     (-1/9 . "accidentals.mirroredflat")
 506     (-4/9 . "accidentals.flat.slash")
 507     (-5/9 . "accidentals.flat")
 508     (-8/9 . "accidentals.flat.slashslash")
 509     (-1 . "accidentals.flatflat")))
 510
 511 (define-public alteration-hufnagel-glyph-name-alist
 512   '((-1/2 . "accidentals.hufnagelM1")
 513     (0 . "accidentals.vaticana0")
 514     (1/2 . "accidentals.mensural1")))
 515
 516 (define-public alteration-medicaea-glyph-name-alist
 517   '((-1/2 . "accidentals.medicaeaM1")
 518     (0 . "accidentals.vaticana0")
 519     (1/2 . "accidentals.mensural1")))
 520
 521 (define-public alteration-vaticana-glyph-name-alist
 522   '((-1/2 . "accidentals.vaticanaM1")
 523     (0 . "accidentals.vaticana0")
 524     (1/2 . "accidentals.mensural1")))
 525
 526 (define-public alteration-mensural-glyph-name-alist
 527   '((-1/2 . "accidentals.mensuralM1")
 528     (0 . "accidentals.vaticana0")
 529     (1/2 . "accidentals.mensural1")))
 530
 531
 532 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 533 ;; * Pitch Trill Heads
 534 ;; * Parentheses
 535
 536 (define-public (parentheses-item::calc-parenthesis-stencils grob)
 537   (let* ((font (ly:grob-default-font grob))
 538          (lp (ly:font-get-glyph font "accidentals.leftparen"))
 539          (rp (ly:font-get-glyph font "accidentals.rightparen")))
 540
 541     (list lp rp)))
 542
 543 (define-public (parentheses-item::calc-angled-bracket-stencils grob)
 544   (let* ((parent (ly:grob-parent grob Y))
 545          (y-extent (ly:grob-extent parent parent Y))
 546          (half-thickness 0.05) ; should it be a property?
 547          (width 0.5) ; should it be a property?
 548          (angularity 1.5)  ; makes angle brackets
 549          (white-padding 0.1) ; should it be a property?
 550          (lp (ly:stencil-aligned-to
 551                  (ly:stencil-aligned-to
 552                    (make-parenthesis-stencil y-extent
 553                                              half-thickness
 554                                              (- width)
 555                                              angularity)
 556                    Y CENTER)
 557                  X RIGHT))
 558          (lp-x-extent
 559            (interval-widen (ly:stencil-extent lp X) white-padding))
 560          (rp (ly:stencil-aligned-to
 561                  (ly:stencil-aligned-to
 562                    (make-parenthesis-stencil y-extent
 563                                              half-thickness
 564                                              width
 565                                              angularity)
 566                    Y CENTER)
 567                  X LEFT))
 568           (rp-x-extent
 569             (interval-widen (ly:stencil-extent rp X) white-padding)))
 570     (set! lp (ly:make-stencil (ly:stencil-expr lp)
 571                               lp-x-extent
 572                               (ly:stencil-extent lp Y)))
 573     (set! rp (ly:make-stencil (ly:stencil-expr rp)
 574                               rp-x-extent
 575                               (ly:stencil-extent rp Y)))
 576     (list (stencil-whiteout lp)
 577           (stencil-whiteout rp))))
 578
 579 (define (parenthesize-elements grob . rest)
 580   (let* ((refp (if (null? rest)
 581                    grob
 582                    (car rest)))
 583          (elts (ly:grob-object grob 'elements))
 584          (x-ext (ly:relative-group-extent elts refp X))
 585          (stencils (ly:grob-property grob 'stencils))
 586          (lp (car stencils))
 587          (rp (cadr stencils))
 588          (padding (ly:grob-property grob 'padding 0.1)))
 589
 590     (ly:stencil-add
 591      (ly:stencil-translate-axis lp (- (car x-ext) padding) X)
 592      (ly:stencil-translate-axis rp (+ (cdr x-ext) padding) X))))
 593
 594
 595 (define-public (parentheses-item::print me)
 596   (let* ((elts (ly:grob-object me 'elements))
 597          (y-ref (ly:grob-common-refpoint-of-array me elts Y))
 598          (x-ref (ly:grob-common-refpoint-of-array me elts X))
 599          (stencil (parenthesize-elements me x-ref))
 600          (elt-y-ext (ly:relative-group-extent elts y-ref Y))
 601          (y-center (interval-center elt-y-ext)))
 602
 603     (ly:stencil-translate
 604      stencil
 605      (cons
 606       (- (ly:grob-relative-coordinate me x-ref X))
 607       (- y-center (ly:grob-relative-coordinate me y-ref Y))))))
 608
 609
 610
 611 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 612 ;;
 613
 614 (define-public (chain-grob-member-functions grob value . funcs)
 615   (for-each
 616    (lambda (func)
 617      (set! value (func grob value)))
 618    funcs)
 619
 620   value)
 621
 622
 623 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 624 ;; falls/doits
 625
 626 (define-public (bend::print spanner)
 627   (define (close  a b)
 628     (< (abs (- a b)) 0.01))
 629
 630   (let* ((delta-y (* 0.5 (ly:grob-property spanner 'delta-position)))
 631          (left-span (ly:spanner-bound spanner LEFT))
 632          (dots (if (and (grob::has-interface left-span 'note-head-interface)
 633                         (ly:grob? (ly:grob-object left-span 'dot)))
 634                    (ly:grob-object left-span 'dot) #f))
 635
 636          (right-span (ly:spanner-bound spanner RIGHT))
 637          (thickness (* (ly:grob-property spanner 'thickness)
 638                        (ly:output-def-lookup (ly:grob-layout spanner)
 639                                              'line-thickness)))
 640          (padding (ly:grob-property spanner 'padding 0.5))
 641          (common (ly:grob-common-refpoint right-span
 642                                           (ly:grob-common-refpoint spanner
 643                                                                    left-span X)
 644                                           X))
 645          (common-y (ly:grob-common-refpoint spanner left-span Y))
 646          (minimum-length (ly:grob-property spanner 'minimum-length 0.5))
 647
 648          (left-x (+ padding
 649                     (max
 650                      (interval-end (ly:grob-robust-relative-extent
 651                                     left-span common X))
 652                      (if
 653                       (and dots
 654                            (close
 655                             (ly:grob-relative-coordinate dots common-y Y)
 656                             (ly:grob-relative-coordinate spanner common-y Y)))
 657                       (interval-end
 658                        (ly:grob-robust-relative-extent dots common X))
 659                       ;; TODO: use real infinity constant.
 660                       -10000))))
 661          (right-x (max (- (interval-start
 662                            (ly:grob-robust-relative-extent right-span common X))
 663                           padding)
 664                        (+ left-x minimum-length)))
 665          (self-x (ly:grob-relative-coordinate spanner common X))
 666          (dx (- right-x left-x))
 667          (exp (list 'path thickness
 668                     `(quote
 669                       (rmoveto
 670                        ,(- left-x self-x) 0
 671
 672                        rcurveto
 673                        ,(/ dx 3)
 674                        0
 675                        ,dx ,(* 0.66 delta-y)
 676                        ,dx ,delta-y)))))
 677
 678     (ly:make-stencil
 679      exp
 680      (cons (- left-x self-x) (- right-x self-x))
 681      (cons (min 0 delta-y)
 682            (max 0 delta-y)))))
 683
 684
 685 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 686 ;; grace spacing
 687
 688 (define-public (grace-spacing::calc-shortest-duration grob)
 689   (let* ((cols (ly:grob-object grob 'columns))
 690          (get-difference
 691           (lambda (idx)
 692             (ly:moment-sub (ly:grob-property
 693                             (ly:grob-array-ref cols (1+ idx)) 'when)
 694                            (ly:grob-property
 695                             (ly:grob-array-ref cols idx) 'when))))
 696
 697          (moment-min (lambda (x y)
 698                        (cond
 699                         ((and x y)
 700                          (if (ly:moment<? x y)
 701                              x
 702                              y))
 703                         (x x)
 704                         (y y)))))
 705
 706     (fold moment-min #f (map get-difference
 707                              (iota (1- (ly:grob-array-length cols)))))))
 708
 709
 710 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 711 ;; fingering
 712
 713 (define-public (fingering::calc-text grob)
 714   (let* ((event (event-cause grob))
 715          (digit (ly:event-property event 'digit)))
 716
 717     (if (> digit 5)
 718         (ly:input-message (ly:event-property event 'origin)
 719                           "Warning: Fingering notation for finger number ~a"
 720                           digit))
 721
 722     (number->string digit 10)))
 723
 724 (define-public (string-number::calc-text grob)
 725   (let ((digit (ly:event-property (event-cause grob) 'string-number)))
 726
 727     (number->string digit 10)))
 728
 729 (define-public (stroke-finger::calc-text grob)
 730   (let* ((digit (ly:event-property (event-cause grob) 'digit))
 731          (text (ly:event-property (event-cause grob) 'text)))
 732
 733     (if (string? text)
 734         text
 735         (vector-ref (ly:grob-property grob 'digit-names)
 736                     (1- (max (min 5 digit) 1))))))
 737
 738
 739 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 740 ;; dynamics
 741
 742 (define-public (hairpin::calc-grow-direction grob)
 743   (if (eq? (ly:event-property (event-cause grob) 'class) 'decrescendo-event)
 744       START
 745       STOP))
 746
 747 (define-public (dynamic-text-spanner::before-line-breaking grob)
 748   "Monitor left bound of @code{DynamicTextSpanner} for absolute dynamics.
 749 If found, ensure @code{DynamicText} does not collide with spanner text by
 750 changing @code{'attach-dir} and @code{'padding}.  Reads the
 751 @code{'right-padding} property of @code{DynamicText} to fine tune space
 752 between the two text elements."
 753   (let ((left-bound (ly:spanner-bound grob LEFT)))
 754     (if (grob::has-interface left-bound 'dynamic-text-interface)
 755         (let* ((details (ly:grob-property grob 'bound-details))
 756                (left-details (ly:assoc-get 'left details))
 757                (my-padding (ly:assoc-get 'padding left-details))
 758                (script-padding (ly:grob-property left-bound 'right-padding 0)))
 759
 760           (and (number? my-padding)
 761                (ly:grob-set-nested-property! grob
 762                                              '(bound-details left attach-dir)
 763                                              RIGHT)
 764                (ly:grob-set-nested-property! grob
 765                                              '(bound-details left padding)
 766                                              (+ my-padding script-padding)))))))
 767
 768
 769 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 770 ;; lyrics
 771
 772 (define-public (lyric-text::print grob)
 773   "Allow interpretation of tildes as lyric tieing marks."
 774
 775   (let ((text (ly:grob-property grob 'text)))
 776
 777     (grob-interpret-markup grob (if (string? text)
 778                                     (make-tied-lyric-markup text)
 779                                     text))))
 780
 781 (define-public ((grob::calc-property-by-copy prop) grob)
 782   (ly:event-property (event-cause grob) prop))
 783
 784
 785 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 786 ;; fret boards
 787
 788 (define-public (fret-board::calc-stencil grob)
 789   (grob-interpret-markup
 790    grob
 791    (make-fret-diagram-verbose-markup
 792     (ly:grob-property grob 'dot-placement-list))))
 793
 794
 795 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 796 ;; scripts
 797
 798 (define-public (script-interface::calc-x-offset grob)
 799   (ly:grob-property grob 'positioning-done)
 800   (let* ((shift (ly:grob-property grob 'toward-stem-shift 0.0))
 801          (note-head-location
 802           (ly:self-alignment-interface::centered-on-x-parent grob))
 803          (note-head-grob (ly:grob-parent grob X))
 804          (stem-grob (ly:grob-object note-head-grob 'stem)))
 805
 806     (+ note-head-location
 807        ;; If the property 'toward-stem-shift is defined and the script
 808        ;; has the same direction as the stem, move the script accordingly.
 809        ;; Since scripts can also be over skips, we need to check whether
 810        ;; the grob has a stem at all.
 811        (if (ly:grob? stem-grob)
 812            (let ((dir1 (ly:grob-property grob 'direction))
 813                  (dir2 (ly:grob-property stem-grob 'direction)))
 814              (if (equal? dir1 dir2)
 815                  (let* ((common-refp (ly:grob-common-refpoint grob stem-grob X))
 816                         (stem-location
 817                          (ly:grob-relative-coordinate stem-grob common-refp X)))
 818                    (* shift (- stem-location note-head-location)))
 819                  0.0))
 820            0.0))))
 821
 822
 823 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 824 ;; instrument names
 825
 826 (define-public (system-start-text::print grob)
 827   (let* ((left-bound (ly:spanner-bound grob LEFT))
 828          (left-mom (ly:grob-property left-bound 'when))
 829          (name (if (moment<=? left-mom ZERO-MOMENT)
 830                    (ly:grob-property grob 'long-text)
 831                    (ly:grob-property grob 'text))))
 832
 833     (if (and (markup? name)
 834              (!= (ly:item-break-dir left-bound) CENTER))
 835
 836         (grob-interpret-markup grob name)
 837         (ly:grob-suicide! grob))))
 838
 839 (define-public (system-start-text::calc-x-offset grob)
 840   (let* ((left-bound (ly:spanner-bound grob LEFT))
 841          (left-mom (ly:grob-property left-bound 'when))
 842          (layout (ly:grob-layout grob))
 843          (indent (ly:output-def-lookup layout
 844                                        (if (moment<=? left-mom ZERO-MOMENT)
 845                                            'indent
 846                                            'short-indent)
 847                                        0.0))
 848          (system (ly:grob-system grob))
 849          (my-extent (ly:grob-extent grob system X))
 850          (elements (ly:grob-object system 'elements))
 851          (common (ly:grob-common-refpoint-of-array system elements X))
 852          (total-ext empty-interval)
 853          (align-x (ly:grob-property grob 'self-alignment-X 0))
 854          (padding (min 0 (- (interval-length my-extent) indent)))
 855          (right-padding (- padding
 856                            (/ (* padding (1+ align-x)) 2))))
 857
 858     ;; compensate for the variation in delimiter extents by
 859     ;; calculating an X-offset correction based on united extents
 860     ;; of all delimiters in this system
 861     (let unite-delims ((l (ly:grob-array-length elements)))
 862       (if (> l 0)
 863           (let ((elt (ly:grob-array-ref elements (1- l))))
 864
 865             (if (grob::has-interface elt 'system-start-delimiter-interface)
 866                 (let ((dims (ly:grob-extent elt common X)))
 867                   (if (interval-sane? dims)
 868                       (set! total-ext (interval-union total-ext dims)))))
 869             (unite-delims (1- l)))))
 870
 871     (+
 872      (ly:side-position-interface::x-aligned-side grob)
 873      right-padding
 874      (- (interval-length total-ext)))))
 875
 876 (define-public (system-start-text::calc-y-offset grob)
 877
 878   (define (live-elements-list me)
 879     (let ((elements (ly:grob-object me 'elements)))
 880
 881       (filter! grob::is-live?
 882                (ly:grob-array->list elements))))
 883
 884   (let* ((left-bound (ly:spanner-bound grob LEFT))
 885          (live-elts (live-elements-list grob))
 886          (system (ly:grob-system grob))
 887          (extent empty-interval))
 888
 889     (if (and (pair? live-elts)
 890              (interval-sane? (ly:grob-extent grob system Y)))
 891         (let get-extent ((lst live-elts))
 892           (if (pair? lst)
 893               (let ((axis-group (car lst)))
 894
 895                 (if (and (ly:spanner? axis-group)
 896                          (equal? (ly:spanner-bound axis-group LEFT)
 897                                  left-bound))
 898                     (set! extent (add-point extent
 899                                             (ly:grob-relative-coordinate
 900                                              axis-group system Y))))
 901                 (get-extent (cdr lst)))))
 902         ;; no live axis group(s) for this instrument name -> remove from system
 903         (ly:grob-suicide! grob))
 904
 905     (+
 906      (ly:self-alignment-interface::y-aligned-on-self grob)
 907      (interval-center extent))))
 908
 909
 910 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 911 ;; ambitus
 912
 913 (define-public (ambitus::print grob)
 914   (let ((heads (ly:grob-object grob 'note-heads)))
 915
 916     (if (and (ly:grob-array? heads)
 917              (= (ly:grob-array-length heads) 2))
 918         (let* ((common (ly:grob-common-refpoint-of-array grob heads Y))
 919                (head-down (ly:grob-array-ref heads 0))
 920                (head-up (ly:grob-array-ref heads 1))
 921                (gap (ly:grob-property grob 'gap 0.35))
 922                (point-min (+ (interval-end (ly:grob-extent head-down common Y))
 923                              gap))
 924                (point-max (- (interval-start (ly:grob-extent head-up common Y))
 925                              gap)))
 926
 927           (if (< point-min point-max)
 928               (let* ((layout (ly:grob-layout grob))
 929                      (line-thick (ly:output-def-lookup layout 'line-thickness))
 930                      (blot (ly:output-def-lookup layout 'blot-diameter))
 931                      (grob-thick (ly:grob-property grob 'thickness 2))
 932                      (width (* line-thick grob-thick))
 933                      (x-ext (symmetric-interval (/ width 2)))
 934                      (y-ext (cons point-min point-max))
 935                      (line (ly:round-filled-box x-ext y-ext blot))
 936                      (y-coord (ly:grob-relative-coordinate grob common Y)))
 937
 938                 (ly:stencil-translate-axis line (- y-coord) Y))
 939               empty-stencil))
 940         (begin
 941           (ly:grob-suicide! grob)
 942           (list)))))
 943
 944 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 945 ;;  laissez-vibrer tie
 946 ;;
 947 ;;  needed so we can make laissez-vibrer a pure print
 948 ;;
 949 (define-public (laissez-vibrer::print grob)
 950  (ly:tie::print grob))
 951