scm/chords-ignatzek.scm

   1 ;;;
   2 ;;; chord-name.scm --  chord name utility functions
   3 ;;;
   4 ;;; source file of the GNU LilyPond music typesetter
   5 ;;;
   6 ;;; (c)  2000--2003  Han-Wen Nienhuys
   7
   8
   9 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  10 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  11 ;;
  12 ;; jazz-part 2
  13 ;;
  14 ;; after Klaus Ignatzek,   Die Jazzmethode fuer Klavier 1.
  15 ;;
  16 ;; The idea is: split chords into
  17 ;;
  18 ;;  ROOT PREFIXES MAIN-NAME ALTERATIONS SUFFIXES ADDITIONS
  19 ;;
  20 ;; and put that through a layout routine.
  21 ;;
  22 ;; the split is a procedural process, with lots of set!.
  23 ;;
  24
  25
  26 ;; todo: naming is confusing: steps  (0 based) vs. steps (1 based).
  27 (define (pitch-step p)
  28   "Musicological notation for an interval. Eg. C to D is 2."
  29   (+ 1 (ly:pitch-steps p)))
  30
  31 (define (get-step x ps)
  32   "Does PS have the X step? Return that step if it does."
  33   (if (null? ps)
  34       #f
  35       (if (= (- x 1) (ly:pitch-steps (car ps)))
  36           (car ps)
  37           (get-step x (cdr ps)))
  38       ))
  39
  40 (define (replace-step p ps)
  41   "Copy PS, but replace the step of P in PS."
  42   (if (null? ps)
  43       '()
  44       (let*
  45           (
  46            (t (replace-step p (cdr ps)))
  47            )
  48
  49         (if (= (ly:pitch-steps p) (ly:pitch-steps (car ps)))
  50             (cons p t)
  51             (cons (car ps) t)
  52             ))
  53       ))
  54
  55 (define (remove-step x ps)
  56   "Copy PS, but leave out the Xth step."
  57   (if (null? ps)
  58       '()
  59       (let*
  60           (
  61            (t (remove-step x (cdr ps)))
  62            )
  63
  64         (if (= (- x 1) (ly:pitch-steps (car ps)))
  65             t
  66             (cons (car ps) t)
  67             ))
  68       ))
  69
  70
  71 (define-public (ignatzek-chord-names
  72                 in-pitches bass inversion
  73                 context)
  74
  75   (define (remove-uptil-step x ps)
  76     "Copy PS, but leave out everything below the Xth step."
  77     (if (null? ps)
  78         '()
  79         (if (< (ly:pitch-steps (car ps)) (- x 1))
  80             (remove-uptil-step x (cdr ps))
  81             ps)
  82         )
  83     )
  84   (define name-root (ly:get-context-property context 'chordRootNamer))
  85   (define name-note
  86     (let ((nn (ly:get-context-property context 'chordNoteNamer)))
  87       (if (eq? nn '())
  88           ; replacing the next line with name-root gives guile-error...? -rz
  89
  90           ;; apparently sequence of defines is equivalent to let, not let* ? -hwn
  91           (ly:get-context-property context 'chordRootNamer)
  92           ;; name-root
  93           nn)))
  94
  95   (define (is-natural-alteration? p)
  96     (= (natural-chord-alteration p)  (ly:pitch-alteration p))
  97     )
  98
  99
 100   (define (ignatzek-format-chord-name
 101            root
 102            prefix-modifiers
 103            main-name
 104            alteration-pitches
 105            addition-pitches
 106            suffix-modifiers
 107            bass-pitch
 108            )
 109
 110     "Format for the given (lists of) pitches. This is actually more
 111 work than classifying the pitches."
 112
 113     (define (filter-main-name p)
 114     "The main name: don't print anything for natural 5 or 3."
 115     (if
 116      (or (not (ly:pitch? p))
 117          (and (is-natural-alteration? p)
 118           (or (= (pitch-step p) 5)
 119               (= (pitch-step p) 3))))
 120      '()
 121      (list (name-step p))
 122      ))
 123
 124     (define (glue-word-to-step word x)
 125       (make-line-markup
 126        (list
 127         (make-simple-markup word)
 128         (name-step x)))
 129       )
 130
 131     (define (suffix-modifier->markup mod)
 132       (if (or (= 4 (pitch-step mod))
 133               (= 2 (pitch-step mod)))
 134           (glue-word-to-step "sus" mod)
 135           (glue-word-to-step "huh" mod)
 136           ))
 137
 138     (define (prefix-modifier->markup mod)
 139       (if (and (= 3 (pitch-step mod))
 140                (= -1 (ly:pitch-alteration mod)))
 141           (make-simple-markup "m")
 142           (make-simple-markup "huh")
 143           ))
 144
 145     (define (filter-alterations alters)
 146       "Filter out uninteresting (natural) pitches from ALTERS."
 147
 148       (define (altered? p)
 149         (not (is-natural-alteration? p)))
 150
 151       (if
 152        (null? alters)
 153        '()
 154        (let*
 155            (
 156             (l (filter-list altered? alters))
 157             (lp (last-pair alters))
 158             )
 159
 160          ;; we want the highest also if unaltered
 161          (if (and (not (altered? (car lp)))
 162                   (> (pitch-step (car lp)) 5))
 163              (append l (last-pair alters))
 164              l)
 165          )))
 166
 167     (define (name-step pitch)
 168       (define (step-alteration pitch)
 169         (- (ly:pitch-alteration pitch)
 170            (natural-chord-alteration pitch)
 171            ))
 172
 173       (let*
 174           (
 175            (num-markup (make-simple-markup
 176                         (number->string (pitch-step pitch))))
 177            (args (list num-markup))
 178            (total (if (= (ly:pitch-alteration pitch) 0)
 179                       (if (= (pitch-step pitch) 7)
 180                           (list (ly:get-context-property context 'majorSevenSymbol))
 181                           args)
 182                       (cons (accidental->markup (step-alteration pitch)) args)
 183                       ))
 184            )
 185
 186         (make-line-markup total)))
 187
 188     (let*
 189         (
 190          (sep (ly:get-context-property context 'chordNameSeparator))
 191          (root-markup (name-root root))
 192          (add-markups (map (lambda (x)
 193                              (glue-word-to-step "add" x))
 194                            addition-pitches))
 195          (filtered-alterations (filter-alterations alteration-pitches))
 196          (alterations (map name-step filtered-alterations))
 197          (suffixes (map suffix-modifier->markup suffix-modifiers))
 198          (prefixes (map prefix-modifier->markup prefix-modifiers))
 199          (main-markups (filter-main-name main-name))
 200          (to-be-raised-stuff (markup-join
 201                               (append
 202                                main-markups
 203                                alterations
 204                                suffixes
 205                                add-markups) sep))
 206          (base-stuff (if bass-pitch
 207                          (list sep (name-note bass-pitch))
 208                          '()))
 209          )
 210
 211       (set! base-stuff
 212             (append
 213              (list root-markup
 214                    (markup-join prefixes sep)
 215                    (make-super-markup to-be-raised-stuff))
 216              base-stuff))
 217       (make-line-markup       base-stuff)
 218
 219        ))
 220
 221   (let*
 222       (
 223        (root (car in-pitches))
 224        (pitches (map (lambda (x) (ly:pitch-diff x root)) (cdr in-pitches)))
 225        (exceptions (ly:get-context-property context 'chordNameExceptions))
 226        (exception (assoc-get-default pitches exceptions #f))
 227        (prefixes '())
 228        (suffixes '())
 229        (add-steps '())
 230        (main-name #f)
 231        (bass-note #f)
 232        (alterations '())
 233        )
 234
 235     (if
 236      exception
 237      (make-line-markup
 238       (list (name-root root) exception))
 239
 240      (begin                             ; no exception.
 241
 242        ; handle sus4 and sus2 suffix: if there is a 3 together with
 243        ; sus2 or sus4, then we explicitly say  add3.
 244        (map
 245         (lambda (j)
 246           (if (get-step j pitches)
 247               (begin
 248                 (if (get-step 3 pitches)
 249                     (begin
 250                       (set! add-steps (cons (get-step 3 pitches) add-steps))
 251                       (set! pitches (remove-step 3 pitches))
 252                       ))
 253                 (set! suffixes  (cons (get-step j pitches) suffixes))
 254                 )
 255               )
 256           ) '(2 4) )
 257
 258        ;; do minor-3rd modifier.
 259        (if (and (get-step 3 pitches)
 260                 (= (ly:pitch-alteration (get-step 3 pitches)) -1))
 261            (set! prefixes (cons (get-step 3 pitches) prefixes))
 262            )
 263
 264        ;; lazy bum. Should write loop.
 265        (cond
 266         ((get-step 7 pitches) (set! main-name (get-step 7 pitches)))
 267         ((get-step 6 pitches) (set! main-name (get-step 6 pitches)))
 268         ((get-step 5 pitches) (set! main-name (get-step 5 pitches)))
 269         ((get-step 4 pitches) (set! main-name (get-step 4 pitches)))
 270         ((get-step 3 pitches) (set! main-name (get-step 3 pitches)))
 271         )
 272
 273        (let*
 274            (
 275             (3-diff? (lambda (x y)
 276                        (= (- (pitch-step y) (pitch-step x)) 2)))
 277             (split (split-at 3-diff? (remove-uptil-step 5 pitches)))
 278             )
 279          (set! alterations (append alterations (car split)))
 280          (set! add-steps (append add-steps (cdr split)))
 281          (set! alterations (delq main-name alterations))
 282          (set! add-steps (delq main-name add-steps))
 283
 284          (if (ly:pitch? inversion)
 285              (set! bass-note inversion)
 286              )
 287
 288          (if (ly:pitch? bass)
 289              (set! bass-note bass)
 290              )
 291
 292          ;; chords with natural (5 7 9 11 13) or leading subsequence.
 293          ;; etc. are named by the top pitch, without any further
 294          ;; alterations.
 295          (if (and
 296               (ly:pitch? main-name)
 297               (= 7 (pitch-step main-name))
 298               (is-natural-alteration? main-name)
 299               (pair? (remove-uptil-step 7 alterations))
 300               (reduce (lambda (x y) (and x y))
 301                       (map is-natural-alteration? alterations)))
 302              (begin
 303                (set! main-name (tail alterations))
 304                (set! alterations '())
 305                ))
 306
 307          (ignatzek-format-chord-name root prefixes main-name alterations add-steps suffixes bass-note)
 308          )
 309        ))))
 310