lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token PROPERTY
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSLATOR
 302 %token TRANSPOSE
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306
 307 /* escaped */
 308 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 309 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 310 %token E_BACKSLASH
 311 %token <i> E_UNSIGNED
 312 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 313 %token FIGURE_SPACE
 314
 315 %type <i>       exclamations questions dots optional_rest
 316 %type <i>        bass_mod
 317 %type <scm>     grace_head
 318 %type <scm>     oct_check
 319 %type <scm>     context_mod_list
 320 %type <scm>     lyric_element
 321 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 322 %token <i>      DIGIT
 323 %token <scm>    NOTENAME_PITCH
 324 %token <scm>    TONICNAME_PITCH
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DURATION_IDENTIFIER
 327 %token <scm>    FRACTION
 328 %token <id>     IDENTIFIER
 329 %token DRUMS
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    CHORD_MODIFIER
 332 %token <scm>    SCORE_IDENTIFIER
 333 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    NUMBER_IDENTIFIER
 335 %token <scm>    EVENT_IDENTIFIER
 336 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    RESTNAME
 339 %token <scm>    STRING
 340 %token <scm>    SCM_T
 341 %token <i>      UNSIGNED
 342 %token <scm>   REAL
 343
 344 %token MARKUP
 345 %token <scm> MARKUP_HEAD_MARKUP0
 346 %token <scm> MARKUP_HEAD_EMPTY
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 355 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 356
 357 %type <outputdef> output_def
 358 %type <scm>     lilypond_header lilypond_header_body
 359 %type <music>   open_event close_event
 360 %type <i>       sub_quotes sup_quotes
 361 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 362 %type <music>   Repeated_music
 363 %type <scm>     Alternative_music
 364 %type <i>       tremolo_type
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       script_dir
 367 %type <scm>     identifier_init
 368
 369 %type <music> note_chord_element chord_body chord_body_element
 370 %type <scm>  chord_body_elements
 371 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 372
 373 %type <scm>   post_events
 374 %type <music> gen_text_def direction_less_event direction_reqd_event
 375 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 376 %type <scm>    steno_tonic_pitch
 377 %type <scm>     duration_length fraction
 378
 379 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 380
 381 %type <scm>  embedded_scm scalar
 382 %type <music>   Music Sequential_music Simultaneous_music
 383 %type <music>   relative_music re_rhythmed_music
 384 %type <music>   music_property_def context_change
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music>   post_event tagged_post_event
 389 %type <music> command_req
 390 %type <music> string_number_event
 391 %type <scm>     string bare_number number_expression number_term number_factor
 392 %type <score>   score_block score_body
 393
 394 %type <scm>     translator_spec_block translator_spec_body
 395 %type <music>   tempo_event
 396 %type <scm>     script_abbreviation
 397
 398
 399
 400 %left '-' '+'
 401
 402 /* We don't assign precedence to / and *, because we might need varied
 403 prec levels in different prods */
 404
 405 %left UNARY_MINUS
 406
 407 %%
 408
 409 lilypond:       /* empty */
 410         | lilypond toplevel_expression {}
 411         | lilypond assignment  { }
 412         | lilypond error {
 413                 THIS->error_level_  = 1;
 414         }
 415         | lilypond INVALID      {
 416                 THIS->error_level_  = 1;
 417         }
 418         ;
 419
 420 toplevel_expression:
 421         lilypond_header {
 422                 THIS->input_file_->header_ = $1;
 423         }
 424         | score_block {
 425                 Score * sc = $1;
 426
 427                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 428
 429                 Path p = split_path (THIS->output_basename_);
 430                 int *c =  &THIS->input_file_->score_count_;
 431                 if (*c)
 432                         {
 433                         p.base += "-" + to_string (*c);
 434                         }
 435
 436                 (*c)++;
 437                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 438
 439                 for (int i=0; i < sc->defs_.size (); i++)
 440                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 441
 442                 if (sc->defs_.is_empty ())
 443                 {
 444                    Music_output_def *id =
 445                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 446                                 ("$defaultpaper"));
 447
 448                    id = id ? id->clone () : new Paper_def;
 449
 450                    default_rendering (sc->music_, id->self_scm(), head, outname);
 451
 452                    scm_gc_unprotect_object (id->self_scm ());
 453                 }
 454                 scm_gc_unprotect_object (sc->self_scm());
 455         }
 456         | output_def {
 457                 SCM id = SCM_EOL;
 458                 if (dynamic_cast<Paper_def*> ($1))
 459                         id = scm_makfrom0str ("$defaultpaper");
 460                 else if (dynamic_cast<Midi_def*> ($1))
 461                         id = scm_makfrom0str ("$defaultmidi");
 462                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 463                 scm_gc_unprotect_object ($1->self_scm ());
 464         }
 465         ;
 466
 467 embedded_scm:
 468         SCM_T
 469         | SCM_IDENTIFIER
 470         ;
 471
 472
 473
 474
 475 lilypond_header_body:
 476         {
 477                 $$ = ly_make_anonymous_module ();
 478                 THIS->lexer_->add_scope ($$);
 479         }
 480         | lilypond_header_body assignment  {
 481
 482         }
 483         ;
 484
 485 lilypond_header:
 486         HEADER '{' lilypond_header_body '}'     {
 487                 $$ = THIS->lexer_-> remove_scope();
 488         }
 489         ;
 490
 491
 492 /*
 493         DECLARATIONS
 494 */
 495 assignment:
 496         STRING {
 497                 THIS->push_spot ();
 498         }
 499         /* cont */ '=' identifier_init  {
 500
 501         /*
 502                 Should find generic way of associating input with objects.
 503         */
 504                 Input ip = THIS->pop_spot ();
 505
 506                 if (! regular_identifier_b ($1))
 507                 {
 508                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 509                 }
 510
 511                 THIS->lexer_->set_identifier ($1, $4);
 512
 513 /*
 514  TODO: devise standard for protection in parser.
 515
 516   The parser stack lives on the C-stack, which means that
 517 all objects can be unprotected as soon as they're here.
 518
 519 */
 520         }
 521         | embedded_scm { }
 522         ;
 523
 524
 525 identifier_init:
 526         score_block {
 527                 $$ = $1->self_scm ();
 528                 scm_gc_unprotect_object ($$);
 529         }
 530         | full_markup {
 531                 $$ = $1;
 532         }
 533         | output_def {
 534                 $$ = $1->self_scm ();
 535                 scm_gc_unprotect_object ($$);
 536         }
 537         | translator_spec_block {
 538                 $$ = $1;
 539         }
 540         | Music  {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | post_event {
 545                 $$ = $1->self_scm ();
 546                 scm_gc_unprotect_object ($$);
 547         }
 548         | number_expression {
 549                 $$ = $1;
 550         }
 551         | string {
 552                 $$ = $1;
 553         }
 554         | embedded_scm  {
 555                 $$ = $1;
 556         }
 557         ;
 558
 559 translator_spec_block:
 560         TRANSLATOR '{' translator_spec_body '}'
 561                 {
 562                 $$ = $3;
 563         }
 564         ;
 565
 566 translator_spec_body:
 567         /**/ {
 568                 $$ = Context_def::make_scm ();
 569                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 570         }
 571         | TRANSLATOR_IDENTIFIER {
 572                 $$ = $1;
 573                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 574         }
 575         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 576                 Context_def*td = unsmob_context_def($$);
 577
 578                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 579                         SCM tag = gh_caar (p);
 580
 581                         /* TODO: should make new tag "grob-definition" ? */
 582                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 583                                                         tag, gh_cons (ly_cdar (p), SCM_EOL), SCM_UNDEFINED));
 584                 }
 585         }
 586         | translator_spec_body context_mod {
 587                 unsmob_context_def ($$)->add_context_mod ($2);
 588         }
 589         ;
 590
 591 /*
 592         SCORE
 593 */
 594 score_block:
 595         SCORE {
 596                 THIS->push_spot ();
 597         }
 598         /*cont*/ '{' score_body '}'     {
 599                 THIS->pop_spot ();
 600                 $$ = $4;
 601
 602         }
 603         ;
 604
 605 score_body:
 606         Music   {
 607                 $$ = new Score;
 608
 609                 $$->set_spot (THIS->here_input ());
 610                 SCM m = $1->self_scm ();
 611                 scm_gc_unprotect_object (m);
 612
 613                 /*
 614                         guh.
 615                 */
 616                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 617                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 618                         m = gh_call1 (gh_car (check_funcs), m);
 619                 $$->music_ = m;
 620
 621         }
 622         | SCORE_IDENTIFIER {
 623                 $$ = new Score ( *unsmob_score ($1));
 624                 $$->set_spot (THIS->here_input ());
 625         }
 626         | score_body lilypond_header    {
 627                 $$->header_ = $2;
 628         }
 629         | score_body output_def {
 630                 $$->defs_.push ($2);
 631                 scm_gc_unprotect_object ($2->self_scm ());
 632         }
 633         | score_body error {
 634
 635         }
 636         ;
 637
 638
 639 /*
 640         MIDI
 641 */
 642 output_def:
 643         music_output_def_body '}' {
 644                 $$ = $1;
 645                 THIS-> lexer_-> remove_scope ();
 646         }
 647         ;
 648
 649 music_output_def_head:
 650         MIDI    {
 651                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 652
 653
 654                 Midi_def* p =0;
 655                 if (id)
 656                         p = dynamic_cast<Midi_def*> (id->clone ());
 657                 else
 658                         p = new Midi_def;
 659
 660                 $$ = p;
 661                 THIS->lexer_->add_scope (p->scope_);
 662         }
 663         | PAPER         {
 664                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 665                   Paper_def *p = 0;
 666                 if (id)
 667                         p = dynamic_cast<Paper_def*> (id->clone ());
 668                 else
 669                         p = new Paper_def;
 670
 671                 THIS->lexer_->add_scope (p->scope_);
 672                 $$ = p;
 673         }
 674         ;
 675
 676
 677 music_output_def_body:
 678         music_output_def_head '{' {
 679
 680         }
 681         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 682                 scm_gc_unprotect_object ($1->self_scm ());
 683                 Music_output_def * o =  unsmob_music_output_def ($3);
 684                 $$ = o;
 685                 THIS->lexer_->remove_scope ();
 686                 THIS->lexer_->add_scope (o->scope_);
 687         }
 688         | music_output_def_body assignment  {
 689
 690         }
 691         | music_output_def_body translator_spec_block   {
 692                 $$->assign_translator ($2);
 693         }
 694         | music_output_def_body tempo_event  {
 695                 /*
 696                         junk this ? there already is tempo stuff in
 697                         music.
 698                 */
 699                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 700                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 701                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 702                 if (md)
 703                         md->set_tempo (d->get_length (), m);
 704                 scm_gc_unprotect_object ($2->self_scm ());
 705         }
 706         | music_output_def_body error {
 707
 708         }
 709         ;
 710
 711 tempo_event:
 712         TEMPO steno_duration '=' bare_unsigned  {
 713                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 714                 $$->set_mus_property ("tempo-unit", $2);
 715                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 716         }
 717         ;
 718
 719 /*
 720 The representation of a  list is the
 721
 722   (LIST . LAST-CONS)
 723
 724  to have  efficient append.
 725 */
 726 Music_list:
 727         /* empty */ {
 728                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 729         }
 730         | Music_list Music {
 731                 SCM s = $$;
 732                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 733                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 734                 if (gh_pair_p (ly_cdr (s)))
 735                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 736                 else
 737                         gh_set_car_x (s, c); /* set first cons */
 738                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 739         }
 740         | Music_list error {
 741         }
 742         ;
 743
 744
 745 Music:
 746         Simple_music
 747         | Composite_music
 748         ;
 749
 750 Alternative_music:
 751         /* empty */ {
 752                 $$ = SCM_EOL;
 753         }
 754         | ALTERNATIVE '{' Music_list '}' {
 755                 $$ = $3;
 756         }
 757         ;
 758
 759 Repeated_music:
 760         REPEAT string bare_unsigned Music Alternative_music
 761         {
 762                 Music *beg = $4;
 763                 int times = $3;
 764                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 765                 if (times < scm_ilength (alts)) {
 766                   unsmob_music (gh_car (alts))
 767                     ->origin ()->warning (
 768                     _("More alternatives than repeats.  Junking excess alternatives."));
 769                   alts = ly_truncate_list (times, alts);
 770                 }
 771
 772
 773                 static SCM proc;
 774                 if (!proc)
 775                         proc = scm_c_eval_string ("make-repeated-music");
 776
 777                 SCM mus = scm_call_1 (proc, $2);
 778                 scm_gc_protect_object (mus); // UGH.
 779                 Music *r =unsmob_music (mus);
 780                 if (beg)
 781                         {
 782                         r-> set_mus_property ("element", beg->self_scm ());
 783                         scm_gc_unprotect_object (beg->self_scm ());
 784                         }
 785                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 786
 787                 r-> set_mus_property ("elements",alts);
 788                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 789                         /*
 790                         we can not get durations and other stuff correct down the line, so we have to
 791                         add to the duration log here.
 792                         */
 793                         static SCM func;
 794
 795                         if (!func)
 796                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 797
 798                         int dots = ($3 % 3) ? 0 : 1;
 799                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 800
 801                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 802
 803                         if (seq) {
 804                                 int list_len =scm_ilength (seq->music_list ());
 805                                 if (list_len != 2)
 806                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 807                                 shift -= 1;
 808                                 r->compress (Moment (Rational (1,list_len)));
 809                                 }
 810                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 811
 812                 }
 813                 r->set_spot (*$4->origin ());
 814
 815                 $$ = r;
 816         }
 817         ;
 818
 819 Sequential_music:
 820         SEQUENTIAL '{' Music_list '}'           {
 821                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 822                 $$->set_mus_property ("elements", ly_car ($3));
 823                 $$->set_spot(THIS->here_input());
 824         }
 825         | '{' Music_list '}'            {
 826                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 827                 $$->set_mus_property ("elements", ly_car ($2));
 828                 $$->set_spot(THIS->here_input());
 829         }
 830         ;
 831
 832 Simultaneous_music:
 833         SIMULTANEOUS '{' Music_list '}'{
 834                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 835                 $$->set_mus_property ("elements", ly_car ($3));
 836                 $$->set_spot(THIS->here_input());
 837
 838         }
 839         | simul_open Music_list simul_close     {
 840                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 841                 $$->set_mus_property ("elements", ly_car ($2));
 842                 $$->set_spot(THIS->here_input());
 843         }
 844         ;
 845
 846 Simple_music:
 847         event_chord             { $$ = $1; }
 848         | APPLYOUTPUT embedded_scm {
 849                 if (!ly_input_procedure_p ($2))
 850                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 851                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 852                 $$->set_mus_property ("procedure", $2);
 853                 $$->set_spot (THIS->here_input());
 854         }
 855         | APPLYCONTEXT embedded_scm {
 856                 if (!ly_input_procedure_p ($2))
 857                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 858                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 859                 $$->set_mus_property ("procedure", $2);
 860                 $$->set_spot (THIS->here_input());
 861         }
 862         | MUSIC_IDENTIFIER {
 863                 $$ = unsmob_music ($1);
 864         }
 865         | music_property_def
 866         | context_change
 867         ;
 868
 869
 870 optional_context_mod:
 871         /**/ { $$ = SCM_EOL; }
 872         | WITH '{' context_mod_list '}'  { $$ = $3; }
 873         ;
 874
 875 grace_head:
 876         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 877         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 878         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 879         ;
 880
 881 context_mod_list:
 882         /* */  { $$ = SCM_EOL; }
 883         | context_mod_list context_mod  {
 884                  $$ = gh_cons ($2, $1);
 885         }
 886         ;
 887
 888 Composite_music:
 889         AUTOCHANGE Music        {
 890                 static SCM proc ;
 891                 if (!proc)
 892                         proc = scm_c_eval_string ("make-autochange-music");
 893
 894                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 895                 scm_gc_unprotect_object ($2->self_scm ());
 896                 $$ = unsmob_music (res);
 897                 scm_gc_protect_object (res);
 898                 $$->set_spot (THIS->here_input());
 899         }
 900         | PARTCOMBINE Music Music {
 901                 static SCM proc;
 902                 if (!proc)
 903                         proc = scm_c_eval_string ("make-part-combine-music");
 904
 905                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 906                         $3->self_scm (), SCM_UNDEFINED));
 907                 scm_gc_unprotect_object ($3->self_scm ());
 908                 scm_gc_unprotect_object ($2->self_scm ());
 909                 $$ = unsmob_music (res);
 910                 scm_gc_protect_object (res);
 911                 $$->set_spot (THIS->here_input());
 912         }
 913         | grace_head Music {
 914 #if 1
 915         /*
 916                 The other version is for easier debugging  of
 917                 Sequential_music_iterator in combination with grace notes.
 918         */
 919
 920 /*
 921
 922 TODO: should distinguish between both grace types in the
 923 basic music objects too, since the meaning is different.
 924
 925 */
 926
 927                 String start_str = "start" + ly_scm2string ($1) + "Music";
 928                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 929
 930                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 931                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 932
 933                 Music *startm = unsmob_music (start);
 934                 Music *stopm = unsmob_music (stop);
 935
 936                 SCM ms = SCM_EOL;
 937                 if (stopm) {
 938                         stopm = stopm->clone ();
 939                         ms = scm_cons (stopm->self_scm (), ms);
 940                         scm_gc_unprotect_object (stopm->self_scm ());
 941                 }
 942                 ms = scm_cons ($2->self_scm (), ms);
 943                 scm_gc_unprotect_object ($2->self_scm());
 944                 if (startm) {
 945                         startm = startm->clone ();
 946                         ms = scm_cons (startm->self_scm () , ms);
 947                         scm_gc_unprotect_object (startm->self_scm ());
 948                 }
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string optional_context_mod Music {
 964                 $$ = context_spec_music ($2, $4, $6, $5);
 965
 966         }
 967         | CONTEXT STRING optional_context_mod Music {
 968                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 969         }
 970         | NEWCONTEXT string optional_context_mod Music {
 971                 $$ = context_spec_music ($2, get_next_unique_context (),
 972                                          $4, $3);
 973         }
 974
 975         | TIMES {
 976                 THIS->push_spot ();
 977         }
 978         /* CONTINUED */
 979                 fraction Music
 980
 981         {
 982                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 983                 Music *mp = $4;
 984
 985                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 986                 $$->set_spot (THIS->pop_spot ());
 987
 988                 $$->set_mus_property ("element", mp->self_scm ());
 989                 scm_gc_unprotect_object (mp->self_scm ());
 990                 $$->set_mus_property ("numerator", gh_int2scm (n));
 991                 $$->set_mus_property ("denominator", gh_int2scm (d));
 992                 $$->compress (Moment (Rational (n,d)));
 993
 994         }
 995         | Repeated_music                { $$ = $1; }
 996         | Simultaneous_music            { $$ = $1; }
 997         | Sequential_music              { $$ = $1; }
 998         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 999                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1000                 Music *p = $4;
1001                 Pitch from = *unsmob_pitch ($2);
1002                 Pitch to = *unsmob_pitch ($3);
1003
1004                 p->transpose (interval (from, to));
1005                 $$->set_mus_property ("element", p->self_scm ());
1006                 scm_gc_unprotect_object (p->self_scm ());
1007         }
1008         | APPLY embedded_scm Music  {
1009                 if (!ly_input_procedure_p ($2))
1010                         {
1011                         THIS->parser_error (_ ("\\apply takes function argument"));
1012                         $$ = $3;
1013                         }
1014                 else
1015                         {
1016                         SCM ret = gh_call1 ($2, $3->self_scm ());
1017                         Music *m = unsmob_music (ret);
1018                         if (!m) {
1019                                 THIS->parser_error ("\\apply must return a Music");
1020                                 m = MY_MAKE_MUSIC("Music");
1021                                 }
1022                         $$ = m;
1023                         }
1024         }
1025         | NOTES
1026                 {
1027                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1028                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1029         }
1030         Music
1031                 { $$ = $3;
1032                   THIS->lexer_->pop_state ();
1033                 }
1034         | DRUMS
1035                 {
1036                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1037                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1038         }
1039         Music
1040                 { $$ = $3;
1041                   THIS->lexer_->pop_state ();
1042                 }
1043         | FIGURES
1044                 { THIS->lexer_->push_figuredbass_state (); }
1045         Music
1046                 {
1047                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1048                   chm->set_mus_property ("element", $3->self_scm ());
1049                   $$ = chm;
1050                   scm_gc_unprotect_object ($3->self_scm());
1051
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | CHORDS {
1055                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1056                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1057                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1058                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1059
1060         } Music {
1061                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1062                   chm->set_mus_property ("element", $3->self_scm ());
1063                   scm_gc_unprotect_object ($3->self_scm());
1064                   $$ = chm;
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | LYRICS
1069                 { THIS->lexer_->push_lyric_state (); }
1070         Music
1071                 {
1072                   $$ = $3;
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | relative_music        { $$ = $1; }
1076         | re_rhythmed_music     { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music * p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1088
1089                 $$->set_mus_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1102           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1109           l->set_mus_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_mus_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 context_change:
1117         CHANGE STRING '=' STRING  {
1118                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1119                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1120                 t-> set_mus_property ("change-to-id", $4);
1121
1122                 $$ = t;
1123                 $$->set_spot (THIS->here_input ());
1124         }
1125         ;
1126
1127 property_operation:
1128         STRING '='  scalar {
1129                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1130                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1131         }
1132         | STRING UNSET {
1133                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1134                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1135         }
1136         | STRING SET embedded_scm '=' embedded_scm {
1137                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1138                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1139         }
1140         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1141                 $$ = scm_list_n (ly_symbol2scm ("push"),
1142                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1143         }
1144         | STRING REVERT embedded_scm {
1145                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1146                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1147         }
1148         ;
1149
1150 translator_mod:
1151         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1152         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1153         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1154
1155         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1156         | DENIES { $$ = ly_symbol2scm ("denies"); }
1157
1158         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1159         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1160         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1161         | NAME { $$ = ly_symbol2scm ("context-name"); }
1162         ;
1163
1164 context_mod:
1165         property_operation { $$ = $1; }
1166         | translator_mod STRING {
1167                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1168         }
1169         ;
1170
1171 music_property_def:
1172         PROPERTY STRING '.' property_operation {
1173                 Music * t = property_op_to_music ($4);
1174                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1175
1176                 csm->set_mus_property ("element", t->self_scm ());
1177                 scm_gc_unprotect_object (t->self_scm ());
1178
1179                 $$ = csm;
1180                 $$->set_spot (THIS->here_input ());
1181
1182                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1183         }
1184         | ONCE music_property_def {
1185                 $$ = $2;
1186                 SCM e = $2->get_mus_property ("element");
1187                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1188         }
1189         ;
1190
1191
1192 scalar:
1193         string          { $$ = $1; }
1194         | bare_int      { $$ = gh_int2scm ($1); }
1195         | embedded_scm  { $$ = $1; }
1196         | full_markup {  $$ = $1; }
1197         | DIGIT { $$ = gh_int2scm ($1); }
1198         ;
1199
1200 /*
1201 This is a trick:
1202
1203 Adding pre_events to the simple_element
1204 makes the choice between
1205
1206   string:  STRING
1207
1208 and
1209
1210   simple_element: STRING
1211
1212 a single shift/reduction conflict.
1213
1214 nevertheless, this is not very clean, and we should find a different
1215 solution.
1216
1217 */
1218 pre_events: {
1219                 THIS->push_spot ();
1220         }
1221         ;
1222
1223 event_chord:
1224         pre_events simple_element post_events   {
1225                 SCM elts = $2-> get_mus_property ("elements");
1226
1227                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1228
1229                 $2->set_mus_property ("elements", elts);
1230                 $$ = $2;
1231         }
1232         | command_element
1233         | note_chord_element
1234         ;
1235
1236
1237 note_chord_element:
1238         chord_body optional_notemode_duration post_events
1239         {
1240                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1241                 SCM es = $1->get_mus_property ("elements");
1242                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1243
1244                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1245                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1246                 es = gh_append2 (es, postevs);
1247
1248                 $1-> set_mus_property ("elements", es);
1249                 $$ = $1;
1250         }
1251         ;
1252
1253 chord_open: '<'
1254         ;
1255
1256 chord_close: '>'
1257         ;
1258
1259 simul_open: LESSLESS
1260         ;
1261
1262 simul_close: MOREMORE
1263         ;
1264
1265 chord_body:
1266         chord_open chord_body_elements chord_close
1267         {
1268                 $$ = MY_MAKE_MUSIC("EventChord");
1269                 $$->set_mus_property ("elements",
1270                         scm_reverse_x ($2, SCM_EOL));
1271         }
1272         ;
1273
1274 chord_body_elements:
1275         /* empty */             { $$ = SCM_EOL; }
1276         | chord_body_elements chord_body_element {
1277                 $$ = gh_cons ($2->self_scm(), $1);
1278                 scm_gc_unprotect_object ($2->self_scm());
1279         }
1280         ;
1281
1282 chord_body_element:
1283         pitch exclamations questions post_events
1284         {
1285                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1286                 n->set_mus_property ("pitch", $1);
1287                 if ($3 % 2)
1288                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1289                 if ($2 % 2 || $3 % 2)
1290                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1291
1292                 if (gh_pair_p ($4)) {
1293                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1294                         n->set_mus_property ("articulations", arts);
1295                 }
1296                 $$ = n;
1297         }
1298         | DRUM_PITCH post_events {
1299                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1300                 n->set_mus_property ("duration" ,$2);
1301                 n->set_mus_property ("drum-type" , $1);
1302                 n->set_spot (THIS->here_input());
1303
1304                 if (gh_pair_p ($2)) {
1305                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1306                         n->set_mus_property ("articulations", arts);
1307                 }
1308                 $$ = n;
1309         }
1310         ;
1311
1312 command_element:
1313         command_req {
1314                 $$ = MY_MAKE_MUSIC("EventChord");
1315                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1316                 scm_gc_unprotect_object ($1->self_scm());
1317
1318                 $$-> set_spot (THIS->here_input ());
1319                 $1-> set_spot (THIS->here_input ());
1320         }
1321         | SKIP duration_length {
1322                 Music * skip = MY_MAKE_MUSIC("SkipMusic");
1323                 skip->set_mus_property ("duration", $2);
1324
1325                 $$ = skip;
1326         }
1327         | OCTAVE { THIS->push_spot (); }
1328           pitch {
1329                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1330                 $$ = l;
1331                 $$->set_spot (THIS->pop_spot ());
1332                 $$->set_mus_property ("pitch", $3);
1333         }
1334         | E_LEFTSQUARE {
1335                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1336                 l->set_mus_property ("span-direction", gh_int2scm (START));
1337                 l->set_spot (THIS->here_input ());
1338
1339                 $$ = MY_MAKE_MUSIC("EventChord");
1340                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1341                 scm_gc_unprotect_object (l->self_scm());
1342                 $$->set_spot (THIS->here_input ());
1343         }
1344         | E_RIGHTSQUARE {
1345                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1346                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1347                 l->set_spot (THIS->here_input ());
1348
1349                 $$ = MY_MAKE_MUSIC("EventChord");
1350                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1351                 $$->set_spot (THIS->here_input ());
1352                 scm_gc_unprotect_object (l->self_scm());
1353         }
1354         | E_BACKSLASH {
1355                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1356                 $$->set_spot (THIS->here_input ());
1357         }
1358         | '|'      {
1359
1360                 $$ = MY_MAKE_MUSIC("BarCheck");
1361                 $$->set_spot (THIS->here_input ());
1362         }
1363         | BAR STRING                    {
1364                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1365
1366                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1367                 csm->set_mus_property ("element", t->self_scm ());
1368                 scm_gc_unprotect_object (t->self_scm ());
1369
1370                 $$ = csm;
1371                 $$->set_spot (THIS->here_input ());
1372
1373                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1374         }
1375         | PARTIAL duration_length       {
1376                 Moment m = - unsmob_duration ($2)->get_length ();
1377                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1378
1379                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1380                 sp->set_mus_property ("element", p->self_scm ());
1381                 scm_gc_unprotect_object (p->self_scm ());
1382
1383                 $$ =sp ;
1384                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1385         }
1386         | CLEF STRING  {
1387                 static SCM proc ;
1388                 if (!proc)
1389                         proc = scm_c_eval_string ("make-clef-set");
1390
1391                 SCM result = scm_call_1 (proc, $2);
1392                 scm_gc_protect_object (result);
1393                 $$ = unsmob_music (result);
1394         }
1395         | TIME_T fraction  {
1396                 static SCM proc;
1397                 if (!proc)
1398                         proc = scm_c_eval_string ("make-time-signature-set");
1399
1400                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1401                 scm_gc_protect_object (result);
1402                 $$ = unsmob_music (result);
1403         }
1404         | MARK scalar {
1405                 static SCM proc;
1406                 if (!proc)
1407                         proc = scm_c_eval_string ("make-mark-set");
1408
1409                 SCM result = scm_call_1 (proc, $2);
1410                 scm_gc_protect_object (result);
1411                 $$ = unsmob_music (result);
1412         }
1413         ;
1414
1415 command_req:
1416         BREATHE {
1417                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1418         }
1419         | E_TILDE {
1420                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1421         }
1422         | MARK DEFAULT  {
1423                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1424                 $$ = m;
1425         }
1426         | tempo_event {
1427                 $$ = $1;
1428         }
1429         | KEY DEFAULT {
1430                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1431                 $$ = key;
1432         }
1433         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1434
1435                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1436                 if (scm_ilength ($3) > 0)
1437                 {
1438                         key->set_mus_property ("pitch-alist", $3);
1439                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1440                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1441                 } else {
1442                         THIS->parser_error (_("Second argument must be pitch list."));
1443                 }
1444
1445                 $$ = key;
1446         }
1447         ;
1448
1449 post_events:
1450         /* empty */ {
1451                 $$ = SCM_EOL;
1452         }
1453         | post_events post_event {
1454                 $2->set_spot (THIS->here_input ());
1455                 $$ = gh_cons ($2->self_scm(), $$);
1456                 scm_gc_unprotect_object ($2->self_scm());
1457         }
1458         | post_events tagged_post_event {
1459                 $2 -> set_spot (THIS->here_input ());
1460                 $$ = scm_cons ($2->self_scm(), $$);
1461                 scm_gc_unprotect_object ($2->self_scm());
1462         }
1463         ;
1464
1465
1466 tagged_post_event:
1467         '-' TAG embedded_scm post_event {
1468                 tag_music ($4, $3, THIS->here_input ());
1469                 $$ = $4;
1470         }
1471         ;
1472
1473 post_event:
1474         direction_less_event {
1475                 $$ = $1;
1476         }
1477         | HYPHEN {
1478                 if (!THIS->lexer_->lyric_state_b ())
1479                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1480                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1481         }
1482         | EXTENDER {
1483                 if (!THIS->lexer_->lyric_state_b ())
1484                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1485                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1486         }
1487         | script_dir direction_reqd_event {
1488                 if ($1)
1489                         $2->set_mus_property ("direction", gh_int2scm ($1));
1490                 $$ = $2;
1491         }
1492         | script_dir direction_less_event {
1493                 if ($1)
1494                         $2->set_mus_property ("direction", gh_int2scm ($1));
1495                 $$ = $2;
1496         }
1497         | string_number_event
1498         ;
1499
1500 string_number_event:
1501         E_UNSIGNED {
1502                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1503                 s->set_mus_property ("string-number",  gh_int2scm($1));
1504                 s->set_spot (THIS->here_input ());
1505                 $$ = s;
1506         }
1507         ;
1508
1509
1510 direction_less_event:
1511         '['  {
1512
1513
1514 /*
1515
1516 TODO: should take all these defs out of the parser, adn make use
1517 configurable, i.e.
1518
1519
1520 (set-articulation '~ "trill")
1521
1522 */
1523                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1524                 m->set_spot (THIS->here_input());
1525                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1526                 $$ = m;
1527         }
1528         | ']'  {
1529                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1530                 m->set_spot (THIS->here_input());
1531                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1532                 $$ = m;
1533         }
1534         | '~' {
1535                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1536                 m->set_spot (THIS->here_input());
1537                 $$ = m;
1538         }
1539         | close_event {
1540                 $$ = $1;
1541                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1542                         gh_int2scm (START));
1543         }
1544         | open_event {
1545                 $$ = $1;
1546                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1547                         gh_int2scm (STOP));
1548         }
1549         | EVENT_IDENTIFIER      {
1550                 $$ = unsmob_music ($1);
1551         }
1552         | tremolo_type  {
1553                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1554                a->set_spot (THIS->here_input ());
1555                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1556                $$ = a;
1557         }
1558         ;
1559
1560 direction_reqd_event:
1561         gen_text_def {
1562                 $$ = $1;
1563         }
1564         | script_abbreviation {
1565                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1566                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1567                 if (gh_string_p (s))
1568                         a->set_mus_property ("articulation-type", s);
1569                 else THIS->parser_error (_ ("Expecting string as script definition"));
1570                 $$ = a;
1571         }
1572         ;
1573
1574 oct_check:
1575         /**/ { $$ = SCM_EOL; }
1576         | '='  { $$ = gh_int2scm (0); }
1577         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1578         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1579         ;
1580
1581 sup_quotes:
1582         '\'' {
1583                 $$ = 1;
1584         }
1585         | sup_quotes '\'' {
1586                 $$ ++;
1587         }
1588         ;
1589
1590 sub_quotes:
1591         ',' {
1592                 $$ = 1;
1593         }
1594         | sub_quotes ',' {
1595                 $$ ++ ;
1596         }
1597         ;
1598
1599 steno_pitch:
1600         NOTENAME_PITCH  {
1601                 $$ = $1;
1602         }
1603         | NOTENAME_PITCH sup_quotes     {
1604                 Pitch p = *unsmob_pitch ($1);
1605                 p = p.transposed (Pitch ($2,0,0));
1606                 $$ = p.smobbed_copy ();
1607         }
1608         | NOTENAME_PITCH sub_quotes      {
1609                 Pitch p =* unsmob_pitch ($1);
1610                 p = p.transposed (Pitch (-$2,0,0));
1611                 $$ = p.smobbed_copy ();
1612         }
1613         ;
1614
1615 /*
1616 ugh. duplication
1617 */
1618
1619 steno_tonic_pitch:
1620         TONICNAME_PITCH {
1621                 $$ = $1;
1622         }
1623         | TONICNAME_PITCH sup_quotes    {
1624                 Pitch p = *unsmob_pitch ($1);
1625                 p = p.transposed (Pitch ($2,0,0));
1626                 $$ = p.smobbed_copy ();
1627         }
1628         | TONICNAME_PITCH sub_quotes     {
1629                 Pitch p =* unsmob_pitch ($1);
1630
1631                 p = p.transposed (Pitch (-$2,0,0));
1632                 $$ = p.smobbed_copy ();
1633         }
1634         ;
1635
1636 pitch:
1637         steno_pitch {
1638                 $$ = $1;
1639         }
1640         ;
1641
1642 pitch_also_in_chords:
1643         pitch
1644         | steno_tonic_pitch
1645         ;
1646
1647 close_event:
1648         '('     {
1649                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1650                 $$ = s;
1651                 s->set_spot (THIS->here_input());
1652         }
1653         | E_OPEN        {
1654                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1655                 $$ = s;
1656                 s->set_spot (THIS->here_input());
1657         }
1658         | E_SMALLER {
1659                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1660                 $$ = s;
1661                 s->set_spot (THIS->here_input());
1662         }
1663         | E_BIGGER {
1664                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1665                 $$ = s;
1666                 s->set_spot (THIS->here_input());
1667         }
1668         ;
1669
1670
1671 open_event:
1672         E_EXCLAMATION   {
1673                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1674                 s->set_spot (THIS->here_input());
1675
1676                 $$ = s;
1677         }
1678         | ')'   {
1679                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1680                 $$ = s;
1681                 s->set_spot (THIS->here_input());
1682
1683         }
1684         | E_CLOSE       {
1685                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1686                 $$ = s;
1687                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1688                 s->set_spot (THIS->here_input());
1689         }
1690         ;
1691
1692 gen_text_def:
1693         full_markup {
1694                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1695                 t->set_mus_property ("text", $1);
1696                 t->set_spot (THIS->here_input ());
1697                 $$ = t;
1698         }
1699         | string {
1700                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1701                 t->set_mus_property ("text", make_simple_markup ($1));
1702                 t->set_spot (THIS->here_input ());
1703                 $$ = t;
1704
1705         }
1706         | DIGIT {
1707                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1708                 t->set_mus_property ("digit",  gh_int2scm ($1));
1709                 t->set_spot (THIS->here_input ());
1710                 $$ = t;
1711         }
1712         ;
1713
1714 script_abbreviation:
1715         '^'             {
1716                 $$ = scm_makfrom0str ("Hat");
1717         }
1718         | '+'           {
1719                 $$ = scm_makfrom0str ("Plus");
1720         }
1721         | '-'           {
1722                 $$ = scm_makfrom0str ("Dash");
1723         }
1724         | '|'           {
1725                 $$ = scm_makfrom0str ("Bar");
1726         }
1727         | '>'           {
1728                 $$ = scm_makfrom0str ("Larger");
1729         }
1730         | '.'           {
1731                 $$ = scm_makfrom0str ("Dot");
1732         }
1733         | '_' {
1734                 $$ = scm_makfrom0str ("Underscore");
1735         }
1736         ;
1737
1738 script_dir:
1739         '_'     { $$ = DOWN; }
1740         | '^'   { $$ = UP; }
1741         | '-'   { $$ = CENTER; }
1742         ;
1743
1744
1745 absolute_pitch:
1746         steno_pitch     {
1747                 $$ = $1;
1748         }
1749         ;
1750
1751 duration_length:
1752         multiplied_duration {
1753                 $$ = $1;
1754         }
1755         ;
1756
1757 optional_notemode_duration:
1758         {
1759                 Duration dd = THIS->default_duration_;
1760                 $$ = dd.smobbed_copy ();
1761
1762                 THIS->beam_check ($$);
1763         }
1764         | multiplied_duration   {
1765                 $$ = $1;
1766                 THIS->default_duration_ = *unsmob_duration ($$);
1767
1768                 THIS->beam_check ($$);
1769         }
1770         ;
1771
1772 steno_duration:
1773         bare_unsigned dots              {
1774                 int l = 0;
1775                 if (!is_duration_b ($1))
1776                         THIS->parser_error (_f ("not a duration: %d", $1));
1777                 else
1778                         l =  intlog2 ($1);
1779
1780                 $$ = Duration (l, $2).smobbed_copy ();
1781         }
1782         | DURATION_IDENTIFIER dots      {
1783                 Duration *d =unsmob_duration ($1);
1784                 Duration k (d->duration_log (),d->dot_count () + $2);
1785
1786                 *d = k;
1787                 $$ = $1;
1788         }
1789         ;
1790
1791
1792
1793
1794 multiplied_duration:
1795         steno_duration {
1796                 $$ = $1;
1797         }
1798         | multiplied_duration '*' bare_unsigned {
1799                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1800         }
1801         | multiplied_duration '*' FRACTION {
1802                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1803
1804                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1805         }
1806         ;
1807
1808 fraction:
1809         FRACTION { $$ = $1; }
1810         | UNSIGNED '/' UNSIGNED {
1811                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1812         }
1813         ;
1814
1815 dots:
1816         /* empty */     {
1817                 $$ = 0;
1818         }
1819         | dots '.' {
1820                 $$ ++;
1821         }
1822         ;
1823
1824
1825 tremolo_type:
1826         ':'     {
1827                 $$ =0;
1828         }
1829         | ':' bare_unsigned {
1830                 if (!is_duration_b ($2))
1831                         THIS->parser_error (_f ("not a duration: %d", $2));
1832                 $$ = $2;
1833         }
1834         ;
1835
1836
1837
1838 /*****************************************************************
1839                 BASS FIGURES
1840 *****************************************************************/
1841 bass_number:
1842         DIGIT   {
1843                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1844         }
1845         | UNSIGNED {
1846                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1847         }
1848         | STRING { $$ =  $1; }
1849         ;
1850
1851 bass_mod:
1852         '-'     { $$ = -2; }
1853         | '+'   { $$ = 2; }
1854         | '!'   { $$ = 0; }
1855         ;
1856
1857 bass_figure:
1858         FIGURE_SPACE {
1859                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1860                 $$ = bfr->self_scm();
1861                 scm_gc_unprotect_object ($$);
1862         }
1863         | bass_number  {
1864                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1865                 $$ = bfr->self_scm();
1866
1867                 bfr->set_mus_property ("figure", $1);
1868
1869                 scm_gc_unprotect_object ($$);
1870         }
1871         | bass_figure bass_mod {
1872                 Music *m = unsmob_music ($1);
1873                 if ($2) {
1874                         SCM salter =m->get_mus_property ("alteration");
1875                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1876                         m->set_mus_property ("alteration",
1877                                 gh_int2scm (alter + $2));
1878                 } else {
1879                         m->set_mus_property ("alteration", gh_int2scm (0));
1880                 }
1881         }
1882         ;
1883
1884 br_bass_figure:
1885         '[' bass_figure {
1886                 $$ = $2;
1887                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1888         }
1889         | bass_figure   {
1890                 $$ = $1;
1891         }
1892         | br_bass_figure ']' {
1893                 $$ = $1;
1894                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1895         }
1896         ;
1897
1898 figure_list:
1899         /**/            {
1900                 $$ = SCM_EOL;
1901         }
1902         | figure_list br_bass_figure {
1903                 $$ = scm_cons ($2, $1);
1904         }
1905         ;
1906
1907 figure_spec:
1908         FIGURE_OPEN figure_list FIGURE_CLOSE {
1909                 Music * m = MY_MAKE_MUSIC("EventChord");
1910                 $2 = scm_reverse_x ($2, SCM_EOL);
1911                 m->set_mus_property ("elements",  $2);
1912                 $$ = m->self_scm ();
1913         }
1914         ;
1915
1916
1917 optional_rest:
1918         /**/   { $$ = 0; }
1919         | REST { $$ = 1; }
1920         ;
1921
1922 simple_element:
1923         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1924
1925                 Input i = THIS->pop_spot ();
1926                 if (!THIS->lexer_->note_state_b ())
1927                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1928
1929                 Music *n = 0;
1930                 if ($6)
1931                         n =  MY_MAKE_MUSIC("RestEvent");
1932                 else
1933                         n =  MY_MAKE_MUSIC("NoteEvent");
1934
1935                 n->set_mus_property ("pitch", $1);
1936                 n->set_mus_property ("duration", $5);
1937
1938                 if (gh_number_p ($4))
1939                 {
1940                         int q = gh_scm2int ($4);
1941                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1942                 }
1943
1944                 if ($3 % 2)
1945                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1946                 if ($2 % 2 || $3 % 2)
1947                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1948
1949                 Music *v = MY_MAKE_MUSIC("EventChord");
1950                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1951                 scm_gc_unprotect_object (n->self_scm());
1952
1953                 v->set_spot (i);
1954                 n->set_spot (i);
1955                 $$ = v;
1956         }
1957         | DRUM_PITCH optional_notemode_duration {
1958                 Input i = THIS->pop_spot ();
1959
1960                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1961                 n->set_mus_property ("duration" ,$2);
1962                 n->set_mus_property ("drum-type" , $1);
1963
1964                 Music *v = MY_MAKE_MUSIC("EventChord");
1965                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1966                 scm_gc_unprotect_object (n->self_scm());
1967                 v->set_spot (i);
1968                 n->set_spot (i);
1969                 $$ = v;
1970
1971         }
1972         | figure_spec optional_notemode_duration {
1973                 Music * m = unsmob_music ($1);
1974                 Input i = THIS->pop_spot ();
1975                 m->set_spot (i);
1976                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1977                 {
1978                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1979                 }
1980                 $$ = m;
1981         }
1982         | RESTNAME optional_notemode_duration           {
1983
1984                 Input i = THIS->pop_spot ();
1985                 Music * ev = 0;
1986                 if (ly_scm2string ($1) =="s") {
1987                         /* Space */
1988                         ev = MY_MAKE_MUSIC("SkipEvent");
1989                   }
1990                 else {
1991                         ev = MY_MAKE_MUSIC("RestEvent");
1992
1993                     }
1994                 ev->set_mus_property ("duration" ,$2);
1995                 ev->set_spot (i);
1996                 Music * velt = MY_MAKE_MUSIC("EventChord");
1997                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1998                 velt->set_spot (i);
1999
2000                 scm_gc_unprotect_object (ev->self_scm());
2001
2002                 $$ = velt;
2003         }
2004         | MULTI_MEASURE_REST optional_notemode_duration         {
2005                 THIS->pop_spot ();
2006
2007                 static SCM proc ;
2008                 if (!proc)
2009                         proc = scm_c_eval_string ("make-multi-measure-rest");
2010
2011                 SCM mus = scm_call_2 (proc, $2,
2012                         make_input (THIS->here_input()));
2013                 scm_gc_protect_object (mus);
2014                 $$ = unsmob_music (mus);
2015         }
2016
2017         | lyric_element optional_notemode_duration      {
2018                 Input i = THIS->pop_spot ();
2019                 if (!THIS->lexer_->lyric_state_b ())
2020                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2021
2022                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2023                 lreq->set_mus_property ("text", $1);
2024                 lreq->set_mus_property ("duration",$2);
2025                 lreq->set_spot (i);
2026                 Music * velt = MY_MAKE_MUSIC("EventChord");
2027                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2028
2029                 $$= velt;
2030         }
2031         | new_chord {
2032                 THIS->pop_spot ();
2033
2034                 if (!THIS->lexer_->chord_state_b ())
2035                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2036                 $$ = unsmob_music ($1);
2037         }
2038         ;
2039
2040 lyric_element:
2041         full_markup { $$ = $1; }
2042         | STRING {  $$ = $1 ; }
2043         ;
2044
2045 new_chord:
2046         steno_tonic_pitch optional_notemode_duration   {
2047                 $$ = make_chord ($1, $2, SCM_EOL);
2048         }
2049         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2050                 SCM its = scm_reverse_x ($4, SCM_EOL);
2051                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2052         }
2053         ;
2054
2055 chord_items:
2056         /**/ {
2057                 $$ = SCM_EOL;
2058         }
2059         | chord_items chord_item {
2060                 $$ = gh_cons ($2, $$);
2061         }
2062         ;
2063
2064 chord_separator:
2065         CHORD_COLON {
2066                 $$ = ly_symbol2scm ("chord-colon");
2067         }
2068         | CHORD_CARET {
2069                 $$ = ly_symbol2scm ("chord-caret");
2070         }
2071         | CHORD_SLASH steno_tonic_pitch {
2072                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2073         }
2074         | CHORD_BASS steno_tonic_pitch {
2075                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2076         }
2077         ;
2078
2079 chord_item:
2080         chord_separator {
2081                 $$ = $1;
2082         }
2083         | step_numbers {
2084                 $$ = scm_reverse_x ($1, SCM_EOL);
2085         }
2086         | CHORD_MODIFIER  {
2087                 $$ = $1;
2088         }
2089         ;
2090
2091 step_numbers:
2092         step_number { $$ = gh_cons ($1, SCM_EOL); }
2093         | step_numbers '.' step_number {
2094                 $$ = gh_cons ($3, $$);
2095         }
2096         ;
2097
2098 step_number:
2099         bare_unsigned {
2100                 $$ = make_chord_step ($1, 0);
2101         }
2102         | bare_unsigned '+' {
2103                 $$ = make_chord_step ($1, SHARP);
2104         }
2105         | bare_unsigned CHORD_MINUS {
2106                 $$ = make_chord_step ($1, FLAT);
2107         }
2108         ;
2109
2110 /*
2111         UTILITIES
2112
2113 TODO: should deprecate in favor of Scheme?
2114
2115  */
2116 number_expression:
2117         number_expression '+' number_term {
2118                 $$ = scm_sum ($1, $3);
2119         }
2120         | number_expression '-' number_term {
2121                 $$ = scm_difference ($1, $3);
2122         }
2123         | number_term
2124         ;
2125
2126 number_term:
2127         number_factor {
2128                 $$ = $1;
2129         }
2130         | number_factor '*' number_factor {
2131                 $$ = scm_product ($1, $3);
2132         }
2133         | number_factor '/' number_factor {
2134                 $$ = scm_divide ($1, $3);
2135         }
2136         ;
2137
2138 number_factor:
2139         '-'  number_factor { /* %prec UNARY_MINUS */
2140                 $$ = scm_difference ($2, SCM_UNDEFINED);
2141         }
2142         | bare_number
2143         ;
2144
2145
2146 bare_number:
2147         UNSIGNED        {
2148                 $$ = gh_int2scm ($1);
2149         }
2150         | REAL          {
2151                 $$ = $1;
2152         }
2153         | NUMBER_IDENTIFIER             {
2154                 $$ = $1;
2155         }
2156         | REAL NUMBER_IDENTIFIER        {
2157                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2158         }
2159         | UNSIGNED NUMBER_IDENTIFIER    {
2160                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2161         }
2162         ;
2163
2164
2165 bare_unsigned:
2166         UNSIGNED {
2167                         $$ = $1;
2168         }
2169         | DIGIT {
2170                 $$ = $1;
2171         }
2172         ;
2173
2174 bare_int:
2175         bare_number {
2176                 if (scm_integer_p ($1) == SCM_BOOL_T)
2177                 {
2178                         int k = gh_scm2int ($1);
2179                         $$ = k;
2180                 } else
2181                 {
2182                         THIS->parser_error (_ ("need integer number arg"));
2183                         $$ = 0;
2184                 }
2185         }
2186         | '-' bare_int {
2187                 $$ = -$2;
2188         }
2189         ;
2190
2191
2192 string:
2193         STRING          {
2194                 $$ = $1;
2195         }
2196         | STRING_IDENTIFIER     {
2197                 $$ = $1;
2198         }
2199         | string '+' string {
2200                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2201         }
2202         ;
2203
2204
2205 exclamations:
2206                 { $$ = 0; }
2207         | exclamations '!'      { $$ ++; }
2208         ;
2209
2210 questions:
2211                 { $$ = 0; }
2212         | questions '?' { $$ ++; }
2213         ;
2214
2215
2216
2217 full_markup:
2218         MARKUP_IDENTIFIER {
2219                 $$ = $1;
2220         }
2221         | MARKUP
2222                 { THIS->lexer_->push_markup_state (); }
2223         markup
2224                 { $$ = $3;
2225                   THIS->lexer_->pop_state ();
2226                 }
2227         ;
2228
2229
2230 /*
2231 This should be done more dynamically if possible.
2232 */
2233 markup:
2234         STRING {
2235                 $$ = make_simple_markup ($1);
2236         }
2237         | MARKUP_HEAD_EMPTY {
2238                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2239         }
2240         | MARKUP_HEAD_MARKUP0 markup {
2241                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2242         }
2243         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2244                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2245         }
2246         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2247                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2248         }
2249         | markup_line {
2250                 $$ = $1;
2251         }
2252         | MARKUP_HEAD_LIST0 markup_list {
2253                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2254         }
2255         | MARKUP_HEAD_SCM0 embedded_scm {
2256                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2257         }
2258         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2259                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2260         }
2261         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2262                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2263         }
2264         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2265                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2266         }
2267         | MARKUP_IDENTIFIER {
2268                 $$ = $1;
2269         }
2270
2271         ;
2272
2273 markup_list:
2274         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2275         ;
2276
2277 markup_line:
2278         '{' markup_list_body '}' {
2279                 static SCM line ;
2280                 if (!line)
2281                         line = scm_c_eval_string ("line-markup");
2282
2283                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2284         }
2285         ;
2286
2287 markup_list_body:
2288         /**/ {  $$ = SCM_EOL; }
2289         | markup_list_body markup {
2290                 $$ = gh_cons ($2, $1) ;
2291         }
2292         ;
2293
2294
2295 %%
2296
2297 void
2298 My_lily_parser::set_yydebug (bool )
2299 {
2300 #if 0
2301         yydebug = 1;
2302 #endif
2303 }
2304
2305 extern My_lily_parser * current_parser;
2306
2307 void
2308 My_lily_parser::do_yyparse ()
2309 {
2310         current_parser = this;;
2311         yyparse ((void*)this);
2312 }
2313
2314
2315 /*
2316 Should make this optional?    It will also complain when you do
2317
2318         [s4]
2319
2320 which is entirely legitimate.
2321
2322 Or we can scrap it. Barchecks should detect wrong durations, and
2323 skipTypesetting speeds it up a lot.
2324 */
2325
2326 void
2327 My_lily_parser::beam_check (SCM dur)
2328 {
2329   Duration *d = unsmob_duration (dur);
2330   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2331     {
2332       Music * m = unsmob_music (last_beam_start_);
2333       m->origin ()->warning (_("Suspect duration found following this beam"));
2334     }
2335   last_beam_start_ = SCM_EOL;
2336 }
2337
2338
2339
2340
2341 /*
2342
2343 It is a little strange to have this function in this file, but
2344 otherwise, we have to import music classes into the lexer.
2345
2346 */
2347 int
2348 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2349 {
2350         if (gh_string_p (sid)) {
2351                 *destination = sid;
2352                 return STRING_IDENTIFIER;
2353         } else if (gh_number_p (sid)) {
2354                 *destination = sid;
2355                 return NUMBER_IDENTIFIER;
2356         } else if (unsmob_context_def (sid)) {
2357                 *destination = unsmob_context_def (sid)->clone_scm();
2358                 return TRANSLATOR_IDENTIFIER;
2359         } else if (unsmob_score (sid)) {
2360                 Score *sc =  new Score (*unsmob_score (sid));
2361                 *destination =sc->self_scm ();
2362                 return SCORE_IDENTIFIER;
2363         } else if (Music * mus =unsmob_music (sid)) {
2364                 *destination = unsmob_music (sid)->clone ()->self_scm();
2365                 unsmob_music (*destination)->
2366                         set_mus_property ("origin", make_input (last_input_));
2367                 return dynamic_cast<Event*> (mus)
2368                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2369         } else if (unsmob_duration (sid)) {
2370                 *destination = unsmob_duration (sid)->smobbed_copy();
2371                 return DURATION_IDENTIFIER;
2372         } else if (unsmob_music_output_def (sid)) {
2373                 Music_output_def *p = unsmob_music_output_def (sid);
2374                 p = p->clone ();
2375
2376                 *destination = p->self_scm();
2377                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2378         } else if (Text_item::markup_p (sid)) {
2379                 *destination = sid;
2380                 return MARKUP_IDENTIFIER;
2381         }
2382
2383         return -1;
2384 }
2385
2386 Music *
2387 property_op_to_music (SCM op)
2388 {
2389         Music * m = 0;
2390         SCM tag = gh_car (op);
2391         SCM symbol  = gh_cadr (op);
2392         SCM args = gh_cddr (op);
2393         SCM grob_val = SCM_UNDEFINED;
2394         SCM grob_sym = SCM_UNDEFINED;
2395         SCM val = SCM_UNDEFINED;
2396
2397         if (tag == ly_symbol2scm ("assign"))
2398                 {
2399                 m =  MY_MAKE_MUSIC("PropertySet");
2400                 val = gh_car (args);
2401                 }
2402         else if (tag == ly_symbol2scm ("unset"))
2403                 m =  MY_MAKE_MUSIC("PropertyUnset");
2404         else if (tag == ly_symbol2scm ("poppush")
2405                  || tag == ly_symbol2scm ("push"))
2406                 {
2407                 m  = MY_MAKE_MUSIC("OverrideProperty");
2408                 grob_sym = gh_car (args);
2409                 grob_val = gh_cadr (args);
2410                 }
2411         else if (tag == ly_symbol2scm ("pop")) {
2412                 m = MY_MAKE_MUSIC("RevertProperty");
2413                 grob_sym = gh_car (args);
2414                 }
2415
2416         m->set_mus_property ("symbol", symbol);
2417
2418         if (val != SCM_UNDEFINED)
2419                 m->set_mus_property ("value", val);
2420         if (grob_val != SCM_UNDEFINED)
2421                 m->set_mus_property ("grob-value", grob_val);
2422
2423         if (grob_sym != SCM_UNDEFINED)
2424                 {
2425                 bool itc = internal_type_checking_global_b;
2426                 /* UGH.
2427                 */
2428                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2429                 if (autobeam)
2430                         internal_type_checking_global_b = false;
2431                 m->set_mus_property ("grob-property", grob_sym);
2432                 if (autobeam)
2433                         internal_type_checking_global_b = itc;
2434                 }
2435
2436         if (op == ly_symbol2scm ("poppush"))
2437                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2438
2439
2440         return m;
2441 }
2442
2443 Music*
2444 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2445 {
2446         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2447
2448         csm->set_mus_property ("element", m->self_scm ());
2449         scm_gc_unprotect_object (m->self_scm ());
2450
2451         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2452         csm->set_mus_property ("property-operations", ops);
2453
2454         if (gh_string_p (id))
2455                 csm->set_mus_property ("context-id", id);
2456         return csm;
2457 }
2458
2459
2460 SCM
2461 get_next_unique_context ()
2462 {
2463         static int new_context_count;
2464
2465         char s[1024];
2466         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2467
2468         return scm_makfrom0str (s);
2469 }
2470