mf/parmesan-clefs.mf

   1 % -%-Fundamental-%- -*-Metafont-*-
   2 % parmesan-clefs.mf -- implement ancient clefs
   3 %
   4 % source file of LilyPond's pretty-but-neat music font
   5 %
   6 % (c)  2001--2003 Juergen Reuter <reuter@ipd.uka.de>
   7 %
   8
   9 fet_begingroup ("clefs")
  10
  11 %
  12 % character aligment:
  13 %
  14 %   Each clef is associated with a particular pitch: the treble clef
  15 %   with the 'g', the alto clef with the 'c', the bass clef with the
  16 %   'f', etc.  The shape of each clef character defines a vertical
  17 %   position that is assumed to represent this pitch.  For the treble
  18 %   clef, it is the vertical position of the center of the spiral
  19 %   ending that represents the 'g' pitch.  For the bass clef, it is
  20 %   the center between the two fat dots that define the vertical
  21 %   position of the 'f' pitch.  For the alto clef, it is the vertical
  22 %   center of the clef that is aligned with the 'c' pitch.  For each
  23 %   clef character, this center should be vertically aligned with the
  24 %   point (0, 0).  The horizontal alignment of each clef character
  25 %   should be such that the vertical line through the point (0, 0)
  26 %   touches the left-most edge of the clef.
  27 %
  28 %   TODO: document exact_center
  29 %
  30 % set_char_box() conventions:
  31 %
  32 % * breapth: Ignored (as far as I know).  Should be set to 0.
  33 %
  34 % * width: Should match the head's width.
  35 %
  36 % * depth: Should match the bottom edge of the head.  Affects vertical
  37 %   collision handling.
  38 %
  39 % * height: Should match the top edge of the head.  Affects vertical
  40 %   collision handling.
  41 %
  42
  43
  44 %%%%%%%%
  45 %
  46 %
  47 %
  48 % Editio Vaticana
  49 %
  50 %
  51 %
  52 def draw_vaticana_do_clef(expr exact_center, reduction) =
  53         save reduced_il;
  54
  55         reduced_il# = staff_space# * reduction;
  56
  57         set_char_box(0.0reduced_il#, 0.5reduced_il#,
  58                      0.8reduced_il#, 0.8reduced_il#);
  59
  60         define_pixels(reduced_il);
  61
  62         pickup pencircle xscaled 0.6stafflinethickness yscaled 0.6reduced_il;
  63
  64         save za, zb, zc, zd, ze, zf;
  65         pair za, zb, zc, zd, ze, zf;
  66
  67         rt  za = exact_center + (0.50reduced_il, -.45reduced_il);
  68             zb = exact_center + (0.25reduced_il, -.50reduced_il);
  69         lft zc = exact_center + (0.00reduced_il, -.25reduced_il);
  70         lft zd = exact_center + (0.00reduced_il, +.25reduced_il);
  71             ze = exact_center + (0.25reduced_il, +.50reduced_il);
  72         rt  zf = exact_center + (0.50reduced_il, +.45reduced_il);
  73         draw za .. zb .. zc --  % lower punctum
  74              zd .. ze .. zf;    % upper punctum
  75 enddef;
  76
  77
  78 fet_beginchar("Ed. Vat. do clef", "vaticana_do", "vatdoclef")
  79         if test = 1:
  80                 draw_staff(-1,3, 0.0);
  81         fi;
  82         draw_vaticana_do_clef((0,0), 1.0);
  83 fet_endchar;
  84 fet_beginchar("Ed. Vat. do clef", "vaticana_do_change", "vatcdoclef")
  85         draw_vaticana_do_clef((0,0), 1.0); % no reduction
  86 fet_endchar;
  87
  88
  89 def draw_vaticana_fa_clef(expr exact_center, reduction) =
  90
  91         save reduced_il, z;
  92         reduced_il# = staff_space# * reduction;
  93         define_pixels(reduced_il);
  94
  95         save za, zb, zc, zd, ze;
  96         pair za, zb, zc, zd, ze;
  97
  98         %left-handed punctum
  99         pickup pencircle xscaled 0.6stafflinethickness yscaled 0.5reduced_il;
 100         lft za = exact_center + (+0.00reduced_il, +0.00reduced_il);
 101             zb = exact_center + (+0.25reduced_il, +0.05reduced_il);
 102         rt  zc = exact_center + (+0.50reduced_il, -0.05reduced_il);
 103         draw za .. zb .. zc;
 104
 105         %stem
 106         pickup pencircle scaled 0.6stafflinethickness;
 107         xpart zc = xpart zd = xpart ze;
 108         ypart zd = ypart exact_center = bot ypart ze + 1.5reduced_il;
 109         draw zd -- ze;
 110
 111         %right-handed puncta as in do clef
 112         draw_vaticana_do_clef(exact_center + (0.55reduced_il, 0), reduction);
 113
 114         set_char_box(0.0reduced_il#, 1.05reduced_il#,
 115                      1.5reduced_il#, 0.8reduced_il#);
 116 enddef;
 117
 118
 119 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa", "vatfaclef")
 120         if test = 1:
 121                 draw_staff(-1,3, 0.0);
 122         fi;
 123         draw_vaticana_fa_clef((0,0), 1.0);
 124 fet_endchar;
 125 fet_beginchar("Ed. Vat. fa clef", "vaticana_fa_change", "vatcfaclef")
 126         draw_vaticana_fa_clef((0,0), 1.0); % no reduction
 127 fet_endchar;
 128
 129 %%%%%%%%
 130 %
 131 %
 132 %
 133 % Editio Medicaea
 134 %
 135 %
 136 %
 137 def draw_medicaea_do_clef(expr exact_center, reduction) =
 138         save reduced_il, reduced_slt;
 139         reduced_il# = staff_space# * reduction;
 140         reduced_slt# = stafflinethickness# * reduction;
 141         define_pixels(reduced_il);
 142         define_pixels(reduced_slt);
 143
 144         save flag_height;
 145         flag_height# = 0.5 reduced_il#;
 146         define_pixels(flag_height);
 147
 148         %upper flag
 149         save za, zb;
 150         pair za, zb;
 151         pickup pencircle xscaled reduced_slt yscaled flag_height;
 152         xpart exact_center
 153                 = lft xpart za
 154                 = rt xpart zb - reduced_il;
 155         ypart za = ypart exact_center +
 156                 0.5 (reduced_il - flag_height - staff_space);
 157         ypart zb = ypart za - reduced_il + flag_height;
 158         draw za -- zb;
 159
 160         %lower flag
 161         save za, zb;
 162         pair za, zb;
 163         pickup pencircle xscaled reduced_slt yscaled flag_height;
 164         xpart exact_center
 165                 = lft xpart za
 166                 = rt xpart zb - reduced_il;
 167         ypart za = ypart exact_center +
 168                  0.5 (reduced_il - flag_height + staff_space);
 169         ypart zb = ypart za - reduced_il + flag_height;
 170         draw za -- zb;
 171
 172         %stem
 173         save za, zb;
 174         pair za, zb;
 175         pickup pencircle scaled reduced_slt;
 176         lft xpart za = lft xpart zb = xpart exact_center;
 177         ypart exact_center
 178                 = top ypart zb - 1.5 reduced_il
 179                 = bot ypart za + 1.5 reduced_il;
 180         draw za -- zb;
 181
 182         set_char_box(0, 1.0reduced_il#,
 183                      1.5reduced_il#, 1.5reduced_il#);
 184 enddef;
 185
 186
 187 fet_beginchar("Ed. Med. do clef", "medicaea_do", "meddoclef")
 188         if test = 1:
 189                 draw_staff(-1,3, 0.0);
 190         fi;
 191         draw_medicaea_do_clef((0,0), 1.0);
 192 fet_endchar;
 193 fet_beginchar("Ed. Med. do clef", "medicaea_do_change", "cmeddoclef")
 194         draw_medicaea_do_clef((0,0), .8);
 195 fet_endchar;
 196
 197
 198 def draw_medicaea_fa_clef(expr exact_center, reduction) =
 199         % inspired by Regensburger Edition of Medicaea (1885/86), in:
 200         % MGG, volume 2, col. 1327 ("Choralreform"), fig. 2.
 201
 202         save reduced_il, reduced_slt;
 203         reduced_il# = staff_space# * reduction;
 204         reduced_slt# = stafflinethickness# * reduction;
 205         define_pixels(reduced_il);
 206         define_pixels(reduced_slt);
 207
 208         save za, zb, zc, zd, ze;
 209         pair za, zb, zc, zd, ze;
 210
 211         %stem
 212         pickup pencircle scaled stafflinethickness;
 213         xpart za = xpart zb =
 214                 xpart exact_center + 0.4reduced_il;
 215         ypart za = ypart exact_center = bot ypart zb + 1.5reduced_il;
 216         draw za -- zb;
 217
 218         %left-handed punctum
 219         pickup pencircle xscaled reduced_slt yscaled reduced_il;
 220         lft zc = exact_center;
 221         zd = exact_center + (0.4reduced_il, 0);
 222         draw zc -- zd;
 223
 224         %right-handed puncta as in do clef
 225         draw_medicaea_do_clef(exact_center + (0.7reduced_il, 0), reduction);
 226
 227         set_char_box(0, 1.7reduced_il#, 1.5reduced_il#, 1.5reduced_il#);
 228 enddef;
 229
 230
 231 fet_beginchar("Ed. Med. fa clef", "medicaea_fa", "medfaclef")
 232         if test = 1:
 233                 draw_staff(-1,3, 0.0);
 234         fi;
 235         draw_medicaea_fa_clef((0,0), 1.0);
 236 fet_endchar;
 237 fet_beginchar("Ed. Med. fa clef", "medicaea_fa_change", "cmedfaclef")
 238         draw_medicaea_fa_clef((0,0), .8);
 239 fet_endchar;
 240
 241
 242 %%%%%%%%
 243 %
 244 %
 245 %
 246 % Mensural Notation
 247 %
 248 %
 249 %
 250 brevis_wid# := 2 staff_space#;
 251
 252 def draw_brevis(expr exact_center, reduction, small_width, small_height) =
 253         %
 254         % inspired by function draw_brevis of
 255         % feta-bolletjes.mf
 256         %
 257         save reduced_slt, reduced_nht;
 258         save stem_width, head_width;
 259         save serif_size, serif_protrude;
 260         save holeheight, beamheight;
 261
 262         reduced_slt# = stafflinethickness# * reduction;
 263         reduced_nht# = noteheight# * reduction;
 264         stem_width# = 1.4 reduced_slt#;
 265         if small_width:
 266                 head_width# = 0.5brevis_wid# * reduction;
 267         else:
 268                 head_width# = brevis_wid# * reduction;
 269         fi;
 270         if small_height:
 271                 serif_size# = 0.64 reduced_slt#;
 272                 serif_protrude# = 0.96 serif_size#;
 273                 holeheight# = 3 reduced_slt#;
 274                 beamheight# = 0.32(reduced_nht# - holeheight#);
 275         else:
 276                 serif_size# = 1.0 reduced_slt#;
 277                 serif_protrude# = 1.5 serif_size#;
 278                 holeheight# = 3 reduced_slt#;
 279                 beamheight# = 0.5(reduced_nht# - holeheight#);
 280         fi;
 281         define_pixels(reduced_slt);
 282         define_pixels(stem_width);
 283         define_pixels(head_width);
 284         define_pixels(serif_size);
 285         define_pixels(serif_protrude);
 286         define_pixels(beamheight);
 287
 288         penpos1(stem_width, 0);
 289         penpos2(stem_width, 0);
 290         penpos3(beamheight, 90);
 291         penpos4(beamheight, 90);
 292         penpos5(stem_width, 180);
 293
 294         z1l = exact_center;
 295         z2l = z1l + (0, -reduced_slt/2);
 296         z3r = z2r + serif_size*(1,-1);
 297         y4r = y3r;
 298         x4l = x1l + head_width/2;
 299         z5l = z3l + (-serif_size, -serif_protrude);
 300
 301         penlabels(1,2,3,4,5);
 302         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 303                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 304 enddef;
 305
 306 %
 307 % width:        interval from left end to right end
 308 % height:       interval from bottom of lower beam to top of upper beam
 309 % exact_center: the coordinates of the vertical center point of the
 310 %               left edge.
 311 %
 312 def draw_full_brevis(expr exact_center, bwidth, bheight, blinethickness) =
 313
 314         save xoffs, yoffs, brevis_width, brevis_height, linethickness;
 315         xoffs# = xpart exact_center;
 316         yoffs# = ypart exact_center;
 317         brevis_width# = bwidth; brevis_height# = bheight;
 318         linethickness# = blinethickness;
 319
 320         save stem_width, beam_height, serif_size, serif_protrude, hole_height;
 321         stem_width# = 1.4 linethickness#;
 322         hole_height# = 3 linethickness#;
 323         2 beam_height# + hole_height# = brevis_height#;
 324         serif_size# = (hole_height# - linethickness#)/2;
 325         serif_protrude# = 1.5 serif_size#;
 326
 327         define_pixels(xoffs, yoffs, brevis_width, brevis_height, linethickness);
 328         define_pixels(stem_width, beam_height, serif_size, serif_protrude);
 329
 330         penpos1(stem_width, 0);
 331         penpos2(stem_width, 0);
 332         penpos3(beam_height, 90);
 333         penpos4(beam_height, 90);
 334         penpos5(stem_width, 180);
 335         z1l = (xoffs, yoffs);
 336         z2l = z1l + (0, -linethickness);
 337         z3r = z2r + serif_size*(1,-1);
 338         y4r = y3r;
 339         x4l = x1l + brevis_width/2;
 340         z5l = z3l + (-serif_size, -serif_protrude);
 341         fill z1r -- z1l -- z5r{down} .. z5l{up} .. z3l{right}
 342                 -- z4l -- z4r -- z3r{left} .. z2r{up} -- cycle;
 343
 344         addto currentpicture also currentpicture
 345                 yscaled -1 shifted (0, 2*yoffs);
 346
 347         pickup pencircle scaled linethickness;
 348         top y6 = yoffs + brevis_height/2;
 349         bot y7 = yoffs - brevis_height/2;
 350         lft x6 = lft x7 = xoffs;
 351         draw z6 -- z7;
 352
 353         addto currentpicture also currentpicture
 354                 xscaled -1 shifted (2xoffs + brevis_width, 0);
 355 enddef;
 356
 357
 358 def draw_neo_mensural_c_clef(expr exact_center, reduction) =
 359         save reduced_il, reduced_slt, stem_width;
 360         reduced_il# = staff_space# * reduction;
 361         reduced_slt# = stafflinethickness# * reduction;
 362         stem_width# = 1.4 reduced_slt#;
 363         define_pixels(reduced_il, reduced_slt, stem_width);
 364
 365         draw_full_brevis(exact_center + (3reduced_slt#, 0),
 366                          2reduced_il#, reduced_il#, reduced_slt#);
 367
 368         pickup pencircle xscaled stem_width yscaled blot_diameter;
 369         lft x8  = lft x9  = xoffs - 3reduced_slt;
 370         lft x10 = lft x11 = lft x8  + 3reduced_slt;
 371         rt  x12 = rt  x13 = lft x10 + 2reduced_il;
 372         rt  x14 = rt  x15 = rt  x12 + 3reduced_slt;
 373         top y9 - bot y8 = 4reduced_il;
 374         top y9 + bot y8 = 2yoffs;
 375         y12 = y14 = y10 = y8; y13 = y15 = y11 = y9;
 376         draw z8 -- z9;
 377         draw z10 -- z11;
 378         draw z12 -- z13;
 379         draw z14 -- z15;
 380
 381         set_char_box(0, 2reduced_il# + 6reduced_slt#,
 382                      2reduced_il#, 2reduced_il#);
 383 enddef;
 384
 385
 386 fet_beginchar("neo-mensural c clef", "neo_mensural_c", "neomenscclef")
 387         if test = 1:
 388                 draw_staff(-1,3, 0.0);
 389         fi;
 390         draw_neo_mensural_c_clef((0,0), 1.0);
 391 fet_endchar;
 392 fet_beginchar("neo-mensural c clef", "neo_mensural_c_change", "cneomenscclef")
 393         draw_neo_mensural_c_clef((0,0), .8);
 394 fet_endchar;
 395
 396
 397 def draw_petrucci_c_clef(expr exact_center, flare_align, reduction) =
 398         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 399         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 400         % Also by Petrucci's Canti C, Venedig 1503.  In: MGG, volume
 401         % 9, p. 1681/1682.
 402
 403         save reduced_il, reduced_slt;
 404         reduced_il# = staff_space# * reduction;
 405         reduced_slt# = stafflinethickness# * reduction;
 406         draw_full_brevis(exact_center + (0, 0.5staff_space#),
 407                          reduced_il#, reduced_il#, reduced_slt#);
 408         define_pixels(reduced_il);
 409         addto currentpicture also currentpicture shifted (0, -reduced_il);
 410
 411         save half_reduced_il, left_depth, left_height;
 412         half_reduced_il# = staff_space# * sqrt(reduction);
 413         left_height# = half_reduced_il# * min(3.2, 3.2 + 0.2 + flare_align);
 414         left_depth# = half_reduced_il# * min(3.2, 3.2 + 0.2 - flare_align);
 415
 416         define_pixels(half_reduced_il);
 417         define_pixels(left_depth, left_height);
 418
 419         save xoffs, yoffs;
 420         xoffs# = xpart exact_center;
 421         yoffs# = ypart exact_center;
 422         define_pixels(xoffs, yoffs);
 423
 424         pickup pencircle xscaled 1.4 stafflinethickness yscaled blot_diameter;
 425         lft x8 = lft x9 = xoffs;
 426         top y8 = yoffs + left_height;
 427         bot y9 = yoffs - left_depth;
 428         draw z8 .. z9;
 429
 430         rt x10 = rt x11 = xoffs + brevis_width;
 431         y10 = min(y8 - 0.2*half_reduced_il, yoffs + 2.2half_reduced_il);
 432         y11 = max(y9 + 0.2*half_reduced_il, yoffs - 2.2half_reduced_il);
 433         draw z10 .. z11;
 434
 435         set_char_box(0, reduced_il#, left_depth#, left_height#);
 436 enddef;
 437
 438
 439 fet_beginchar("petrucci c1 clef", "petrucci_c1", "petruccic1clef")
 440         if test = 1:
 441                 draw_staff(-1,3, 0.0);
 442         fi;
 443         draw_petrucci_c_clef((0,0), +2, 1.0);
 444 fet_endchar;
 445 fet_beginchar("petrucci c1 clef", "petrucci_c1_change", "cpetruccic1clef")
 446         draw_petrucci_c_clef((0,0), +2, .8);
 447 fet_endchar;
 448
 449 fet_beginchar("petrucci c2 clef", "petrucci_c2", "petruccic2clef")
 450         if test = 1:
 451                 draw_staff(-1,3, 0.0);
 452         fi;
 453         draw_petrucci_c_clef((0,0), +1, 1.0);
 454 fet_endchar;
 455 fet_beginchar("petrucci c2 clef", "petrucci_c2_change", "cpetruccic2clef")
 456         draw_petrucci_c_clef((0,0), +1, .8);
 457 fet_endchar;
 458
 459 fet_beginchar("petrucci c3 clef", "petrucci_c3", "petruccic3clef")
 460         if test = 1:
 461                 draw_staff(-1,3, 0.0);
 462         fi;
 463         draw_petrucci_c_clef((0,0), 0, 1.0);
 464 fet_endchar;
 465 fet_beginchar("petrucci c3 clef", "petrucci_c3_change", "cpetruccic3clef")
 466         draw_petrucci_c_clef((0,0), 0, .8);
 467 fet_endchar;
 468
 469 fet_beginchar("petrucci c4 clef", "petrucci_c4", "petruccic4clef")
 470         if test = 1:
 471                 draw_staff(-1,3, 0.0);
 472         fi;
 473         draw_petrucci_c_clef((0,0), -1, 1.0);
 474 fet_endchar;
 475 fet_beginchar("petrucci c4 clef", "petrucci_c4_change", "cpetruccic4clef")
 476         draw_petrucci_c_clef((0,0), -1, .8);
 477 fet_endchar;
 478
 479 fet_beginchar("petrucci c5 clef", "petrucci_c5", "petruccic5clef")
 480         if test = 1:
 481                 draw_staff(-1,3, 0.0);
 482         fi;
 483         draw_petrucci_c_clef((0,0), -2, 1.0);
 484 fet_endchar;
 485 fet_beginchar("petrucci c5 clef", "petrucci_c5_change", "cpetruc5iceclef")
 486         draw_petrucci_c_clef((0,0), -2, .8);
 487 fet_endchar;
 488
 489
 490 def draw_mensural_c_clef(expr exact_center, reduction) =
 491         % inspired by Ockeghem, "Missa Prolationum", in: MGG, volume
 492         % 9, table 94.
 493         draw_petrucci_c_clef(exact_center, 0, reduction);
 494
 495         addto currentpicture also currentpicture shifted (0, -staff_space);
 496
 497         save half_reduced_il;
 498         save left_depth, left_height;
 499
 500         half_reduced_il# = staff_space# * sqrt(reduction);
 501         left_height# = 3.2 * half_reduced_il#;
 502         left_depth# = left_height# + staff_space#;
 503
 504         set_char_box(0, reduced_il#, left_depth#, left_height#);
 505 enddef;
 506
 507
 508 fet_beginchar("mensural c clef", "mensural_c", "menscclef")
 509         if test = 1:
 510                 draw_staff(-1,3, 0.0);
 511         fi;
 512         draw_mensural_c_clef((0,0), 1.0);
 513 fet_endchar;
 514 fet_beginchar("mensural c clef", "mensural_c_change", "cmenscclef")
 515         draw_mensural_c_clef((0,0), .8);
 516 fet_endchar;
 517
 518 def draw_diamond(expr exact_center, reduction) =
 519         save stem_width, reduced_il, reduced_nht, holeheight, beamheight;
 520         save rh_height, rh_width;
 521
 522         stem_width# = 1.4 reduced_slt#;
 523         reduced_il# = staff_space# * reduction;
 524         reduced_nht# = noteheight# * reduction;
 525         holeheight# = 3 reduced_slt#;
 526         beamheight# = 0.4(reduced_nht# - holeheight#);
 527
 528         rh_height# = 1.2reduced_il#;
 529         rh_width# / rh_height# = tand(30);
 530
 531         define_pixels(beamheight);
 532         define_pixels(stem_width);
 533         define_pixels(rh_height);
 534         define_pixels(rh_width);
 535
 536         pickup pencircle
 537                 xscaled beamheight
 538                 yscaled stem_width
 539                 rotated 45;
 540
 541         draw
 542                 exact_center + (-rh_width/2, 0) --
 543                 exact_center + (0, rh_height/2) --
 544                 exact_center + (+rh_width/2, 0) --
 545                 exact_center + (0, -rh_height/2) --
 546                 cycle;
 547 enddef;
 548
 549 def draw_petrucci_f_clef(expr exact_center, reduction) =
 550         % inspired by L'homme arme super voces musicales in Misse
 551         % Josquin, 1502, Petrucci, in: MGG, volume 7, col. 200; also
 552         % inspired by Gaspar van Weerbeke, "Virgo Maria" (1502), in:
 553         % MGG, volume 9, col. 653 ("Motette"), fig. 3.; also by Andr'e
 554         % Campra, "Entr'ee des s'er'enades" (1710), in: MGG, volume 2,
 555         % col. 1649 ("Contredanse"), fig. 2.
 556         %
 557         draw_brevis(exact_center, reduction, true, false);
 558
 559         save reduced_il, reduced_slt;
 560         save stem_width, interline;
 561
 562         reduced_il# = staff_space# * reduction;
 563         reduced_slt# = stafflinethickness# * reduction;
 564         stem_width# = 1.4 reduced_slt#;
 565         interline# = staff_space#;
 566
 567         define_pixels(reduced_il);
 568         define_pixels(reduced_slt);
 569         define_pixels(stem_width);
 570         define_pixels(interline);
 571
 572         addto currentpicture also currentpicture
 573                 yscaled -1 shifted (0, 2*(ypart exact_center));
 574         addto currentpicture also currentpicture
 575                 xscaled -1 shifted (2x4l,0);
 576
 577
 578         % brevis stem
 579         pickup pencircle xscaled stem_width yscaled blot_diameter;
 580         z6 = exact_center + (2x4l - stem_width/2, 0);
 581         z7 = z6 + (0, -4reduced_il);
 582         draw z6 .. z7;
 583
 584         % upper diamond
 585         draw_diamond(exact_center + (1.6interline*reduction, interline/2),
 586                      reduction);
 587         pickup pencircle xscaled stem_width yscaled blot_diameter;
 588         z8 = exact_center +
 589              (1.6interline*reduction + stem_width/2, interline*reduction);
 590         z9 = z8 + (0, 1.5interline*reduction);
 591         draw z8 .. z9; % diamond stem
 592
 593         % lower diamond
 594         draw_diamond(exact_center + (1.6interline*reduction, -interline/2),
 595                      reduction);
 596         pickup pencircle xscaled stem_width yscaled blot_diameter;
 597         z10 = exact_center +
 598               (1.6interline*reduction - stem_width/2, -interline*reduction);
 599         z11 = z10 + (0, -3.5interline*reduction);
 600         draw z10 .. z11; % diamond stem
 601
 602         save reduced_il, rh_height, rh_width;
 603         reduced_il# = staff_space# * reduction;
 604         rh_height# = 1.2reduced_il#;
 605         rh_width# / rh_height# = tand(30);
 606         set_char_box(0, 1.6interline#*reduction + 0.5rh_width#,
 607                      4.5*interline#*reduction, 2.5*interline#*reduction);
 608 enddef;
 609
 610
 611 fet_beginchar("petrucci f clef", "petrucci_f", "petruccifclef")
 612         if test = 1:
 613                 draw_staff(-1,3, 0.0);
 614         fi;
 615         draw_petrucci_f_clef((0,0), 1.0);
 616 fet_endchar;
 617 fet_beginchar("petrucci f clef", "petrucci_f_change", "cpetruccifclef")
 618         draw_petrucci_f_clef((0,0), .8);
 619 fet_endchar;
 620
 621
 622 def draw_mensural_f_clef(expr exact_center, reduction) =
 623         %
 624         % inspired by Philippe le Duc, "Dite Signori" (1590), in: MGG,
 625         % volume 3, col. 848 ("Duc"); also by John Dowland, "The First
 626         % Booke of Songes" (1597), in: MGG, volume 3, col. 721
 627         % ("Dowland"), fig. 3.
 628
 629         save reduced_slt, stem_width, reduced_nht, holeheight, beamheight;
 630
 631         reduced_slt# = stafflinethickness# * reduction;
 632         stem_width# = 1.4 reduced_slt#;
 633         reduced_nht# = noteheight# * reduction;
 634         holeheight# = 3 reduced_slt#;
 635         beamheight# = 0.4(reduced_nht# - holeheight#);
 636
 637         define_pixels(beamheight, stem_width, staff_space);
 638
 639         pickup pencircle
 640                 xscaled beamheight
 641                 yscaled stem_width
 642                 rotated 45;
 643
 644         draw
 645                 exact_center + (1.0 staff_space, 0.55 staff_space) --
 646                 exact_center + (1.1 staff_space, 0.45 staff_space);
 647
 648         draw
 649                 exact_center + (1.1 staff_space, -0.55 staff_space) --
 650                 exact_center + (1.1 staff_space, -0.45 staff_space);
 651
 652         draw    halfcircle scaled 1.1 staff_space rotated -90
 653                 shifted (-exact_center + (+0.05 staff_space, 0));
 654
 655         set_char_box(0.5beamheight#, 1.1staff_space# + 0.5beamheight#,
 656                      0.55staff_space# + 0.5stem_width#,
 657                      0.55staff_space# + 0.5stem_width#);
 658 enddef;
 659
 660 fet_beginchar("mensural f clef", "mensural_f", "mensfclef")
 661         if test = 1:
 662                 draw_staff(-1,3, 0.0);
 663         fi;
 664         draw_mensural_f_clef((0,0), 1.0);
 665 fet_endchar;
 666 fet_beginchar("mensural f clef", "mensural_f_change", "cmensfclef")
 667         draw_mensural_f_clef((0,0), .8);
 668 fet_endchar;
 669
 670
 671 def draw_mensural_g_clef(expr exact_center, reduction) =
 672         %
 673         % TODO: Rewrite me!  This clef looks completely awful! --jr
 674         %
 675
 676         %
 677         % inspired by Francisco Guerrero, "Lib. 1.  Missarum" (1566),
 678         % in: MGG, volume 3, col. 858 ("Ducis"); also by Stefano
 679         % Fabri, "Quam speciosa veteranis" (1611), in: MGG, volume 3,
 680         % col. 1698 ("Fabri"); also by Philippus Dulichius,
 681         % "Fasciculus novus ..." (1598), in: MGG, volume 3, col. 919
 682         % ("Dulichius"), fig. 1; also by Noe Faignient, "Ic sal de
 683         % Heer myn God gebenedye" (1568), in: MGG, volume 3, col. 1735
 684         % ("Faignient").
 685         %
 686         % Metafont code partially inspired by Schwabacher 'G' of yswab
 687         % font.
 688
 689         save reduced_il, stem_width, height, width, apex_o, hair;
 690
 691         reduced_il#=staff_space#*reduction;
 692
 693         set_char_box(0.0reduced_il#, 1.2reduced_il#,
 694                      0.8reduced_il#, 1.5reduced_il#);
 695
 696         stem_width# = 0.17 reduced_il#;
 697         height# = 1.5 reduced_il#;
 698         width# = 1.13 reduced_il#;
 699         apex_o# = 0.02 reduced_il#;
 700         hair# =  3 stafflinethickness#;
 701         define_pixels(reduced_il, stem_width, height, width, apex_o, hair);
 702
 703         penpos1(2 stem_width, -142);
 704         z1l = (0.715 width, 0.742 height);
 705         penpos1'(hair, -90);
 706         z1'l = z1r;
 707         penpos2(1.179 stem_width, -142);
 708         z2l = (width, 0.466 height);
 709         penpos3(hair, 77);
 710         z3 = (0.764 width, 0.067 height);
 711         z4 = (0.59 width, -apex_o);
 712         penpos5(1.179 stem_width, 32);
 713         z5l=(0, 0.457 height);
 714         penpos6(hair, -56.5);
 715         z7 = (x4 - 0.843 stem_width, height + apex_o);
 716         z7 - z6l = whatever * dir33.5;
 717         penpos8(1.286 stem_width, -130);
 718         z8r = (0.715 width, 0.742 height) + (-apex_o, apex_o);
 719         z6r - z8r = whatever * (z7 - z8l);
 720         filldraw
 721                 z1'r{dir45} .. z2r{down} .. z3r{dir207} .. z5r{up} ..
 722                 z6r{z7-z6l} & z6r -- z8r -- z8l -- z7 --- z6l ...
 723                 z5l{down} .. z4{right} .. z3l{dir27} .. z2l{up} ..
 724                 z1l{1/3[z6l,z7]-z1l} & z1l -- z1r -- z1'r & cycle
 725                 shifted (-exact_center + (0, -0.75reduced_il));
 726
 727         penpos9(stem_width, 0);
 728         x9r = x4; y9 = 0.3 height;
 729
 730         pickup pencircle
 731                 scaled stem_width
 732                 rotated 45;
 733         draw    z9 -- (z9 + (0, -0.4reduced_il))
 734                 shifted (-exact_center + (0, -0.75reduced_il));
 735
 736         pickup pencircle
 737                 xscaled stem_width
 738                 yscaled hair
 739                 rotated 30;
 740
 741         draw halfcircle
 742                 scaled 0.5 reduced_il
 743                 rotated -90
 744                 shifted z8
 745                 shifted (0, 0.25reduced_il)
 746                 shifted (-exact_center + (0, -0.75reduced_il));
 747
 748         draw halfcircle
 749                 scaled 0.4 reduced_il
 750                 rotated 90
 751                 shifted (z8 + (0, 0.45 reduced_il))
 752                 shifted (0, 0.25reduced_il)
 753                 shifted (-exact_center + (0, -0.75reduced_il));
 754 enddef;
 755
 756
 757 fet_beginchar("mensural g clef", "mensural_g", "mensgclef")
 758         if test = 1:
 759                 draw_staff(-1,3, 0.0);
 760         fi;
 761         draw_mensural_g_clef((0,0), 1.0);
 762 fet_endchar;
 763 fet_beginchar("mensural g clef", "mensural_g_change", "cmensgclef")
 764         draw_mensural_g_clef((0,0), .8);
 765 fet_endchar;
 766
 767
 768
 769 def draw_petrucci_g_clef(expr exact_center, reduction) =
 770         % inspired by Josquin Desprez, "Stabat Mater", Libro tertio,
 771         % 1519, printed by Petrucci, in: MGG, volume 7, Table 11.
 772
 773         save reduced_il, reduced_slt;
 774
 775         reduced_il# = staff_space# * reduction;
 776         reduced_slt# = stafflinethickness# * reduction;
 777         define_pixels(reduced_il, reduced_slt);
 778
 779         set_char_box(0, 1.25 reduced_il#,
 780                      0.65 reduced_il#, 3.80 reduced_il#);
 781
 782         save za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 783         pair za, zb, zc, zd, ze, zf, zg, zh, zi, zj;
 784
 785         pickup pencircle
 786                 xscaled 0.50 reduced_slt
 787                 yscaled 0.22 reduced_il
 788                 rotated -35;
 789
 790         lft za = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 791         lft zb = exact_center + (1.00 reduced_il, +1.20 reduced_il);
 792         lft zc = exact_center + (0.70 reduced_il, +2.00 reduced_il);
 793         lft zd = exact_center + (0.30 reduced_il, +3.00 reduced_il);
 794         lft ze = exact_center + (0.80 reduced_il, +3.70 reduced_il);
 795         lft zf = exact_center + (1.00 reduced_il, +3.00 reduced_il);
 796         lft zg = exact_center + (0.60 reduced_il, +2.00 reduced_il);
 797         lft zh = exact_center + (0.30 reduced_il, +1.70 reduced_il);
 798         lft zi = exact_center + (0.00 reduced_il, +0.75 reduced_il);
 799         lft zj = exact_center + (0.20 reduced_il, +0.60 reduced_il);
 800
 801         draw za{-1,2} .. zb .. zc .. zd .. ze .. zf .. zg .. zh .. zi .. zj;
 802
 803         save za, zb, zc, zd, ze, zf;
 804         pair za, zb, zc, zd, ze, zf;
 805
 806         pickup pencircle
 807                 xscaled 0.75 reduced_slt
 808                 yscaled 0.33 reduced_il
 809                 rotated -35;
 810
 811         lft za = exact_center + (1.05 reduced_il, +0.45 reduced_il);
 812         lft zb = exact_center + (0.55 reduced_il, +0.45 reduced_il);
 813         lft zc = exact_center + (0.55 reduced_il, -0.45 reduced_il);
 814         lft zd = exact_center + (1.05 reduced_il, -0.45 reduced_il);
 815         lft ze = exact_center + (1.10 reduced_il, +0.00 reduced_il);
 816         lft zf = exact_center + (0.80 reduced_il, +0.00 reduced_il);
 817
 818         draw za .. zb .. zc .. zd .. {up}ze -- zf;
 819 enddef;
 820
 821
 822 fet_beginchar("petrucci g clef", "petrucci_g", "petruccigclef")
 823         if test = 1:
 824                 draw_staff(-1,3, 0.0);
 825         fi;
 826         draw_petrucci_g_clef((0,0), 1.0);
 827 fet_endchar;
 828 fet_beginchar("petrucci g clef", "petrucci_g_change", "cpetruccigclef")
 829         draw_petrucci_g_clef((0,0), .8);
 830 fet_endchar;
 831
 832
 833
 834 %%%%%%%%
 835 %
 836 %
 837 %
 838 % Hufnagel
 839 %
 840 %
 841 %
 842 def draw_hufnagel_do_clef(expr exact_center, reduction) =
 843         %
 844         % inspired by Graduale of Friedrich Zollner (1442), in: MGG,
 845         % volume 9, col. 1413 ("Neustift"), fig. 1.
 846         %
 847         save reduced_il;
 848
 849         reduced_il# = staff_space# * reduction;
 850
 851         define_pixels(reduced_il);
 852
 853         pickup pencircle
 854                 xscaled (0.60reduced_il)
 855                 yscaled (0.10reduced_il)
 856                 rotated 40;
 857         save za, zb, zc, zd, ze, zf;
 858         pair za, zb, zc, zd, ze, zf;
 859
 860         za = exact_center + (+0.30reduced_il, +.45reduced_il);
 861         zb = exact_center + (+0.20reduced_il, +.45reduced_il);
 862         zc = exact_center + (-0.10reduced_il, +.60reduced_il);
 863         zd = exact_center + (-0.40reduced_il, +.45reduced_il);
 864         ze = exact_center + (-0.40reduced_il, -.45reduced_il);
 865         zf = exact_center + (-0.20reduced_il, -.55reduced_il);
 866         draw za .. zb .. zc -- zd -- ze -- zf;
 867
 868         set_char_box(0.60reduced_il#, 0.50reduced_il#,
 869                      0.70reduced_il#, 0.75reduced_il#);
 870 enddef;
 871
 872
 873 fet_beginchar("Hufnagel do clef", "hufnagel_do", "hufnageldoclef")
 874         if test = 1:
 875                 draw_staff(-1,3, 0.0);
 876         fi;
 877         draw_hufnagel_do_clef((0,0), 1.0);
 878 fet_endchar;
 879 fet_beginchar("Hufnagel do clef", "hufnagel_do_change", "chufnageldoclef")
 880         draw_hufnagel_do_clef((1.3 staff_space#,0), .8);
 881 fet_endchar;
 882
 883
 884 def draw_hufnagel_fa_clef(expr exact_center, reduction) =
 885         %
 886         % inspired by Bamberger Manuscript (15th century), in:
 887         % MGG, volume 2, table 59.
 888         %
 889         save reduced_il;
 890
 891         reduced_il# = staff_space# * reduction;
 892
 893         define_pixels(reduced_il);
 894
 895         pickup pencircle
 896                 xscaled (0.60reduced_il)
 897                 yscaled (0.10reduced_il)
 898                 rotated 40;
 899         save za, zb, zc, zd, ze, zf;
 900         pair za, zb, zc, zd, ze, zf;
 901
 902         za = exact_center + (+0.30reduced_il, +0.70reduced_il);
 903         zb = exact_center + (+0.20reduced_il, +0.70reduced_il);
 904         zc = exact_center + (-0.10reduced_il, +0.85reduced_il);
 905         zd = exact_center + (-0.40reduced_il, +0.70reduced_il);
 906         ze = exact_center + (-0.40reduced_il, -1.10reduced_il);
 907         draw za .. zb .. zc -- zd -- ze;
 908
 909         save zg, zh, zi, zj;
 910         pair zg, zh, zi, zj;
 911
 912         zg = exact_center + (+0.30reduced_il, -0.05reduced_il);
 913         zh = exact_center + (+0.20reduced_il, -0.05reduced_il);
 914         zi = exact_center + (-0.10reduced_il, +0.10reduced_il);
 915         zj = exact_center + (-0.40reduced_il, -0.05reduced_il);
 916         draw zg .. zh .. zi -- zj;
 917
 918         set_char_box(0.60reduced_il#, 0.60reduced_il#,
 919                      1.15reduced_il#, 1.00reduced_il#);
 920 enddef;
 921
 922
 923 fet_beginchar("Hufnagel fa clef", "hufnagel_fa", "hufnagelfaclef")
 924         if test = 1:
 925                 draw_staff(-1,3, 0.0);
 926         fi;
 927         draw_hufnagel_fa_clef((0,0), 1.0);
 928 fet_endchar;
 929 fet_beginchar("Hufnagel fa clef", "hufnagel_fa_change", "chufnagelfaclef")
 930         draw_hufnagel_fa_clef((0,0), .8);
 931 fet_endchar;
 932
 933
 934 def draw_hufnagel_do_fa_clef(expr exact_center, reduction) =
 935         draw_hufnagel_do_clef(exact_center, reduction);
 936         draw_hufnagel_fa_clef(exact_center + (0, -2staff_space), reduction);
 937         set_char_box(0.60reduced_il#, 0.60reduced_il#,
 938                      1.15reduced_il# + 2staff_space#, 0.75reduced_il#);
 939 enddef;
 940
 941
 942 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa", "hufnageldofaclef")
 943         if test = 1:
 944                 draw_staff(-1,3, 0.0);
 945         fi;
 946         draw_hufnagel_do_fa_clef((0,0), 1.0);
 947 fet_endchar;
 948 fet_beginchar("Hufnagel do/fa clef", "hufnagel_do_fa_change",
 949               "chufnageldofaclef")
 950         draw_hufnagel_do_fa_clef((0,0), .8);
 951 fet_endchar;
 952
 953
 954 fet_endgroup ("clefs")