lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "lily-guile.hh"
  14 #include "notename-table.hh"
  15 #include "scalar.hh"
  16 #include "translation-property.hh"
  17 #include "lookup.hh"
  18 #include "misc.hh"
  19 #include "my-lily-lexer.hh"
  20 #include "paper-def.hh"
  21 #include "midi-def.hh"
  22 #include "main.hh"
  23 #include "file-path.hh"
  24 #include "keyword.hh"
  25 #include "debug.hh"
  26 #include "parseconstruct.hh"
  27 #include "dimensions.hh"
  28 #include "identifier.hh"
  29 #include "command-request.hh"
  30 #include "musical-request.hh"
  31 #include "my-lily-parser.hh"
  32 #include "context-specced-music.hh"
  33 #include "translator-group.hh"
  34 #include "score.hh"
  35 #include "music-list.hh"
  36 #include "duration-convert.hh"
  37 #include "change-translator.hh"
  38 #include "file-results.hh"
  39 #include "mudela-version.hh"
  40 #include "scope.hh"
  41 #include "relative-music.hh"
  42 #include "transposed-music.hh"
  43 #include "time-scaled-music.hh"
  44 #include "repeated-music.hh"
  45
  46 // mmm
  47 Mudela_version oldest_version ("1.0.16");
  48 Mudela_version version ("1.0.16");
  49
  50
  51 // needed for bison.simple's malloc() and free()
  52 #include <malloc.h>
  53
  54 struct Assignment {
  55         String *name_p_;
  56         Identifier *id_p_;
  57         ~Assignment () {
  58                 delete name_p_;
  59                 delete id_p_;
  60         }
  61         Assignment () {
  62                 name_p_ = 0;
  63                 id_p_ =0;
  64         }
  65         Assignment (Assignment const&s)
  66         {
  67                 name_p_ = new String (*s.name_p_);
  68                 id_p_ = s.id_p_->clone ();
  69         }
  70 };
  71
  72 Paper_def* current_paper = 0;
  73
  74 #ifndef NDEBUG
  75 #define YYDEBUG 1
  76 #endif
  77
  78 #define YYERROR_VERBOSE 1
  79
  80 #define YYPARSE_PARAM my_lily_parser_l
  81 #define YYLEX_PARAM my_lily_parser_l
  82 #define THIS ((My_lily_parser *) my_lily_parser_l)
  83
  84 #define yyerror THIS->parser_error
  85 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f("expecting %d arguments", s))
  86
  87 %}
  88
  89
  90 %union {
  91     Array<Interval>* intarr;
  92     Array<Musical_pitch> *pitch_arr;
  93     Link_array<Request> *reqvec;
  94     Array<String> * strvec;
  95     Array<int> *intvec;
  96     Notename_table *chordmodifiertab;
  97     Duration *duration;
  98     Identifier *id;
  99     Music *music;
 100     Music_list *music_list;
 101     Score *score;
 102     Scope *scope;
 103     Interval *interval;
 104     Musical_req* musreq;
 105     Music_output_def * outputdef;
 106     Musical_pitch * pitch;
 107     Midi_def* midi;
 108     Moment *moment;
 109     Notename_table *notenametab;
 110     Paper_def *paper;
 111     Real real;
 112     Request * request;
 113     Scalar *scalar;
 114
 115     String *string;
 116     Tempo_req *tempo;
 117     Translator* trans;
 118     char c;
 119     int i;
 120     int ii[10];
 121 }
 122 %{
 123
 124 int
 125 yylex (YYSTYPE *s,  void * v_l)
 126 {
 127         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 128         My_lily_lexer * lex_l = pars_l->lexer_p_;
 129
 130         lex_l->lexval_l = (void*) s;
 131         return lex_l->yylex ();
 132 }
 133
 134
 135 %}
 136
 137 %pure_parser
 138
 139 /* tokens which are not keywords */
 140
 141 %token ABSDYNAMIC
 142 %token ACCEPTS
 143 %token ALTERNATIVE
 144 %token BAR
 145 %token CADENZA
 146 %token CHORDMODIFIERS
 147 %token CHORDS
 148 %token CLEF
 149 %token CM_T
 150 %token CONSISTS
 151 %token CONSISTSEND
 152 %token DURATION
 153 %token EXTENDER
 154 %token FONT
 155 %token GROUPING
 156 %token HEADER
 157 %token IN_T
 158 %token KEY
 159 %token KEYSIGNATURE
 160 %token LYRICS
 161 %token MARK
 162 %token MEASURES
 163 %token MIDI
 164 %token MM_T
 165 %token MUSICAL_PITCH
 166 %token NAME
 167 %token NOTENAMES
 168 %token NOTES
 169 %token PAPER
 170 %token PARTIAL
 171 %token PENALTY
 172 %token PROPERTY
 173 %token PT_T
 174 %token RELATIVE
 175 %token REMOVE
 176 %token REPEAT
 177 %token SCM_T
 178 %token SCMFILE
 179 %token SCORE
 180 %token SCRIPT
 181 %token SHAPE
 182 %token SKIP
 183 %token SPANDYNAMIC
 184 %token TEMPO
 185 %token TIME_T
 186 %token TIMES
 187 %token TRANSLATOR
 188 %token TRANSPOSE
 189 %token TYPE
 190 %token CONTEXT
 191 %token VERSION
 192
 193 /* escaped */
 194 %token E_EXCLAMATION E_SMALLER E_BIGGER E_CHAR
 195
 196 %type <i>       dots exclamations questions
 197 %token <i>      DIGIT
 198 %token <pitch>  NOTENAME_PITCH
 199 %token <pitch>  TONICNAME_PITCH
 200 %token <pitch>  CHORDMODIFIER_PITCH
 201 %token <id>     DURATION_IDENTIFIER
 202 %token <id>     IDENTIFIER
 203 %token <id>     NOTENAME_TABLE_IDENTIFIER
 204 %token <id>     MUSIC_IDENTIFIER
 205 %token <id>     REQUEST_IDENTIFIER
 206 %token <id>     REAL_IDENTIFIER
 207 %token <id>     STRING_IDENTIFIER
 208 %token <id>     TRANS_IDENTIFIER
 209 %token <id>     INT_IDENTIFIER
 210 %token <id>     SCORE_IDENTIFIER
 211 %token <id>     MIDI_IDENTIFIER
 212 %token <id>     PAPER_IDENTIFIER
 213 %token <real>   REAL
 214 %token <string> DURATION RESTNAME
 215 %token <string> STRING
 216 %token <i>      UNSIGNED
 217
 218
 219 %type <outputdef> output_def
 220 %type <scope>   mudela_header mudela_header_body
 221 %type <request> open_request_parens close_request_parens open_request close_request
 222 %type <request> request_with_dir request_that_take_dir verbose_request
 223 %type <i>       sub_quotes sup_quotes
 224 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 225 %type <music>   Alternative_music Repeated_music
 226 %type <i>       abbrev_type
 227 %type <i>       int unsigned
 228 %type <i>       script_dir
 229 %type <i>       optional_modality
 230 %type <id>      identifier_init
 231 %type <duration> steno_duration notemode_duration
 232 %type <duration> entered_notemode_duration explicit_duration
 233 %type <intvec>  intastint_list int_list
 234 %type <reqvec>  pre_requests post_requests
 235 %type <request> gen_text_def
 236 %type <pitch>   explicit_musical_pitch steno_musical_pitch musical_pitch absolute_musical_pitch
 237 %type <pitch>   steno_tonic_pitch
 238
 239 %type <pitch_arr>       pitch_list
 240 %type <music>   chord notemode_chord
 241 %type <pitch_arr>       chord_additions chord_subtractions chord_notes
 242 %type <pitch>   chord_addsub chord_note chord_inversion notemode_chord_inversion
 243 %type <midi>    midi_block midi_body
 244 %type <duration>        duration_length
 245
 246 %type <scalar>  scalar
 247 %type <music>   Music  relative_music Sequential_music Simultaneous_music
 248 %type <music>   property_def translator_change
 249 %type <music_list> Music_list
 250 %type <paper>   paper_block paper_def_body
 251 %type <real>    real_expression real real_with_dimension
 252 %type <request> abbrev_command_req
 253 %type <request> post_request
 254 %type <request> command_req verbose_command_req
 255 %type <request> extender_req
 256 %type <string>  string
 257 %type <score>   score_block score_body
 258 %type <intarr>  shape_array
 259
 260 %type <string>  script_abbreviation
 261 %type <trans>   translator_spec_block translator_spec_body
 262 %type <tempo>   tempo_request
 263 %type <notenametab> notenames_body notenames_block chordmodifiers_block
 264
 265
 266
 267
 268 %left '-' '+'
 269 %left '*' '/'
 270 %left UNARY_MINUS
 271
 272 %%
 273
 274 mudela: /* empty */
 275         | mudela toplevel_expression {}
 276         | mudela assignment { }
 277         | mudela error
 278         | mudela check_version { }
 279         ;
 280
 281 toplevel_expression:
 282         notenames_block                 {
 283                 THIS->lexer_p_->set_notename_table ($1);
 284         }
 285         | chordmodifiers_block                  {
 286                 THIS->lexer_p_->set_chordmodifier_table ($1);
 287         }
 288         | mudela_header {
 289                 delete header_global_p;
 290                 header_global_p = $1;
 291         }
 292         | score_block {
 293                 score_global_array.push ($1);
 294         }
 295         | paper_block {
 296                 Identifier * id = new
 297                         Paper_def_identifier ($1, PAPER_IDENTIFIER);
 298                 THIS->lexer_p_->set_identifier ("$defaultpaper", id)
 299         }
 300         | midi_block {
 301                 Identifier * id = new
 302                         Midi_def_identifier ($1, MIDI_IDENTIFIER);
 303                 THIS->lexer_p_->set_identifier ("$defaultmidi", id)
 304         }
 305         | embedded_scm {
 306         }
 307         ;
 308
 309 embedded_scm:
 310         SCMFILE STRING semicolon {
 311                 read_lily_scm_file (*$2);
 312                 delete $2;
 313         }
 314         | SCM_T STRING semicolon {
 315                 gh_eval_str ($2->ch_l ());
 316                 delete $2;
 317         };
 318
 319 check_version:
 320         VERSION STRING semicolon                {
 321                 Mudela_version ver (*$2);
 322                 if (!((ver >= oldest_version) && (ver <= version))) {
 323                         if (THIS->ignore_version_b_) {
 324                                 THIS->here_input ().error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 325                         } else {
 326                                 THIS->fatal_error_i_ = 1;
 327                                 THIS->parser_error (_f ("incorrect mudela version: %s (%s, %s)", ver.str (), oldest_version.str (), version.str ()));
 328                         }
 329                 }
 330         }
 331         ;
 332
 333
 334 chordmodifiers_block:
 335         CHORDMODIFIERS '{' notenames_body '}'  {  $$ = $3; }
 336         ;
 337
 338
 339 notenames_block:
 340         NOTENAMES '{' notenames_body '}'  {  $$ = $3; }
 341         ;
 342
 343
 344
 345 notenames_body:
 346         /**/    {
 347                 $$ = new Notename_table;
 348         }
 349         | NOTENAME_TABLE_IDENTIFIER     {
 350                 $$ = $1-> access_content_Notename_table(true);
 351         }
 352         | notenames_body STRING '=' explicit_musical_pitch {
 353                 (*$$)[*$2] = *$4;
 354
 355                 delete $4;
 356                 delete $2;
 357         }
 358         ;
 359
 360 mudela_header_body:
 361         {
 362                 $$ = new Scope;
 363                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 364         }
 365         | mudela_header_body assignment semicolon {
 366
 367         }
 368         ;
 369
 370 mudela_header:
 371         HEADER '{' mudela_header_body '}'       {
 372                 $$ = $3;
 373                 THIS->lexer_p_-> scope_l_arr_.pop ();
 374         }
 375         ;
 376
 377
 378 /*
 379         DECLARATIONS
 380 */
 381 assignment:
 382         STRING {
 383                 THIS->remember_spot ();
 384         }
 385         /* cont */ '=' identifier_init  {
 386             THIS->lexer_p_->set_identifier (*$1, $4);
 387             $4->init_b_ = THIS->init_parse_b_;
 388             $4->set_spot (THIS->pop_spot ());
 389         }
 390         ;
 391
 392
 393
 394 identifier_init:
 395         score_block {
 396                 $$ = new Score_identifier ($1, SCORE_IDENTIFIER);
 397
 398         }
 399         | chordmodifiers_block {
 400                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 401         }
 402         | notenames_block {
 403                 $$ = new Notename_table_identifier ($1, NOTENAME_TABLE_IDENTIFIER);
 404         }
 405         | paper_block {
 406                 $$ = new Paper_def_identifier ($1, PAPER_IDENTIFIER);
 407         }
 408         | midi_block {
 409                 $$ = new Midi_def_identifier ($1, MIDI_IDENTIFIER);
 410
 411         }
 412         | translator_spec_block {
 413                 $$ = new Translator_identifier ($1, TRANS_IDENTIFIER);
 414         }
 415         | Music  {
 416                 $$ = new Music_identifier ($1, MUSIC_IDENTIFIER);
 417         }
 418
 419         | post_request {
 420                 $$ = new Request_identifier ($1, REQUEST_IDENTIFIER);
 421         }
 422         | explicit_duration {
 423                 $$ = new Duration_identifier ($1, DURATION_IDENTIFIER);
 424         }
 425         | real {
 426                 $$ = new Real_identifier (new Real ($1), REAL_IDENTIFIER);
 427         }
 428         | string {
 429                 $$ = new String_identifier ($1, STRING_IDENTIFIER);
 430         }
 431         | int   {
 432                 $$ = new int_identifier (new int ($1), INT_IDENTIFIER);
 433         }
 434         ;
 435
 436 translator_spec_block:
 437         TRANSLATOR '{' translator_spec_body '}'
 438                 {
 439                 $$ = $3;
 440         }
 441         ;
 442
 443 translator_spec_body:
 444         TRANS_IDENTIFIER        {
 445                 $$ = $1->access_content_Translator (true);
 446                 $$-> set_spot (THIS->here_input ());
 447         }
 448         | TYPE STRING semicolon {
 449                 Translator* t = get_translator_l (*$2);
 450                 Translator_group * tg = dynamic_cast<Translator_group*> (t);
 451
 452                 if (!tg)
 453                         THIS->parser_error (_("Need a translator group for a context"));
 454
 455                 t = t->clone ();
 456                 t->set_spot (THIS->here_input ());
 457                 $$ = t;
 458                 delete $2;
 459         }
 460         | translator_spec_body STRING '=' identifier_init semicolon     {
 461                 Identifier* id = $4;
 462                 String_identifier *s = dynamic_cast<String_identifier*> (id);
 463                 Real_identifier *r= dynamic_cast<Real_identifier*>(id);
 464                 int_identifier *i = dynamic_cast<int_identifier*> (id);
 465
 466                 String str;
 467                 if (s) str = *s->access_content_String (false);
 468                 if (i) str = to_str (*i->access_content_int (false));
 469                 if (r) str = to_str (*r->access_content_Real (false));
 470                 if (!s && !i && !r)
 471                         THIS->parser_error (_("Wrong type for property value"));
 472
 473                 delete $4;
 474                 /* ugh*/
 475                 Translator_group * tr = dynamic_cast<Translator_group*>($$);
 476                 tr->set_property (*$2, str);
 477         }
 478         | translator_spec_body NAME STRING semicolon {
 479                 $$->type_str_ = *$3;
 480                 delete $3;
 481         }
 482         | translator_spec_body CONSISTS STRING semicolon {
 483                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, true);
 484                 delete $3;
 485         }
 486         | translator_spec_body CONSISTSEND STRING semicolon {
 487                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, true);
 488                 delete $3;
 489         }
 490         | translator_spec_body ACCEPTS STRING semicolon {
 491                 dynamic_cast<Translator_group*> ($$)-> set_acceptor (*$3, true);
 492                 delete $3;
 493         }
 494         | translator_spec_body REMOVE STRING semicolon {
 495                 dynamic_cast<Translator_group*> ($$)-> set_element (*$3, false);
 496                 delete $3;
 497         }
 498         ;
 499
 500 /*
 501         SCORE
 502 */
 503 score_block:
 504         SCORE { THIS->remember_spot ();
 505         }
 506         /*cont*/ '{' score_body '}'     {
 507                 $$ = $4;
 508                 $$->set_spot (THIS->pop_spot ());
 509                 if (!$$->def_p_arr_.size ())
 510                         $$->add_output (THIS->default_paper_p ());
 511
 512         }
 513         ;
 514
 515 score_body:             {
 516                 $$ = new Score;
 517         }
 518         | SCORE_IDENTIFIER {
 519                 $$ = $1->access_content_Score (true);
 520         }
 521         | score_body mudela_header      {
 522                 $$->header_p_ = $2;
 523         }
 524         | score_body Music      {
 525                 if ($$->music_p_)
 526                         $2->warning (_ ("More than one music block"));
 527                 $$->music_p_ = $2;
 528         }
 529         | score_body output_def {
 530                 $$->add_output ($2);
 531         }
 532         | score_body error {
 533
 534         }
 535         ;
 536
 537 output_def:
 538         paper_block {
 539                 $$ = $1;
 540         }
 541         |  midi_block           {
 542                 $$= $1;
 543         }
 544         ;
 545
 546 intastint_list:
 547         /* */   { $$ =new Array<int>; }
 548         | intastint_list int '*' int    {
 549                 $$->push ($2); $$->push ($4);
 550         }
 551         | intastint_list int    {
 552                 $$->push ($2); $$->push (1);
 553         }
 554         ;
 555
 556
 557 /*
 558         PAPER
 559 */
 560 paper_block:
 561         PAPER '{' paper_def_body '}'    {
 562                 $$ = $3;
 563                 THIS-> lexer_p_->scope_l_arr_.pop ();
 564         }
 565         ;
 566
 567
 568 optional_dot:
 569         /* empty */
 570         | '.'
 571         ;
 572
 573 paper_def_body:
 574         /* empty */                     {
 575                 Paper_def *p = THIS->default_paper_p ();
 576                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 577                 $$ = p;
 578         }
 579         | PAPER_IDENTIFIER      {
 580                 Paper_def *p = $1->access_content_Paper_def (true);
 581                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 582                 $$ = p;
 583         }
 584         | paper_def_body int '=' FONT STRING            { // ugh, what a syntax
 585                 Lookup * l = new Lookup;
 586                 l->font_name_ = *$5;
 587                 delete $5;
 588                 $$->set_lookup ($2, l);
 589         }
 590         | paper_def_body assignment semicolon {
 591
 592         }
 593         | paper_def_body translator_spec_block {
 594                 $$->assign_translator ($2);
 595         }
 596         | paper_def_body SHAPE '=' shape_array semicolon {
 597                 $$->shape_int_a_ = *$4;
 598                 delete $4;
 599         }
 600         | paper_def_body error {
 601
 602         }
 603         ;
 604
 605
 606 real:
 607         real_expression         { $$ = $1; }
 608         ;
 609
 610
 611 real_with_dimension:
 612         REAL CM_T       {
 613                 $$ = $1 CM;
 614         }
 615         | REAL PT_T     {
 616                 $$ = $1 PT;
 617         }
 618         | REAL IN_T     {
 619                 $$ = $1 INCH;
 620         }
 621         | REAL MM_T     {
 622                 $$ = $1 MM;
 623         }
 624         ;
 625
 626 real_expression:
 627         REAL            {
 628                 $$ = $1;
 629         }
 630         | real_with_dimension
 631         | REAL_IDENTIFIER               {
 632                 $$= *$1->access_content_Real (false);
 633         }
 634         | '-'  real_expression %prec UNARY_MINUS {
 635                 $$ = -$2;
 636         }
 637         | real_expression '*' real_expression {
 638                 $$ = $1 * $3;
 639         }
 640         | real_expression '/' real_expression {
 641                 $$ = $1 / $3;
 642         }
 643         | real_expression '+' real_expression {
 644                 $$ = $1  + $3;
 645         }
 646         | real_expression '-' real_expression {
 647                 $$ = $1 - $3;
 648         }
 649         | '(' real_expression ')'       {
 650                 $$ = $2;
 651         }
 652         ;
 653
 654
 655 shape_array:
 656         /* empty */ {
 657                 $$ = new Array<Interval>;
 658         }
 659         | shape_array real real {
 660                 $$->push(Interval($2, $2 + $3));
 661         };
 662
 663 /*
 664         MIDI
 665 */
 666 midi_block:
 667         MIDI
 668
 669         '{' midi_body '}'       { $$ = $3; }
 670         ;
 671
 672 midi_body: /* empty */          {
 673                 $$ = THIS->default_midi_p ();
 674         }
 675         | MIDI_IDENTIFIER       {
 676                 $$ = $1-> access_content_Midi_def (true);
 677         }
 678         | midi_body translator_spec_block       {
 679                 $$-> assign_translator ($2);
 680         }
 681         | midi_body tempo_request semicolon {
 682                 $$->set_tempo ($2->dur_.length_mom (), $2->metronome_i_);
 683                 delete $2;
 684         }
 685         | midi_body error {
 686
 687         }
 688         ;
 689
 690 tempo_request:
 691         TEMPO steno_duration '=' unsigned       {
 692                 $$ = new Tempo_req;
 693                 $$->dur_ = *$2;
 694                 delete $2;
 695                 $$-> metronome_i_ = $4;
 696         }
 697         ;
 698
 699 Music_list: /* empty */ {
 700                 $$ = new Music_list;
 701         }
 702         | Music_list Music {
 703                 $$->add_music ($2);
 704         }
 705         | Music_list error {
 706         }
 707         ;
 708
 709
 710 Music:
 711         Simple_music
 712         | Composite_music
 713         ;
 714
 715 Alternative_music:
 716         /* empty */ {
 717
 718                 /* UGH*/
 719                Music_list* m = new Music_list;
 720                $$ = new Sequential_music (m);
 721         }
 722         | ALTERNATIVE Simultaneous_music {
 723                 $$ = $2;
 724         }
 725         | ALTERNATIVE Sequential_music {
 726                 $$ = $2;
 727         }
 728         ;
 729
 730 Repeated_music: REPEAT unsigned Music Alternative_music {
 731                 Music_sequence* m = dynamic_cast <Music_sequence*> ($4);
 732                 assert (m);
 733                 $$ = new Repeated_music ($3, $2 >? 1, m);
 734         }
 735         ;
 736
 737 Sequential_music: '{' Music_list '}'            {
 738                 $$ = new Sequential_music ($2);
 739         }
 740         ;
 741
 742 Simultaneous_music: '<' Music_list '>'  {
 743                 $$ = new Simultaneous_music ($2);
 744         }
 745         ;
 746
 747 Simple_music:
 748         request_chord           { $$ = $1; }
 749         | MUSIC_IDENTIFIER { $$ = $1->access_content_Music (true); }
 750         | property_def
 751         | translator_change
 752         | Simple_music '*' unsigned '/' unsigned        {
 753                 /* urg */
 754                 $$ = new Time_scaled_music ($3, $5, $1);
 755         }
 756         | Simple_music '*' unsigned              {
 757                 $$ = new Time_scaled_music ($3, 1, $1);
 758         }
 759         ;
 760
 761
 762 Composite_music:
 763         CONTEXT STRING Music    {
 764                 Context_specced_music *csm =  new Context_specced_music ($3);
 765
 766                 csm->translator_type_str_ = *$2;
 767                 csm->translator_id_str_ = "";
 768                 delete $2;
 769
 770                 $$ = csm;
 771         }
 772         | CONTEXT STRING '=' STRING Music {
 773                 Context_specced_music *csm =  new Context_specced_music ($5);
 774
 775                 csm->translator_type_str_ = *$2;
 776                 csm->translator_id_str_ = *$4;
 777                 delete $2;
 778                 delete $4;
 779
 780                 $$ = csm;
 781         }
 782         | TIMES {
 783                 THIS->remember_spot ();
 784         }
 785         /* CONTINUED */
 786                 unsigned '/' unsigned Music
 787
 788         {
 789                 $$ = new Time_scaled_music ($3, $5, $6);
 790                 $$->set_spot (THIS->pop_spot ());
 791         }
 792         | Repeated_music                { $$ = $1; }
 793         | Simultaneous_music            { $$ = $1; }
 794         | Sequential_music              { $$ = $1; }
 795         | TRANSPOSE musical_pitch Music {
 796                 $$ = new Transposed_music ($3, *$2);
 797                 delete $2;
 798         }
 799         | TRANSPOSE steno_tonic_pitch Music {
 800                 $$ = new Transposed_music ($3, *$2);
 801                 delete $2;
 802         }
 803         | NOTES
 804                 { THIS->lexer_p_->push_note_state (); }
 805         Music
 806                 { $$ = $3;
 807                   THIS->lexer_p_->pop_state ();
 808                 }
 809         | CHORDS
 810                 { THIS->lexer_p_->push_chord_state (); }
 811         Music
 812                 {
 813                   $$ = $3;
 814                   THIS->lexer_p_->pop_state ();
 815         }
 816         | LYRICS
 817                 { THIS->lexer_p_->push_lyric_state (); }
 818         Music
 819                 {
 820                   $$ = $3;
 821                   THIS->lexer_p_->pop_state ();
 822         }
 823         | relative_music        { $$ = $1; }
 824         ;
 825
 826 relative_music:
 827         RELATIVE absolute_musical_pitch Music {
 828                 $$ = new Relative_octave_music ($3, *$2);
 829                 delete $2;
 830         }
 831         ;
 832
 833 translator_change:
 834         TRANSLATOR STRING '=' STRING  {
 835                 Change_translator * t = new Change_translator;
 836                 t-> change_to_type_str_ = *$2;
 837                 t-> change_to_id_str_ = *$4;
 838
 839                 $$ = t;
 840                 $$->set_spot (THIS->here_input ());
 841                 delete $2;
 842                 delete $4;
 843         }
 844         ;
 845
 846 property_def:
 847         PROPERTY STRING '.' STRING '=' scalar   {
 848                 Translation_property *t = new Translation_property;
 849
 850                 t-> var_str_ = *$4;
 851                 t-> value_ = *$6;
 852
 853                 Context_specced_music *csm = new Context_specced_music (t);
 854                 $$ = csm;
 855                 $$->set_spot (THIS->here_input ());
 856
 857                 csm-> translator_type_str_ = *$2;
 858
 859                 delete $2;
 860                 delete $4;
 861                 delete $6;
 862         }
 863         ;
 864
 865 scalar:
 866         string          { $$ = new Scalar (*$1); delete $1; }
 867         | int           { $$ = new Scalar ($1); }
 868         ;
 869
 870
 871 request_chord:
 872         pre_requests simple_element post_requests       {
 873                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 874                 for (int i=0; i < $1->size(); i++)
 875                         l->add_music ($1->elem(i));
 876                 for (int i=0; i < $3->size(); i++)
 877                         l->add_music ($3->elem(i));
 878                 $$ = $2;
 879
 880         }
 881         | command_element
 882         ;
 883
 884 command_element:
 885         command_req {
 886                 $$ = new Request_chord;
 887                 $$-> set_spot (THIS->here_input ());
 888                 $1-> set_spot (THIS->here_input ());
 889                 ((Simultaneous_music*)$$) ->add_music ($1);//ugh
 890         }
 891         ;
 892
 893 command_req:
 894         abbrev_command_req
 895         | verbose_command_req semicolon { $$ = $1; }
 896         ;
 897
 898 abbrev_command_req:
 899         extender_req {
 900                 $$ = $1;
 901         }
 902         | '|'                           {
 903                 $$ = new Barcheck_req;
 904         }
 905         | '~'   {
 906                 $$ = new Tie_req;
 907         }
 908         | '['           {
 909                 Beam_req*b= new Beam_req;
 910                 b->spantype_ = START;
 911                 $$ =b;
 912         }
 913         | ']'           {
 914                 Beam_req*b= new Beam_req;
 915                 b->spantype_ = STOP;
 916                 $$ = b;
 917         }
 918         ;
 919
 920
 921 verbose_command_req:
 922         BAR STRING                      {
 923                 $$ = new Bar_req (*$2);
 924                 delete $2;
 925         }
 926         | MARK STRING {
 927                 $$ = new Mark_req (*$2);
 928                 delete $2;
 929         }
 930         | MARK unsigned {
 931                 $$ = new Mark_req (to_str ($2));
 932         }
 933         | TIME_T unsigned '/' unsigned  {
 934                 Time_signature_change_req *m = new Time_signature_change_req;
 935                 m->beats_i_ = $2;
 936                 m->one_beat_i_=$4;
 937                 $$ = m;
 938         }
 939         | PENALTY int   {
 940                 Break_req * b = new Break_req;
 941                 b->penalty_i_ = $2;
 942                 b-> set_spot (THIS->here_input ());
 943                 $$ = b;
 944         }
 945         | SKIP duration_length {
 946                 Skip_req * skip_p = new Skip_req;
 947                 skip_p->duration_ = *$2;
 948                 delete $2;
 949                 $$ = skip_p;
 950         }
 951         | tempo_request {
 952                 $$ = $1;
 953         }
 954         | CADENZA unsigned      {
 955                 $$ = new Cadenza_req ($2);
 956         }
 957         | PARTIAL duration_length       {
 958                 $$ = new Partial_measure_req ($2->length_mom ());
 959                 delete $2;
 960         }
 961         | CLEF STRING {
 962                 $$ = new Clef_change_req (*$2);
 963                 delete $2;
 964         }
 965         | KEY NOTENAME_PITCH optional_modality  {
 966                 Key_change_req *key_p= new Key_change_req;
 967                 key_p->pitch_arr_.push(*$2);
 968                 key_p->ordinary_key_b_ = true;
 969                 key_p->modality_i_ = $3;
 970                 $$ = key_p;
 971                 delete $2;
 972         }
 973         | KEYSIGNATURE pitch_list {
 974                 Key_change_req *key_p= new Key_change_req;
 975                 key_p->pitch_arr_ = *$2;
 976                 key_p->ordinary_key_b_ = false;
 977                 $$ = key_p;
 978                 delete $2;
 979         }
 980         | GROUPING intastint_list  {
 981                   Measure_grouping_req * mr_p = new Measure_grouping_req;
 982                   for (int i=0; i < $2->size();)
 983                     {
 984                       mr_p->elt_length_arr_.push (Moment (1, $2->elem(i++)));
 985                       mr_p->beat_i_arr_.push ($2->elem(i++));
 986                     }
 987
 988
 989                 $$ = mr_p;
 990                 delete $2;
 991         }
 992         ;
 993
 994 post_requests:
 995         {
 996                 $$ = new Link_array<Request>;
 997         }
 998         | post_requests post_request {
 999                 $2->set_spot (THIS->here_input ());
1000                 $$->push ($2);
1001         }
1002         ;
1003
1004 post_request:
1005         verbose_request
1006         | request_with_dir
1007         | close_request
1008         ;
1009
1010
1011 request_that_take_dir:
1012         gen_text_def
1013         | verbose_request
1014         | script_abbreviation {
1015                 Identifier*i = THIS->lexer_p_->lookup_identifier ("dash-" + *$1);
1016                 Articulation_req *a = new Articulation_req;
1017                 a->articulation_str_ = *i->access_content_String (false);
1018                 delete $1;
1019                 $$ = a;
1020         }
1021         ;
1022
1023 request_with_dir:
1024         script_dir request_that_take_dir        {
1025                 if (G_script_req * gs = dynamic_cast<G_script_req*> ($2))
1026                         gs->dir_ = $1;
1027                 else if ($1)
1028                         $2->warning ("Can't specify direction for this request");
1029                 $$ = $2;
1030         }
1031         ;
1032
1033 verbose_request:
1034         REQUEST_IDENTIFIER      {
1035                 $$ = (Request*)$1->access_content_Request (true);
1036                 $$->set_spot (THIS->here_input ());
1037         }
1038         | ABSDYNAMIC '{' STRING '}'     {
1039                 Absolute_dynamic_req *ad_p = new Absolute_dynamic_req;
1040                 ad_p ->loudness_str_ = *$3;
1041                 ad_p->set_spot (THIS->here_input ());
1042                 delete $3;
1043                 $$ =ad_p;
1044         }
1045         | SPANDYNAMIC '{' int int '}' {
1046                 Span_dynamic_req * sp_p = new Span_dynamic_req;
1047                 sp_p-> dynamic_dir_  = Direction($3);
1048                 sp_p->spantype_ = Direction($4);
1049                 sp_p->set_spot (THIS->here_input ());
1050                 $$ = sp_p;
1051         }
1052         | abbrev_type   {
1053                 Abbreviation_req* a = new Abbreviation_req;
1054                 a->set_spot (THIS->here_input ());
1055                 a->type_i_ = $1;
1056                 $$ = a;
1057         }
1058         | SCRIPT STRING         {
1059                 Articulation_req * a = new Articulation_req;
1060                 a->articulation_str_ = *$2;
1061                 a->set_spot (THIS->here_input ());
1062                 $$ = a;
1063                 delete $2;
1064         }
1065         ;
1066
1067 optional_modality:
1068         /* empty */     {
1069                 $$ = 0;
1070         }
1071         | int   {
1072                 $$ = $1;
1073         }
1074         ;
1075
1076 sup_quotes:
1077         '\'' {
1078                 $$ = 1;
1079         }
1080         | sup_quotes '\'' {
1081                 $$ ++;
1082         }
1083         ;
1084
1085 sub_quotes:
1086         ',' {
1087                 $$ = 1;
1088         }
1089         | sub_quotes ',' {
1090                 $$ ++ ;
1091         }
1092         ;
1093
1094 steno_musical_pitch:
1095         NOTENAME_PITCH  {
1096                 $$ = $1;
1097         }
1098         | NOTENAME_PITCH sup_quotes     {
1099                 $$ = $1;
1100                 $$->octave_i_ +=  $2;
1101         }
1102         | NOTENAME_PITCH sub_quotes      {
1103                 $$ = $1;
1104                 $$->octave_i_ += - $2;
1105         }
1106         ;
1107
1108 steno_tonic_pitch:
1109         TONICNAME_PITCH {
1110                 $$ = $1;
1111         }
1112         | TONICNAME_PITCH sup_quotes    {
1113                 $$ = $1;
1114                 $$->octave_i_ +=  $2;
1115         }
1116         | TONICNAME_PITCH sub_quotes     {
1117                 $$ = $1;
1118                 $$->octave_i_ += - $2;
1119         }
1120         ;
1121
1122 explicit_musical_pitch:
1123         MUSICAL_PITCH '{' int_list '}'  {/* ugh */
1124                 Array<int> &a = *$3;
1125                 ARRAY_SIZE(a,3);
1126                 $$ = new Musical_pitch;
1127                 $$->octave_i_ = a[0];
1128                 $$->notename_i_ = a[1];
1129                 $$->accidental_i_ = a[2];
1130                 delete &a;
1131         }
1132         ;
1133
1134 musical_pitch:
1135         steno_musical_pitch
1136         | explicit_musical_pitch
1137         ;
1138
1139 explicit_duration:
1140         DURATION '{' int_list '}'       {
1141                 $$ = new Duration;
1142                 Array<int> &a = *$3;
1143                 ARRAY_SIZE(a,2);
1144
1145                 $$-> durlog_i_ = a[0];
1146                 $$-> dots_i_ = a[1];
1147
1148                 delete &a;
1149         }
1150         ;
1151
1152 extender_req:
1153         EXTENDER {
1154                 if (!THIS->lexer_p_->lyric_state_b ())
1155                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1156                 $$ = new Extender_req;
1157         }
1158         ;
1159
1160 close_request:
1161         close_request_parens {
1162                 $$ = $1;
1163                 dynamic_cast<Span_req*> ($$)->spantype_ = START;
1164         }
1165
1166 close_request_parens:
1167         '('     {
1168                 $$= new Slur_req;
1169         }
1170         | E_SMALLER {
1171                 Span_dynamic_req*s =new Span_dynamic_req;
1172                 $$ = s;
1173                 s->dynamic_dir_ = UP;
1174         }
1175         | E_BIGGER {
1176                 Span_dynamic_req*s =new Span_dynamic_req;
1177                 $$ = s;
1178                 s->dynamic_dir_ = DOWN;
1179         }
1180         ;
1181
1182
1183 open_request:
1184         open_request_parens {
1185                 $$ = $1;
1186                 dynamic_cast<Span_req*> ($$)->spantype_ = STOP;
1187         }
1188         ;
1189
1190 open_request_parens:
1191         E_EXCLAMATION   {
1192                 Span_dynamic_req *s =  new Span_dynamic_req;
1193                 s->dynamic_dir_ = SMALLER;
1194                 $$ = s;
1195
1196         }
1197         | ')'   {
1198                 $$= new Slur_req
1199         }
1200         ;
1201
1202 gen_text_def:
1203         string {
1204                 Text_script_req *t  = new Text_script_req;
1205                 $$ = t;
1206                 t->text_str_ = *$1;
1207                 delete $1;
1208                 $$->set_spot (THIS->here_input ());
1209         }
1210         | DIGIT {
1211                 Text_script_req* t  = new Text_script_req;
1212                 $$ = t;
1213                 t->text_str_ = to_str ($1);
1214                 t->style_str_ = "finger";
1215                 $$->set_spot (THIS->here_input ());
1216         }
1217         ;
1218
1219 script_abbreviation:
1220         '^'             {
1221                 $$ = new String ("hat");
1222         }
1223         | '+'           {
1224                 $$ = new String ("plus");
1225         }
1226         | '-'           {
1227                 $$ = new String ("dash");
1228         }
1229         | '|'           {
1230                 $$ = new String ("bar");
1231         }
1232         | '>'           {
1233                 $$ = new String ("larger");
1234         }
1235         | '.'           {
1236                 $$ = new String ("dot");
1237         }
1238         ;
1239
1240
1241 script_dir:
1242         '_'     { $$ = DOWN; }
1243         | '^'   { $$ = UP; }
1244         | '-'   { $$ = CENTER; }
1245         ;
1246
1247 pre_requests:
1248         {
1249                 $$ = new Link_array<Request>;
1250         }
1251         | pre_requests open_request {
1252                 $$->push ($2);
1253         }
1254         ;
1255
1256 absolute_musical_pitch:
1257         steno_musical_pitch     {
1258                 $$ = $1;
1259         }
1260         ;
1261
1262 duration_length:
1263         steno_duration {
1264                 $$ = $1;
1265         }
1266         | duration_length '*' unsigned {
1267                 $$->plet_.iso_i_ *= $3;
1268         }
1269         | duration_length '/' unsigned {
1270                 $$->plet_.type_i_ *= $3;
1271         }
1272         ;
1273
1274 entered_notemode_duration:
1275         dots            {
1276                 $$ = new Duration (THIS->default_duration_);
1277                 if ($1)
1278                         $$->dots_i_  = $1;
1279         }
1280         | steno_duration        {
1281                 THIS->set_last_duration ($1);
1282         }
1283         ;
1284
1285 notemode_duration:
1286         entered_notemode_duration {
1287                 $$ = $1;
1288         }
1289         ;
1290
1291 steno_duration:
1292         unsigned                {
1293                 $$ = new Duration;
1294                 if (!Duration::duration_type_b ($1))
1295                         THIS->parser_error (_f ("not a duration: %d", $1));
1296                 else {
1297                         $$->durlog_i_ = Duration_convert::i2_type ($1);
1298                      }
1299         }
1300         | DURATION_IDENTIFIER   {
1301                 $$ = $1->access_content_Duration (true);
1302         }
1303         | steno_duration '.'    {
1304                 $$->dots_i_ ++;
1305         }
1306         ;
1307
1308
1309 abbrev_type:
1310         ':'     {
1311                 $$ =0;
1312         }
1313         | ':' unsigned {
1314                 if (!Duration::duration_type_b ($2))
1315                         THIS->parser_error (_f ("not a duration: %d", $2));
1316                 else if ($2 < 8)
1317                         THIS->parser_error (_ ("can't abbreviate"));
1318                 $$ = $2;
1319         }
1320         ;
1321
1322
1323 simple_element:
1324         musical_pitch exclamations questions notemode_duration  {
1325                 if (!THIS->lexer_p_->note_state_b ())
1326                         THIS->parser_error (_ ("have to be in Note mode for notes"));
1327
1328
1329                 Note_req *n = new Note_req;
1330
1331                 n->pitch_ = *$1;
1332                 delete $1;
1333                 n->duration_ = *$4;
1334                 delete $4;
1335                 n->cautionary_b_ = $3 % 2;
1336                 n->forceacc_b_ = $2 % 2 || n->cautionary_b_;
1337
1338                 Simultaneous_music*v = new Request_chord;
1339                 v->set_spot (THIS->here_input ());
1340                 n->set_spot (THIS->here_input ());
1341
1342                 v->add_music (n);
1343
1344                 $$ = v;
1345         }
1346         | RESTNAME notemode_duration            {
1347                 $$ = THIS->get_rest_element (*$1, $2);
1348                 delete $1;  // delete notename
1349         }
1350         | MEASURES notemode_duration    {
1351                 Multi_measure_rest_req* m = new Multi_measure_rest_req;
1352                 m->duration_ = *$2;
1353                 delete $2;
1354
1355                 Simultaneous_music*velt_p = new Request_chord;
1356                 velt_p->set_spot (THIS->here_input ());
1357                 velt_p->add_music (m);
1358                 $$ = velt_p;
1359         }
1360         | STRING notemode_duration                      {
1361                 if (!THIS->lexer_p_->lyric_state_b ())
1362                         THIS->parser_error (_ ("have to be in Lyric mode for lyrics"));
1363                 $$ = THIS->get_word_element (*$1, $2);
1364                 delete $1;
1365         }
1366         | chord {
1367                 if (!THIS->lexer_p_->chord_state_b ())
1368                         THIS->parser_error (_ ("have to be in Chord mode for chords"));
1369                 $$ = $1;
1370         }
1371         | '@' notemode_chord '@' {
1372                 if (!THIS->lexer_p_->note_state_b ())
1373                         THIS->parser_error (_ ("have to be in Note mode for @chords"));
1374                 $$ = $2;
1375         }
1376         ;
1377
1378 chord:
1379         steno_tonic_pitch notemode_duration chord_additions chord_subtractions chord_inversion {
1380                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1381         };
1382
1383 notemode_chord:
1384         steno_musical_pitch notemode_duration chord_additions chord_subtractions notemode_chord_inversion {
1385                 $$ = THIS->get_chord (*$1, $3, $4, $5, *$2);
1386         };
1387
1388
1389 chord_additions:
1390         {
1391                 $$ = new Array<Musical_pitch>;
1392         }
1393         | '-' chord_notes {
1394                 $$ = $2;
1395         }
1396         ;
1397
1398 chord_notes:
1399         {
1400                 $$ = new Array<Musical_pitch>;
1401         }
1402         | chord_notes chord_addsub {
1403                 $$ = $1;
1404                 $$->push (*$2);
1405         }
1406         ;
1407
1408 chord_subtractions:
1409         {
1410                 $$ = new Array<Musical_pitch>;
1411         }
1412         | '^' chord_notes {
1413                 $$ = $2;
1414         }
1415         ;
1416
1417
1418 /*
1419         forevery : X : optional_X sucks. Devise  a solution.
1420 */
1421
1422
1423 chord_addsub:
1424         chord_note optional_dot
1425         | CHORDMODIFIER_PITCH optional_dot
1426         ;
1427
1428 chord_inversion:
1429         {
1430                 $$ = 0;
1431         }
1432         | '/' steno_tonic_pitch {
1433                 $$ = $2
1434         }
1435         ;
1436
1437 notemode_chord_inversion:
1438         {
1439                 $$ = 0;
1440         }
1441         | '/' steno_musical_pitch {
1442                 $$ = $2
1443         }
1444         ;
1445
1446 chord_note:
1447         unsigned {
1448                 $$ = new Musical_pitch;
1449                 $$->notename_i_ = ($1 - 1) % 7;
1450                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1451                 $$->accidental_i_ = 0;
1452         }
1453         | unsigned '+' {
1454                 $$ = new Musical_pitch;
1455                 $$->notename_i_ = ($1 - 1) % 7;
1456                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1457                 $$->accidental_i_ = 1;
1458         }
1459         | unsigned '-' {
1460                 $$ = new Musical_pitch;
1461                 $$->notename_i_ = ($1 - 1) % 7;
1462                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1463                 $$->accidental_i_ = -1;
1464         }
1465         ;
1466
1467 /*
1468         UTILITIES
1469  */
1470 pitch_list:                     {
1471                 $$ = new Array<Musical_pitch>;
1472         }
1473         | pitch_list musical_pitch      {
1474                 $$->push (*$2);
1475                 delete $2;
1476         }
1477         ;
1478
1479
1480 int_list:
1481         /**/                    {
1482                 $$ = new Array<int>
1483         }
1484         | int_list int          {
1485                 $$->push ($2);
1486         }
1487         ;
1488
1489 unsigned:
1490         UNSIGNED        {
1491                 $$ = $1;
1492         }
1493         | DIGIT {
1494                 $$ = $1;
1495         };
1496
1497 int:
1498         unsigned {
1499                 $$ = $1;
1500         }
1501         | '-' unsigned {
1502                 $$ = -$2;
1503         }
1504         | INT_IDENTIFIER        {
1505                 $$ = *$1->access_content_int (false);
1506         }
1507         ;
1508
1509
1510 string:
1511         STRING          {
1512                 $$ = $1;
1513         }
1514         | STRING_IDENTIFIER     {
1515                 $$ = $1->access_content_String (true);
1516         }
1517         | string '+' string {
1518                 *$$ += *$3;
1519                 delete $3;
1520         }
1521         ;
1522
1523
1524
1525
1526 dots:
1527                         { $$ = 0; }
1528         | dots '.'      { $$ ++; }
1529         ;
1530
1531
1532
1533 exclamations:
1534                 { $$ = 0; }
1535         | exclamations '!'      { $$ ++; }
1536         ;
1537
1538 questions:
1539                 { $$ = 0; }
1540         | questions '?' { $$ ++; }
1541         ;
1542
1543
1544 semicolon:
1545         ';'
1546         ;
1547 %%
1548
1549 void
1550 My_lily_parser::set_yydebug (bool b)
1551 {
1552 #ifdef YYDEBUG
1553         yydebug = b;
1554 #endif
1555 }
1556 void
1557 My_lily_parser::do_yyparse ()
1558 {
1559         yyparse ((void*)this);
1560 }
1561
1562
1563