mf/feta-toevallig.mf

   1 %
   2 % Accidentals from various sources, notably
   3 %
   4 %   Baerenreiter edition of Schuberts `Auf dem Strom' (sharp, natural)
   5 %   F Hofmeister edition of Muellers `Etueden fuer Horn'  (double sharp, flat)
   6 %
   7
   8
   9 %tracingall;
  10 %proofing := 2;
  11 %\tracingequations:= tracingonline := 1;
  12
  13 fet_begingroup("accidentals");
  14
  15 fet_beginchar("Sharp" , "1", "sharp");
  16         set_char_box(0, 1.1 interline#, 1.5 interline#,
  17                 1.5 interline#);
  18
  19         save interbeam, interstem, beamheight, beamwidth,
  20                 stemwidth;
  21
  22         interbeam := 1.05 interline;
  23         interstem := 7/16 ;
  24         beamheight := 4 stafflinethickness;
  25         beamwidth := w;
  26         stemwidth := 1.3 stafflinethickness;
  27         roundness := blot_diameter;
  28         pair center;
  29         center := (.5 w, 0);
  30
  31         roundness + 2 spanwidth = beamwidth;
  32         roundness + 2 spanheight = beamheight;
  33
  34         2 horizontal_protrusion  + interstem * beamwidth + stemwidth
  35                 = beamwidth;
  36
  37 % wanske: whole beamheight; or ca 18 degrees
  38 %       z2 - z1 = (beamwidth - roundness, beamheight/2);
  39         z2 - z1 = (beamwidth - roundness, beamheight);
  40         z1 + z2 = 2*center;
  41         beamslope = (y2-y1)/(x2-x1);
  42
  43         pair hspan, vspan;
  44         hspan = (spanwidth, beamslope * spanwidth);
  45         vspan = (0, spanheight);
  46
  47
  48         path beam;
  49         beam := (hspan + vspan -- -hspan
  50                 +  vspan -- -hspan -vspan -- hspan - vspan -- cycle )
  51                 shifted center;
  52
  53         draw_rounded_path((beam shifted (0,-interbeam/2)), roundness);
  54         draw_rounded_path((beam shifted (0,interbeam/2)), roundness);
  55
  56         pickup pencircle scaled stemwidth;
  57         x3 = x4 = xpart center;
  58         bot y3 = -1.5 interline + ypart center;
  59         top y4 = 1.5 interline + ypart center;
  60
  61         path stem;
  62         stem := z3 .. z4;
  63         numeric xs;
  64         xs := interstem* beamwidth / 2;
  65         draw stem shifted (- xs, - xs* beamslope);
  66         draw stem shifted (xs , xs *beamslope);
  67         labels(1,2,3,4);
  68         fet_endchar;
  69
  70 fet_beginchar( "Natural", "0", "natural")
  71         set_char_box(0, 8/12 interline#, 1.5 interline#, 1.5 interline#);
  72
  73         save interbeam, interstem, beamheight, beamwidth,
  74                 stemwidth;
  75
  76         beamheight = 4.5 stafflinethickness;
  77         interstem + stemwidth =  w;
  78         stemwidth = 1.3 stafflinethickness;
  79
  80         z2 -z1 = (interstem, slope * interstem);
  81         xpart .5 [z2,z1] = xcenter ;
  82         xcenter = w/2;
  83
  84
  85         pickup penrazor scaled beamheight rotated 90;
  86         top y2 = interline - 3/2 stafflinethickness ;
  87         slope =  stafflinethickness / interstem;
  88
  89         draw z1 .. z2;
  90         draw (xpart z1, -y2) .. (xpart z2, -y1);
  91         beamtop = top y2;
  92
  93         pickup pencircle scaled stemwidth;
  94         xpart z3 = xpart z1;
  95         xpart z4 = xpart z2;
  96         top y3 = 1.5 interline;
  97         top y4 = beamtop;
  98
  99         draw (xpart z1, -y4) .. z3;
 100         draw (xpart z2, -y3) .. z4;
 101
 102         labels(1,2,3,4);
 103         fet_endchar;
 104
 105
 106 %
 107 % Dedicated to my mom.    (3/10/97)
 108 %
 109 % Mamma, ik hou van je; kom je alsjeblieft terug?
 110 %    -- HW
 111 %
 112
 113 % TODO: remove crook_fatness
 114 def draw_meta_flat(expr xcenter, w, crook_fatness) =
 115         clearxy;
 116         save crook_thinness;
 117         save top_stem_thick, bottom_stem_thick, hair;
 118         save center;
 119         pair center;
 120         center = (xcenter, 0);
 121
 122         crook_thinness = 1.25 stafflinethickness;
 123         top_stem_thick = 2 stafflinethickness;
 124         bottom_stem_thick = 1.2 stafflinethickness;
 125
 126
 127         z1 = (0, 2 interline) + center;
 128         z2 = (0, - 1/2 interline)+  center;
 129
 130         penpos1(top_stem_thick, 0);
 131         penpos2(bottom_stem_thick, 0);
 132
 133         fill simple_serif(z1r, z1l, 30) -- z2l -- z2r -- cycle;
 134
 135
 136         y3l = (interline - stafflinethickness)/2 + ypart center;
 137         z3l = whatever [z2r,z1r];
 138
 139         z3r = .26 [z2r, z1r];
 140
 141
 142         z4 = (3/8 interline, interline/2) + center;
 143         penpos4(whatever, 53);
 144         y4l - y4r = 2 crook_thinness ;
 145 %       y4l - y4r = 6/20[crook_thinness, crook_fatness] ;
 146
 147         y5r = 1/4 interline + ypart center;
 148         x5l = w + xpart center;
 149         penpos5(crook_fatness, -175);
 150
 151         z8 = (0, - interline/2 - stafflinethickness/2) + center;
 152
 153         z9 = (x5,0);
 154
 155         save ne_angle;
 156         ne_angle = angle(z9 - z8);
 157
 158         z7 = 8/33 [z8,z9];
 159         z6l = 18/33 [z8,z9] + .5 crook_thinness *dir(ne_angle -90);
 160
 161         penpos7(crook_thinness, ne_angle + 90);
 162
 163         z6r = .3 (z9-z8) + z7r;
 164
 165 %       penpos7(crook_thinness, angle(dir(z8-center) -180);
 166
 167         penpos8(whatever, ne_angle + 90);
 168         x8r =  xpart center - bottom_stem_thick/2;
 169         penlabels(range 0 thru 10);
 170
 171         z10 = (bottom_stem_thick/2, -1/5 interline) + center;
 172
 173         unfill z3r{up} .. z4r{right} .. tension .9
 174                 .. z6r ---
 175                 z7r{left}
 176                 .. z10 {up} -- cycle;
 177         fill z8r{down}
 178                 .. tension 0.8 ..z8l{(z9-z8)}
 179                 .. z7l
 180                 .. z6l
 181                 .. z5l{up}
 182                 .. z4l{left} .. z3l -- cycle;
 183
 184         labels(10);
 185 enddef;
 186
 187
 188 %
 189 % unfortunately, 600dpi is not enough to show the brush of the stem.
 190 %
 191 fet_beginchar("Flat", "-1", "flat")
 192         set_char_box(1.2 stafflinethickness#, .8 interline#, .5 interline#, 2 interline#);
 193         draw_meta_flat(0, w, 1/3 interline);
 194         fet_endchar;
 195
 196
 197 fet_beginchar("Double flat", "-2", "flatflat")
 198         save left_wid, overlap, right_wid;
 199         left_wid = .7;
 200         right_wid = .8;
 201         overlap = .05;
 202         set_char_box(1.2 stafflinethickness#, (left_wid + right_wid -overlap) *interline#, .5 interline#, 2 interline#);
 203         draw_meta_flat(0, left_wid*  interline, 1/3 interline);
 204         draw_meta_flat((left_wid - overlap) *interline,
 205                 right_wid *interline, 1/3 interline);
 206         fet_endchar;
 207
 208 fet_beginchar("Double sharp", "2", "sharpsharp")
 209         set_char_box(0, interline#, .5 interline#, .5 interline#);
 210         save klaverblad, klaversteel;
 211
 212         klaversteel = 1/15 interline;
 213         klaverblad = .35 interline;
 214
 215         z1 = (klaversteel, 0);
 216         z2 = (w/2 - klaverblad / 10, h - klaverblad);
 217         z3 = (w/2, h);
 218         z4 = z2 reflectedabout((0,0), (1,1));
 219         z5 = z1 reflectedabout((0,0), (1,1));
 220
 221         labels(1,2,3,4,5);
 222         draw_rounded_path(
 223                 z1{dir 45} .. {right}z2 -- z3 -- z4{down} .. {dir 225}z5 .. cycle,
 224         1/20 interline);
 225
 226         addto currentpicture also currentpicture yscaled (-d/h);
 227         addto currentpicture also currentpicture xscaled (-1);
 228
 229         % ugh
 230         currentpicture := currentpicture  shifted (w/2,0);
 231
 232
 233         fet_endchar;
 234
 235
 236 fet_endgroup("accidentals");
 237