scm/ly-syntax-constructors.scm

   1 ;;;; define-syntax.scm -- Defines functions for syntax expressions
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2006 Erik Sandberg <mandolaerik@gmail.com>
   6
   7 ;; TODO: use separate module for syntax
   8 ;; constructors. Also create wrapper around the constructor?
   9 (define define-ly-syntax define-public)
  10
  11 ;; A ly-syntax constructor takes two extra parameters, parser and
  12 ;; location. These are mainly used for reporting errors and
  13 ;; warnings. This function is a syntactic sugar which uses the
  14 ;; location arg to set the origin of the returned music object; this
  15 ;; behaviour is usually desired
  16 (defmacro define-ly-syntax-loc (args . body)
  17   (primitive-eval `(define-ly-syntax ,args
  18                      (let ((m ,(cons 'begin body)))
  19                        (set! (ly:music-property m 'origin) ,(third args))
  20                        m))))
  21
  22 ;; Like define-ly-syntax-loc, but adds parser and location
  23 ;; parameters. Useful for simple constructors that don't need to
  24 ;; report errors.
  25 (defmacro define-ly-syntax-simple (args . body)
  26   (primitive-eval `(define-ly-syntax ,(cons* (car args)
  27                                              'parser
  28                                              'location
  29                                              (cdr args))
  30                      (let ((m ,(cons 'begin body)))
  31                        (set! (ly:music-property m 'origin) location)
  32                        m))))
  33
  34 ;; Music function: Apply function and check return value.
  35 (define-ly-syntax-loc (music-function parser loc fun args)
  36   (let ((m (apply fun (cons* parser loc args))))
  37     (if (ly:music? m)
  38         m
  39         (begin
  40           (ly:parser-error parser (_ "Music head function must return Music object") loc)
  41           (make-music 'Music)))))
  42
  43 (define-ly-syntax-simple (void-music)
  44   (make-music 'Music))
  45
  46 (define-ly-syntax-simple (sequential-music mlist)
  47   (make-sequential-music mlist))
  48
  49 (define-ly-syntax-simple (simultaneous-music mlist)
  50   (make-simultaneous-music mlist))
  51
  52 (define-ly-syntax-simple (event-chord mlist)
  53   (make-music 'EventChord
  54               'elements mlist))
  55
  56 (define-ly-syntax-simple (unrelativable-music mus)
  57   (make-music 'UnrelativableMusic
  58               'element mus))
  59
  60 (define-ly-syntax-simple (context-change type id)
  61   (make-music 'ContextChange
  62               'change-to-type type
  63               'change-to-id id))
  64
  65 (define-ly-syntax-simple (voice-separator)
  66   (make-music 'VoiceSeparator))
  67
  68 (define-ly-syntax-simple (bar-check)
  69   (make-music 'BarCheck))
  70
  71 (define-ly-syntax-simple (time-scaled-music fraction music)
  72   (make-music 'TimeScaledMusic
  73               'element (ly:music-compress music (ly:make-moment (car fraction) (cdr fraction)))
  74               'numerator (car fraction)
  75               'denominator (cdr fraction)))
  76
  77 (define-ly-syntax-simple (transpose-music pitch music)
  78   (make-music 'TransposedMusic
  79               'element (ly:music-transpose music pitch)))
  80
  81 (define-ly-syntax-simple (skip-music dur)
  82   (make-music 'SkipMusic
  83               'duration dur))
  84
  85 (define-ly-syntax-simple (repeat type num body alts)
  86   (make-repeat type num body alts))
  87
  88 ;; UGH. TODO: represent mm rests in a decent way as music expressions.
  89 ;; Also eliminate glue-mm-rests while we are at it.
  90 (define-ly-syntax (multi-measure-rest parser location duration articulations)
  91   (let* ((mus (make-multi-measure-rest duration location))
  92          (elts (ly:music-property mus 'elements)))
  93     (set! (ly:music-property mus 'elements)
  94           (append elts articulations))
  95     mus))
  96
  97 (define-ly-syntax-simple (context-specification type id mus ops create-new)
  98   (let* ((type-sym (if (symbol? type) type (string->symbol type)))
  99          (csm (context-spec-music mus type-sym id)))
 100     (set! (ly:music-property csm 'property-operations) ops)
 101     (if create-new (set! (ly:music-property csm 'create-new) #t))
 102     csm))
 103
 104 (define-ly-syntax (property-operation parser location once ctx music-type symbol . args)
 105   (let* ((props (case music-type
 106                   ((PropertySet) (list 'value (car args)))
 107                   ((PropertyUnset) '())
 108                   ((OverrideProperty) (list 'grob-value (car args)
 109                                             'grob-property-path (cdr args)
 110                                             'pop-first #t))
 111                   ((RevertProperty) (list 'grob-property-path args))
 112                   (else (ly:error (_ "Invalid property operation ~a") music-type))))
 113          (oprops (if once (cons* 'once once props) props))
 114          (m (apply make-music music-type
 115                    'symbol symbol
 116                    'origin location
 117                    oprops)))
 118     (make-music 'ContextSpeccedMusic
 119                 'element m
 120                 'context-type ctx
 121                 'origin location)))
 122
 123 ;; TODO: It seems that this function rarely returns anything useful.
 124 (define (get-first-context-id type mus)
 125   "Find the name of a ContextSpeccedMusic with given type"
 126   (let ((id (ly:music-property mus 'context-id)))
 127     (if (and (eq? (ly:music-property mus 'type) 'ContextSpeccedMusic)
 128              (eq? (ly:music-property mus 'context-type) type)
 129              (string? id)
 130              (not (string-null? id)))
 131         id
 132         '())))
 133
 134 (define unique-counter -1)
 135 (define (get-next-unique-voice-name)
 136   (set! unique-counter (1+ unique-counter))
 137   (call-with-output-string (lambda (p) (format p "uniqueContext~s" unique-counter))))
 138
 139 (define (lyric-combine-music sync music loc)
 140   (make-music 'LyricCombineMusic
 141               'element music
 142               'associated-context sync
 143               'origin loc))
 144
 145 (define-ly-syntax (lyric-combine parser location voice music)
 146   (lyric-combine-music voice music location))
 147
 148 (define-ly-syntax (add-lyrics parser location music addlyrics-list)
 149   (let* ((existing-voice-name (get-first-context-id 'Voice music))
 150          (voice-name (if (string? existing-voice-name)
 151                          existing-voice-name
 152                          (get-next-unique-voice-name)))
 153          (voice (if (string? existing-voice-name)
 154                     (music)
 155                     (make-music 'ContextSpeccedMusic
 156                                 'element music
 157                                 'context-type 'Voice
 158                                 'context-id voice-name
 159                                 'origin (ly:music-property music 'origin))))
 160          (lyricstos (map (lambda (mus)
 161                            (let* ((loc (ly:music-property mus 'origin))
 162                                   (lyr (lyric-combine-music voice-name mus loc)))
 163                              (make-music 'ContextSpeccedMusic
 164                                          'create-new #t
 165                                          'context-type 'Lyrics
 166                                          'element lyr
 167                                          'origin loc)))
 168                          addlyrics-list)))
 169     (make-simultaneous-music (cons voice lyricstos))))