scm/framework-gnome.scm

   1 ;;;; framework-gnome.scm --
   2 ;;;;
   3 ;;;;  source file of the GNU LilyPond music typesetter
   4 ;;;;
   5 ;;;; (c) 2004--2005 Jan Nieuwenhuizen <janneke@gnu.org>
   6
   7 ;;;; See output-gnome.scm for usage information.
   8
   9
  10 (define-module (scm framework-gnome))
  11
  12 (use-modules (guile) (oop goops) (lily))
  13
  14 (use-modules
  15  (srfi srfi-2)
  16  (ice-9 regex)
  17  (gnome gtk)
  18  (gnome gtk gdk-event)
  19  (gnome gw canvas))
  20
  21 (define-public (output-framework basename book scopes fields )
  22   (gnome-main book basename))
  23
  24 (define SCROLLBAR-SIZE 20)
  25 (define BUTTON-HEIGHT 25)
  26 (define PANELS-HEIGHT 80)
  27
  28 (define PIXELS-PER-UNIT 2)
  29 ;; 2.5??
  30 (define OUTPUT-SCALE (* 2.5 PIXELS-PER-UNIT))
  31 (define-public output-scale OUTPUT-SCALE)
  32
  33 (define (debugf string . rest)
  34   (if #f
  35       (apply stderr (cons string rest))))
  36
  37 (define-class <gnome-outputter> ()
  38   (name #:init-value "untitled" #:init-keyword #:name #:accessor name)
  39
  40   ;; FIXME
  41   (dragging #:init-value #f #:accessor dragging)
  42   (drag-origin #:init-value #f #:accessor drag-origin)
  43   (drag-location #:init-value #f #:accessor drag-location)
  44
  45   (page-stencils ;;#:init-value '#()
  46    #:init-keyword #:page-stencils #:accessor page-stencils)
  47   (window #:init-value (make <gtk-window> #:type 'toplevel) #:accessor window)
  48   (scrolled #:init-value (make <gtk-scrolled-window>) #:accessor scrolled)
  49   (canvas #:init-value #f #:accessor canvas)
  50   (page-number #:init-value 0 #:accessor page-number)
  51   (pixels-per-unit #:init-value PIXELS-PER-UNIT #:accessor pixels-per-unit)
  52   (text-items #:init-value '() #:accessor text-items)
  53   (grob #:init-value #f #:accessor grob)
  54   (item-grobs #:init-value (make-hash-table 31) #:accessor item-grobs)
  55   (window-width #:init-keyword #:window-width #:accessor window-width)
  56   (window-height #:init-keyword #:window-height #:accessor window-height)
  57   (canvas-width #:init-keyword #:canvas-width #:accessor canvas-width)
  58   (canvas-height #:init-keyword #:canvas-height #:accessor canvas-height))
  59
  60 (define-method (initialize (go <gnome-outputter>))
  61   (let* ((save (make <gtk-button> #:label "Save"))
  62          (exit (make <gtk-button> #:label "Exit"))
  63          (next (make <gtk-button> #:label "Next"))
  64          (prev (make <gtk-button> #:label "Previous"))
  65          (vbox (make <gtk-vbox> #:homogeneous #f))
  66          (hbox (make <gtk-hbox> #:homogeneous #f)))
  67
  68     (set-size-request (window go) (window-width go) (window-height go))
  69
  70     (set-size-request (scrolled go) (window-width go) (- (window-height go)
  71                                                          BUTTON-HEIGHT
  72                                                          SCROLLBAR-SIZE))
  73
  74     (new-canvas go)
  75
  76     (add (window go) vbox)
  77     (add vbox (scrolled go))
  78
  79     (add (scrolled go) (canvas go))
  80
  81     ;; buttons
  82     (add vbox hbox)
  83     (set-size-request hbox (window-width go) BUTTON-HEIGHT)
  84
  85     ;; hmm?  These are broken when using <gnome-outputter>.
  86     ;;(set-child-packing vbox hbox #f #f 0 'end)
  87     ;;(set-child-packing hbox button #f #f 0 'end)
  88
  89     (set-size-request exit (quotient (window-width go) 2) BUTTON-HEIGHT)
  90
  91
  92     (add hbox next)
  93     (add hbox prev)
  94     (add hbox save)
  95     (add hbox exit)
  96
  97     ;; signals
  98     (connect exit 'clicked (lambda (b) (gtk-main-quit)))
  99     (connect save 'clicked (lambda (b) (save-tweaks go)))
 100     (connect next 'clicked (lambda (b) (dump-page go (1+ (page-number go)))))
 101     (connect prev 'clicked (lambda (b) (dump-page go (1- (page-number go)))))
 102     (connect (window go) 'key-press-event
 103              (lambda (w e) (key-press-event go w e)))
 104
 105     (show-all (window go))))
 106
 107
 108 (define (gnome-main book name)
 109   (let* ((paper (ly:paper-book-paper book))
 110          (hsize (ly:output-def-lookup paper 'hsize))
 111          (vsize (ly:output-def-lookup paper 'vsize))
 112          (page-width (inexact->exact (ceiling (* OUTPUT-SCALE hsize))))
 113          (page-height (inexact->exact (ceiling (* OUTPUT-SCALE vsize))))
 114          ;;(page-width (inexact->exact (ceiling hsize)))
 115          ;;(page-height (inexact->exact (ceiling vsize)))
 116
 117          (screen-width (gdk-screen-width))
 118          (screen-height (gdk-screen-height))
 119          (desktop-height (- screen-height PANELS-HEIGHT))
 120
 121          (go (make <gnome-outputter>
 122                #:name name
 123                #:page-stencils (list->vector (ly:paper-book-pages book))
 124                #:canvas-width page-width
 125                #:canvas-height page-height
 126                #:window-width
 127                ;; huh, *2 -- pixels-per-unit?
 128                (min (+ SCROLLBAR-SIZE (* page-width 2)) screen-width)
 129                #:window-height
 130                (min (+ BUTTON-HEIGHT SCROLLBAR-SIZE (* page-height 2))
 131                     desktop-height))))
 132
 133     ;; ugh.  The GOOPS doc promises this is called automagically.
 134     ;; possibly a goops 1.6.4 problem
 135     (initialize go)
 136
 137     (dump-page go 0)
 138
 139     (gtk-main)))
 140
 141 (define (dump-page go number)
 142   (if (or (not (page-stencils go))
 143           (< number 0)
 144           (>= number (vector-length (page-stencils go))))
 145       (stderr "No such page: ~S\n" (1+ number))
 146
 147       (let ((old-canvas (canvas go)))
 148         (new-canvas go)
 149         (set! (page-number go) number)
 150
 151         ;; no destroy method for gnome-canvas-text yet.
 152         ;;(map destroy (gtk-container-get-children main-canvas))
 153         ;;(map destroy text-items)
 154
 155         (set! (text-items go) '())
 156         (debugf "page-stencil ~S: ~S\n"
 157                 (page-number go)
 158                 (vector-ref (page-stencils go) (page-number go)))
 159
 160         (ly:interpret-stencil-expression
 161          ;; ;;(vector-ref (page-stencils go) (page-number go))
 162          (ly:stencil-expr (vector-ref (page-stencils go) (page-number go)))
 163          gnome-output-expression go '(0 . 0))
 164
 165         (if old-canvas (destroy old-canvas))
 166         (add (scrolled go) (canvas go))
 167         (show (canvas go)))))
 168
 169 (define x-editor #f)
 170 (define (get-x-editor)
 171   (if (not x-editor)
 172       (set! x-editor (getenv "XEDITOR")))
 173   x-editor)
 174
 175 (define ifs #f)
 176 (define (get-ifs)
 177   (if (not ifs)
 178       (set! ifs (getenv "IFS")))
 179   (if (not ifs)
 180       (set! ifs "       "))
 181   ifs)
 182
 183 (define (spawn-editor location)
 184   (let* ((file-name (car location))
 185          (line (cadr location))
 186          (column (caddr location))
 187          (template (substring (get-x-editor) 0))
 188
 189          ;; Adhere to %l %c %f?
 190          (command
 191           (regexp-substitute/global
 192            #f "%l" (regexp-substitute/global
 193                     #f "%c"
 194                     (regexp-substitute/global
 195                      #f "%f" template 'pre file-name 'post)
 196                     'pre (number->string column)
 197                     'post)
 198            'pre (number->string line) 'post)))
 199
 200     (debugf "spawning: ~s\n" command)
 201     (if (= (primitive-fork) 0)
 202         (let ((command-list (string-split command #\ )));; (get-ifs))))
 203           (apply execlp command-list)
 204           (primitive-exit)))))
 205
 206 (define location-callback spawn-editor)
 207
 208 (define (get-location grob)
 209   (and-let* ((p? (procedure? point-and-click))
 210              (g grob)
 211              (cause (ly:grob-property grob 'cause))
 212              (music-origin (if (ly:music? cause)
 213                                (ly:music-property cause 'origin)
 214                                ;; How come #<unspecied> [and '()]
 215                                ;; are #t? :-(
 216                                #f)))
 217             (if (ly:input-location? music-origin)
 218                 (ly:input-location music-origin)
 219                 #f)))
 220
 221
 222 (define-method (tweak (go <gnome-outputter>) item offset)
 223   (let* ((grob (hashq-ref (item-grobs go) item #f))
 224          (extra-offset (ly:grob-property grob 'extra-offset))
 225          (origin (if (null? extra-offset) '(0 . 0)
 226                      (offset-flip-y extra-offset))))
 227
 228     (if grob
 229         (ly:grob-replace-tweak
 230          grob (list tweak-grob-property
 231                     'extra-offset
 232                     (offset-flip-y (offset-add origin offset)))))))
 233
 234 (define-method (save-tweaks (go <gnome-outputter>))
 235   (let* ((dumper (ly:make-dumper))
 236          (tweaks (ly:all-tweaks))
 237          (serialized-tweaks
 238           (map
 239            (lambda (tweak) (append
 240                             (list (ly:dumper-key-serial dumper (car tweak))
 241                                   (list 'unquote (procedure-name (cadr tweak))))
 242                             (cddr tweak)))
 243            tweaks)))
 244
 245     (if (not (null? serialized-tweaks))
 246         (let ((file (open-file (string-append (name go) ".twy") "w")))
 247           (format file
 248                   ";;;tweaks. Generated file. Do not edit.
 249 (ly:tweak-clear-registry)
 250 (ly:tweak-define-keys `~S)
 251 (ly:tweak-define-tweaks `~S)"
 252                   (ly:dumper-definitions dumper)
 253                   serialized-tweaks)))))
 254
 255 ;;;(define (item-event go grob item event)
 256 (define (item-event go item event)
 257   ;;(stderr "EVENT: ~S\n" event)
 258   ;;(stderr "TYPE: ~S\n" (gdk-event:type event))
 259   (case (gdk-event:type event)
 260     ((enter-notify) (gobject-set-property item 'fill-color "red"))
 261     ((leave-notify) (gobject-set-property item 'fill-color "black"))
 262     ((motion-notify) (if (ly:grob? (dragging go))
 263                          (let ((x (gdk-event-motion:x event))
 264                                (y (gdk-event-motion:y event))
 265                                (s output-scale)
 266                                (r (drag-location go)))
 267                            ;;(stderr "MOVED AT: ~S ~S\n" x y)
 268                            (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 269                            (set! (drag-location go) (cons x y)))))
 270     ((button-release) (if (ly:grob? (dragging go))
 271                           (let ((x (gdk-event-button:x event))
 272                                 (y (gdk-event-button:y event))
 273                                 (s output-scale)
 274                                 (o (drag-origin go))
 275                                 (r (drag-location go)))
 276                             (move item (/ (- x (car r)) s) (/ (- y (cdr r)) s))
 277                             (set! (drag-location go) #f)
 278                             (set! (drag-origin go) #f)
 279                             (stderr "RELEASE at: ~S ~S\n" x y)
 280                             (set! (dragging go) #f)
 281                             (tweak go item (cons (/ (- x (car o)) s)
 282                                                  (/ (- y (cdr o)) s))))))
 283     ((button-press)
 284      (let ((button (gdk-event-button:button event)))
 285        (cond
 286         ((= button 1)
 287          (if (null? (gdk-event-button:modifiers event))
 288              (let ((x (gdk-event-button:x event))
 289                    (y (gdk-event-button:y event)))
 290                (stderr "CLICK at: ~S ~S\n" x y)
 291                (set! (dragging go) (hashq-ref (item-grobs go) item #f))
 292                (set! (drag-origin go) (cons x y))
 293                (set! (drag-location go) (cons x y)))
 294              (begin
 295                (stderr "CLICK WITH MODIFIERS: ~S\n"
 296                        (gdk-event-button:modifiers event))
 297
 298                ;; some modifier, do jump to source
 299                (and-let* ((grob (hashq-ref (item-grobs go) item #f))
 300                           (location (get-location grob)))
 301                          (location-callback location)))))
 302         ((= button 2)
 303          (and-let* ((grob (hashq-ref (item-grobs go) item #f)))
 304
 305                    (let ((properties (ly:grob-properties grob))
 306                          (basic-properties (ly:grob-basic-properties grob))
 307                          (x (inexact->exact (gdk-event-button:x-root event)))
 308                          (y (inexact->exact (gdk-event-button:y-root event))))
 309
 310                      (debugf "GROB: ~S\n" grob)
 311                      (debugf "PROPERTIES: ~S\n" properties)
 312                      (debugf "BASIC PROPERTIES: ~S\n" basic-properties)
 313
 314                      ;; FIXME: dialog iso window?
 315                      ;; http://www.gtk.org/tutorial/sec-textentries.html
 316                      (let ((window (make <gtk-window>))
 317                            (vbox (make <gtk-vbox>))
 318                            (ok (make <gtk-button> #:label "Ok")))
 319
 320                        (add window vbox)
 321                        (connect ok 'clicked (lambda (b) (destroy window)))
 322
 323                        (for-each
 324                         (lambda (x)
 325                           (let ((label (make <gtk-label>
 326                                          ;;#:label (symbol->string (car x))))
 327                                          #:label (format #f "~S" (car x))))
 328                                 ;;(symbol->string (car x))))
 329                                 (entry (make <gtk-entry>
 330                                          #:text (format #f "~S" (cdr x))))
 331                                 (hbox (make <gtk-hbox>)))
 332                             (add hbox label)
 333                             (add hbox entry)
 334                             (set-size-request label 150 BUTTON-HEIGHT)
 335                             (add vbox hbox)))
 336                         (append properties basic-properties))
 337                        (add vbox ok)
 338
 339                        (show-all window)
 340                        (move window x y))))))))
 341
 342     ((2button-press) (gobject-set-property item 'fill-color "green"))
 343     ((key-press)
 344      (let ((keyval (gdk-event-key:keyval event))
 345            (mods (gdk-event-key:modifiers event))
 346            (step (quotient (pixels-per-unit go) 2)))
 347        (cond ((and (null? mods)
 348                    (eq? keyval gdk:Up))
 349               (tweak go item (cons 0 (- 0 step))))
 350              ((and (null? mods)
 351                    (eq? keyval gdk:Down))
 352               (tweak go item (cons 0 step)))
 353              ((and (null? mods)
 354                    (eq? keyval gdk:Left))
 355               (tweak go item (cons (- 0 step) 0)))
 356              ((and (null? mods)
 357                    (eq? keyval gdk:Right))
 358               (tweak go item (cons step 0)))))))
 359   #t)
 360
 361 (define (scale-canvas go factor)
 362   (set! (pixels-per-unit go) (* (pixels-per-unit go) factor))
 363   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 364   (for-each
 365    (lambda (x)
 366      (let ((scale (gobject-get-property x 'scale))
 367            (points (gobject-get-property x 'size-points)))
 368        ;;(gobject-set-property x 'scale pixels-per-unit)
 369        (gobject-set-property x 'size-points (* points factor))))
 370    (text-items go)))
 371
 372 (define (key-press-event go item event)
 373   (let ((keyval (gdk-event-key:keyval event))
 374         (mods (gdk-event-key:modifiers event)))
 375     (cond ((and (or (eq? keyval gdk:q)
 376                     (eq? keyval gdk:w))
 377                 (equal? mods '(control-mask modifier-mask)))
 378            (gtk-main-quit))
 379           ((and (eq? keyval gdk:s)
 380                 (equal? mods '(control-mask modifier-mask)))
 381                 (save-tweaks go))
 382           ((and #t ;;(null? mods)
 383                 (eq? keyval gdk:plus))
 384            (scale-canvas go 2))
 385           ((and #t ;; (null? mods)
 386                 (eq? keyval gdk:minus))
 387            (scale-canvas go 0.5))
 388           ((or (eq? keyval gdk:Page-Up)
 389                (eq? keyval gdk:BackSpace))
 390            (dump-page go (1- (page-number go))))
 391           ((or (eq? keyval gdk:Page-Down)
 392                (eq? keyval gdk:space))
 393            (dump-page go (1+ (page-number go)))))
 394     #f))
 395
 396 (define (new-canvas go)
 397   (set! (canvas go) (make <gnome-canvas>))
 398   (set-size-request (canvas go) (window-width go) (window-height go))
 399   (set-scroll-region (canvas go) 0 0 (canvas-width go) (canvas-height go))
 400   (set-pixels-per-unit (canvas go) (pixels-per-unit go))
 401   (make <gnome-canvas-rect>
 402     #:parent (root (canvas go))
 403     #:x2 (canvas-width go) #:y2 (canvas-height go)
 404     #:fill-color "white"))
 405
 406 (define output-gnome-module #f)
 407 (define (get-output-gnome-module go)
 408   (if (not output-gnome-module)
 409       (let ((m  (resolve-module '(scm output-gnome))))
 410         (module-define! m 'canvas-root (lambda () (root (canvas go))))
 411         (module-define! m 'output-scale output-scale)
 412         (set! output-gnome-module m)))
 413   output-gnome-module)
 414
 415 (define-public (gnome-output-expression go expr)
 416   (let* ((m (get-output-gnome-module go))
 417          (result (eval expr m)))
 418     (cond
 419      ((ly:grob? result) (set! (grob go) result))
 420      ((is-a? result <gnome-canvas-item>)
 421
 422       ;; AAARGH; grobs happen after stencils
 423       ;; (connect result 'event (lambda (w e) (item-event go (grob go) w e)))
 424       (connect result 'event (lambda (w e) (item-event go w e)))
 425       (if (grob go)
 426           (hashq-set! (item-grobs go) result (grob go)))
 427       (set! (grob go) #f)
 428
 429       (if (is-a? result <gnome-canvas-text>)
 430           (set! (text-items go) (cons result (text-items go))))))))