lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 is_regular_identifier (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_2 (simple, a);
 143 }
 144
 145
 146 bool
 147 is_is_duration (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC ("PropertySet");
 199         p->set_property ("symbol", sym);
 200         p->set_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token ();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token ADDQUOTE
 241 %token NEWADDLYRICS
 242 %token ALIAS
 243 %token ALTERNATIVE
 244 %token APPLY
 245 %token APPLYCONTEXT
 246 %token APPLYOUTPUT
 247 %token AUTOCHANGE
 248 %token BAR
 249 %token BREATHE
 250 %token CHANGE
 251 %token CHORDMODIFIERS
 252 %token CHORDS
 253 %token LESSLESS
 254 %token MOREMORE
 255 %token CLEF
 256 %token COMMANDSPANREQUEST
 257 %token CONSISTS
 258 %token CONSISTSEND
 259 %token CONTEXT
 260 %token DEFAULT
 261 %token DENIES
 262 %token DESCRIPTION
 263 %token EXTENDER
 264 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 265 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 266 %token GRACE
 267 %token ACCIACCATURA
 268 %token APPOGGIATURA
 269 %token GROBDESCRIPTIONS
 270 %token HEADER
 271 %token HYPHEN
 272 %token INVALID
 273 %token KEY
 274 %token LYRICS
 275 %token MARK
 276 %token MIDI
 277 %token MULTI_MEASURE_REST
 278 %token NAME
 279 %token NEWCONTEXT
 280 %token NOTES
 281 %token OCTAVE
 282 %token ONCE
 283 %token OVERRIDE SET REVERT
 284 %token PAPER
 285 %token PARTCOMBINE
 286 %token PARTIAL
 287 %token QUOTE
 288 %token RELATIVE
 289 %token REMOVE
 290 %token REPEAT
 291 %token REST
 292 %token SCM_T
 293 %token SCORE
 294 %token SEQUENTIAL
 295 %token SIMULTANEOUS
 296 %token SKIP
 297 %token SPANREQUEST
 298 %token TAG
 299 %token TEMPO
 300 %token TIMES
 301 %token TIME_T
 302 %token TRANSPOSE
 303 %token TRANSPOSITION
 304 %token TYPE
 305 %token UNSET
 306 %token WITH
 307
 308 /* escaped */
 309 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 310 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 311 %token E_BACKSLASH
 312 %token <i> E_UNSIGNED
 313 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 314 %token FIGURE_SPACE
 315
 316 %type <i>       exclamations questions dots optional_rest
 317 %type <i>        bass_mod
 318 %type <scm>     grace_head
 319 %type <scm>     oct_check
 320 %type <scm>     context_mod_list
 321 %type <scm>     lyric_element
 322 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 323 %token <i>      DIGIT
 324 %token <scm>    NOTENAME_PITCH
 325 %token <scm>    TONICNAME_PITCH
 326 %token <scm>    CHORDMODIFIER_PITCH
 327 %token <scm>    DURATION_IDENTIFIER
 328 %token <scm>    FRACTION
 329 %token <id>     IDENTIFIER
 330 %token DRUMS
 331 %token <scm>    DRUM_PITCH
 332 %token <scm>    CHORD_MODIFIER
 333 %token <scm>    SCORE_IDENTIFIER
 334 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    EVENT_IDENTIFIER
 337 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 338 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 339 %token <scm>    RESTNAME
 340 %token <scm>    STRING
 341 %token <scm>    SCM_T
 342 %token <i>      UNSIGNED
 343 %token <scm>   REAL
 344
 345 %token MARKUP
 346 %token <scm> MARKUP_HEAD_MARKUP0
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0
 350 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 357
 358 %type <outputdef> output_def
 359 %type <scm>     lilypond_header lilypond_header_body
 360 %type <music>   open_event close_event
 361 %type <i>       sub_quotes sup_quotes
 362 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 363 %type <music>   Repeated_music
 364 %type <scm>     Alternative_music
 365 %type <i>       tremolo_type
 366 %type <i>       bare_int  bare_unsigned
 367 %type <i>       script_dir
 368 %type <scm>     identifier_init
 369
 370 %type <music> note_chord_element chord_body chord_body_element
 371 %type <scm>  chord_body_elements
 372 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 373
 374 %type <scm>   post_events
 375 %type <music> gen_text_def direction_less_event direction_reqd_event
 376 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 377 %type <scm>    steno_tonic_pitch
 378 %type <scm>     duration_length fraction
 379
 380 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 381
 382 %type <scm>  embedded_scm scalar
 383 %type <music>   Music Sequential_music Simultaneous_music
 384 %type <music>   relative_music re_rhythmed_music
 385 %type <music>   music_property_def context_change
 386 %type <scm> context_prop_spec
 387 %type <scm> Music_list
 388 %type <scm> property_operation context_mod context_def_mod optional_context_mod
 389 %type <outputdef>  music_output_def_body music_output_def_head
 390 %type <music>   post_event tagged_post_event
 391 %type <music> command_req
 392 %type <music> string_number_event
 393 %type <scm>     string bare_number number_expression number_term number_factor
 394 %type <score>   score_block score_body
 395
 396 %type <scm>     context_def_spec_block context_def_spec_body
 397 %type <music>   tempo_event
 398 %type <scm>     script_abbreviation
 399
 400
 401
 402 %left '-' '+'
 403
 404 /* We don't assign precedence to / and *, because we might need varied
 405 prec levels in different prods */
 406
 407 %left UNARY_MINUS
 408
 409 %%
 410
 411 lilypond:       /* empty */
 412         | lilypond toplevel_expression {}
 413         | lilypond assignment  { }
 414         | lilypond error {
 415                 THIS->error_level_  = 1;
 416         }
 417         | lilypond INVALID      {
 418                 THIS->error_level_  = 1;
 419         }
 420         ;
 421
 422 toplevel_expression:
 423         lilypond_header {
 424                 THIS->input_file_->header_ = $1;
 425         }
 426         | add_quote {
 427         }
 428         | score_block {
 429                 Score * sc = $1;
 430
 431                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 432
 433                 Path p = split_path (THIS->output_basename_);
 434                 int *c =  &THIS->input_file_->score_count_;
 435                 if (*c)
 436                         {
 437                         p.base += "-" + to_string (*c);
 438                         }
 439
 440                 (*c)++;
 441                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 442
 443                 for (int i=0; i < sc->defs_.size (); i++)
 444                         default_rendering (sc->music_, sc->defs_[i]->self_scm (), head, outname);
 445
 446                 if (sc->defs_.is_empty ())
 447                 {
 448                    Music_output_def *id =
 449                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 450                                 ("$defaultpaper"));
 451
 452                    id = id ? id->clone () : new Paper_def;
 453
 454                    default_rendering (sc->music_, id->self_scm (), head, outname);
 455
 456                    scm_gc_unprotect_object (id->self_scm ());
 457                 }
 458                 scm_gc_unprotect_object (sc->self_scm ());
 459         }
 460         | output_def {
 461                 SCM id = SCM_EOL;
 462                 if (dynamic_cast<Paper_def*> ($1))
 463                         id = scm_makfrom0str ("$defaultpaper");
 464                 else if (dynamic_cast<Midi_def*> ($1))
 465                         id = scm_makfrom0str ("$defaultmidi");
 466                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 467                 scm_gc_unprotect_object ($1->self_scm ());
 468         }
 469         ;
 470
 471
 472 embedded_scm:
 473         SCM_T
 474         | SCM_IDENTIFIER
 475         ;
 476
 477
 478
 479
 480 lilypond_header_body:
 481         {
 482                 $$ = ly_make_anonymous_module ();
 483                 THIS->lexer_->add_scope ($$);
 484         }
 485         | lilypond_header_body assignment  {
 486
 487         }
 488         ;
 489
 490 lilypond_header:
 491         HEADER '{' lilypond_header_body '}'     {
 492                 $$ = THIS->lexer_-> remove_scope ();
 493         }
 494         ;
 495
 496
 497 /*
 498         DECLARATIONS
 499 */
 500 assignment:
 501         STRING {
 502                 THIS->push_spot ();
 503         }
 504         /* cont */ '=' identifier_init  {
 505
 506         /*
 507                 Should find generic way of associating input with objects.
 508         */
 509                 Input ip = THIS->pop_spot ();
 510
 511                 if (! is_regular_identifier ($1))
 512                 {
 513                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 514                 }
 515
 516                 THIS->lexer_->set_identifier ($1, $4);
 517
 518 /*
 519  TODO: devise standard for protection in parser.
 520
 521   The parser stack lives on the C-stack, which means that
 522 all objects can be unprotected as soon as they're here.
 523
 524 */
 525         }
 526         | embedded_scm { }
 527         ;
 528
 529
 530 identifier_init:
 531         score_block {
 532                 $$ = $1->self_scm ();
 533                 scm_gc_unprotect_object ($$);
 534         }
 535         | full_markup {
 536                 $$ = $1;
 537         }
 538         | output_def {
 539                 $$ = $1->self_scm ();
 540                 scm_gc_unprotect_object ($$);
 541         }
 542         | context_def_spec_block {
 543                 $$ = $1;
 544         }
 545         | Music  {
 546                 $$ = $1->self_scm ();
 547                 scm_gc_unprotect_object ($$);
 548         }
 549         | post_event {
 550                 $$ = $1->self_scm ();
 551                 scm_gc_unprotect_object ($$);
 552         }
 553         | number_expression {
 554                 $$ = $1;
 555         }
 556         | string {
 557                 $$ = $1;
 558         }
 559         | embedded_scm  {
 560                 $$ = $1;
 561         }
 562         ;
 563
 564 context_def_spec_block:
 565         CONTEXT '{' context_def_spec_body '}'
 566                 {
 567                 $$ = $3;
 568         }
 569         ;
 570
 571 context_def_spec_body:
 572         /**/ {
 573                 $$ = Context_def::make_scm ();
 574                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 575         }
 576         | CONTEXT_DEF_IDENTIFIER        {
 577                 $$ = $1;
 578                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 579         }
 580         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 581                 Context_def*td = unsmob_context_def ($$);
 582
 583                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 584                         SCM tag = gh_caar (p);
 585
 586                         /* TODO: should make new tag "grob-definition" ? */
 587                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 588                                                         tag, gh_cons (ly_cdar (p), SCM_EOL)));
 589                 }
 590         }
 591         | context_def_spec_body context_mod {
 592                 unsmob_context_def ($$)->add_context_mod ($2);
 593         }
 594         ;
 595
 596 /*
 597         SCORE
 598 */
 599 score_block:
 600         SCORE {
 601                 THIS->push_spot ();
 602         }
 603         /*cont*/ '{' score_body '}'     {
 604                 THIS->pop_spot ();
 605                 $$ = $4;
 606
 607         }
 608         ;
 609
 610 score_body:
 611         Music   {
 612                 $$ = new Score;
 613
 614                 $$->set_spot (THIS->here_input ());
 615                 SCM m = $1->self_scm ();
 616                 scm_gc_unprotect_object (m);
 617
 618                 /*
 619                         guh.
 620                 */
 621                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 622                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 623                         m = gh_call1 (gh_car (check_funcs), m);
 624                 $$->music_ = m;
 625
 626         }
 627         | SCORE_IDENTIFIER {
 628                 $$ = new Score ( *unsmob_score ($1));
 629                 $$->set_spot (THIS->here_input ());
 630         }
 631         | score_body lilypond_header    {
 632                 $$->header_ = $2;
 633         }
 634         | score_body output_def {
 635                 $$->defs_.push ($2);
 636                 scm_gc_unprotect_object ($2->self_scm ());
 637         }
 638         | score_body error {
 639
 640         }
 641         ;
 642
 643
 644 /*
 645         MIDI
 646 */
 647 output_def:
 648         music_output_def_body '}' {
 649                 $$ = $1;
 650                 THIS-> lexer_-> remove_scope ();
 651         }
 652         ;
 653
 654 music_output_def_head:
 655         MIDI    {
 656                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 657
 658
 659                 Midi_def* p =0;
 660                 if (id)
 661                         p = dynamic_cast<Midi_def*> (id->clone ());
 662                 else
 663                         p = new Midi_def;
 664
 665                 $$ = p;
 666                 THIS->lexer_->add_scope (p->scope_);
 667         }
 668         | PAPER         {
 669                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 670                   Paper_def *p = 0;
 671                 if (id)
 672                         p = dynamic_cast<Paper_def*> (id->clone ());
 673                 else
 674                         p = new Paper_def;
 675
 676                 THIS->lexer_->add_scope (p->scope_);
 677                 $$ = p;
 678         }
 679         ;
 680
 681
 682 music_output_def_body:
 683         music_output_def_head '{' {
 684
 685         }
 686         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 687                 scm_gc_unprotect_object ($1->self_scm ());
 688                 Music_output_def * o =  unsmob_music_output_def ($3);
 689                 $$ = o;
 690                 THIS->lexer_->remove_scope ();
 691                 THIS->lexer_->add_scope (o->scope_);
 692         }
 693         | music_output_def_body assignment  {
 694
 695         }
 696         | music_output_def_body context_def_spec_block  {
 697                 $$->assign_context_def ($2);
 698         }
 699         | music_output_def_body tempo_event  {
 700                 /*
 701                         junk this ? there already is tempo stuff in
 702                         music.
 703                 */
 704                 int m = gh_scm2int ( $2->get_property ("metronome-count"));
 705                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 706                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 707                 if (md)
 708                         md->set_tempo (d->get_length (), m);
 709                 scm_gc_unprotect_object ($2->self_scm ());
 710         }
 711         | music_output_def_body error {
 712
 713         }
 714         ;
 715
 716 tempo_event:
 717         TEMPO steno_duration '=' bare_unsigned  {
 718                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 719                 $$->set_property ("tempo-unit", $2);
 720                 $$->set_property ("metronome-count", gh_int2scm ( $4));
 721         }
 722         ;
 723
 724 /*
 725 The representation of a  list is the
 726
 727   (LIST . LAST-CONS)
 728
 729  to have  efficient append.
 730 */
 731 Music_list:
 732         /* empty */ {
 733                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 734         }
 735         | Music_list Music {
 736                 SCM s = $$;
 737                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 738                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 739                 if (gh_pair_p (ly_cdr (s)))
 740                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 741                 else
 742                         gh_set_car_x (s, c); /* set first cons */
 743                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 744         }
 745         | Music_list error {
 746         }
 747         ;
 748
 749
 750 Music:
 751         Simple_music
 752         | Composite_music
 753         ;
 754
 755 Alternative_music:
 756         /* empty */ {
 757                 $$ = SCM_EOL;
 758         }
 759         | ALTERNATIVE '{' Music_list '}' {
 760                 $$ = $3;
 761         }
 762         ;
 763
 764 Repeated_music:
 765         REPEAT string bare_unsigned Music Alternative_music
 766         {
 767                 Music *beg = $4;
 768                 int times = $3;
 769                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 770                 if (times < scm_ilength (alts)) {
 771                   unsmob_music (gh_car (alts))
 772                     ->origin ()->warning (
 773                     _("More alternatives than repeats.  Junking excess alternatives."));
 774                   alts = ly_truncate_list (times, alts);
 775                 }
 776
 777
 778                 static SCM proc;
 779                 if (!proc)
 780                         proc = scm_c_eval_string ("make-repeated-music");
 781
 782                 SCM mus = scm_call_1 (proc, $2);
 783                 scm_gc_protect_object (mus); // UGH.
 784                 Music *r =unsmob_music (mus);
 785                 if (beg)
 786                         {
 787                         r-> set_property ("element", beg->self_scm ());
 788                         scm_gc_unprotect_object (beg->self_scm ());
 789                         }
 790                 r->set_property ("repeat-count", gh_int2scm (times >? 1));
 791
 792                 r-> set_property ("elements",alts);
 793                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 794                         /*
 795                         we can not get durations and other stuff correct down the line, so we have to
 796                         add to the duration log here.
 797                         */
 798                         static SCM func;
 799
 800                         if (!func)
 801                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 802
 803                         int dots = ($3 % 3) ? 0 : 1;
 804                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 805
 806                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 807
 808                         if (seq) {
 809                                 int list_len =scm_ilength (seq->music_list ());
 810                                 if (list_len != 2)
 811                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 812                                 shift -= 1;
 813                                 r->compress (Moment (Rational (1,list_len)));
 814                                 }
 815                         gh_call3 (func, r->self_scm (), gh_int2scm (shift),gh_int2scm (dots));
 816
 817                 }
 818                 r->set_spot (*$4->origin ());
 819
 820                 $$ = r;
 821         }
 822         ;
 823
 824 Sequential_music:
 825         SEQUENTIAL '{' Music_list '}'           {
 826                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 827                 $$->set_property ("elements", ly_car ($3));
 828                 $$->set_spot (THIS->here_input ());
 829         }
 830         | '{' Music_list '}'            {
 831                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 832                 $$->set_property ("elements", ly_car ($2));
 833                 $$->set_spot (THIS->here_input ());
 834         }
 835         ;
 836
 837 Simultaneous_music:
 838         SIMULTANEOUS '{' Music_list '}'{
 839                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 840                 $$->set_property ("elements", ly_car ($3));
 841                 $$->set_spot (THIS->here_input ());
 842
 843         }
 844         | simul_open Music_list simul_close     {
 845                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 846                 $$->set_property ("elements", ly_car ($2));
 847                 $$->set_spot (THIS->here_input ());
 848         }
 849         ;
 850
 851 Simple_music:
 852         event_chord             { $$ = $1; }
 853         | APPLYOUTPUT embedded_scm {
 854                 if (!ly_input_procedure_p ($2))
 855                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 856                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 857                 $$->set_property ("procedure", $2);
 858                 $$->set_spot (THIS->here_input ());
 859         }
 860         | APPLYCONTEXT embedded_scm {
 861                 if (!ly_input_procedure_p ($2))
 862                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 863                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 864                 $$->set_property ("procedure", $2);
 865                 $$->set_spot (THIS->here_input ());
 866         }
 867         | MUSIC_IDENTIFIER {
 868                 $$ = unsmob_music ($1);
 869         }
 870         | music_property_def
 871         | context_change
 872         ;
 873
 874
 875 optional_context_mod:
 876         /**/ { $$ = SCM_EOL; }
 877         | WITH '{' context_mod_list '}'  { $$ = $3; }
 878         ;
 879
 880 grace_head:
 881         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 882         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 883         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 884         ;
 885
 886 context_mod_list:
 887         /* */  { $$ = SCM_EOL; }
 888         | context_mod_list context_mod  {
 889                  $$ = gh_cons ($2, $1);
 890         }
 891         ;
 892
 893 Composite_music:
 894         AUTOCHANGE Music        {
 895                 static SCM proc ;
 896                 if (!proc)
 897                         proc = scm_c_eval_string ("make-autochange-music");
 898
 899                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 900                 scm_gc_unprotect_object ($2->self_scm ());
 901                 $$ = unsmob_music (res);
 902                 scm_gc_protect_object (res);
 903                 $$->set_spot (THIS->here_input ());
 904         }
 905         | PARTCOMBINE Music Music {
 906                 static SCM proc;
 907                 if (!proc)
 908                         proc = scm_c_eval_string ("make-part-combine-music");
 909
 910                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 911                         $3->self_scm (), SCM_UNDEFINED));
 912                 scm_gc_unprotect_object ($3->self_scm ());
 913                 scm_gc_unprotect_object ($2->self_scm ());
 914                 $$ = unsmob_music (res);
 915                 scm_gc_protect_object (res);
 916                 $$->set_spot (THIS->here_input ());
 917         }
 918         | grace_head Music {
 919 #if 1
 920         /*
 921                 The other version is for easier debugging  of
 922                 Sequential_music_iterator in combination with grace notes.
 923         */
 924
 925 /*
 926
 927 TODO: should distinguish between both grace types in the
 928 basic music objects too, since the meaning is different.
 929
 930 */
 931
 932                 String start_str = "start" + ly_scm2string ($1) + "Music";
 933                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 934
 935                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 936                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 937
 938                 Music *startm = unsmob_music (start);
 939                 Music *stopm = unsmob_music (stop);
 940
 941                 SCM ms = SCM_EOL;
 942                 if (stopm) {
 943                         stopm = stopm->clone ();
 944                         ms = scm_cons (stopm->self_scm (), ms);
 945                         scm_gc_unprotect_object (stopm->self_scm ());
 946                 }
 947                 ms = scm_cons ($2->self_scm (), ms);
 948                 scm_gc_unprotect_object ($2->self_scm ());
 949                 if (startm) {
 950                         startm = startm->clone ();
 951                         ms = scm_cons (startm->self_scm () , ms);
 952                         scm_gc_unprotect_object (startm->self_scm ());
 953                 }
 954
 955                 Music* seq = MY_MAKE_MUSIC ("SequentialMusic");
 956                 seq->set_property ("elements", ms);
 957
 958
 959                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 960                 $$->set_property ("element", seq->self_scm ());
 961                 scm_gc_unprotect_object (seq->self_scm ());
 962 #else
 963                 $$ = MY_MAKE_MUSIC ("GraceMusic");
 964                 $$->set_property ("element", $2->self_scm ());
 965                 scm_gc_unprotect_object ($2->self_scm ());
 966 #endif
 967         }
 968         | CONTEXT string '=' string optional_context_mod Music {
 969                 $$ = context_spec_music ($2, $4, $6, $5);
 970
 971         }
 972         | CONTEXT STRING optional_context_mod Music {
 973                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 974         }
 975         | NEWCONTEXT string optional_context_mod Music {
 976                 $$ = context_spec_music ($2, get_next_unique_context (),
 977                                          $4, $3);
 978         }
 979
 980         | TIMES {
 981                 THIS->push_spot ();
 982         }
 983         /* CONTINUED */
 984                 fraction Music
 985
 986         {
 987                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 988                 Music *mp = $4;
 989
 990                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
 991                 $$->set_spot (THIS->pop_spot ());
 992
 993                 $$->set_property ("element", mp->self_scm ());
 994                 scm_gc_unprotect_object (mp->self_scm ());
 995                 $$->set_property ("numerator", gh_int2scm (n));
 996                 $$->set_property ("denominator", gh_int2scm (d));
 997                 $$->compress (Moment (Rational (n,d)));
 998
 999         }
1000         | Repeated_music                { $$ = $1; }
1001         | Simultaneous_music            { $$ = $1; }
1002         | Sequential_music              { $$ = $1; }
1003         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1004                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1005                 Music *p = $4;
1006                 Pitch from = *unsmob_pitch ($2);
1007                 Pitch to = *unsmob_pitch ($3);
1008
1009                 p->transpose (interval (from, to));
1010                 $$->set_property ("element", p->self_scm ());
1011                 scm_gc_unprotect_object (p->self_scm ());
1012         }
1013         | APPLY embedded_scm Music  {
1014                 if (!ly_input_procedure_p ($2))
1015                         {
1016                         THIS->parser_error (_ ("\\apply takes function argument"));
1017                         $$ = $3;
1018                         }
1019                 else
1020                         {
1021                         SCM ret = gh_call1 ($2, $3->self_scm ());
1022                         Music *m = unsmob_music (ret);
1023                         if (!m) {
1024                                 THIS->parser_error ("\\apply must return a Music");
1025                                 m = MY_MAKE_MUSIC ("Music");
1026                                 }
1027                         $$ = m;
1028                         }
1029         }
1030         | NOTES
1031                 {
1032                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1033                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1034         }
1035         Music
1036                 { $$ = $3;
1037                   THIS->lexer_->pop_state ();
1038                 }
1039         | DRUMS
1040                 {
1041                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1042                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1043         }
1044         Music
1045                 { $$ = $3;
1046                   THIS->lexer_->pop_state ();
1047                 }
1048         | FIGURES
1049                 { THIS->lexer_->push_figuredbass_state (); }
1050         Music
1051                 {
1052                   Music * chm = MY_MAKE_MUSIC ("UntransposableMusic");
1053                   chm->set_property ("element", $3->self_scm ());
1054                   $$ = chm;
1055                   scm_gc_unprotect_object ($3->self_scm ());
1056
1057                   THIS->lexer_->pop_state ();
1058         }
1059         | CHORDS {
1060                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1061                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1062                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1063                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1064
1065         } Music {
1066                   Music * chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1067                   chm->set_property ("element", $3->self_scm ());
1068                   scm_gc_unprotect_object ($3->self_scm ());
1069                   $$ = chm;
1070
1071                   THIS->lexer_->pop_state ();
1072         }
1073         | LYRICS
1074                 { THIS->lexer_->push_lyric_state (); }
1075         Music
1076                 {
1077                   $$ = $3;
1078                   THIS->lexer_->pop_state ();
1079         }
1080         | relative_music        { $$ = $1; }
1081         | re_rhythmed_music     { $$ = $1; }
1082         | TAG embedded_scm Music {
1083                 tag_music ($3, $2, THIS->here_input ());
1084                 $$ = $3;
1085         }
1086         ;
1087
1088 relative_music:
1089         RELATIVE absolute_pitch Music {
1090                 Music * p = $3;
1091                 Pitch pit = *unsmob_pitch ($2);
1092                 $$ = MY_MAKE_MUSIC ("RelativeOctaveMusic");
1093
1094                 $$->set_property ("element", p->self_scm ());
1095                 scm_gc_unprotect_object (p->self_scm ());
1096
1097
1098                 Pitch retpitch = p->to_relative_octave (pit);
1099                 if (lily_1_8_relative)
1100                         $$->set_property ("last-pitch", retpitch.smobbed_copy ());
1101         }
1102         ;
1103
1104 re_rhythmed_music:
1105         ADDLYRICS Music Music {
1106         Music*l =MY_MAKE_MUSIC ("LyricCombineMusic");
1107           l->set_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1108           scm_gc_unprotect_object ($3->self_scm ());
1109           scm_gc_unprotect_object ($2->self_scm ());
1110           $$ = l;
1111         }
1112         | NEWADDLYRICS string Music {
1113           Music*l =MY_MAKE_MUSIC ("NewLyricCombineMusic");
1114           l->set_property ("element", $3->self_scm ());
1115           scm_gc_unprotect_object ($3->self_scm ());
1116           $$ = l;
1117           l->set_property ("associated-context", $2);
1118         }
1119         ;
1120
1121 context_change:
1122         CHANGE STRING '=' STRING  {
1123                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1124                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1125                 t-> set_property ("change-to-id", $4);
1126
1127                 $$ = t;
1128                 $$->set_spot (THIS->here_input ());
1129         }
1130         ;
1131
1132 property_operation:
1133         STRING '='  scalar {
1134                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1135                         scm_string_to_symbol ($1), $3);
1136         }
1137         | UNSET STRING {
1138                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1139                         scm_string_to_symbol ($2));
1140         }
1141         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1142                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1143                         scm_string_to_symbol ($2), $3, $5);
1144         }
1145         | REVERT STRING embedded_scm {
1146                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1147                         scm_string_to_symbol ($2), $3);
1148         }
1149         ;
1150
1151 context_def_mod:
1152         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1153         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1154         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1155
1156         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1157         | DENIES { $$ = ly_symbol2scm ("denies"); }
1158
1159         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1160         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1161         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1162         | NAME { $$ = ly_symbol2scm ("context-name"); }
1163         ;
1164
1165 context_mod:
1166         property_operation { $$ = $1; }
1167         | context_def_mod STRING {
1168                 $$ = scm_list_2 ($1, $2);
1169         }
1170         ;
1171
1172 context_prop_spec:
1173         STRING  {
1174                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1));
1175         }
1176         | STRING '.' STRING {
1177                 $$ = scm_list_2 (scm_string_to_symbol ($1), scm_string_to_symbol ($3));
1178         }
1179         ;
1180
1181 music_property_def:
1182         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1183                 $$ = property_op_to_music (scm_list_4 (
1184                         ly_symbol2scm ("poppush"),
1185                         gh_cadr ($2),
1186                         $3, $5));
1187                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1188         }
1189         | REVERT context_prop_spec embedded_scm {
1190                 $$ = property_op_to_music (scm_list_3 (
1191                         ly_symbol2scm ("pop"),
1192                         gh_cadr ($2),
1193                         $3));
1194
1195                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1196         }
1197         | SET context_prop_spec '=' scalar {
1198                 $$ = property_op_to_music (scm_list_3 (
1199                         ly_symbol2scm ("assign"),
1200                         gh_cadr ($2),
1201                         $4));
1202                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1203         }
1204         | UNSET context_prop_spec {
1205                 $$ = property_op_to_music (scm_list_2 (
1206                         ly_symbol2scm ("unset"),
1207                         gh_cadr ($2)));
1208                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1209         }
1210         | ONCE music_property_def {
1211                 SCM e = $2->get_property ("element");
1212                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1213                 $$ = $2;
1214
1215         }
1216         ;
1217
1218
1219
1220 scalar:
1221         string          { $$ = $1; }
1222         | bare_int      { $$ = gh_int2scm ($1); }
1223         | embedded_scm  { $$ = $1; }
1224         | full_markup {  $$ = $1; }
1225         | DIGIT { $$ = gh_int2scm ($1); }
1226         ;
1227
1228 /*
1229 This is a trick:
1230
1231 Adding pre_events to the simple_element
1232 makes the choice between
1233
1234   string:  STRING
1235
1236 and
1237
1238   simple_element: STRING
1239
1240 a single shift/reduction conflict.
1241
1242 nevertheless, this is not very clean, and we should find a different
1243 solution.
1244
1245 */
1246 pre_events: {
1247                 THIS->push_spot ();
1248         }
1249         ;
1250
1251 event_chord:
1252         pre_events simple_element post_events   {
1253                 SCM elts = $2-> get_property ("elements");
1254
1255                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1256
1257                 $2->set_property ("elements", elts);
1258                 $$ = $2;
1259         }
1260         | command_element
1261         | note_chord_element
1262         ;
1263
1264
1265 note_chord_element:
1266         chord_body optional_notemode_duration post_events
1267         {
1268                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1269                 SCM es = $1->get_property ("elements");
1270                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1271
1272                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1273                   unsmob_music (gh_car (s))->set_property ("duration", dur);
1274                 es = gh_append2 (es, postevs);
1275
1276                 $1-> set_property ("elements", es);
1277                 $$ = $1;
1278         }
1279         ;
1280
1281 chord_open: '<'
1282         ;
1283
1284 chord_close: '>'
1285         ;
1286
1287 simul_open: LESSLESS
1288         ;
1289
1290 simul_close: MOREMORE
1291         ;
1292
1293 chord_body:
1294         chord_open chord_body_elements chord_close
1295         {
1296                 $$ = MY_MAKE_MUSIC ("EventChord");
1297                 $$->set_property ("elements",
1298                         scm_reverse_x ($2, SCM_EOL));
1299         }
1300         ;
1301
1302 chord_body_elements:
1303         /* empty */             { $$ = SCM_EOL; }
1304         | chord_body_elements chord_body_element {
1305                 $$ = gh_cons ($2->self_scm (), $1);
1306                 scm_gc_unprotect_object ($2->self_scm ());
1307         }
1308         ;
1309
1310 chord_body_element:
1311         pitch exclamations questions post_events
1312         {
1313                 Music * n = MY_MAKE_MUSIC ("NoteEvent");
1314                 n->set_property ("pitch", $1);
1315                 if ($3 % 2)
1316                         n->set_property ("cautionary", SCM_BOOL_T);
1317                 if ($2 % 2 || $3 % 2)
1318                         n->set_property ("force-accidental", SCM_BOOL_T);
1319
1320                 if (gh_pair_p ($4)) {
1321                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1322                         n->set_property ("articulations", arts);
1323                 }
1324                 $$ = n;
1325         }
1326         | DRUM_PITCH post_events {
1327                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
1328                 n->set_property ("duration" ,$2);
1329                 n->set_property ("drum-type" , $1);
1330                 n->set_spot (THIS->here_input ());
1331
1332                 if (gh_pair_p ($2)) {
1333                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1334                         n->set_property ("articulations", arts);
1335                 }
1336                 $$ = n;
1337         }
1338         ;
1339
1340 add_quote:
1341         ADDQUOTE string Music {
1342                 static SCM adder;
1343                 if (!adder)
1344                         adder = scm_c_eval_string ("add-quotable");
1345
1346                 scm_call_2 (adder, $2, $3->self_scm ());
1347                 scm_gc_unprotect_object ($3->self_scm ());
1348         }
1349         ;
1350
1351 command_element:
1352         command_req {
1353                 $$ = MY_MAKE_MUSIC ("EventChord");
1354                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1355                 scm_gc_unprotect_object ($1->self_scm ());
1356
1357                 $$-> set_spot (THIS->here_input ());
1358                 $1-> set_spot (THIS->here_input ());
1359         }
1360         | SKIP duration_length {
1361                 Music * skip = MY_MAKE_MUSIC ("SkipMusic");
1362                 skip->set_property ("duration", $2);
1363
1364                 $$ = skip;
1365         }
1366         | QUOTE STRING duration_length {
1367                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1368                 SCM evs =  SCM_EOL;
1369                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1370                 {
1371                         SCM key = $2; // use symbol?
1372                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1373                 }
1374                 Music * quote = 0;
1375                 if (gh_vector_p (evs))
1376                 {
1377                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1378                         quote->set_property ("duration", $3);
1379                         quote->set_property ("quoted-events", evs);
1380                 } else {
1381                         THIS->here_input ().warning (_f ("Can\'t find music"));
1382                         quote = MY_MAKE_MUSIC ("Event");
1383                 }
1384                 quote->set_spot (THIS->here_input ());
1385                 $$ = quote;
1386         }
1387         | OCTAVE { THIS->push_spot (); }
1388           pitch {
1389                 Music *l = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1390                 $$ = l;
1391                 $$->set_spot (THIS->pop_spot ());
1392                 $$->set_property ("pitch", $3);
1393         }
1394         | E_LEFTSQUARE {
1395                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1396                 l->set_property ("span-direction", gh_int2scm (START));
1397                 l->set_spot (THIS->here_input ());
1398
1399                 $$ = MY_MAKE_MUSIC ("EventChord");
1400                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1401                 scm_gc_unprotect_object (l->self_scm ());
1402                 $$->set_spot (THIS->here_input ());
1403         }
1404         | E_RIGHTSQUARE {
1405                 Music *l = MY_MAKE_MUSIC ("LigatureEvent");
1406                 l->set_property ("span-direction", gh_int2scm (STOP));
1407                 l->set_spot (THIS->here_input ());
1408
1409                 $$ = MY_MAKE_MUSIC ("EventChord");
1410                 $$->set_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1411                 $$->set_spot (THIS->here_input ());
1412                 scm_gc_unprotect_object (l->self_scm ());
1413         }
1414         | E_BACKSLASH {
1415                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1416                 $$->set_spot (THIS->here_input ());
1417         }
1418         | '|'      {
1419
1420                 $$ = MY_MAKE_MUSIC ("BarCheck");
1421                 $$->set_spot (THIS->here_input ());
1422         }
1423         | TRANSPOSITION pitch {
1424                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1425                                         $2);
1426                 $$->set_spot (THIS-> here_input ());
1427                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1428                         $$ , SCM_EOL);
1429         }
1430         | BAR STRING                    {
1431                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1432
1433                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1434                                         t, SCM_EOL);
1435                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1436                 $$->set_spot (THIS->here_input ());
1437                 t->set_spot (THIS->here_input ());
1438         }
1439         | PARTIAL duration_length       {
1440                 Moment m = - unsmob_duration ($2)->get_length ();
1441                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1442                 p->set_spot (THIS->here_input ());
1443                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1444                                         p, SCM_EOL);
1445                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1446                                         p, SCM_EOL);
1447                 $$ =p ;
1448         }
1449         | CLEF STRING  {
1450                 static SCM proc ;
1451                 if (!proc)
1452                         proc = scm_c_eval_string ("make-clef-set");
1453
1454                 SCM result = scm_call_1 (proc, $2);
1455                 scm_gc_protect_object (result);
1456                 $$ = unsmob_music (result);
1457         }
1458         | TIME_T fraction  {
1459                 static SCM proc;
1460                 if (!proc)
1461                         proc = scm_c_eval_string ("make-time-signature-set");
1462
1463                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1464                 scm_gc_protect_object (result);
1465                 $$ = unsmob_music (result);
1466         }
1467         | MARK scalar {
1468                 static SCM proc;
1469                 if (!proc)
1470                         proc = scm_c_eval_string ("make-mark-set");
1471
1472                 SCM result = scm_call_1 (proc, $2);
1473                 scm_gc_protect_object (result);
1474                 $$ = unsmob_music (result);
1475         }
1476         ;
1477
1478 command_req:
1479         BREATHE {
1480                 $$ = MY_MAKE_MUSIC ("BreathingSignEvent");
1481         }
1482         | E_TILDE {
1483                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1484         }
1485         | MARK DEFAULT  {
1486                 Music * m = MY_MAKE_MUSIC ("MarkEvent");
1487                 $$ = m;
1488         }
1489         | tempo_event {
1490                 $$ = $1;
1491         }
1492         | KEY DEFAULT {
1493                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1494                 $$ = key;
1495         }
1496         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1497
1498                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1499                 if (scm_ilength ($3) > 0)
1500                 {
1501                         key->set_property ("pitch-alist", $3);
1502                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1503                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1504                 } else {
1505                         THIS->parser_error (_("Second argument must be pitch list."));
1506                 }
1507
1508                 $$ = key;
1509         }
1510         ;
1511
1512 post_events:
1513         /* empty */ {
1514                 $$ = SCM_EOL;
1515         }
1516         | post_events post_event {
1517                 $2->set_spot (THIS->here_input ());
1518                 $$ = gh_cons ($2->self_scm (), $$);
1519                 scm_gc_unprotect_object ($2->self_scm ());
1520         }
1521         | post_events tagged_post_event {
1522                 $2 -> set_spot (THIS->here_input ());
1523                 $$ = scm_cons ($2->self_scm (), $$);
1524                 scm_gc_unprotect_object ($2->self_scm ());
1525         }
1526         ;
1527
1528
1529 tagged_post_event:
1530         '-' TAG embedded_scm post_event {
1531                 tag_music ($4, $3, THIS->here_input ());
1532                 $$ = $4;
1533         }
1534         ;
1535
1536 post_event:
1537         direction_less_event {
1538                 $$ = $1;
1539         }
1540         | HYPHEN {
1541                 if (!THIS->lexer_->is_lyric_state ())
1542                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1543                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1544         }
1545         | EXTENDER {
1546                 if (!THIS->lexer_->is_lyric_state ())
1547                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1548                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1549         }
1550         | script_dir direction_reqd_event {
1551                 if ($1)
1552                         $2->set_property ("direction", gh_int2scm ($1));
1553                 $$ = $2;
1554         }
1555         | script_dir direction_less_event {
1556                 if ($1)
1557                         $2->set_property ("direction", gh_int2scm ($1));
1558                 $$ = $2;
1559         }
1560         | string_number_event
1561         ;
1562
1563 string_number_event:
1564         E_UNSIGNED {
1565                 Music * s = MY_MAKE_MUSIC ("StringNumberEvent");
1566                 s->set_property ("string-number",  gh_int2scm ($1));
1567                 s->set_spot (THIS->here_input ());
1568                 $$ = s;
1569         }
1570         ;
1571
1572
1573 direction_less_event:
1574         '['  {
1575
1576
1577 /*
1578
1579 TODO: should take all these defs out of the parser, adn make use
1580 configurable, i.e.
1581
1582
1583 (set-articulation '~ "trill")
1584
1585 */
1586                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1587                 m->set_spot (THIS->here_input ());
1588                 m->set_property ("span-direction" , gh_int2scm (START));
1589                 $$ = m;
1590         }
1591         | ']'  {
1592                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1593                 m->set_spot (THIS->here_input ());
1594                 m->set_property ("span-direction" , gh_int2scm (STOP));
1595                 $$ = m;
1596         }
1597         | '~' {
1598                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1599                 m->set_spot (THIS->here_input ());
1600                 $$ = m;
1601         }
1602         | close_event {
1603                 $$ = $1;
1604                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1605                         gh_int2scm (START));
1606         }
1607         | open_event {
1608                 $$ = $1;
1609                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1610                         gh_int2scm (STOP));
1611         }
1612         | EVENT_IDENTIFIER      {
1613                 $$ = unsmob_music ($1);
1614         }
1615         | tremolo_type  {
1616                Music * a = MY_MAKE_MUSIC ("TremoloEvent");
1617                a->set_spot (THIS->here_input ());
1618                a->set_property ("tremolo-type", gh_int2scm ($1));
1619                $$ = a;
1620         }
1621         ;
1622
1623 direction_reqd_event:
1624         gen_text_def {
1625                 $$ = $1;
1626         }
1627         | script_abbreviation {
1628                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1629                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1630                 if (gh_string_p (s))
1631                         a->set_property ("articulation-type", s);
1632                 else THIS->parser_error (_ ("Expecting string as script definition"));
1633                 $$ = a;
1634         }
1635         ;
1636
1637 oct_check:
1638         /**/ { $$ = SCM_EOL; }
1639         | '='  { $$ = gh_int2scm (0); }
1640         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1641         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1642         ;
1643
1644 sup_quotes:
1645         '\'' {
1646                 $$ = 1;
1647         }
1648         | sup_quotes '\'' {
1649                 $$ ++;
1650         }
1651         ;
1652
1653 sub_quotes:
1654         ',' {
1655                 $$ = 1;
1656         }
1657         | sub_quotes ',' {
1658                 $$ ++ ;
1659         }
1660         ;
1661
1662 steno_pitch:
1663         NOTENAME_PITCH  {
1664                 $$ = $1;
1665         }
1666         | NOTENAME_PITCH sup_quotes     {
1667                 Pitch p = *unsmob_pitch ($1);
1668                 p = p.transposed (Pitch ($2,0,0));
1669                 $$ = p.smobbed_copy ();
1670         }
1671         | NOTENAME_PITCH sub_quotes      {
1672                 Pitch p =* unsmob_pitch ($1);
1673                 p = p.transposed (Pitch (-$2,0,0));
1674                 $$ = p.smobbed_copy ();
1675         }
1676         ;
1677
1678 /*
1679 ugh. duplication
1680 */
1681
1682 steno_tonic_pitch:
1683         TONICNAME_PITCH {
1684                 $$ = $1;
1685         }
1686         | TONICNAME_PITCH sup_quotes    {
1687                 Pitch p = *unsmob_pitch ($1);
1688                 p = p.transposed (Pitch ($2,0,0));
1689                 $$ = p.smobbed_copy ();
1690         }
1691         | TONICNAME_PITCH sub_quotes     {
1692                 Pitch p =* unsmob_pitch ($1);
1693
1694                 p = p.transposed (Pitch (-$2,0,0));
1695                 $$ = p.smobbed_copy ();
1696         }
1697         ;
1698
1699 pitch:
1700         steno_pitch {
1701                 $$ = $1;
1702         }
1703         ;
1704
1705 pitch_also_in_chords:
1706         pitch
1707         | steno_tonic_pitch
1708         ;
1709
1710 close_event:
1711         '('     {
1712                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1713                 $$ = s;
1714                 s->set_spot (THIS->here_input ());
1715         }
1716         | E_OPEN        {
1717                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1718                 $$ = s;
1719                 s->set_spot (THIS->here_input ());
1720         }
1721         | E_SMALLER {
1722                 Music *s =MY_MAKE_MUSIC ("CrescendoEvent");
1723                 $$ = s;
1724                 s->set_spot (THIS->here_input ());
1725         }
1726         | E_BIGGER {
1727                 Music *s =MY_MAKE_MUSIC ("DecrescendoEvent");
1728                 $$ = s;
1729                 s->set_spot (THIS->here_input ());
1730         }
1731         ;
1732
1733
1734 open_event:
1735         E_EXCLAMATION   {
1736                 Music *s =  MY_MAKE_MUSIC ("CrescendoEvent");
1737                 s->set_spot (THIS->here_input ());
1738
1739                 $$ = s;
1740         }
1741         | ')'   {
1742                 Music * s= MY_MAKE_MUSIC ("SlurEvent");
1743                 $$ = s;
1744                 s->set_spot (THIS->here_input ());
1745
1746         }
1747         | E_CLOSE       {
1748                 Music * s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1749                 $$ = s;
1750                 s->set_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1751                 s->set_spot (THIS->here_input ());
1752         }
1753         ;
1754
1755 gen_text_def:
1756         full_markup {
1757                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1758                 t->set_property ("text", $1);
1759                 t->set_spot (THIS->here_input ());
1760                 $$ = t;
1761         }
1762         | string {
1763                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1764                 t->set_property ("text", make_simple_markup ($1));
1765                 t->set_spot (THIS->here_input ());
1766                 $$ = t;
1767
1768         }
1769         | DIGIT {
1770                 Music * t = MY_MAKE_MUSIC ("FingerEvent");
1771                 t->set_property ("digit",  gh_int2scm ($1));
1772                 t->set_spot (THIS->here_input ());
1773                 $$ = t;
1774         }
1775         ;
1776
1777 script_abbreviation:
1778         '^'             {
1779                 $$ = scm_makfrom0str ("Hat");
1780         }
1781         | '+'           {
1782                 $$ = scm_makfrom0str ("Plus");
1783         }
1784         | '-'           {
1785                 $$ = scm_makfrom0str ("Dash");
1786         }
1787         | '|'           {
1788                 $$ = scm_makfrom0str ("Bar");
1789         }
1790         | '>'           {
1791                 $$ = scm_makfrom0str ("Larger");
1792         }
1793         | '.'           {
1794                 $$ = scm_makfrom0str ("Dot");
1795         }
1796         | '_' {
1797                 $$ = scm_makfrom0str ("Underscore");
1798         }
1799         ;
1800
1801 script_dir:
1802         '_'     { $$ = DOWN; }
1803         | '^'   { $$ = UP; }
1804         | '-'   { $$ = CENTER; }
1805         ;
1806
1807
1808 absolute_pitch:
1809         steno_pitch     {
1810                 $$ = $1;
1811         }
1812         ;
1813
1814 duration_length:
1815         multiplied_duration {
1816                 $$ = $1;
1817         }
1818         ;
1819
1820 optional_notemode_duration:
1821         {
1822                 Duration dd = THIS->default_duration_;
1823                 $$ = dd.smobbed_copy ();
1824
1825                 THIS->beam_check ($$);
1826         }
1827         | multiplied_duration   {
1828                 $$ = $1;
1829                 THIS->default_duration_ = *unsmob_duration ($$);
1830
1831                 THIS->beam_check ($$);
1832         }
1833         ;
1834
1835 steno_duration:
1836         bare_unsigned dots              {
1837                 int l = 0;
1838                 if (!is_is_duration ($1))
1839                         THIS->parser_error (_f ("not a duration: %d", $1));
1840                 else
1841                         l =  intlog2 ($1);
1842
1843                 $$ = Duration (l, $2).smobbed_copy ();
1844         }
1845         | DURATION_IDENTIFIER dots      {
1846                 Duration *d =unsmob_duration ($1);
1847                 Duration k (d->duration_log (),d->dot_count () + $2);
1848
1849                 *d = k;
1850                 $$ = $1;
1851         }
1852         ;
1853
1854
1855
1856
1857 multiplied_duration:
1858         steno_duration {
1859                 $$ = $1;
1860         }
1861         | multiplied_duration '*' bare_unsigned {
1862                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1863         }
1864         | multiplied_duration '*' FRACTION {
1865                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1866
1867                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1868         }
1869         ;
1870
1871 fraction:
1872         FRACTION { $$ = $1; }
1873         | UNSIGNED '/' UNSIGNED {
1874                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1875         }
1876         ;
1877
1878 dots:
1879         /* empty */     {
1880                 $$ = 0;
1881         }
1882         | dots '.' {
1883                 $$ ++;
1884         }
1885         ;
1886
1887
1888 tremolo_type:
1889         ':'     {
1890                 $$ =0;
1891         }
1892         | ':' bare_unsigned {
1893                 if (!is_is_duration ($2))
1894                         THIS->parser_error (_f ("not a duration: %d", $2));
1895                 $$ = $2;
1896         }
1897         ;
1898
1899
1900
1901 /*****************************************************************
1902                 BASS FIGURES
1903 *****************************************************************/
1904 bass_number:
1905         DIGIT   {
1906                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1907         }
1908         | UNSIGNED {
1909                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1910         }
1911         | STRING { $$ =  $1; }
1912         ;
1913
1914 bass_mod:
1915         '-'     { $$ = -2; }
1916         | '+'   { $$ = 2; }
1917         | '!'   { $$ = 0; }
1918         ;
1919
1920 bass_figure:
1921         FIGURE_SPACE {
1922                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1923                 $$ = bfr->self_scm ();
1924                 scm_gc_unprotect_object ($$);
1925         }
1926         | bass_number  {
1927                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
1928                 $$ = bfr->self_scm ();
1929
1930                 bfr->set_property ("figure", $1);
1931
1932                 scm_gc_unprotect_object ($$);
1933         }
1934         | bass_figure bass_mod {
1935                 Music *m = unsmob_music ($1);
1936                 if ($2) {
1937                         SCM salter =m->get_property ("alteration");
1938                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1939                         m->set_property ("alteration",
1940                                 gh_int2scm (alter + $2));
1941                 } else {
1942                         m->set_property ("alteration", gh_int2scm (0));
1943                 }
1944         }
1945         ;
1946
1947 br_bass_figure:
1948         '[' bass_figure {
1949                 $$ = $2;
1950                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
1951         }
1952         | bass_figure   {
1953                 $$ = $1;
1954         }
1955         | br_bass_figure ']' {
1956                 $$ = $1;
1957                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
1958         }
1959         ;
1960
1961 figure_list:
1962         /**/            {
1963                 $$ = SCM_EOL;
1964         }
1965         | figure_list br_bass_figure {
1966                 $$ = scm_cons ($2, $1);
1967         }
1968         ;
1969
1970 figure_spec:
1971         FIGURE_OPEN figure_list FIGURE_CLOSE {
1972                 Music * m = MY_MAKE_MUSIC ("EventChord");
1973                 $2 = scm_reverse_x ($2, SCM_EOL);
1974                 m->set_property ("elements",  $2);
1975                 $$ = m->self_scm ();
1976         }
1977         ;
1978
1979
1980 optional_rest:
1981         /**/   { $$ = 0; }
1982         | REST { $$ = 1; }
1983         ;
1984
1985 simple_element:
1986         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1987
1988                 Input i = THIS->pop_spot ();
1989                 if (!THIS->lexer_->is_note_state ())
1990                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1991
1992                 Music *n = 0;
1993                 if ($6)
1994                         n =  MY_MAKE_MUSIC ("RestEvent");
1995                 else
1996                         n =  MY_MAKE_MUSIC ("NoteEvent");
1997
1998                 n->set_property ("pitch", $1);
1999                 n->set_property ("duration", $5);
2000
2001                 if (gh_number_p ($4))
2002                 {
2003                         int q = gh_scm2int ($4);
2004                         n->set_property ("absolute-octave", gh_int2scm (q-1));
2005                 }
2006
2007                 if ($3 % 2)
2008                         n->set_property ("cautionary", SCM_BOOL_T);
2009                 if ($2 % 2 || $3 % 2)
2010                         n->set_property ("force-accidental", SCM_BOOL_T);
2011
2012                 Music *v = MY_MAKE_MUSIC ("EventChord");
2013                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2014                 scm_gc_unprotect_object (n->self_scm ());
2015
2016                 v->set_spot (i);
2017                 n->set_spot (i);
2018                 $$ = v;
2019         }
2020         | DRUM_PITCH optional_notemode_duration {
2021                 Input i = THIS->pop_spot ();
2022
2023                 Music *n =  MY_MAKE_MUSIC ("NoteEvent");
2024                 n->set_property ("duration" ,$2);
2025                 n->set_property ("drum-type" , $1);
2026
2027                 Music *v = MY_MAKE_MUSIC ("EventChord");
2028                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2029                 scm_gc_unprotect_object (n->self_scm ());
2030                 v->set_spot (i);
2031                 n->set_spot (i);
2032                 $$ = v;
2033
2034         }
2035         | figure_spec optional_notemode_duration {
2036                 Music * m = unsmob_music ($1);
2037                 Input i = THIS->pop_spot ();
2038                 m->set_spot (i);
2039                 for (SCM s = m->get_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2040                 {
2041                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2042                 }
2043                 $$ = m;
2044         }
2045         | RESTNAME optional_notemode_duration           {
2046
2047                 Input i = THIS->pop_spot ();
2048                 Music * ev = 0;
2049                 if (ly_scm2string ($1) =="s") {
2050                         /* Space */
2051                         ev = MY_MAKE_MUSIC ("SkipEvent");
2052                   }
2053                 else {
2054                         ev = MY_MAKE_MUSIC ("RestEvent");
2055
2056                     }
2057                 ev->set_property ("duration" ,$2);
2058                 ev->set_spot (i);
2059                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2060                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2061                 velt->set_spot (i);
2062
2063                 scm_gc_unprotect_object (ev->self_scm ());
2064
2065                 $$ = velt;
2066         }
2067         | MULTI_MEASURE_REST optional_notemode_duration         {
2068                 THIS->pop_spot ();
2069
2070                 static SCM proc ;
2071                 if (!proc)
2072                         proc = scm_c_eval_string ("make-multi-measure-rest");
2073
2074                 SCM mus = scm_call_2 (proc, $2,
2075                         make_input (THIS->here_input ()));
2076                 scm_gc_protect_object (mus);
2077                 $$ = unsmob_music (mus);
2078         }
2079
2080         | lyric_element optional_notemode_duration      {
2081                 Input i = THIS->pop_spot ();
2082                 if (!THIS->lexer_->is_lyric_state ())
2083                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2084
2085                 Music * lreq = MY_MAKE_MUSIC ("LyricEvent");
2086                 lreq->set_property ("text", $1);
2087                 lreq->set_property ("duration",$2);
2088                 lreq->set_spot (i);
2089                 Music * velt = MY_MAKE_MUSIC ("EventChord");
2090                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2091
2092                 $$= velt;
2093         }
2094         | new_chord {
2095                 THIS->pop_spot ();
2096
2097                 if (!THIS->lexer_->is_chord_state ())
2098                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2099                 $$ = unsmob_music ($1);
2100         }
2101         ;
2102
2103 lyric_element:
2104         full_markup { $$ = $1; }
2105         | STRING {  $$ = $1 ; }
2106         ;
2107
2108 new_chord:
2109         steno_tonic_pitch optional_notemode_duration   {
2110                 $$ = make_chord ($1, $2, SCM_EOL);
2111         }
2112         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2113                 SCM its = scm_reverse_x ($4, SCM_EOL);
2114                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2115         }
2116         ;
2117
2118 chord_items:
2119         /**/ {
2120                 $$ = SCM_EOL;
2121         }
2122         | chord_items chord_item {
2123                 $$ = gh_cons ($2, $$);
2124         }
2125         ;
2126
2127 chord_separator:
2128         CHORD_COLON {
2129                 $$ = ly_symbol2scm ("chord-colon");
2130         }
2131         | CHORD_CARET {
2132                 $$ = ly_symbol2scm ("chord-caret");
2133         }
2134         | CHORD_SLASH steno_tonic_pitch {
2135                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2136         }
2137         | CHORD_BASS steno_tonic_pitch {
2138                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2139         }
2140         ;
2141
2142 chord_item:
2143         chord_separator {
2144                 $$ = $1;
2145         }
2146         | step_numbers {
2147                 $$ = scm_reverse_x ($1, SCM_EOL);
2148         }
2149         | CHORD_MODIFIER  {
2150                 $$ = $1;
2151         }
2152         ;
2153
2154 step_numbers:
2155         step_number { $$ = gh_cons ($1, SCM_EOL); }
2156         | step_numbers '.' step_number {
2157                 $$ = gh_cons ($3, $$);
2158         }
2159         ;
2160
2161 step_number:
2162         bare_unsigned {
2163                 $$ = make_chord_step ($1, 0);
2164         }
2165         | bare_unsigned '+' {
2166                 $$ = make_chord_step ($1, SHARP);
2167         }
2168         | bare_unsigned CHORD_MINUS {
2169                 $$ = make_chord_step ($1, FLAT);
2170         }
2171         ;
2172
2173 /*
2174         UTILITIES
2175
2176 TODO: should deprecate in favor of Scheme?
2177
2178  */
2179 number_expression:
2180         number_expression '+' number_term {
2181                 $$ = scm_sum ($1, $3);
2182         }
2183         | number_expression '-' number_term {
2184                 $$ = scm_difference ($1, $3);
2185         }
2186         | number_term
2187         ;
2188
2189 number_term:
2190         number_factor {
2191                 $$ = $1;
2192         }
2193         | number_factor '*' number_factor {
2194                 $$ = scm_product ($1, $3);
2195         }
2196         | number_factor '/' number_factor {
2197                 $$ = scm_divide ($1, $3);
2198         }
2199         ;
2200
2201 number_factor:
2202         '-'  number_factor { /* %prec UNARY_MINUS */
2203                 $$ = scm_difference ($2, SCM_UNDEFINED);
2204         }
2205         | bare_number
2206         ;
2207
2208
2209 bare_number:
2210         UNSIGNED        {
2211                 $$ = gh_int2scm ($1);
2212         }
2213         | REAL          {
2214                 $$ = $1;
2215         }
2216         | NUMBER_IDENTIFIER             {
2217                 $$ = $1;
2218         }
2219         | REAL NUMBER_IDENTIFIER        {
2220                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2221         }
2222         | UNSIGNED NUMBER_IDENTIFIER    {
2223                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2224         }
2225         ;
2226
2227
2228 bare_unsigned:
2229         UNSIGNED {
2230                         $$ = $1;
2231         }
2232         | DIGIT {
2233                 $$ = $1;
2234         }
2235         ;
2236
2237 bare_int:
2238         bare_number {
2239                 if (scm_integer_p ($1) == SCM_BOOL_T)
2240                 {
2241                         int k = gh_scm2int ($1);
2242                         $$ = k;
2243                 } else
2244                 {
2245                         THIS->parser_error (_ ("need integer number arg"));
2246                         $$ = 0;
2247                 }
2248         }
2249         | '-' bare_int {
2250                 $$ = -$2;
2251         }
2252         ;
2253
2254
2255 string:
2256         STRING          {
2257                 $$ = $1;
2258         }
2259         | STRING_IDENTIFIER     {
2260                 $$ = $1;
2261         }
2262         | string '+' string {
2263                 $$ = scm_string_append (scm_list_2 ($1, $3));
2264         }
2265         ;
2266
2267
2268 exclamations:
2269                 { $$ = 0; }
2270         | exclamations '!'      { $$ ++; }
2271         ;
2272
2273 questions:
2274                 { $$ = 0; }
2275         | questions '?' { $$ ++; }
2276         ;
2277
2278
2279
2280 full_markup:
2281         MARKUP_IDENTIFIER {
2282                 $$ = $1;
2283         }
2284         | MARKUP
2285                 { THIS->lexer_->push_markup_state (); }
2286         markup
2287                 { $$ = $3;
2288                   THIS->lexer_->pop_state ();
2289                 }
2290         ;
2291
2292
2293 /*
2294 This should be done more dynamically if possible.
2295 */
2296 markup:
2297         STRING {
2298                 $$ = make_simple_markup ($1);
2299         }
2300         | MARKUP_HEAD_EMPTY {
2301                 $$ = scm_list_1 ($1);
2302         }
2303         | MARKUP_HEAD_MARKUP0 markup {
2304                 $$ = scm_list_2 ($1, $2);
2305         }
2306         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2307                 $$ = scm_list_3 ($1, $2, $3);
2308         }
2309         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2310                 $$  = scm_list_3 ($1, $2, $3);
2311         }
2312         | markup_line {
2313                 $$ = $1;
2314         }
2315         | MARKUP_HEAD_LIST0 markup_list {
2316                 $$ = scm_list_2 ($1,$2);
2317         }
2318         | MARKUP_HEAD_SCM0 embedded_scm {
2319                 $$ = scm_list_2 ($1, $2);
2320         }
2321         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2322                 $$ = scm_list_4 ($1, $2, $3, $4);
2323         }
2324         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2325                 $$ = scm_list_4 ($1, $2, $3, $4);
2326         }
2327         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2328                 $$ = scm_list_3 ($1, $2, $3);
2329         }
2330         | MARKUP_IDENTIFIER {
2331                 $$ = $1;
2332         }
2333         | STRING_IDENTIFIER {
2334                 $$ = $1;
2335         }
2336         ;
2337
2338 markup_list:
2339         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2340         ;
2341
2342 markup_line:
2343         '{' markup_list_body '}' {
2344                 static SCM line ;
2345                 if (!line)
2346                         line = scm_c_eval_string ("line-markup");
2347
2348                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2349         }
2350         ;
2351
2352 markup_list_body:
2353         /**/ {  $$ = SCM_EOL; }
2354         | markup_list_body markup {
2355                 $$ = gh_cons ($2, $1) ;
2356         }
2357         ;
2358
2359
2360 %%
2361
2362 void
2363 My_lily_parser::set_yydebug (bool )
2364 {
2365 #if 0
2366         yydebug = 1;
2367 #endif
2368 }
2369
2370 extern My_lily_parser * current_parser;
2371
2372 void
2373 My_lily_parser::do_yyparse ()
2374 {
2375         current_parser = this;;
2376         yyparse ((void*)this);
2377 }
2378
2379
2380 /*
2381 Should make this optional?    It will also complain when you do
2382
2383         [s4]
2384
2385 which is entirely legitimate.
2386
2387 Or we can scrap it. Barchecks should detect wrong durations, and
2388 skipTypesetting speeds it up a lot.
2389 */
2390
2391 void
2392 My_lily_parser::beam_check (SCM dur)
2393 {
2394   Duration *d = unsmob_duration (dur);
2395   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2396     {
2397       Music * m = unsmob_music (last_beam_start_);
2398       m->origin ()->warning (_("Suspect duration found following this beam"));
2399     }
2400   last_beam_start_ = SCM_EOL;
2401 }
2402
2403
2404
2405
2406 /*
2407
2408 It is a little strange to have this function in this file, but
2409 otherwise, we have to import music classes into the lexer.
2410
2411 */
2412 int
2413 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2414 {
2415         if (gh_string_p (sid)) {
2416                 *destination = sid;
2417                 return STRING_IDENTIFIER;
2418         } else if (gh_number_p (sid)) {
2419                 *destination = sid;
2420                 return NUMBER_IDENTIFIER;
2421         } else if (unsmob_context_def (sid)) {
2422                 *destination = unsmob_context_def (sid)->clone_scm ();
2423                 return CONTEXT_DEF_IDENTIFIER;
2424         } else if (unsmob_score (sid)) {
2425                 Score *sc =  new Score (*unsmob_score (sid));
2426                 *destination =sc->self_scm ();
2427                 return SCORE_IDENTIFIER;
2428         } else if (Music * mus =unsmob_music (sid)) {
2429                 mus = mus->clone ();
2430                 *destination = mus->self_scm ();
2431                 unsmob_music (*destination)->
2432                         set_property ("origin", make_input (last_input_));
2433                 return dynamic_cast<Event*> (mus)
2434                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2435         } else if (unsmob_duration (sid)) {
2436                 *destination = unsmob_duration (sid)->smobbed_copy ();
2437                 return DURATION_IDENTIFIER;
2438         } else if (unsmob_music_output_def (sid)) {
2439                 Music_output_def *p = unsmob_music_output_def (sid);
2440                 p = p->clone ();
2441
2442                 *destination = p->self_scm ();
2443                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2444         } else if (Text_item::markup_p (sid)) {
2445                 *destination = sid;
2446                 return MARKUP_IDENTIFIER;
2447         }
2448
2449         return -1;
2450 }
2451
2452 Music *
2453 property_op_to_music (SCM op)
2454 {
2455         Music * m = 0;
2456         SCM tag = gh_car (op);
2457         SCM symbol  = gh_cadr (op);
2458         SCM args = gh_cddr (op);
2459         SCM grob_val = SCM_UNDEFINED;
2460         SCM grob_sym = SCM_UNDEFINED;
2461         SCM val = SCM_UNDEFINED;
2462
2463         if (tag == ly_symbol2scm ("assign"))
2464                 {
2465                 m =  MY_MAKE_MUSIC ("PropertySet");
2466                 val = gh_car (args);
2467                 }
2468         else if (tag == ly_symbol2scm ("unset"))
2469                 m =  MY_MAKE_MUSIC ("PropertyUnset");
2470         else if (tag == ly_symbol2scm ("poppush")
2471                  || tag == ly_symbol2scm ("push"))
2472                 {
2473                 m  = MY_MAKE_MUSIC ("OverrideProperty");
2474                 grob_sym = gh_car (args);
2475                 grob_val = gh_cadr (args);
2476                 }
2477         else if (tag == ly_symbol2scm ("pop")) {
2478                 m = MY_MAKE_MUSIC ("RevertProperty");
2479                 grob_sym = gh_car (args);
2480                 }
2481
2482         m->set_property ("symbol", symbol);
2483
2484         if (val != SCM_UNDEFINED)
2485                 m->set_property ("value", val);
2486         if (grob_val != SCM_UNDEFINED)
2487                 m->set_property ("grob-value", grob_val);
2488
2489         if (grob_sym != SCM_UNDEFINED)
2490                 {
2491                 bool itc = internal_type_checking_global_b;
2492                 /* UGH.
2493                 */
2494                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2495                 if (autobeam)
2496                         internal_type_checking_global_b = false;
2497                 m->set_property ("grob-property", grob_sym);
2498                 if (autobeam)
2499                         internal_type_checking_global_b = itc;
2500                 }
2501
2502         if (op == ly_symbol2scm ("poppush"))
2503                 m->set_property ("pop-first", SCM_BOOL_T);
2504
2505
2506         return m;
2507 }
2508
2509 Music*
2510 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2511 {
2512         Music * csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2513
2514         csm->set_property ("element", m->self_scm ());
2515         scm_gc_unprotect_object (m->self_scm ());
2516
2517         csm->set_property ("context-type",
2518                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2519         csm->set_property ("property-operations", ops);
2520
2521         if (gh_string_p (id))
2522                 csm->set_property ("context-id", id);
2523         return csm;
2524 }
2525
2526
2527 SCM
2528 get_next_unique_context ()
2529 {
2530         static int new_context_count;
2531
2532         char s[1024];
2533         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2534
2535         return scm_makfrom0str (s);
2536 }
2537