mf/feta-nummer.mf

   1 % feta-nummer.mf -- implement bold Orator numerals
   2 %
   3 % part of LilyPond's pretty-but-neat music font
   4 %
   5 % source file of the Feta (not the Font-En-Tja) music font
   6 %
   7 % (c) 1997, 1998 Jan Nieuwenhuizen <janneke@gnu.org>
   8
   9 fet_begingroup("nummer")
  10
  11 define_pixels(height,thick,thick,thin,hair,flare);
  12 define_pixels(foot_top,foot_width);
  13 define_pixels(kuulleke);
  14
  15 def calc_kuulleke(expr w,alpha) =
  16         begingroup;
  17         save beta; beta=(alpha-90)/2;
  18         save gamma; gamma=(90+alpha)/2;
  19
  20         penpos1(w/cosd(alpha),alpha);
  21         penpos2(hair,90+beta);
  22         z2=z1l+(1/2hair/tand((alpha+90)/2))*dir(beta);
  23
  24         penpos3(hair,gamma-90);
  25         z3=z1r-(1/2hair/tand((90-alpha)/2))*dir(gamma);
  26         z4=z1+kuulleke*dir(alpha-90);
  27         endgroup;
  28         enddef;
  29
  30 % should make generic macro?
  31 %
  32 def draw_foot(expr xpos) =
  33         begingroup;
  34         clearxy;
  35         penpos1(thick,0);
  36         z1=(xpos,foot_top);
  37         penpos2(foot_width,0);
  38         z2=(x1,0);
  39         penpos3(hair,-90);
  40         z3r=z2r;
  41         penpos4(hair,90);
  42         z4l=z2l;
  43         z5=(x1,kuulleke);
  44         penlabels(1,2,3,4);
  45         fill z1..{right}z1r{down}..{right}z3l..z3r{left}..z5
  46                 ..{left}z4l..z4r{right}..{up}z1l{right}..z1..cycle;
  47         endgroup;
  48         enddef;
  49
  50 def draw_six =
  51         set_char_box(0, 2/3height#*widen, 0, height#);
  52         message "w:"&decimal w;
  53         message "h:"&decimal h;
  54
  55         penpos1(thin,90);
  56         z1=(thick,h/2+thin-hair/2);
  57         penpos2(hair,90);
  58         z2=(w/2,y1);
  59         penpos3(7/8thick,0);
  60         % yup, should use the path fract [] "everywhere"
  61         z3r=(w,1/2[0,y1]);
  62         penpos4(hair,-90);
  63         z4r=(x2,0);
  64         penpos5(7/8thick,180);
  65         z5r=(0,y1);
  66         penpos6(hair,90);
  67         z6r=(w-flare,h);
  68         penpos7(7/8thick,180);
  69         z7r=(0,h/2);
  70         penpos10(7/8thick,180);
  71         z10r=(0,y3);
  72         penlabels(1,2,3,4,5,6,7,8,9,10,11);
  73         save t; t=tense;
  74         fill z5{right}..z2r{right}..tension t..z3r{down}
  75                 ..tension t..z4r{left}
  76                 ..tension t..z7r{up}..tension t..z6r{right}
  77                 ..z6l{left}..tension t..z7l{down}..z10l{up}..cycle;
  78         draw_flare(z6r,0,-90,hair,flare);
  79         unfill z2l{right}..tension t..z3l{down}..tension t
  80                 ..z4l{left}..tension t..z10l{up}..tension t..cycle;
  81         enddef;
  82
  83 save dot_diam;
  84 dot_diam# = 7/8flare#;
  85 define_pixels(dot_diam);
  86
  87 code := 43;
  88
  89 % urg
  90 fet_beginchar("Numeral comma", ",", "comma")
  91         set_char_box(0, dot_diam#, 3/2dot_diam#, dot_diam#);
  92         pickup pencircle scaled dot_diam;
  93         draw (dot_diam/2,dot_diam/2);
  94         z0=(w/3,0);
  95         alpha=65;
  96         penpos1(thin,alpha+90);
  97         z1l=(w/2,-1.5h+hair);
  98         z2=(w,h/2);
  99         pickup pencircle;
 100         filldraw z1l{dir(alpha)}..{up}z2..{z0-z2}z0{right}..{dir(180+alpha)}z1r..cycle;
 101         labels(0,1,2);
 102         penlabels(1);
 103 fet_endchar;
 104
 105 fet_beginchar("Numeral dash", "-", "dash")
 106         set_char_box(0, height#/3, 0, height#);
 107         pickup pencircle scaled thin;
 108         lft x1 = -b;
 109         rt x2 = w;
 110         y1 = y2 = h/3;
 111         draw z1 .. z2;
 112 fet_endchar;
 113
 114 fet_beginchar("Numeral dot", ".", "dot")
 115         set_char_box(0, dot_diam#, 0, dot_diam#);
 116         pickup pencircle scaled dot_diam;
 117         draw (dot_diam/2,dot_diam/2);
 118 fet_endchar;
 119
 120
 121 % skip slash
 122
 123 code := 47;
 124
 125 fet_beginchar("Numeral 0", "0", "zero")
 126 %       set_char_box(0, 4/5height#*widen, 0, height#);
 127         set_char_box(0, 11/15height#*widen, 0, height#);
 128         message "w:"&decimal w;
 129         message "h:"&decimal h;
 130         penpos1(thin,90);
 131         z1r=(w/2,h);
 132         penpos2(thick,180);
 133         z2r=(0,h/2);
 134         penpos3(thin,-90);
 135         z3r=(w/2,0);
 136         penpos4(thick,0);
 137         z4r=(w,h/2);
 138         fill z1r..z2r..z3r..z4r..cycle;
 139         save t; t=1/tense;
 140         penlabels(1,2,3,4);
 141         unfill z1l..tension t..z2l..tension t..z3l
 142                 ..tension t..z4l..tension t..cycle;
 143 fet_endchar;
 144
 145 fet_beginchar("Numeral 1", "1", "one")
 146 %       set_char_box(0, 19/30height#*widen, 0, height#);
 147         set_char_box(0, 1/2foot_width#+3/2thick#+1/2hair#, 0, height#);
 148         message "w:"&decimal w;
 149         message "h:"&decimal h;
 150
 151         save alpha; alpha=0;
 152         calc_kuulleke(thick,alpha);
 153         z1=(3/2thick,height);
 154
 155         penpos5(thick,0);
 156         z5=(x1,foot_top);
 157
 158         z6=(0,h/2);
 159         save beta; beta=angle(z1l-z6);
 160         penpos7(thin,beta-90);
 161         z7l=z6;
 162         penpos8(thin/cosd(beta),-90);
 163         z8l=z1l;
 164         penpos9(thin,beta-90);
 165         z9r=z8r+(thin/cosd(beta))*(0,-1);
 166         penlabels(1,2,3,4,5,6,7,8,9);
 167         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 168         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l..z3r{down}
 169                 ..{down}z5r{left}..z5..{left}z5l{up}..{up}z2l..cycle;
 170         fill z7l{dir(beta)}..{dir(beta)}z1l..z2r..z9r{up}
 171                 ..z9l{dir(180+beta)}..{dir(180+beta)}z7r..cycle;
 172         penlabels(7,8,9);
 173
 174         draw_foot(x1);
 175 fet_endchar;
 176
 177 fet_beginchar("Numeral 2", "2", "two")
 178         set_char_box(0, 11/15height#*widen, 0, height#);
 179         message "w:"&decimal w;
 180         message "h:"&decimal h;
 181         clearxy;
 182         save alpha; alpha=-45*widen;
 183         save beta; beta=85;
 184         save gamma; gamma=beta-10;
 185         save theta; theta=20/widen;
 186         penpos1(hair,90+beta);
 187         z1=(0,0)+(1/2sqrt(2)*hair)*dir(45);
 188         penpos3(hair,90+gamma);
 189         z3=(w,thick)+(1/2sqrt(2)*hair)*dir(-135);
 190         penpos2(thick,90+alpha);
 191         x2-x1=x3-x2; y2=11/16thick/widen;
 192         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(gamma)}z3r
 193                 ..z3l{dir(180+gamma)}..{dir(180+alpha)}z2l
 194                 ..{dir(180+beta)}z1l..cycle;
 195
 196         penpos4(thick,0);
 197         z4r=(w-thin/2,.72h);
 198         penpos5(thin,90);
 199         z5r=(1/2hair+flare,h);
 200         penlabels(1,2,3,4);
 201         penlabels(5,6);
 202         save t; t=tense;
 203         fill z1l{dir(beta)}..tension t..z4r{up}
 204                 ..tension t..z5r{left}..z5l{right}
 205                 ..z4l{down}..tension t
 206                 ..{dir(180+beta)}z1r..cycle;
 207         draw_flare(z5r,180,90,thin,flare);
 208 fet_endchar;
 209
 210 fet_beginchar("Numeral 3", "3", "three")
 211         set_char_box(0, 2/3height#*widen, 0, height#);
 212         message "w:"&decimal w;
 213         message "h:"&decimal h;
 214         penpos1(hair,-90);
 215         z1l=(17/16thick,h);
 216         penpos2(7/8thick,180);
 217         z2l=(w-thick/8,3/4h+thick/16);
 218         penpos3(thin,90);
 219         z3=(w/2,h/2+1/8thick);
 220         penpos4(thin,90);
 221         z4=(5/8thick+1/2thin,y3);
 222         penpos5(thick,0);
 223         z5r=(w,1/4h+thick/16);
 224         penpos6(hair,-90);
 225         z6r=(9/8thick,0);
 226         penpos7(3/2thin,90);
 227         z7=(x5,y3);
 228         penlabels(1,2,3,4,5,6,7);
 229         save alpha; alpha=25;
 230         save t; t=tense;
 231         fill z1l{right}..tension t..z2l{down}..z7r{dir(180+alpha)}
 232                 ..z7l{dir(-alpha)}..z5r{down}..tension t..z6r{left}
 233                 ..z6l{right}..tension t..z5l{up}
 234                 ..tension t..z3l{left}..z4l{left}
 235                 ..z4r{right}..z3r{right}..tension t..z2r{up}
 236                 ..tension t..z1r{left}..cycle;
 237         draw_flare(z1l,180,90,hair,7/8flare);
 238         draw_flare(z6r,180,-90,hair,flare);
 239 fet_endchar;
 240
 241 fet_beginchar("Numeral 4", "4", "four")
 242         set_char_box(0, 4/5height#*widen, 0, height#);
 243         message "w:"&decimal w;
 244         message "h:"&decimal h;
 245
 246         save alpha; alpha=0;
 247         calc_kuulleke(3/2thick,alpha);
 248         z1r=(w-3/4thick,height);
 249
 250         z5=(thin,1/4height+thin);
 251         save beta; beta=angle(z3r-z5);
 252         penpos6(thin,-90);
 253         z6l=z5;
 254         penpos7(thin,-90);
 255         y7=y6; x7=w-1/2thin;
 256         penpos8(thin,-alpha);
 257         z8r=z5;
 258         penlabels(1,2,3,4,5,6,7);
 259         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 260         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 261                 ..z3r{dir(180+beta)}..{dir(180+beta)}z8r{right}
 262                 ..{right}z7l..z7r{left}..{left}z6r..z8l{dir(beta)}
 263                 ..{up}z2l..cycle;
 264
 265         clearxy;
 266
 267         save alpha; alpha=beta;
 268         calc_kuulleke(thick,alpha);
 269         z1r=(w-3/4thick,height-(3/2thin)/cosd(alpha));
 270
 271         penpos5(thick,0);
 272         z5=(x1,foot_top);
 273
 274         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 275         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 276                 ..z3r{down}..{down}z5r{left}..z5..{left}z5l{up}
 277                 ..{up}z2l..cycle;
 278         penlabels(1,2,3,4,5);
 279
 280         draw_foot(x5);
 281 fet_endchar;
 282
 283 fet_beginchar("Numeral 5", "5", "five")
 284         set_char_box(0, 7/10height#*widen, 0, height#);
 285         message "w:"&decimal w;
 286         message "h:"&decimal h;
 287         calc_kuulleke(w-thin,0);
 288         z1=(w/2+1/8thick,h);
 289         save alpha; alpha=0;
 290         penpos5(thin,0);
 291         z5l=(x1l,h-15/16thick);
 292         penpos6(hair,90-45);
 293         z6=z5r+1/2hair*dir(-45);
 294         penpos7(thin,0);
 295         z7l=(x1l,h/2+thin-hair);
 296         penlabels(1,2,3,4,5,6,7);
 297         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 298         fill z2r{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z3l
 299                 ..z3r{dir(-135)}..{left}z6r..z6l{down}..z7r{down}
 300                 ..z7l{up}..{up}z2l..cycle;
 301         penpos8(thin,90);
 302         z8l=(x7r,y7r-1/16thick);
 303         penpos9(thin,90);
 304         z9=(x11+3/16thick,10/16[y5,y7]);
 305         penpos10(thick,0);
 306         z10r=(w,1/2[y9r,y11r]);
 307         penpos11(hair,-90);
 308         z11r=(9/8thick,0);
 309         penlabels(8,9,10,11);
 310         save beta; beta=45;
 311         save t; t=tense;
 312         fill z8r{dir(beta)}..z9r{right}..tension t..z10r{down}
 313                 ..tension t..z11r{left}
 314                 ..z11l{right}..tension t..z10l{up}..tension t
 315                 ..z9l{left}..z8l{dir(180+beta+10)}..cycle;
 316         draw_flare(z11r,180,-90,hair,flare);
 317 fet_endchar;
 318
 319 fet_beginchar("Numeral 6", "6", "six")
 320         draw_six;
 321 fet_endchar;
 322
 323 fet_beginchar("Numeral 7", "7", "seven")
 324         set_char_box(0, 11/15height#*widen, 0, height#);
 325         message "w:"&decimal w;
 326         message "h:"&decimal h;
 327
 328         save alpha; alpha=-180;
 329 if true:
 330         penpos1(3/2thick,180+alpha);
 331         penpos2(hair,180+alpha-45);
 332         z2=z1l+(1/4sqrt(2)*hair)*dir(alpha-135);
 333         penpos3(hair,180+alpha+45);
 334         z3=z1r+(1/4sqrt(2)*hair)*dir(alpha-45);
 335         z4=z1+kuulleke*dir(alpha-90);
 336 else:
 337         % shit, does not work
 338         calc_kuulleke(3/2thick,-alpha);
 339 fi
 340         z1l=(thin,0);
 341
 342         save beta; beta=55;
 343         penpos5(thin,90+beta);
 344         z5=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 345
 346         save gamma; gamma=angle(length(z1r-z1),+2kuulleke);
 347         save delta; delta=12;
 348         pickup pencircle;
 349         fill z3l{dir(alpha-gamma)}..z4..{dir(alpha+gamma)}z2r..
 350                 z2l{dir(beta+delta)}..{dir(beta)}z5r
 351                 ..z5l{dir(180+beta)}..{dir(delta-90)}z3r..cycle;
 352         penlabels(1,2,3,4,5);
 353
 354         clearxy;
 355         save alpha; alpha=-45*widen;
 356         penpos1(1/2thick,90);
 357         z1=(3/2thin,h-(thick+thin)/2);
 358         penpos3(thin,90+beta);
 359         z3=(w,h)+(1/2sqrt(2)*thin)*dir(-135);
 360         penpos2(thick,90+alpha);
 361         x2=1/2[x1,x3]-1/4thick; y2=h-15/16thick+thin*widen;
 362
 363         penpos4(thin,0);
 364         z4l=(0,h-thin/2);
 365         penpos5(thin,0);
 366         z5l=(0,h/2+thin/2);
 367
 368         penpos6(9/8thick,90);
 369         z6r=(thin,y1r+2/16thick);
 370
 371         fill z1r{dir(beta)}..{dir(alpha)}z2r..{dir(beta)}z3r
 372                 ..z3l{dir(180+beta)}..{dir(180+alpha)}z2l
 373                 ..{dir(180+beta)}z1l..z6l{down}..{down}z5r
 374                 ..z5l{up}..{up}z4l..z4r{down}..{down}z6r..{right}cycle;
 375         penlabels(1,2,3,4,5,6);
 376 fet_endchar;
 377
 378 fet_beginchar("Numeral 8", "8", "eight")
 379         set_char_box(0, 11/15height#*widen, 0, height#);
 380         message "w:"&decimal w;
 381         message "h:"&decimal h;
 382         save alpha; alpha=60;
 383         save beta; beta=alpha-15;
 384         z1=(w/2,h/2+thick/8);
 385         penpos2(hair,90+180+beta);
 386         z2=(w/3,h/2+thin);
 387         penpos3(3/2thin,0);
 388         z3l=(0,h/4+thin/2);
 389         penpos4(hair,90);
 390         z4l=(x1,0);
 391         penpos5(thick,90+90+alpha);
 392         z5=z1+w/4*dir(alpha-90);
 393         penpos6(thick,90+90+alpha);
 394         z6=z1+(w/4-thin/2)*dir(90+alpha);
 395         penpos7(hair,90);
 396         z7r=(x1,h);
 397         penpos8(3/2thin,0);
 398         z8r=(w-thin/2,3/4h+thin/2);
 399         penpos9(hair,90+180+beta);
 400         z9=(2/3w,h/2);
 401         penlabels(1,2,3,4,5,6,7,8,9);
 402         save t; t=tense;
 403         fill z2r{dir(180+beta)}..z3r{down}..z4r{right}
 404                 ..z5r{dir(90+alpha)}..z6r{dir(90+alpha)}
 405                 ..tension t..z7r{right}..z8r{down}..z9r{dir(180+beta)}
 406                 ..z9l{dir(beta)}..z8l{up}..z7l{left}..z6l{dir(alpha-90)}
 407                 ..z5l{dir(alpha-90)}..tension t..z4l{left}..z3l{up}
 408                 ..z2l{dir(beta)}..cycle;
 409 fet_endchar;
 410
 411 fet_beginchar("Numeral 9", "9", "nine")
 412         draw_six;
 413 %       xy_mirror_char;
 414         currentpicture := currentpicture scaled -1;
 415         currentpicture := currentpicture shifted (w,h);
 416 fet_endchar;
 417
 418 fet_endgroup("nummer")
 419