modules/debian-org/manifests/init.pp

   1 define sysctl($key, $value, $ensure=present) {
   2     file {
   3         "/etc/sysctl.d/$name.conf":
   4             ensure  => $ensure,
   5             owner   => root,
   6             group   => root,
   7             mode    => 0644,
   8             content => "$key = $value\n",
   9             notify  => Exec["procps restart"],
  10     }
  11 }
  12
  13 define set_alternatives($linkto) {
  14     exec {
  15         "/usr/sbin/update-alternatives --set $name $linkto":
  16             unless => "/bin/sh -c '! [ -e $linkto ] || ! [ -e /etc/alternatives/$name ] || ([ -L /etc/alternatives/$name ] && [ /etc/alternatives/$name -ef $linkto ])'"
  17         }
  18 }
  19
  20 define linux_module ($ensure) {
  21     case $ensure {
  22         present: {
  23             exec { "append_module_${name}":
  24                 command => "echo '${name}' >> /etc/modules",
  25                 unless => "grep -q -F -x '${name}' /etc/modules",
  26             }
  27         }
  28         absent: {
  29             exec { "remove_module_${name}":
  30                 command => "sed -i -e'/^${name}\$/d' /etc/modules",
  31                 onlyif => "grep -q -F -x '${name}' /etc/modules",
  32             }
  33         }
  34         default: {
  35              err("invalid ensure value ${ensure}")
  36          }
  37     }
  38 }
  39
  40
  41 class debian-org {
  42     $debianadmin = [ "debian-archive-debian-samhain-reports@master.debian.org", "debian-admin@ftbfs.de", "weasel@debian.org", "steve@lobefin.net", "paravoid@debian.org" ]
  43     package {
  44         "apt-utils": ensure => installed;
  45         "bash-completion": ensure => installed;
  46         "debian.org": ensure => installed;
  47         "dnsutils": ensure => installed;
  48         "dsa-munin-plugins": ensure => installed;
  49         "klogd": ensure => purged;
  50         "less": ensure => installed;
  51         "libfilesystem-ruby1.8": ensure => installed;
  52         "mtr-tiny": ensure => installed;
  53         "nload": ensure => installed;
  54         "pciutils": ensure => installed;
  55         "rsyslog": ensure => purged;
  56         "sysklogd": ensure => purged;
  57     }
  58     case $debarchitecture {
  59         "armhf":
  60         default:
  61             file {
  62                 "/etc/apt/sources.list.d/security.list":
  63                     content => template("debian-org/etc/apt/sources.list.d/security.list.erb"),
  64                     notify  => Exec["apt-get update"];
  65                 "/etc/apt/sources.list.d/backports.org.list":
  66                     content => template("debian-org/etc/apt/sources.list.d/backports.org.list.erb"),
  67                     notify  => Exec["apt-get update"];
  68             }
  69     }
  70     file {
  71         "/etc/apt/preferences":
  72             source => "puppet:///modules/debian-org/apt.preferences";
  73         "/etc/apt/sources.list.d/debian.org.list":
  74             content => template("debian-org/etc/apt/sources.list.d/debian.org.list.erb"),
  75             notify  => Exec["apt-get update"];
  76         "/etc/apt/sources.list.d/volatile.list":
  77             content => template("debian-org/etc/apt/sources.list.d/volatile.list.erb"),
  78             notify  => Exec["apt-get update"];
  79         "/etc/apt/apt.conf.d/local-recommends":
  80             source => "puppet:///modules/debian-org/apt.conf.d/local-recommends";
  81         "/etc/apt/apt.conf.d/local-pdiffs":
  82             source => "puppet:///modules/debian-org/apt.conf.d/local-pdiffs";
  83         "/etc/timezone":
  84             source => "puppet:///modules/debian-org/timezone",
  85             notify => Exec["dpkg-reconfigure tzdata -pcritical -fnoninteractive"];
  86         "/etc/puppet/puppet.conf":
  87             # require => Package["puppet"],
  88             source => "puppet:///modules/debian-org/puppet.conf"
  89             ;
  90         "/etc/default/puppet":
  91             # require => Package["puppet"],
  92             source => "puppet:///modules/debian-org/puppet.default"
  93             ;
  94
  95         "/etc/cron.d/dsa-puppet-stuff":
  96             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron",
  97             require => Package["debian.org"]
  98             ;
  99         "/etc/ldap/ldap.conf":
 100             require => Package["debian.org"],
 101             source => "puppet:///modules/debian-org/ldap.conf",
 102             ;
 103         "/etc/pam.d/common-session":
 104             require => Package["debian.org"],
 105             content => template("debian-org/pam.common-session.erb"),
 106             ;
 107         "/etc/rc.local":
 108             mode   => 0755,
 109             source => "puppet:///modules/debian-org/rc.local",
 110             notify => Exec["rc.local start"],
 111             ;
 112
 113         "/etc/dsa":
 114             mode   => 0755,
 115             ensure  => directory,
 116             ;
 117         "/etc/dsa/cron.ignore.dsa-puppet-stuff":
 118             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron.ignore",
 119             require => Package["debian.org"]
 120             ;
 121     }
 122
 123     # set mmap_min_addr to 4096 to mitigate
 124     # Linux NULL-pointer dereference exploits
 125     sysctl {
 126         "mmap_min_addr" :
 127             key         => "vm.mmap_min_addr",
 128             value       => 4096,
 129     }
 130
 131     set_alternatives {
 132         "editor":
 133             linkto => "/usr/bin/vim.basic",
 134     }
 135
 136     mailalias {
 137         "samhain-reports":
 138             recipient => $debianadmin,
 139             ensure => present;
 140     }
 141
 142     exec {
 143         "dpkg-reconfigure tzdata -pcritical -fnoninteractive":
 144             path        => "/usr/bin:/usr/sbin:/bin:/sbin",
 145             refreshonly => true;
 146         "apt-get update":
 147             command => 'apt-get update',
 148             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 149             refreshonly => true;
 150         "puppetmaster restart":
 151             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 152             refreshonly => true;
 153         "rc.local start":
 154             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 155             refreshonly => true;
 156         "procps restart":
 157             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 158             refreshonly => true;
 159         "init q":
 160             refreshonly => true;
 161     }
 162 }
 163
 164 class debian-proliant inherits debian-org {
 165     package {
 166         "hpacucli": ensure => installed;
 167         "hp-health": ensure => installed;
 168         "arrayprobe": ensure => installed;
 169     }
 170     case getfromhash($nodeinfo, 'squeeze') {
 171         true: {}
 172         default: {
 173             package {
 174                 "cpqarrayd": ensure => installed;
 175             }
 176         }
 177     }
 178     case $debarchitecture {
 179         "amd64": {
 180             package { "lib32gcc1": ensure => installed; }
 181         }
 182     }
 183     file {
 184         "/etc/apt/sources.list.d/debian.restricted.list":
 185             content => template("debian-org/etc/apt/sources.list.d/debian.restricted.list.erb"),
 186             notify  => Exec["apt-get update"];
 187     }
 188 }
 189
 190 class debian-radvd inherits debian-org {
 191     sysctl {
 192         "dsa-accept-ra-default" :
 193             key         => "net.ipv6.conf.default.accept_ra",
 194             value       => 0,
 195     }
 196     sysctl {
 197         "dsa-accept-ra-all" :
 198             key         => "net.ipv6.conf.all.accept_ra",
 199             value       => 0,
 200     }
 201 }
 202 # vim:set et:
 203 # vim:set sts=4 ts=4:
 204 # vim:set shiftwidth=4: