modules/debian-org/manifests/init.pp

   1 define sysctl($key, $value, $ensure=present) {
   2     file {
   3         "/etc/sysctl.d/$name.conf":
   4             ensure  => $ensure,
   5             owner   => root,
   6             group   => root,
   7             mode    => 0644,
   8             content => "$key = $value\n",
   9             notify  => Exec["procps restart"],
  10     }
  11 }
  12
  13 define set_alternatives($linkto) {
  14     exec {
  15         "/usr/sbin/update-alternatives --set $name $linkto":
  16             unless => "/bin/sh -c '! [ -e $linkto ] || ! [ -e /etc/alternatives/$name ] || ([ -L /etc/alternatives/$name ] && [ /etc/alternatives/$name -ef $linkto ])'"
  17         }
  18 }
  19
  20 define linux_module ($ensure) {
  21     case $ensure {
  22         present: {
  23             exec { "append_module_${name}":
  24                 command => "echo '${name}' >> /etc/modules",
  25                 unless => "grep -q -F -x '${name}' /etc/modules",
  26             }
  27         }
  28         absent: {
  29             exec { "remove_module_${name}":
  30                 command => "sed -i -e'/^${name}\$/d' /etc/modules",
  31                 onlyif => "grep -q -F -x '${name}' /etc/modules",
  32             }
  33         }
  34         default: {
  35              err("invalid ensure value ${ensure}")
  36          }
  37     }
  38 }
  39
  40
  41 class debian-org {
  42     package {
  43         "apt-utils": ensure => installed;
  44         "bash-completion": ensure => installed;
  45         "debian.org": ensure => installed;
  46         "dnsutils": ensure => installed;
  47         "dsa-munin-plugins": ensure => installed;
  48         "klogd": ensure => purged;
  49         "less": ensure => installed;
  50         "libfilesystem-ruby1.8": ensure => installed;
  51         "mtr-tiny": ensure => installed;
  52         "nload": ensure => installed;
  53         "pciutils": ensure => installed;
  54         "rsyslog": ensure => purged;
  55         "sysklogd": ensure => purged;
  56     }
  57     file {
  58         "/etc/apt/preferences":
  59             source => "puppet:///modules/debian-org/apt.preferences";
  60         "/etc/apt/sources.list.d/backports.org.list":
  61             content => template("debian-org/etc/apt/sources.list.d/backports.org.list.erb"),
  62             notify  => Exec["apt-get update"];
  63         "/etc/apt/sources.list.d/debian.org.list":
  64             content => template("debian-org/etc/apt/sources.list.d/debian.org.list.erb"),
  65             notify  => Exec["apt-get update"];
  66         "/etc/apt/sources.list.d/security.list":
  67             content => template("debian-org/etc/apt/sources.list.d/security.list.erb"),
  68             notify  => Exec["apt-get update"];
  69         "/etc/apt/sources.list.d/volatile.list":
  70             content => template("debian-org/etc/apt/sources.list.d/volatile.list.erb"),
  71             notify  => Exec["apt-get update"];
  72         "/etc/apt/apt.conf.d/local-recommends":
  73             source => "puppet:///modules/debian-org/apt.conf.d/local-recommends";
  74         "/etc/apt/apt.conf.d/local-pdiffs":
  75             source => "puppet:///modules/debian-org/apt.conf.d/local-pdiffs";
  76         "/etc/timezone":
  77             source => "puppet:///modules/debian-org/timezone",
  78             notify => Exec["dpkg-reconfigure tzdata -pcritical -fnoninteractive"];
  79         "/etc/puppet/puppet.conf":
  80             # require => Package["puppet"],
  81             source => "puppet:///modules/debian-org/puppet.conf"
  82             ;
  83         "/etc/default/puppet":
  84             # require => Package["puppet"],
  85             source => "puppet:///modules/debian-org/puppet.default"
  86             ;
  87
  88         "/etc/cron.d/dsa-puppet-stuff":
  89             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron",
  90             require => Package["debian.org"]
  91             ;
  92         "/etc/ldap/ldap.conf":
  93             require => Package["debian.org"],
  94             source => "puppet:///modules/debian-org/ldap.conf",
  95             ;
  96         "/etc/pam.d/common-session":
  97             require => Package["debian.org"],
  98             content => template("debian-org/pam.common-session.erb"),
  99             ;
 100         "/etc/rc.local":
 101             mode   => 0755,
 102             source => "puppet:///modules/debian-org/rc.local",
 103             notify => Exec["rc.local start"],
 104             ;
 105     }
 106
 107     # set mmap_min_addr to 4096 to mitigate
 108     # Linux NULL-pointer dereference exploits
 109     sysctl {
 110         "mmap_min_addr" :
 111             key         => "vm.mmap_min_addr",
 112             value       => 4096,
 113     }
 114
 115     set_alternatives {
 116         "editor":
 117             linkto => "/usr/bin/vim.basic",
 118     }
 119
 120     exec {
 121         "dpkg-reconfigure tzdata -pcritical -fnoninteractive":
 122             path        => "/usr/bin:/usr/sbin:/bin:/sbin",
 123             refreshonly => true;
 124         "apt-get update":
 125             command => 'apt-get update',
 126             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 127             refreshonly => true;
 128         "puppetmaster restart":
 129             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 130             refreshonly => true;
 131         "rc.local start":
 132             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 133             refreshonly => true;
 134         "procps restart":
 135             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 136             refreshonly => true;
 137         "init q":
 138             refreshonly => true;
 139     }
 140 }
 141
 142 class debian-proliant inherits debian-org {
 143     package {
 144         "hpacucli": ensure => installed;
 145         "hp-health": ensure => installed;
 146         "arrayprobe": ensure => installed;
 147     }
 148     case getfromhash($nodeinfo, 'squeeze') {
 149         true: {}
 150         default: {
 151             package {
 152                 "cpqarrayd": ensure => installed;
 153             }
 154         }
 155     }
 156     case $debarchitecture {
 157         "amd64": {
 158             package { "lib32gcc1": ensure => installed; }
 159         }
 160     }
 161     file {
 162         "/etc/apt/sources.list.d/debian.restricted.list":
 163             content => template("debian-org/etc/apt/sources.list.d/debian.restricted.list.erb"),
 164             notify  => Exec["apt-get update"];
 165     }
 166 }
 167
 168 class debian-radvd inherits debian-org {
 169     sysctl {
 170         "dsa-accept-ra-default" :
 171             key         => "net.ipv6.conf.default.accept_ra",
 172             value       => 0,
 173     }
 174     sysctl {
 175         "dsa-accept-ra-all" :
 176             key         => "net.ipv6.conf.all.accept_ra",
 177             value       => 0,
 178     }
 179 }
 180 # vim:set et:
 181 # vim:set sts=4 ts=4:
 182 # vim:set shiftwidth=4: