modules/debian-org/manifests/init.pp

   1 define sysctl($key, $value, $ensure=present) {
   2     file {
   3         "/etc/sysctl.d/$name.conf":
   4             ensure  => $ensure,
   5             owner   => root,
   6             group   => root,
   7             mode    => 0644,
   8             content => "$key = $value\n",
   9             notify  => Exec["procps restart"],
  10     }
  11 }
  12
  13 define set_alternatives($linkto) {
  14     exec {
  15         "/usr/sbin/update-alternatives --set $name $linkto":
  16             unless => "/bin/sh -c '! [ -e $linkto ] || ! [ -e /etc/alternatives/$name ] || ([ -L /etc/alternatives/$name ] && [ /etc/alternatives/$name -ef $linkto ])'"
  17         }
  18 }
  19
  20 define linux_module ($ensure) {
  21     case $ensure {
  22         present: {
  23             exec { "append_module_${name}":
  24                 command => "echo '${name}' >> /etc/modules",
  25                 unless => "grep -q -F -x '${name}' /etc/modules",
  26             }
  27         }
  28         absent: {
  29             exec { "remove_module_${name}":
  30                 command => "sed -i -e'/^${name}\$/d' /etc/modules",
  31                 onlyif => "grep -q -F -x '${name}' /etc/modules",
  32             }
  33         }
  34         default: {
  35              err("invalid ensure value ${ensure}")
  36          }
  37     }
  38 }
  39
  40
  41 class debian-org {
  42     package {
  43         "apt-utils": ensure => installed;
  44         "bash-completion": ensure => installed;
  45         "debian.org": ensure => installed;
  46         "dnsutils": ensure => installed;
  47         "dsa-munin-plugins": ensure => installed;
  48         "klogd": ensure => purged;
  49         "less": ensure => installed;
  50         "logrotate": ensure => installed;
  51         "libfilesystem-ruby1.8": ensure => installed;
  52         "mtr-tiny": ensure => installed;
  53         "nload": ensure => installed;
  54         "pciutils": ensure => installed;
  55         "rsyslog": ensure => purged;
  56         "sysklogd": ensure => purged;
  57         "userdir-ldap": ensure => installed;
  58     }
  59     file {
  60         "/etc/apt/preferences":
  61             source => "puppet:///modules/debian-org/apt.preferences";
  62         "/etc/apt/sources.list.d/backports.org.list":
  63             content => template("debian-org/etc/apt/sources.list.d/backports.org.list.erb"),
  64             notify  => Exec["apt-get update"];
  65         "/etc/apt/sources.list.d/debian.org.list":
  66             content => template("debian-org/etc/apt/sources.list.d/debian.org.list.erb"),
  67             notify  => Exec["apt-get update"];
  68         "/etc/apt/sources.list.d/security.list":
  69             content => template("debian-org/etc/apt/sources.list.d/security.list.erb"),
  70             notify  => Exec["apt-get update"];
  71         "/etc/apt/sources.list.d/volatile.list":
  72             content => template("debian-org/etc/apt/sources.list.d/volatile.list.erb"),
  73             notify  => Exec["apt-get update"];
  74         "/etc/apt/apt.conf.d/local-recommends":
  75             source => "puppet:///modules/debian-org/apt.conf.d/local-recommends";
  76         "/etc/apt/apt.conf.d/local-pdiffs":
  77             source => "puppet:///modules/debian-org/apt.conf.d/local-pdiffs";
  78         "/etc/timezone":
  79             source => "puppet:///modules/debian-org/timezone",
  80             notify => Exec["dpkg-reconfigure tzdata -pcritical -fnoninteractive"];
  81         "/etc/puppet/puppet.conf":
  82             # require => Package["puppet"],
  83             source => "puppet:///modules/debian-org/puppet.conf"
  84             ;
  85         "/etc/default/puppet":
  86             # require => Package["puppet"],
  87             source => "puppet:///modules/debian-org/puppet.default"
  88             ;
  89
  90         "/etc/cron.d/dsa-puppet-stuff":
  91             source => "puppet:///modules/debian-org/dsa-puppet-stuff.cron",
  92             require => Package["cron"]
  93             ;
  94         "/etc/ldap/ldap.conf":
  95             require => Package["userdir-ldap"],
  96             source => "puppet:///modules/debian-org/ldap.conf",
  97             ;
  98         "/etc/pam.d/common-session":
  99             require => Package["libpam-pwdfile"],
 100             content => template("debian-org/pam.common-session.erb"),
 101             ;
 102         "/etc/rc.local":
 103             mode   => 0755,
 104             source => "puppet:///modules/debian-org/rc.local",
 105             notify => Exec["rc.local start"],
 106             ;
 107     }
 108
 109     # set mmap_min_addr to 4096 to mitigate
 110     # Linux NULL-pointer dereference exploits
 111     sysctl {
 112         "mmap_min_addr" :
 113             key         => "vm.mmap_min_addr",
 114             value       => 4096,
 115     }
 116
 117     set_alternatives {
 118         "editor":
 119             linkto => "/usr/bin/vim.basic",
 120     }
 121
 122     exec {
 123         "dpkg-reconfigure tzdata -pcritical -fnoninteractive":
 124             path        => "/usr/bin:/usr/sbin:/bin:/sbin",
 125             refreshonly => true;
 126         "apt-get update":
 127             command => 'apt-get update',
 128             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 129             refreshonly => true;
 130         "puppetmaster restart":
 131             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 132             refreshonly => true;
 133         "rc.local start":
 134             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 135             refreshonly => true;
 136         "procps restart":
 137             path        => "/etc/init.d:/usr/bin:/usr/sbin:/bin:/sbin",
 138             refreshonly => true;
 139         "init q":
 140             refreshonly => true;
 141     }
 142 }
 143
 144 class debian-proliant inherits debian-org {
 145     package {
 146         "hpacucli": ensure => installed;
 147         "hp-health": ensure => installed;
 148         "arrayprobe": ensure => installed;
 149     }
 150     case getfromhash($nodeinfo, 'squeeze') {
 151         true: {}
 152         default: {
 153             package {
 154                 "cpqarrayd": ensure => installed;
 155             }
 156         }
 157     }
 158     case $debarchitecture {
 159         "amd64": {
 160             package { "lib32gcc1": ensure => installed; }
 161         }
 162     }
 163     file {
 164         "/etc/apt/sources.list.d/debian.restricted.list":
 165             content => template("debian-org/etc/apt/sources.list.d/debian.restricted.list.erb"),
 166             notify  => Exec["apt-get update"];
 167     }
 168 }
 169
 170 class debian-radvd inherits debian-org {
 171     sysctl {
 172         "dsa-accept-ra-default" :
 173             key         => "net.ipv6.conf.default.accept_ra",
 174             value       => 0,
 175     }
 176     sysctl {
 177         "dsa-accept-ra-all" :
 178             key         => "net.ipv6.conf.all.accept_ra",
 179             value       => 0,
 180     }
 181 }
 182 # vim:set et:
 183 # vim:set sts=4 ts=4:
 184 # vim:set shiftwidth=4: