mf/feta-macros.mf

   1 %
   2 % debugging
   3 %
   4 def test_grid =
   5 if test>1:
   6         proofrulethickness 1pt#;
   7         makegrid(0pt,0pt for i:=-5pt step 1pt until 5pt: ,i endfor)
   8                 (0pt,0pt for i:=-5pt step 1pt until 5pt: ,i endfor);
   9         proofrulethickness .1pt#;
  10         makegrid(0pt,0pt for i:=-4.8pt step .2pt until 4.8pt: ,i endfor)
  11                 (0pt,0pt for i:=-4.8pt step .2pt until 4.8pt: ,i endfor);
  12 fi
  13         enddef;
  14
  15 def treq =
  16         tracingequations := tracingonline := 1;
  17 enddef;
  18
  19
  20 def draw_staff(expr first, last, offset)=
  21 if test <> 0:
  22         pickup pencircle scaled stafflinethickness;
  23         for i:= first step 1 until last:
  24                 draw (- staff_space, (i + offset) * staff_space) .. (4 staff_space,( i+ offset)* staff_space);
  25         endfor
  26 fi;
  27
  28 enddef;
  29
  30 % draw the outline of the stafflines. For fine tuning.
  31 def draw_staff_outline(expr first, last, offset)=
  32 if test <> 0:
  33         save p;
  34         path p;
  35         pickup pencircle scaled 2;
  36         for i:= first step 1 until last:
  37                 p := (- staff_space,  (i + offset) * staff_space) .. (4 staff_space,( i+ offset)* staff_space);
  38
  39                 draw p shifted (0, .5 stafflinethickness);
  40                 draw p shifted (0, -.5 stafflinethickness);
  41         endfor
  42 fi;
  43
  44 enddef;
  45
  46 %
  47 % Transforms
  48 %
  49
  50 def scaledabout(expr point, scale) =
  51         shifted -point scaled scale shifted point
  52 enddef;
  53
  54
  55 %
  56 % make a local (restored after endgroup) copy of t_var
  57 %
  58 def local_copy(text type, t_var)=
  59         save copy_temp;
  60         type copy_temp;
  61         copy_temp := t_var;
  62         save t_var;
  63         type t_var;
  64         t_var := copy_temp;
  65 enddef;
  66
  67
  68 %
  69 % Urgh! Want to do parametric types
  70 %
  71
  72 def del_picture_stack=
  73         save save_picture_stack, picture_stack_idx;
  74 enddef;
  75
  76 % better versions of Taupin/Egler savepic cmds
  77 %
  78 %
  79 def make_picture_stack =
  80         % override previous stack.
  81         del_picture_stack;
  82         picture save_picture_stack[];
  83         numeric picture_stack_idx;
  84         picture_stack_idx := 0;
  85         def push_picture(expr p) =
  86                 save_picture_stack[picture_stack_idx] := p ;
  87                 picture_stack_idx := picture_stack_idx + 1;
  88         enddef;
  89         def pop_picture =  save_picture_stack[decr picture_stack_idx] enddef;
  90         def top_picture = save_picture_stack[picture_stack_idx] enddef;
  91 enddef;
  92
  93
  94 % save/restore pens
  95 % why can't I delete individual pens?
  96 def make_pen_stack =
  97         del_pen_stack;
  98         pen save_pen_stack[];
  99         numeric pen_stack_idx;
 100         pen_stack_idx := 0;
 101         def push_pen(expr p) =
 102                 save_pen_stack[pen_stack_idx] := p ;
 103                 pen_stack_idx := pen_stack_idx +1;
 104         enddef;
 105         def pop_pen =  save_pen_stack[decr pen_stack_idx] enddef;
 106         def top_pen = save_pen_stack[pen_stack_idx] enddef;
 107 enddef;
 108 def del_pen_stack=
 109         save save_pen_stack, pen_stack_idx;
 110 enddef;
 111
 112 %
 113 % drawing
 114 %
 115
 116 def soft_penstroke text t =
 117         forsuffixes e = l,r: path_.e:=t; endfor
 118         if cycle path_.l:
 119           cyclestroke_
 120         else:
 121           fill path_.l .. tension1.5 .. reverse path_.r .. tension1.5 .. cycle
 122         fi
 123 enddef;
 124
 125
 126 %
 127 % make a round path segment going from P to Q. 2*A is the angle that the
 128 % path should take.
 129 %
 130
 131 def simple_serif(expr p,q, a)=
 132         p{dir(angle(q-p) -a)} .. q{ - dir(angle(p -q) + a)}
 133 enddef;
 134 %
 135
 136 %
 137 % draw an axis aligned block making sure that edges are on pixels.
 138 %
 139
 140 def draw_rounded_block (expr bottom_left, top_right, roundness) =
 141        save round;
 142        round = floor min(roundness,xpart (top_right-bottom_left),
 143                                    ypart (top_right-bottom_left));
 144
 145
 146        pickup pencircle scaled round;
 147
 148         begingroup;
 149         save x,y;
 150        z2+(round/2,round/2) = top_right;
 151        z4-(round/2,round/2) = bottom_left;
 152         y3 = y2;
 153         y4 = y1;
 154         x2 = x1;
 155         x4 = x3;
 156        fill bot z1 .. rt z1 --- rt z2 .. top z2 ---
 157             top z3 .. lft z3 --- lft z4 .. bot z4 --- cycle;
 158         endgroup;
 159         enddef;
 160
 161
 162
 163  def draw_block (expr bottom_left, top_right) =
 164        draw_rounded_block (bottom_left, top_right, blot_diameter);
 165        enddef;
 166
 167  def draw_square_block (expr bottom_left, top_right) =
 168         save x,y;
 169         x1 = xpart bottom_left;
 170         y1 = ypart bottom_left;
 171         x2 = xpart top_right;
 172         y2 = ypart top_right;
 173
 174
 175         fill (x1,y1) --- (x2,y1) --- (x2,y2) --- (x1,y2) --- cycle;
 176        enddef;
 177
 178
 179  def draw_gridline (expr bottom_left,top_right,thickness) =
 180        draw_rounded_block (bottom_left-(thickness/2,thickness/2),
 181                            top_right+(thickness/2,thickness/2),
 182                            thickness);
 183        enddef;
 184
 185
 186 def draw_brush(expr a,w,b,v) =
 187         save x,y;
 188         z1=a; z2=b;
 189         penpos3(w,angle(z2-z1)+90);
 190         penpos4(w,angle(z2-z1));
 191         penpos5(v,angle(z1-z2)+90);
 192         penpos6(v,angle(z1-z2));
 193         z3 = z4 = z1;
 194         z5 = z6 = z2;
 195
 196         fill z3r{z3r-z5l}..z4l..{z5r-z3l}z3l..z5r{z5r-z3l}..z6l..{z3r-z5l}z5l..cycle;
 197 enddef;
 198
 199
 200
 201 %
 202 % make a superellipsoid segment going from FROM to TO, with SUPERNESS.
 203 % Take superness = sqrt(2)/2 to get a circle segment
 204 %
 205 % see Knuth, p. 267 and p.126
 206 def super_curvelet(expr from, to, superness, dir) =
 207         if dir = 1:
 208          (superness [xpart to, xpart from], superness [ypart from,ypart to]){to - from}
 209         else:
 210          (superness [xpart from, xpart to], superness [ypart  to,ypart from]){to - from}
 211         fi
 212 enddef;
 213
 214
 215 %
 216 % Bulb with smooth inside curve.
 217 %
 218 % alpha = start direction.
 219 % beta = which side to turn to.
 220 % flare = diameter of the bulb
 221 % line = diameter of line attachment
 222 % direction = is ink on left or right side (1 or -1)
 223 %
 224 def flare_path(expr pos,alpha,beta,line,flare, direction) =
 225         begingroup;
 226         clearxy;
 227         penpos1(line,180+beta+alpha);
 228         z1r=pos;
 229         penpos2(flare,180+beta+alpha);
 230         z2=z3;
 231         penpos3(flare,0+alpha);
 232         z3l=z1r+(1/2+0.43)*flare*dir(alpha+beta) ;
 233         save taille;
 234         taille = 0.0;
 235         z4=z2r-  line * dir(alpha);
 236         penlabels(1,2,3,4);
 237         pickup pencircle;
 238         save t; t=0.833;
 239         save p;
 240         path p;
 241         p:=z1r{dir(alpha)}..z3r{dir(180+alpha-beta)}..z2l{dir(alpha+180)}
 242                 ..z3l{dir(180+alpha+beta)}..tension t
 243                 ..z4{dir(180+alpha+beta)}..z1l{dir(alpha+180)};
 244
 245         if direction = 1:
 246                 p
 247         else:
 248                 reverse p
 249         fi
 250         endgroup
 251         enddef;
 252
 253
 254
 255 def brush(expr a,w,b,v) =
 256         begingroup;
 257         draw_brush(a,w,b,v);
 258         penlabels(3,4,5,6);
 259         endgroup;
 260 enddef;
 261
 262 %
 263 % Draw a (rest) crook, starting at thickness STEM in point A,
 264 % ending a ball W to the left, diameter BALLDIAM
 265 % ypart of the center of the ball is BALLDIAM/4 lower than ypart A
 266 %
 267 def balled_crook(expr a, w, balldiam, stem) =
 268 begingroup;
 269         save x,y;
 270         penpos1(balldiam/2,-90);
 271         penpos2(balldiam/2,0);
 272         penpos3(balldiam/2,90);
 273         penpos4(balldiam/2,180);
 274         x4r=xpart a-w; y3r=ypart a+balldiam/4;
 275         x1l=x2l=x3l=x4l;
 276         y1l=y2l=y3l=y4l;
 277         penpos5(stem,250);
 278         x5=x4r+9/8balldiam; y5r=y1r;
 279         penpos6(stem,260);
 280         x6l=xpart a; y6l=ypart a;
 281         penstroke z1e..z2e..z3e..z4e..z1e..z5e{right}..z6e;
 282         penlabels(1,2,3,4,5,6);
 283 endgroup;
 284 enddef;
 285
 286
 287 def y_mirror_char =
 288         currentpicture := currentpicture yscaled -1;
 289         set_char_box(charbp, charwd, charht, chardp);
 290 enddef;
 291
 292
 293 def xy_mirror_char =
 294         currentpicture := currentpicture scaled -1;
 295         set_char_box(charwd, charbp, charht, chardp);
 296 enddef;
 297
 298
 299 %
 300 % center_factor: typically .5, the larger, the larger the radius of the bulb
 301 % radius factor: how much the bulb curves inward
 302 %
 303 def draw_bulb(expr turndir, zl, zr, bulb_rad, radius_factor)=
 304         begingroup;
 305         clearxy;
 306         save rad, ang;
 307
 308         ang = angle(zr-zl);
 309
 310         % don't get near infinity
 311         %z0 = zr + bulb_rad * (zl-zr)/length(zr -zl);
 312         z0 = zr + bulb_rad /length(zr -zl) * (zl-zr);
 313
 314         rad =  bulb_rad;
 315
 316         z1 = z0 + radius_factor* rad * dir(ang + turndir* 100);
 317         z2 = z0 + rad * dir(ang  + turndir*300);
 318         labels(0,1,2);
 319         fill zr{dir (ang + turndir* 90)} .. z1 .. z2 -- cycle;
 320
 321         endgroup
 322 enddef;
 323
 324 pi:=3.14159;