scm/framework-ps.scm

   1 ;;;; framework-ps.scm -- structure for PostScript output
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2005 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   6
   7 (define-module (scm framework-ps))
   8
   9 ;;; this is still too big a mess.
  10
  11 (use-modules (ice-9 regex)
  12              (ice-9 string-fun)
  13              (ice-9 format)
  14              (guile)
  15              (srfi srfi-1)
  16              (srfi srfi-13)
  17              (lily))
  18
  19
  20 (define framework-ps-module (current-module))
  21
  22 ;;(define pdebug stderr)
  23 (define (pdebug . rest) #f)
  24
  25 (define mm-to-bigpoint
  26   (/ 72 25.4))
  27
  28 (define-public (ps-font-command font)
  29   (let* ((name (munge-lily-font-name (ly:font-file-name font)))
  30          (magnify (ly:font-magnification font)))
  31
  32     (string-append
  33      "magfont"
  34      (string-regexp-substitute "[ /%]" "_" name)
  35      "m" (string-encode-integer (inexact->exact (round (* 1000 magnify)))))))
  36
  37 (define (tex-font? fontname)
  38   (or
  39    (equal? (substring fontname 0 2) "cm")
  40    (equal? (substring fontname 0 2) "ec")))
  41
  42 (define (define-fonts paper)
  43   (define font-list (ly:paper-fonts paper))
  44   (define (define-font command fontname scaling)
  45     (string-append
  46      "/" command " { /" fontname " findfont "
  47      (ly:number->string scaling) " output-scale div scalefont } bind def\n"))
  48
  49   (define (standard-tex-font? x)
  50     (or (equal? (substring x 0 2) "ms")
  51         (equal? (substring x 0 2) "cm")))
  52
  53   (define (font-load-command font)
  54     (let* ((specced-font-name (ly:font-name font))
  55            (fontname (if specced-font-name
  56                          (munge-lily-font-name specced-font-name)
  57                          (ly:font-file-name font)))
  58            (command (ps-font-command font))
  59
  60            ;; FIXME -- see (ps-font-command )
  61            (plain (ps-font-command font))
  62            (designsize (ly:font-design-size font))
  63            (magnification (* (ly:font-magnification font)))
  64            (ops (ly:output-def-lookup paper 'outputscale))
  65            (scaling (* ops magnification designsize)))
  66
  67       ;; Bluesky pfbs have UPCASE names (sigh.)
  68       ;; FIXME - don't support Bluesky?
  69       (if (standard-tex-font? fontname)
  70           (set! fontname (string-upcase fontname)))
  71       (if (equal? fontname "unknown")
  72           (display (list font fontname)))
  73       (define-font plain fontname scaling)))
  74
  75   (apply string-append
  76          (map (lambda (x) (font-load-command x))
  77               (filter (lambda (x) (not (ly:pango-font? x)))
  78                       font-list))))
  79
  80 ;; FIXME: duplicated in other output backends
  81 ;; FIXME: silly interface name
  82 (define (output-variables layout)
  83   ;; FIXME: duplicates output-layout's scope-entry->string, mostly
  84   (define (value->string val)
  85     (cond
  86      ((string? val) (string-append "(" val ")"))
  87      ((symbol? val) (symbol->string val))
  88      ((number? val) (number->string val))
  89      (else "")))
  90
  91   (define (output-entry ps-key ly-key)
  92     (string-append
  93      "/" ps-key " "
  94      (value->string (ly:output-def-lookup layout ly-key)) " def\n"))
  95
  96   (string-append
  97    "/lily-output-units "
  98      (number->string mm-to-bigpoint)
  99      " def %% millimeter\n"
 100    (output-entry "staff-line-thickness" 'linethickness)
 101    (output-entry "line-width" 'linewidth)
 102    (output-entry "paper-size" 'papersizename)
 103    (output-entry "staff-height" 'staffheight)   ;junkme.
 104    "/output-scale "
 105      (number->string (ly:output-def-lookup layout 'outputscale))
 106      " def\n"
 107    (output-entry "page-height" 'vsize)
 108    (output-entry "page-width" 'hsize)))
 109
 110 (define (dump-page outputter page page-number page-count landscape?)
 111   (ly:outputter-dump-string
 112    outputter
 113    (string-append
 114     "%%Page: "
 115     (number->string page-number) " " (number->string page-count) "\n"
 116
 117     "%%BeginPageSetup\n"
 118     (if landscape?
 119         "page-width output-scale lily-output-units mul mul 0 translate 90 rotate\n"
 120         "")
 121     "%%EndPageSetup\n"
 122
 123     "start-page { "
 124     "set-ps-scale-to-lily-scale "
 125     "\n"))
 126   (ly:outputter-dump-stencil outputter page)
 127   (ly:outputter-dump-string outputter "} stop-system \nshowpage\n"))
 128
 129 (define (supplies-or-needs paper load-fonts?)
 130   (define (extract-names font)
 131     (if (ly:pango-font? font)
 132         (map car (ly:pango-font-physical-fonts font))
 133         (list (munge-lily-font-name (ly:font-name font)))))
 134
 135   (let* ((fonts (ly:paper-fonts paper))
 136          (names (apply append (map extract-names fonts))))
 137
 138     (apply string-append
 139            (map (lambda (f)
 140                   (format
 141                    (if load-fonts?
 142                     "%%DocumentSuppliedResources: font ~a\n"
 143                     "%%DocumentNeededResources: font ~a\n")
 144                    f))
 145                 (uniq-list (sort names string<?))))))
 146
 147 (define (eps-header paper bbox load-fonts?)
 148   (string-append "%!PS-Adobe-2.0 EPSF-2.0\n"
 149                  "%%Creator: LilyPond "
 150                  (lilypond-version)
 151                  "\n"
 152                  "%%BoundingBox: "
 153                  (string-join (map ly:number->string bbox) " ") "\n"
 154                  "%%Orientation: "
 155                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 156                      "Landscape\n"
 157                      "Portrait\n")
 158                  (supplies-or-needs paper load-fonts?)
 159                  "%%EndComments\n"))
 160
 161 (define (page-header paper page-count load-fonts?)
 162   (string-append "%!PS-Adobe-3.0\n"
 163                  "%%Creator: LilyPond "
 164                  (lilypond-version)
 165                  "\n"
 166
 167                  "%%Pages: " (number->string page-count) "\n"
 168                  "%%PageOrder: Ascend\n"
 169                  "%%Orientation: "
 170                  (if (eq? (ly:output-def-lookup paper 'landscape) #t)
 171                      "Landscape\n"
 172                      "Portrait\n")
 173                  "%%DocumentPaperSizes: "
 174                  (ly:output-def-lookup paper 'papersizename) "\n"
 175                  (supplies-or-needs paper load-fonts?)
 176                  "%%EndComments\n"))
 177
 178 (define (procset file-name)
 179   (string-append
 180    (format
 181     "%%BeginResource: procset (~a) 1 0
 182 ~a
 183 %%EndResource
 184 "
 185     file-name (cached-file-contents file-name))))
 186
 187 (define (setup paper)
 188   (string-append
 189    "\n"
 190    "%%BeginSetup\n"
 191    (define-fonts paper)
 192    (output-variables paper)
 193    "%%EndSetup\n"))
 194
 195 (define-public (munge-lily-font-name name)
 196   ;; FIXME: this fixes PFAPAFemmentaler.pfapfa, and also
 197   ;; PFAaybabtu.otf.pfa, but the second case now produces aybabtu.otf,
 198   ;; which still fails because .otf files cannot be embedded.
 199   (regexp-substitute/global #f "^([eE]mmentaler|[aA]ybabtu)"
 200                             name 'pre "PFA" 1 'post))
 201
 202 (define (cff-font? font)
 203   (let*
 204       ((cff-string (ly:otf-font-table-data font "CFF ")))
 205     (> (string-length cff-string) 0)))
 206
 207 (define-public (ps-embed-cff body font-set-name version)
 208   (let* ((binary-data
 209           (string-append
 210            (format "/~a ~s StartData " font-set-name (string-length body))
 211            body))
 212
 213          (header
 214           (format
 215            "%%BeginResource: font ~a
 216 %!PS-Adobe-3.0 Resource-FontSet
 217 %%DocumentNeededResources: ProcSet (FontSetInit)
 218 %%Title: (FontSet/~a)
 219 %%Version: ~s
 220 %%EndComments
 221 %%IncludeResource: ProcSet (FontSetInit)
 222 %%BeginResource: FontSet (~a)
 223 /FontSetInit /ProcSet findresource begin
 224 %%BeginData: ~s Binary Bytes
 225 "
 226            font-set-name font-set-name version font-set-name
 227            (string-length binary-data)))
 228          (footer "\n%%EndData
 229 %%EndResource
 230 %%EOF
 231 %%EndResource\n"))
 232
 233     (string-append
 234      header
 235      binary-data
 236      footer)))
 237
 238
 239 (define (write-preamble paper load-fonts? port)
 240
 241   (define (load-font-via-GS font-name-filename)
 242     (define (ps-load-file name)
 243       (format
 244        (if (string? name)
 245            "(~a) (r) file .loadfont\n"
 246            "% can't find font file: ~a\n")
 247        name))
 248
 249     (let* ((font (car font-name-filename))
 250            (name (cadr font-name-filename))
 251            (file-name (caddr font-name-filename))
 252            (bare-file-name (ly:find-file file-name)))
 253
 254       (cons
 255        (munge-lily-font-name name)
 256        (cond
 257         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 258          (ps-load-file (ly:find-file
 259                         (format "~a.pfa" (munge-lily-font-name file-name)))))
 260         ((string? bare-file-name)
 261          (ps-load-file (munge-lily-font-name file-name)))
 262         (else
 263          (ly:warning (_ "can't embed ~S=~S") name file-name)
 264           "")))))
 265
 266   (define (dir-join a b)
 267     (if (equal? a "")
 268         b
 269         (string-append a "/" b)))
 270
 271   (define (dir-listing dir-name)
 272     (define (dir-helper dir lst)
 273       (let ((e (readdir dir)))
 274         (if (eof-object? e) lst (dir-helper dir (cons e lst)))))
 275     (reverse (dir-helper (opendir dir-name) '())))
 276
 277   (define (handle-mac-font name filename)
 278     (let*
 279         ((dir-name  (tmpnam))
 280          (files '())
 281          (status 0)
 282          (embed #f))
 283
 284
 285       (mkdir dir-name #o700)
 286
 287       (set! status (ly:system
 288                     (format "cd ~a && fondu -force '~a'" dir-name filename)))
 289
 290       (set! files (dir-listing dir-name))
 291
 292       (for-each
 293        (lambda (f)
 294          (if (and (not embed)
 295                   (string-match (string-append name "\\.") f))
 296              (set! embed
 297                    (font-file-as-ps-string name (dir-join dir-name f))))
 298
 299          (if (or (equal? "." f)
 300                  (equal? ".." f))
 301              #t
 302              (delete-file (dir-join dir-name f))))
 303        files)
 304       (rmdir dir-name)
 305
 306       (if (not embed)
 307           (begin
 308             (set! embed "% failed \n")
 309             (ly:warning (_ "can't extract file matching ~a from ~a") name filename)))
 310       embed))
 311
 312     (define (font-file-as-ps-string name file-name)
 313       (let*
 314           ((downcase-file-name (string-downcase file-name)))
 315
 316       (cond
 317        ((and file-name (string-match "\\.pfa" downcase-file-name))
 318         (cached-file-contents file-name))
 319        ((and file-name (string-match "\\.pfb" downcase-file-name))
 320         (ly:pfb->pfa file-name))
 321        ((and file-name (string-match "\\.ttf" downcase-file-name))
 322         (ly:ttf->pfa file-name))
 323        ((and file-name (string-match "\\.otf" downcase-file-name))
 324         (ps-embed-cff (ly:otf->cff file-name) name 0))
 325        (else
 326         (ly:warning (_ "don't know how to embed ~S=~S") name file-name)
 327         ""))))
 328
 329   (define (load-font font-name-filename)
 330     (let* ((font (car font-name-filename))
 331            (name (cadr font-name-filename))
 332            (file-name (caddr font-name-filename))
 333            (bare-file-name (ly:find-file file-name)))
 334
 335       (cons
 336        (munge-lily-font-name name)
 337        (cond
 338         ((string-match "^([eE]mmentaler|[Aa]ybabtu)" file-name)
 339          (cached-file-contents
 340           (format "~a.pfa" (munge-lily-font-name file-name))))
 341         ((and
 342           (eq? PLATFORM 'darwin)
 343           bare-file-name (string-match "\\.dfont" bare-file-name))
 344          (handle-mac-font name bare-file-name))
 345
 346         ((and
 347           (eq? PLATFORM 'darwin)
 348           bare-file-name (= (stat:size (stat bare-file-name)) 0))
 349          (handle-mac-font name bare-file-name))
 350
 351         ((and font (cff-font? font))
 352          (ps-embed-cff (ly:otf-font-table-data font "CFF ")
 353                        name
 354                        0))
 355
 356         (bare-file-name (font-file-as-ps-string name bare-file-name))
 357         (else
 358          (ly:warning (_ "don't know how to embed font ~s ~s ~s")
 359                      name file-name font))))))
 360
 361
 362   (define (load-fonts paper)
 363     (let* ((fonts (ly:paper-fonts paper))
 364            (all-font-names
 365             (map
 366              (lambda (font)
 367                (cond
 368                 ((string? (ly:font-file-name font))
 369                  (list (list
 370                         font
 371                         (ly:font-name font)
 372                         (ly:font-file-name font))))
 373                 ((ly:pango-font? font)
 374                  (map
 375                   (lambda (name-psname-pair)
 376                     (list #f
 377                           (car name-psname-pair)
 378                           (cdr name-psname-pair)))
 379                   (ly:pango-font-physical-fonts font)))
 380
 381                 (else
 382                  (ly:font-sub-fonts font))))
 383
 384              fonts))
 385            (font-names
 386             (uniq-list
 387              (sort (apply append all-font-names)
 388                    (lambda (x y) (string<? (cadr x) (cadr y))))))
 389
 390
 391            (font-loader (if (ly:get-option 'gs-font-load)
 392                             load-font-via-GS
 393                             load-font))
 394
 395            (pfas (map font-loader font-names)))
 396       pfas))
 397
 398   (if load-fonts?
 399       (for-each
 400        (lambda (f)
 401          (format port "\n%%BeginFont: ~a\n" (car f))
 402          (display (cdr f) port)
 403          (display "\n%%EndFont\n" port))
 404        (load-fonts paper)))
 405
 406   (display (setup paper) port)
 407
 408   ;; adobe note 5002: should initialize variables before loading routines.
 409   (display (procset "music-drawing-routines.ps") port)
 410   (display (procset "lilyponddefs.ps") port)
 411   (display "init-lilypond-parameters\n" port))
 412
 413 (define-public (output-framework basename book scopes fields)
 414   (let* ((filename (format "~a.ps" basename))
 415          (outputter (ly:make-paper-outputter
 416                      ;; FIXME: better wrap open/open-file,
 417                      ;; content-mangling is always bad.
 418                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 419                      (open-file filename "wb")
 420                      "ps"))
 421          (paper (ly:paper-book-paper book))
 422          (pages (ly:paper-book-pages book))
 423          (landscape? (eq? (ly:output-def-lookup paper 'landscape) #t))
 424          (page-number (1- (ly:output-def-lookup paper 'firstpagenumber)))
 425          (page-count (length pages))
 426          (port (ly:outputter-port outputter)))
 427
 428     (output-scopes scopes fields basename)
 429     (display (page-header paper page-count #t) port)
 430     (write-preamble paper #t port)
 431
 432     (for-each
 433      (lambda (page)
 434        (set! page-number (1+ page-number))
 435        (dump-page outputter page page-number page-count landscape?))
 436      pages)
 437
 438     (display "%%Trailer\n%%EOF\n" port)
 439     (ly:outputter-close outputter)
 440     (postprocess-output book framework-ps-module filename
 441                          (ly:output-formats))))
 442
 443 (if (not (defined? 'nan?))
 444     (define (nan? x) #f))
 445
 446 (if (not (defined? 'inf?))
 447     (define (inf? x) #f))
 448
 449 (define-public (dump-stencil-as-EPS paper dump-me filename load-fonts?)
 450   (define (mm-to-bp-box mmbox)
 451     (let* ((scale (ly:output-def-lookup paper 'outputscale))
 452            (box (map
 453                  (lambda (x)
 454                    (inexact->exact
 455                     (round (* x scale mm-to-bigpoint)))) mmbox)))
 456
 457     (list (car box) (cadr box)
 458           (max (1+ (car box)) (caddr box))
 459           (max (1+ (cadr box)) (cadddr box)))))
 460
 461   (let* ((outputter (ly:make-paper-outputter
 462                      ;; FIXME: better wrap open/open-file,
 463                      ;; content-mangling is always bad.
 464                      ;; MINGW hack: need to have "b"inary for embedding CFFs
 465                      (open-file (format "~a.eps" filename) "wb")
 466                      "ps"))
 467          (port (ly:outputter-port outputter))
 468          (xext (ly:stencil-extent dump-me X))
 469          (yext (ly:stencil-extent dump-me Y))
 470          (bbox
 471           (map
 472            (lambda (x)
 473              (if (or (nan? x) (inf? x)
 474                      ;; FIXME: huh?
 475                      (equal? (format #f "~S" x) "+#.#")
 476                      (equal? (format #f "~S" x) "-#.#"))
 477                  0.0 x))
 478            ;; set left of X to 0, to prevent barnumbers
 479            ;; from sticking out of margin.
 480            (list 0.0 (car yext) (cdr xext) (cdr yext))))
 481          (rounded-bbox (mm-to-bp-box bbox))
 482          (port (ly:outputter-port outputter))
 483          (header (eps-header paper rounded-bbox load-fonts?)))
 484
 485     (display header port)
 486     (write-preamble paper load-fonts? port)
 487     (display "start-system { set-ps-scale-to-lily-scale \n" port)
 488     (ly:outputter-dump-stencil outputter dump-me)
 489     (display "} stop-system\n%%Trailer\n%%EOF\n" port)
 490     (ly:outputter-close outputter)))
 491
 492 (define-public (output-preview-framework basename book scopes fields)
 493   (let* ((paper (ly:paper-book-paper book))
 494          (systems (ly:paper-book-systems book))
 495          (scale (ly:output-def-lookup paper 'outputscale))
 496          (to-dump-systems '()))
 497
 498     ;; skip booktitles.
 499     (if (and
 500          (not (ly:get-option 'preview-include-book-title))
 501          (pair? systems)
 502          (ly:paper-system-property (car systems) 'is-book-title #f))
 503
 504         (set! systems (cdr systems)))
 505
 506     (for-each
 507      (lambda (sys)
 508        (if (or
 509             (paper-system-title? sys)
 510             (not (pair? to-dump-systems))
 511             (paper-system-title? (car to-dump-systems)))
 512            (set! to-dump-systems (cons sys to-dump-systems))))
 513      systems)
 514
 515     (dump-stencil-as-EPS
 516      paper
 517      (stack-stencils Y DOWN 0.0
 518                      (map paper-system-stencil (reverse to-dump-systems)))
 519      (format "~a.preview" basename)
 520      #t)
 521
 522     (postprocess-output book framework-ps-module
 523                         (format "~a.preview.eps" basename)
 524                         (cons "png" (ly:output-formats)))))
 525 (if #f
 526     (define-public (output-preview-framework basename book scopes fields)
 527
 528       (let* ((paper (ly:paper-book-paper book))
 529              (systems (ly:paper-book-systems book))
 530              (scale (ly:output-def-lookup paper 'outputscale))
 531              (titles (take-while paper-system-title? systems))
 532              (non-title (find (lambda (x)
 533                                 (not (paper-system-title? x))) systems))
 534              (dump-me
 535               (stack-stencils Y DOWN 0.0
 536                               (map paper-system-stencil
 537                                    (append titles (list non-title))))))
 538         (output-scopes scopes fields basename)
 539         (dump-stencil-as-EPS paper dump-me
 540                              (format "~a.preview" basename)
 541                              #t)
 542
 543         (postprocess-output book framework-ps-module
 544                             (format "~a.preview.eps" basename)
 545                              (ly:output-formats)))))
 546 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 547
 548 (define-public (convert-to-pdf book name)
 549   (let* ((defs (ly:paper-book-paper book))
 550          (papersizename (ly:output-def-lookup defs 'papersizename)))
 551
 552     (if (equal? (basename name ".ps") "-")
 553         (ly:warning (_ "can't convert <stdout> to ~S" "PDF"))
 554         (postscript->pdf (if (string? papersizename) papersizename "a4")
 555                          name))))
 556
 557 (define-public (convert-to-png book name)
 558   (let* ((defs (ly:paper-book-paper book))
 559          (defs-resolution (ly:output-def-lookup defs 'pngresolution))
 560          (resolution (if (number? defs-resolution)
 561                          defs-resolution
 562                          (ly:get-option 'resolution)))
 563          (papersizename (ly:output-def-lookup defs 'papersizename)))
 564
 565     (postscript->png resolution
 566                      (if (string? papersizename) papersizename "a4")
 567                      name)))
 568
 569 (define-public (convert-to-dvi book name)
 570   (ly:warning (_ "can't generate ~S using the postscript back-end") "DVI"))
 571
 572 (define-public (convert-to-tex book name)
 573   (ly:warning (_ "can't generate ~S using the postscript back-end") "TeX"))
 574
 575 (define-public (convert-to-ps book name)
 576   #t)
 577
 578 (define-public (output-classic-framework basename book scopes fields)
 579
 580   (ly:error (_ "\nThe PostScript backend does not support the 'classic'
 581 framework. Use the EPS backend instead,
 582
 583   lilypond -b eps <file>
 584
 585 or remove the lilypond-book specific settings from the input.
 586 ")))