lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token PROPERTY
 287 %token RELATIVE
 288 %token REMOVE
 289 %token REPEAT
 290 %token REST
 291 %token SCM_T
 292 %token SCORE
 293 %token SEQUENTIAL
 294 %token SIMULTANEOUS
 295 %token SKIP
 296 %token SPANREQUEST
 297 %token TAG
 298 %token TEMPO
 299 %token TIMES
 300 %token TIME_T
 301 %token TRANSLATOR
 302 %token TRANSPOSE
 303 %token TYPE
 304 %token UNSET
 305 %token WITH
 306
 307 /* escaped */
 308 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 309 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 310 %token E_BACKSLASH
 311 %token <i> E_UNSIGNED
 312 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 313 %token FIGURE_SPACE
 314
 315 %type <i>       exclamations questions dots optional_rest
 316 %type <i>        bass_mod
 317 %type <scm>     grace_head
 318 %type <scm>     oct_check
 319 %type <scm>     context_mod_list
 320 %type <scm>     lyric_element
 321 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 322 %token <i>      DIGIT
 323 %token <scm>    NOTENAME_PITCH
 324 %token <scm>    TONICNAME_PITCH
 325 %token <scm>    CHORDMODIFIER_PITCH
 326 %token <scm>    DURATION_IDENTIFIER
 327 %token <scm>    FRACTION
 328 %token <id>     IDENTIFIER
 329 %token DRUMS
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    CHORD_MODIFIER
 332 %token <scm>    SCORE_IDENTIFIER
 333 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 334 %token <scm>    NUMBER_IDENTIFIER
 335 %token <scm>    EVENT_IDENTIFIER
 336 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 337 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 338 %token <scm>    RESTNAME
 339 %token <scm>    STRING
 340 %token <scm>    SCM_T
 341 %token <i>      UNSIGNED
 342 %token <scm>   REAL
 343
 344 %token MARKUP
 345 %token <scm> MARKUP_HEAD_MARKUP0
 346 %token <scm> MARKUP_HEAD_EMPTY
 347 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 348 %token <scm> MARKUP_HEAD_SCM0
 349 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 353
 354 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 355 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 356
 357 %type <outputdef> output_def
 358 %type <scm>     lilypond_header lilypond_header_body
 359 %type <music>   open_event close_event
 360 %type <i>       sub_quotes sup_quotes
 361 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 362 %type <music>   Repeated_music
 363 %type <scm>     Alternative_music
 364 %type <i>       tremolo_type
 365 %type <i>       bare_int  bare_unsigned
 366 %type <i>       script_dir
 367 %type <scm>     identifier_init
 368
 369 %type <music> note_chord_element chord_body chord_body_element
 370 %type <scm>  chord_body_elements
 371 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 372
 373 %type <scm>   post_events
 374 %type <music> gen_text_def direction_less_event direction_reqd_event
 375 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 376 %type <scm>    steno_tonic_pitch
 377 %type <scm>     duration_length fraction
 378
 379 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 380
 381 %type <scm>  embedded_scm scalar
 382 %type <music>   Music Sequential_music Simultaneous_music
 383 %type <music>   relative_music re_rhythmed_music
 384 %type <music>   music_property_def context_change
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music>   post_event tagged_post_event
 389 %type <music> command_req
 390 %type <music> string_number_event
 391 %type <scm>     string bare_number number_expression number_term number_factor
 392 %type <score>   score_block score_body
 393
 394 %type <scm>     translator_spec_block translator_spec_body
 395 %type <music>   tempo_event
 396 %type <scm>     script_abbreviation
 397
 398
 399
 400 %left '-' '+'
 401
 402 /* We don't assign precedence to / and *, because we might need varied
 403 prec levels in different prods */
 404
 405 %left UNARY_MINUS
 406
 407 %%
 408
 409 lilypond:       /* empty */
 410         | lilypond toplevel_expression {}
 411         | lilypond assignment  { }
 412         | lilypond error {
 413                 THIS->error_level_  = 1;
 414         }
 415         | lilypond INVALID      {
 416                 THIS->error_level_  = 1;
 417         }
 418         ;
 419
 420 toplevel_expression:
 421         lilypond_header {
 422                 THIS->input_file_->header_ = $1;
 423         }
 424         | score_block {
 425                 Score * sc = $1;
 426
 427                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 428
 429                 Path p = split_path (THIS->output_basename_);
 430                 int *c =  &THIS->input_file_->score_count_;
 431                 if (*c)
 432                         {
 433                         p.base += "-" + to_string (*c);
 434                         }
 435
 436                 (*c)++;
 437                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 438
 439                 for (int i=0; i < sc->defs_.size (); i++)
 440                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 441
 442                 if (sc->defs_.is_empty ())
 443                 {
 444                    Music_output_def *id =
 445                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 446                                 ("$defaultpaper"));
 447
 448                    id = id ? id->clone () : new Paper_def;
 449
 450                    default_rendering (sc->music_, id->self_scm(), head, outname);
 451
 452                    scm_gc_unprotect_object (id->self_scm ());
 453                 }
 454                 scm_gc_unprotect_object (sc->self_scm());
 455         }
 456         | output_def {
 457                 SCM id = SCM_EOL;
 458                 if (dynamic_cast<Paper_def*> ($1))
 459                         id = scm_makfrom0str ("$defaultpaper");
 460                 else if (dynamic_cast<Midi_def*> ($1))
 461                         id = scm_makfrom0str ("$defaultmidi");
 462                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 463                 scm_gc_unprotect_object ($1->self_scm ());
 464         }
 465         ;
 466
 467 embedded_scm:
 468         SCM_T
 469         | SCM_IDENTIFIER
 470         ;
 471
 472
 473
 474
 475 lilypond_header_body:
 476         {
 477                 $$ = ly_make_anonymous_module ();
 478                 THIS->lexer_->add_scope ($$);
 479         }
 480         | lilypond_header_body assignment  {
 481
 482         }
 483         ;
 484
 485 lilypond_header:
 486         HEADER '{' lilypond_header_body '}'     {
 487                 $$ = THIS->lexer_-> remove_scope();
 488         }
 489         ;
 490
 491
 492 /*
 493         DECLARATIONS
 494 */
 495 assignment:
 496         STRING {
 497                 THIS->push_spot ();
 498         }
 499         /* cont */ '=' identifier_init  {
 500
 501         /*
 502                 Should find generic way of associating input with objects.
 503         */
 504                 Input ip = THIS->pop_spot ();
 505
 506                 if (! regular_identifier_b ($1))
 507                 {
 508                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 509                 }
 510
 511                 THIS->lexer_->set_identifier ($1, $4);
 512
 513 /*
 514  TODO: devise standard for protection in parser.
 515
 516   The parser stack lives on the C-stack, which means that
 517 all objects can be unprotected as soon as they're here.
 518
 519 */
 520         }
 521         | embedded_scm { }
 522         ;
 523
 524
 525 identifier_init:
 526         score_block {
 527                 $$ = $1->self_scm ();
 528                 scm_gc_unprotect_object ($$);
 529         }
 530         | full_markup {
 531                 $$ = $1;
 532         }
 533         | output_def {
 534                 $$ = $1->self_scm ();
 535                 scm_gc_unprotect_object ($$);
 536         }
 537         | translator_spec_block {
 538                 $$ = $1;
 539         }
 540         | Music  {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | post_event {
 545                 $$ = $1->self_scm ();
 546                 scm_gc_unprotect_object ($$);
 547         }
 548         | number_expression {
 549                 $$ = $1;
 550         }
 551         | string {
 552                 $$ = $1;
 553         }
 554         | embedded_scm  {
 555                 $$ = $1;
 556         }
 557         ;
 558
 559 translator_spec_block:
 560         TRANSLATOR '{' translator_spec_body '}'
 561                 {
 562                 $$ = $3;
 563         }
 564         ;
 565
 566 translator_spec_body:
 567         /**/ {
 568                 $$ = Context_def::make_scm ();
 569                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 570         }
 571         | TRANSLATOR_IDENTIFIER {
 572                 $$ = $1;
 573                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 574         }
 575         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 576                 Context_def*td = unsmob_context_def($$);
 577
 578                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 579                         SCM tag = gh_caar (p);
 580                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 581                                                         tag, ly_cdar (p), SCM_UNDEFINED));
 582                 }
 583         }
 584         | translator_spec_body context_mod {
 585                 unsmob_context_def ($$)->add_context_mod ($2);
 586         }
 587         ;
 588
 589 /*
 590         SCORE
 591 */
 592 score_block:
 593         SCORE {
 594                 THIS->push_spot ();
 595         }
 596         /*cont*/ '{' score_body '}'     {
 597                 THIS->pop_spot ();
 598                 $$ = $4;
 599
 600         }
 601         ;
 602
 603 score_body:
 604         Music   {
 605                 $$ = new Score;
 606
 607                 $$->set_spot (THIS->here_input ());
 608                 SCM m = $1->self_scm ();
 609                 scm_gc_unprotect_object (m);
 610
 611                 /*
 612                         guh.
 613                 */
 614                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 615                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 616                         m = gh_call1 (gh_car (check_funcs), m);
 617                 $$->music_ = m;
 618
 619         }
 620         | SCORE_IDENTIFIER {
 621                 $$ = new Score ( *unsmob_score ($1));
 622                 $$->set_spot (THIS->here_input ());
 623         }
 624         | score_body lilypond_header    {
 625                 $$->header_ = $2;
 626         }
 627         | score_body output_def {
 628                 $$->defs_.push ($2);
 629                 scm_gc_unprotect_object ($2->self_scm ());
 630         }
 631         | score_body error {
 632
 633         }
 634         ;
 635
 636
 637 /*
 638         MIDI
 639 */
 640 output_def:
 641         music_output_def_body '}' {
 642                 $$ = $1;
 643                 THIS-> lexer_-> remove_scope ();
 644         }
 645         ;
 646
 647 music_output_def_head:
 648         MIDI    {
 649                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 650
 651
 652                 Midi_def* p =0;
 653                 if (id)
 654                         p = dynamic_cast<Midi_def*> (id->clone ());
 655                 else
 656                         p = new Midi_def;
 657
 658                 $$ = p;
 659                 THIS->lexer_->add_scope (p->scope_);
 660         }
 661         | PAPER         {
 662                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 663                   Paper_def *p = 0;
 664                 if (id)
 665                         p = dynamic_cast<Paper_def*> (id->clone ());
 666                 else
 667                         p = new Paper_def;
 668
 669                 THIS->lexer_->add_scope (p->scope_);
 670                 $$ = p;
 671         }
 672         ;
 673
 674
 675 music_output_def_body:
 676         music_output_def_head '{' {
 677
 678         }
 679         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 680                 Music_output_def * o =  unsmob_music_output_def ($3);
 681                 $$ = o;
 682                 THIS->lexer_->remove_scope ();
 683                 THIS->lexer_->add_scope (o->scope_);
 684         }
 685         | music_output_def_body assignment  {
 686
 687         }
 688         | music_output_def_body translator_spec_block   {
 689                 $$->assign_translator ($2);
 690         }
 691         | music_output_def_body tempo_event  {
 692                 /*
 693                         junk this ? there already is tempo stuff in
 694                         music.
 695                 */
 696                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 697                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 698                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 699                 if (md)
 700                         md->set_tempo (d->get_length (), m);
 701                 scm_gc_unprotect_object ($2->self_scm ());
 702         }
 703         | music_output_def_body error {
 704
 705         }
 706         ;
 707
 708 tempo_event:
 709         TEMPO steno_duration '=' bare_unsigned  {
 710                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 711                 $$->set_mus_property ("tempo-unit", $2);
 712                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 713         }
 714         ;
 715
 716 /*
 717 The representation of a  list is the
 718
 719   (LIST . LAST-CONS)
 720
 721  to have  efficient append.
 722 */
 723 Music_list:
 724         /* empty */ {
 725                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 726         }
 727         | Music_list Music {
 728                 SCM s = $$;
 729                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 730                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 731                 if (gh_pair_p (ly_cdr (s)))
 732                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 733                 else
 734                         gh_set_car_x (s, c); /* set first cons */
 735                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 736         }
 737         | Music_list error {
 738         }
 739         ;
 740
 741
 742 Music:
 743         Simple_music
 744         | Composite_music
 745         ;
 746
 747 Alternative_music:
 748         /* empty */ {
 749                 $$ = SCM_EOL;
 750         }
 751         | ALTERNATIVE '{' Music_list '}' {
 752                 $$ = $3;
 753         }
 754         ;
 755
 756 Repeated_music:
 757         REPEAT string bare_unsigned Music Alternative_music
 758         {
 759                 Music *beg = $4;
 760                 int times = $3;
 761                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 762                 if (times < scm_ilength (alts)) {
 763                   unsmob_music (gh_car (alts))
 764                     ->origin ()->warning (
 765                     _("More alternatives than repeats.  Junking excess alternatives."));
 766                   alts = ly_truncate_list (times, alts);
 767                 }
 768
 769
 770                 static SCM proc;
 771                 if (!proc)
 772                         proc = scm_c_eval_string ("make-repeated-music");
 773
 774                 SCM mus = scm_call_1 (proc, $2);
 775                 scm_gc_protect_object (mus); // UGH.
 776                 Music *r =unsmob_music (mus);
 777                 if (beg)
 778                         {
 779                         r-> set_mus_property ("element", beg->self_scm ());
 780                         scm_gc_unprotect_object (beg->self_scm ());
 781                         }
 782                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 783
 784                 r-> set_mus_property ("elements",alts);
 785                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 786                         /*
 787                         we can not get durations and other stuff correct down the line, so we have to
 788                         add to the duration log here.
 789                         */
 790                         static SCM func;
 791
 792                         if (!func)
 793                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 794
 795                         int dots = ($3 % 3) ? 0 : 1;
 796                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 797
 798                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 799
 800                         if (seq) {
 801                                 int list_len =scm_ilength (seq->music_list ());
 802                                 if (list_len != 2)
 803                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 804                                 shift -= 1;
 805                                 r->compress (Moment (Rational (1,list_len)));
 806                                 }
 807                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 808
 809                 }
 810                 r->set_spot (*$4->origin ());
 811
 812                 $$ = r;
 813         }
 814         ;
 815
 816 Sequential_music:
 817         SEQUENTIAL '{' Music_list '}'           {
 818                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 819                 $$->set_mus_property ("elements", ly_car ($3));
 820                 $$->set_spot(THIS->here_input());
 821         }
 822         | '{' Music_list '}'            {
 823                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 824                 $$->set_mus_property ("elements", ly_car ($2));
 825                 $$->set_spot(THIS->here_input());
 826         }
 827         ;
 828
 829 Simultaneous_music:
 830         SIMULTANEOUS '{' Music_list '}'{
 831                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 832                 $$->set_mus_property ("elements", ly_car ($3));
 833                 $$->set_spot(THIS->here_input());
 834
 835         }
 836         | simul_open Music_list simul_close     {
 837                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 838                 $$->set_mus_property ("elements", ly_car ($2));
 839                 $$->set_spot(THIS->here_input());
 840         }
 841         ;
 842
 843 Simple_music:
 844         event_chord             { $$ = $1; }
 845         | APPLYOUTPUT embedded_scm {
 846                 if (!ly_input_procedure_p ($2))
 847                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 848                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 849                 $$->set_mus_property ("procedure", $2);
 850                 $$->set_spot (THIS->here_input());
 851         }
 852         | APPLYCONTEXT embedded_scm {
 853                 if (!ly_input_procedure_p ($2))
 854                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 855                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 856                 $$->set_mus_property ("procedure", $2);
 857                 $$->set_spot (THIS->here_input());
 858         }
 859         | MUSIC_IDENTIFIER {
 860                 $$ = unsmob_music ($1);
 861         }
 862         | music_property_def
 863         | context_change
 864         ;
 865
 866
 867 optional_context_mod:
 868         /**/ { $$ = SCM_EOL; }
 869         | WITH '{' context_mod_list '}'  { $$ = $3; }
 870         ;
 871
 872 grace_head:
 873         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 874         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 875         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 876         ;
 877
 878 context_mod_list:
 879         /* */  { $$ = SCM_EOL; }
 880         | context_mod_list context_mod  {
 881                  $$ = gh_cons ($2, $1);
 882         }
 883         ;
 884
 885 Composite_music:
 886         AUTOCHANGE Music        {
 887                 static SCM proc ;
 888                 if (!proc)
 889                         proc = scm_c_eval_string ("make-autochange-music");
 890
 891                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 892                 scm_gc_unprotect_object ($2->self_scm ());
 893                 $$ = unsmob_music (res);
 894                 scm_gc_protect_object (res);
 895                 $$->set_spot (THIS->here_input());
 896         }
 897         | PARTCOMBINE Music Music {
 898                 static SCM proc;
 899                 if (!proc)
 900                         proc = scm_c_eval_string ("make-part-combine-music");
 901
 902                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 903                         $3->self_scm (), SCM_UNDEFINED));
 904                 scm_gc_unprotect_object ($3->self_scm ());
 905                 scm_gc_unprotect_object ($2->self_scm ());
 906                 $$ = unsmob_music (res);
 907                 scm_gc_protect_object (res);
 908                 $$->set_spot (THIS->here_input());
 909         }
 910         | grace_head Music {
 911 #if 1
 912         /*
 913                 The other version is for easier debugging  of
 914                 Sequential_music_iterator in combination with grace notes.
 915         */
 916
 917 /*
 918
 919 TODO: should distinguish between both grace types in the
 920 basic music objects too, since the meaning is different.
 921
 922 */
 923
 924                 String start_str = "start" + ly_scm2string ($1) + "Music";
 925                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 926
 927                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 928                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 929
 930                 Music *startm = unsmob_music (start);
 931                 Music *stopm = unsmob_music (stop);
 932
 933                 SCM ms = SCM_EOL;
 934                 if (stopm) {
 935                         stopm = stopm->clone ();
 936                         ms = scm_cons (stopm->self_scm (), ms);
 937                         scm_gc_unprotect_object (stopm->self_scm ());
 938                 }
 939                 ms = scm_cons ($2->self_scm (), ms);
 940                 scm_gc_unprotect_object ($2->self_scm());
 941                 if (startm) {
 942                         startm = startm->clone ();
 943                         ms = scm_cons (startm->self_scm () , ms);
 944                         scm_gc_unprotect_object (startm->self_scm ());
 945                 }
 946
 947
 948                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 949                 seq->set_mus_property ("elements", ms);
 950
 951
 952                 $$ = MY_MAKE_MUSIC("GraceMusic");
 953                 $$->set_mus_property ("element", seq->self_scm ());
 954                 scm_gc_unprotect_object (seq->self_scm ());
 955 #else
 956                 $$ = MY_MAKE_MUSIC("GraceMusic");
 957                 $$->set_mus_property ("element", $2->self_scm ());
 958                 scm_gc_unprotect_object ($2->self_scm ());
 959 #endif
 960         }
 961         | CONTEXT string '=' string optional_context_mod Music {
 962                 $$ = context_spec_music ($2, $4, $6, $5);
 963
 964         }
 965         | CONTEXT STRING optional_context_mod Music {
 966                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 967         }
 968         | NEWCONTEXT string optional_context_mod Music {
 969                 $$ = context_spec_music ($2, get_next_unique_context (),
 970                                          $4, $3);
 971         }
 972
 973         | TIMES {
 974                 THIS->push_spot ();
 975         }
 976         /* CONTINUED */
 977                 fraction Music
 978
 979         {
 980                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 981                 Music *mp = $4;
 982
 983                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 984                 $$->set_spot (THIS->pop_spot ());
 985
 986                 $$->set_mus_property ("element", mp->self_scm ());
 987                 scm_gc_unprotect_object (mp->self_scm ());
 988                 $$->set_mus_property ("numerator", gh_int2scm (n));
 989                 $$->set_mus_property ("denominator", gh_int2scm (d));
 990                 $$->compress (Moment (Rational (n,d)));
 991
 992         }
 993         | Repeated_music                { $$ = $1; }
 994         | Simultaneous_music            { $$ = $1; }
 995         | Sequential_music              { $$ = $1; }
 996         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 997                 $$ = MY_MAKE_MUSIC("TransposedMusic");
 998                 Music *p = $4;
 999                 Pitch from = *unsmob_pitch ($2);
1000                 Pitch to = *unsmob_pitch ($3);
1001
1002                 p->transpose (interval (from, to));
1003                 $$->set_mus_property ("element", p->self_scm ());
1004                 scm_gc_unprotect_object (p->self_scm ());
1005         }
1006         | APPLY embedded_scm Music  {
1007                 if (!ly_input_procedure_p ($2))
1008                         {
1009                         THIS->parser_error (_ ("\\apply takes function argument"));
1010                         $$ = $3;
1011                         }
1012                 else
1013                         {
1014                         SCM ret = gh_call1 ($2, $3->self_scm ());
1015                         Music *m = unsmob_music (ret);
1016                         if (!m) {
1017                                 THIS->parser_error ("\\apply must return a Music");
1018                                 m = MY_MAKE_MUSIC("Music");
1019                                 }
1020                         $$ = m;
1021                         }
1022         }
1023         | NOTES
1024                 {
1025                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1026                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1027         }
1028         Music
1029                 { $$ = $3;
1030                   THIS->lexer_->pop_state ();
1031                 }
1032         | DRUMS
1033                 {
1034                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1035                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1036         }
1037         Music
1038                 { $$ = $3;
1039                   THIS->lexer_->pop_state ();
1040                 }
1041         | FIGURES
1042                 { THIS->lexer_->push_figuredbass_state (); }
1043         Music
1044                 {
1045                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1046                   chm->set_mus_property ("element", $3->self_scm ());
1047                   $$ = chm;
1048                   scm_gc_unprotect_object ($3->self_scm());
1049
1050                   THIS->lexer_->pop_state ();
1051         }
1052         | CHORDS {
1053                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1054                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1055                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1056                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1057
1058         } Music {
1059                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1060                   chm->set_mus_property ("element", $3->self_scm ());
1061                   scm_gc_unprotect_object ($3->self_scm());
1062                   $$ = chm;
1063
1064                   THIS->lexer_->pop_state ();
1065         }
1066         | LYRICS
1067                 { THIS->lexer_->push_lyric_state (); }
1068         Music
1069                 {
1070                   $$ = $3;
1071                   THIS->lexer_->pop_state ();
1072         }
1073         | relative_music        { $$ = $1; }
1074         | re_rhythmed_music     { $$ = $1; }
1075         | TAG embedded_scm Music {
1076                 tag_music ($3, $2, THIS->here_input ());
1077                 $$ = $3;
1078         }
1079         ;
1080
1081 relative_music:
1082         RELATIVE absolute_pitch Music {
1083                 Music * p = $3;
1084                 Pitch pit = *unsmob_pitch ($2);
1085                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1086
1087                 $$->set_mus_property ("element", p->self_scm ());
1088                 scm_gc_unprotect_object (p->self_scm ());
1089
1090
1091                 Pitch retpitch = p->to_relative_octave (pit);
1092                 if (lily_1_8_relative)
1093                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1094         }
1095         ;
1096
1097 re_rhythmed_music:
1098         ADDLYRICS Music Music {
1099         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1100           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1101           scm_gc_unprotect_object ($3->self_scm ());
1102           scm_gc_unprotect_object ($2->self_scm ());
1103           $$ = l;
1104         }
1105         | NEWADDLYRICS string Music {
1106           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1107           l->set_mus_property ("element", $3->self_scm ());
1108           scm_gc_unprotect_object ($3->self_scm ());
1109           $$ = l;
1110           l->set_mus_property ("associated-context", $2);
1111         }
1112         ;
1113
1114 context_change:
1115         CHANGE STRING '=' STRING  {
1116                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1117                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1118                 t-> set_mus_property ("change-to-id", $4);
1119
1120                 $$ = t;
1121                 $$->set_spot (THIS->here_input ());
1122         }
1123         ;
1124
1125 property_operation:
1126         STRING '='  scalar {
1127                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1128                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1129         }
1130         | STRING UNSET {
1131                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1132                         scm_string_to_symbol ($1), SCM_UNDEFINED);
1133         }
1134         | STRING SET embedded_scm '=' embedded_scm {
1135                 $$ = scm_list_n (ly_symbol2scm ("poppush"),
1136                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1137         }
1138         | STRING OVERRIDE embedded_scm '=' embedded_scm {
1139                 $$ = scm_list_n (ly_symbol2scm ("push"),
1140                         scm_string_to_symbol ($1), $3, $5, SCM_UNDEFINED);
1141         }
1142         | STRING REVERT embedded_scm {
1143                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1144                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1145         }
1146         ;
1147
1148 translator_mod:
1149         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1150         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1151         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1152
1153         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1154         | DENIES { $$ = ly_symbol2scm ("denies"); }
1155
1156         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1157         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1158         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1159         | NAME { $$ = ly_symbol2scm ("context-name"); }
1160         ;
1161
1162 context_mod:
1163         property_operation { $$ = $1; }
1164         | translator_mod STRING {
1165                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1166         }
1167         ;
1168
1169 music_property_def:
1170         PROPERTY STRING '.' property_operation {
1171                 Music * t = property_op_to_music ($4);
1172                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1173
1174                 csm->set_mus_property ("element", t->self_scm ());
1175                 scm_gc_unprotect_object (t->self_scm ());
1176
1177                 $$ = csm;
1178                 $$->set_spot (THIS->here_input ());
1179
1180                 csm-> set_mus_property ("context-type", scm_string_to_symbol ($2));
1181         }
1182         | ONCE music_property_def {
1183                 $$ = $2;
1184                 SCM e = $2->get_mus_property ("element");
1185                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1186         }
1187         ;
1188
1189
1190 scalar:
1191         string          { $$ = $1; }
1192         | bare_int      { $$ = gh_int2scm ($1); }
1193         | embedded_scm  { $$ = $1; }
1194         | full_markup {  $$ = $1; }
1195         | DIGIT { $$ = gh_int2scm ($1); }
1196         ;
1197
1198 /*
1199 This is a trick:
1200
1201 Adding pre_events to the simple_element
1202 makes the choice between
1203
1204   string:  STRING
1205
1206 and
1207
1208   simple_element: STRING
1209
1210 a single shift/reduction conflict.
1211
1212 nevertheless, this is not very clean, and we should find a different
1213 solution.
1214
1215 */
1216 pre_events: {
1217                 THIS->push_spot ();
1218         }
1219         ;
1220
1221 event_chord:
1222         pre_events simple_element post_events   {
1223                 SCM elts = $2-> get_mus_property ("elements");
1224
1225                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1226
1227                 $2->set_mus_property ("elements", elts);
1228                 $$ = $2;
1229         }
1230         | command_element
1231         | note_chord_element
1232         ;
1233
1234
1235 note_chord_element:
1236         chord_body optional_notemode_duration post_events
1237         {
1238                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1239                 SCM es = $1->get_mus_property ("elements");
1240                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1241
1242                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1243                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1244                 es = gh_append2 (es, postevs);
1245
1246                 $1-> set_mus_property ("elements", es);
1247                 $$ = $1;
1248         }
1249         ;
1250
1251 chord_open: '<'
1252         ;
1253
1254 chord_close: '>'
1255         ;
1256
1257 simul_open: LESSLESS
1258         ;
1259
1260 simul_close: MOREMORE
1261         ;
1262
1263 chord_body:
1264         chord_open chord_body_elements chord_close
1265         {
1266                 $$ = MY_MAKE_MUSIC("EventChord");
1267                 $$->set_mus_property ("elements",
1268                         scm_reverse_x ($2, SCM_EOL));
1269         }
1270         ;
1271
1272 chord_body_elements:
1273         /* empty */             { $$ = SCM_EOL; }
1274         | chord_body_elements chord_body_element {
1275                 $$ = gh_cons ($2->self_scm(), $1);
1276                 scm_gc_unprotect_object ($2->self_scm());
1277         }
1278         ;
1279
1280 chord_body_element:
1281         pitch exclamations questions post_events
1282         {
1283                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1284                 n->set_mus_property ("pitch", $1);
1285                 if ($3 % 2)
1286                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1287                 if ($2 % 2 || $3 % 2)
1288                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1289
1290                 if (gh_pair_p ($4)) {
1291                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1292                         n->set_mus_property ("articulations", arts);
1293                 }
1294                 $$ = n;
1295         }
1296         | DRUM_PITCH post_events {
1297                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1298                 n->set_mus_property ("duration" ,$2);
1299                 n->set_mus_property ("drum-type" , $1);
1300                 n->set_spot (THIS->here_input());
1301
1302                 if (gh_pair_p ($2)) {
1303                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1304                         n->set_mus_property ("articulations", arts);
1305                 }
1306                 $$ = n;
1307         }
1308         ;
1309
1310 command_element:
1311         command_req {
1312                 $$ = MY_MAKE_MUSIC("EventChord");
1313                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1314                 scm_gc_unprotect_object ($1->self_scm());
1315
1316                 $$-> set_spot (THIS->here_input ());
1317                 $1-> set_spot (THIS->here_input ());
1318         }
1319         | SKIP duration_length {
1320                 Music * skip = MY_MAKE_MUSIC("SkipMusic");
1321                 skip->set_mus_property ("duration", $2);
1322
1323                 $$ = skip;
1324         }
1325         | OCTAVE { THIS->push_spot (); }
1326           pitch {
1327                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1328                 $$ = l;
1329                 $$->set_spot (THIS->pop_spot ());
1330                 $$->set_mus_property ("pitch", $3);
1331         }
1332         | E_LEFTSQUARE {
1333                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1334                 l->set_mus_property ("span-direction", gh_int2scm (START));
1335                 l->set_spot (THIS->here_input ());
1336
1337                 $$ = MY_MAKE_MUSIC("EventChord");
1338                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1339                 scm_gc_unprotect_object (l->self_scm());
1340                 $$->set_spot (THIS->here_input ());
1341         }
1342         | E_RIGHTSQUARE {
1343                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1344                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1345                 l->set_spot (THIS->here_input ());
1346
1347                 $$ = MY_MAKE_MUSIC("EventChord");
1348                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1349                 $$->set_spot (THIS->here_input ());
1350                 scm_gc_unprotect_object (l->self_scm());
1351         }
1352         | E_BACKSLASH {
1353                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1354                 $$->set_spot (THIS->here_input ());
1355         }
1356         | '|'      {
1357
1358                 $$ = MY_MAKE_MUSIC("BarCheck");
1359                 $$->set_spot (THIS->here_input ());
1360         }
1361         | BAR STRING                    {
1362                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1363
1364                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1365                 csm->set_mus_property ("element", t->self_scm ());
1366                 scm_gc_unprotect_object (t->self_scm ());
1367
1368                 $$ = csm;
1369                 $$->set_spot (THIS->here_input ());
1370
1371                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1372         }
1373         | PARTIAL duration_length       {
1374                 Moment m = - unsmob_duration ($2)->get_length ();
1375                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1376
1377                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1378                 sp->set_mus_property ("element", p->self_scm ());
1379                 scm_gc_unprotect_object (p->self_scm ());
1380
1381                 $$ =sp ;
1382                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1383         }
1384         | CLEF STRING  {
1385                 static SCM proc ;
1386                 if (!proc)
1387                         proc = scm_c_eval_string ("make-clef-set");
1388
1389                 SCM result = scm_call_1 (proc, $2);
1390                 scm_gc_protect_object (result);
1391                 $$ = unsmob_music (result);
1392         }
1393         | TIME_T fraction  {
1394                 static SCM proc;
1395                 if (!proc)
1396                         proc = scm_c_eval_string ("make-time-signature-set");
1397
1398                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1399                 scm_gc_protect_object (result);
1400                 $$ = unsmob_music (result);
1401         }
1402         | MARK scalar {
1403                 static SCM proc;
1404                 if (!proc)
1405                         proc = scm_c_eval_string ("make-mark-set");
1406
1407                 SCM result = scm_call_1 (proc, $2);
1408                 scm_gc_protect_object (result);
1409                 $$ = unsmob_music (result);
1410         }
1411         ;
1412
1413 command_req:
1414         BREATHE {
1415                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1416         }
1417         | E_TILDE {
1418                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1419         }
1420         | MARK DEFAULT  {
1421                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1422                 $$ = m;
1423         }
1424         | tempo_event {
1425                 $$ = $1;
1426         }
1427         | KEY DEFAULT {
1428                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1429                 $$ = key;
1430         }
1431         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1432
1433                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1434                 if (scm_ilength ($3) > 0)
1435                 {
1436                         key->set_mus_property ("pitch-alist", $3);
1437                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1438                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1439                 } else {
1440                         THIS->parser_error (_("Second argument must be pitch list."));
1441                 }
1442
1443                 $$ = key;
1444         }
1445         ;
1446
1447 post_events:
1448         /* empty */ {
1449                 $$ = SCM_EOL;
1450         }
1451         | post_events post_event {
1452                 $2->set_spot (THIS->here_input ());
1453                 $$ = gh_cons ($2->self_scm(), $$);
1454                 scm_gc_unprotect_object ($2->self_scm());
1455         }
1456         | post_events tagged_post_event {
1457                 $2 -> set_spot (THIS->here_input ());
1458                 $$ = scm_cons ($2->self_scm(), $$);
1459                 scm_gc_unprotect_object ($2->self_scm());
1460         }
1461         ;
1462
1463
1464 tagged_post_event:
1465         '-' TAG embedded_scm post_event {
1466                 tag_music ($4, $3, THIS->here_input ());
1467                 $$ = $4;
1468         }
1469         ;
1470
1471 post_event:
1472         direction_less_event {
1473                 $$ = $1;
1474         }
1475         | HYPHEN {
1476                 if (!THIS->lexer_->lyric_state_b ())
1477                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1478                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1479         }
1480         | EXTENDER {
1481                 if (!THIS->lexer_->lyric_state_b ())
1482                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1483                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1484         }
1485         | script_dir direction_reqd_event {
1486                 if ($1)
1487                         $2->set_mus_property ("direction", gh_int2scm ($1));
1488                 $$ = $2;
1489         }
1490         | script_dir direction_less_event {
1491                 if ($1)
1492                         $2->set_mus_property ("direction", gh_int2scm ($1));
1493                 $$ = $2;
1494         }
1495         | string_number_event
1496         ;
1497
1498 string_number_event:
1499         E_UNSIGNED {
1500                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1501                 s->set_mus_property ("string-number",  gh_int2scm($1));
1502                 s->set_spot (THIS->here_input ());
1503                 $$ = s;
1504         }
1505         ;
1506
1507
1508 direction_less_event:
1509         '['  {
1510
1511
1512 /*
1513
1514 TODO: should take all these defs out of the parser, adn make use
1515 configurable, i.e.
1516
1517
1518 (set-articulation '~ "trill")
1519
1520 */
1521                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1522                 m->set_spot (THIS->here_input());
1523                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1524                 $$ = m;
1525         }
1526         | ']'  {
1527                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1528                 m->set_spot (THIS->here_input());
1529                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1530                 $$ = m;
1531         }
1532         | '~' {
1533                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1534                 m->set_spot (THIS->here_input());
1535                 $$ = m;
1536         }
1537         | close_event {
1538                 $$ = $1;
1539                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1540                         gh_int2scm (START));
1541         }
1542         | open_event {
1543                 $$ = $1;
1544                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1545                         gh_int2scm (STOP));
1546         }
1547         | EVENT_IDENTIFIER      {
1548                 $$ = unsmob_music ($1);
1549         }
1550         | tremolo_type  {
1551                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1552                a->set_spot (THIS->here_input ());
1553                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1554                $$ = a;
1555         }
1556         ;
1557
1558 direction_reqd_event:
1559         gen_text_def {
1560                 $$ = $1;
1561         }
1562         | script_abbreviation {
1563                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1564                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1565                 if (gh_string_p (s))
1566                         a->set_mus_property ("articulation-type", s);
1567                 else THIS->parser_error (_ ("Expecting string as script definition"));
1568                 $$ = a;
1569         }
1570         ;
1571
1572 oct_check:
1573         /**/ { $$ = SCM_EOL; }
1574         | '='  { $$ = gh_int2scm (0); }
1575         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1576         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1577         ;
1578
1579 sup_quotes:
1580         '\'' {
1581                 $$ = 1;
1582         }
1583         | sup_quotes '\'' {
1584                 $$ ++;
1585         }
1586         ;
1587
1588 sub_quotes:
1589         ',' {
1590                 $$ = 1;
1591         }
1592         | sub_quotes ',' {
1593                 $$ ++ ;
1594         }
1595         ;
1596
1597 steno_pitch:
1598         NOTENAME_PITCH  {
1599                 $$ = $1;
1600         }
1601         | NOTENAME_PITCH sup_quotes     {
1602                 Pitch p = *unsmob_pitch ($1);
1603                 p = p.transposed (Pitch ($2,0,0));
1604                 $$ = p.smobbed_copy ();
1605         }
1606         | NOTENAME_PITCH sub_quotes      {
1607                 Pitch p =* unsmob_pitch ($1);
1608                 p = p.transposed (Pitch (-$2,0,0));
1609                 $$ = p.smobbed_copy ();
1610         }
1611         ;
1612
1613 /*
1614 ugh. duplication
1615 */
1616
1617 steno_tonic_pitch:
1618         TONICNAME_PITCH {
1619                 $$ = $1;
1620         }
1621         | TONICNAME_PITCH sup_quotes    {
1622                 Pitch p = *unsmob_pitch ($1);
1623                 p = p.transposed (Pitch ($2,0,0));
1624                 $$ = p.smobbed_copy ();
1625         }
1626         | TONICNAME_PITCH sub_quotes     {
1627                 Pitch p =* unsmob_pitch ($1);
1628
1629                 p = p.transposed (Pitch (-$2,0,0));
1630                 $$ = p.smobbed_copy ();
1631         }
1632         ;
1633
1634 pitch:
1635         steno_pitch {
1636                 $$ = $1;
1637         }
1638         ;
1639
1640 pitch_also_in_chords:
1641         pitch
1642         | steno_tonic_pitch
1643         ;
1644
1645 close_event:
1646         '('     {
1647                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1648                 $$ = s;
1649                 s->set_spot (THIS->here_input());
1650         }
1651         | E_OPEN        {
1652                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1653                 $$ = s;
1654                 s->set_spot (THIS->here_input());
1655         }
1656         | E_SMALLER {
1657                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1658                 $$ = s;
1659                 s->set_spot (THIS->here_input());
1660         }
1661         | E_BIGGER {
1662                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1663                 $$ = s;
1664                 s->set_spot (THIS->here_input());
1665         }
1666         ;
1667
1668
1669 open_event:
1670         E_EXCLAMATION   {
1671                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1672                 s->set_spot (THIS->here_input());
1673
1674                 $$ = s;
1675         }
1676         | ')'   {
1677                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1678                 $$ = s;
1679                 s->set_spot (THIS->here_input());
1680
1681         }
1682         | E_CLOSE       {
1683                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1684                 $$ = s;
1685                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1686                 s->set_spot (THIS->here_input());
1687         }
1688         ;
1689
1690 gen_text_def:
1691         full_markup {
1692                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1693                 t->set_mus_property ("text", $1);
1694                 t->set_spot (THIS->here_input ());
1695                 $$ = t;
1696         }
1697         | string {
1698                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1699                 t->set_mus_property ("text", make_simple_markup ($1));
1700                 t->set_spot (THIS->here_input ());
1701                 $$ = t;
1702
1703         }
1704         | DIGIT {
1705                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1706                 t->set_mus_property ("digit",  gh_int2scm ($1));
1707                 t->set_spot (THIS->here_input ());
1708                 $$ = t;
1709         }
1710         ;
1711
1712 script_abbreviation:
1713         '^'             {
1714                 $$ = scm_makfrom0str ("Hat");
1715         }
1716         | '+'           {
1717                 $$ = scm_makfrom0str ("Plus");
1718         }
1719         | '-'           {
1720                 $$ = scm_makfrom0str ("Dash");
1721         }
1722         | '|'           {
1723                 $$ = scm_makfrom0str ("Bar");
1724         }
1725         | '>'           {
1726                 $$ = scm_makfrom0str ("Larger");
1727         }
1728         | '.'           {
1729                 $$ = scm_makfrom0str ("Dot");
1730         }
1731         | '_' {
1732                 $$ = scm_makfrom0str ("Underscore");
1733         }
1734         ;
1735
1736 script_dir:
1737         '_'     { $$ = DOWN; }
1738         | '^'   { $$ = UP; }
1739         | '-'   { $$ = CENTER; }
1740         ;
1741
1742
1743 absolute_pitch:
1744         steno_pitch     {
1745                 $$ = $1;
1746         }
1747         ;
1748
1749 duration_length:
1750         multiplied_duration {
1751                 $$ = $1;
1752         }
1753         ;
1754
1755 optional_notemode_duration:
1756         {
1757                 Duration dd = THIS->default_duration_;
1758                 $$ = dd.smobbed_copy ();
1759
1760                 THIS->beam_check ($$);
1761         }
1762         | multiplied_duration   {
1763                 $$ = $1;
1764                 THIS->default_duration_ = *unsmob_duration ($$);
1765
1766                 THIS->beam_check ($$);
1767         }
1768         ;
1769
1770 steno_duration:
1771         bare_unsigned dots              {
1772                 int l = 0;
1773                 if (!is_duration_b ($1))
1774                         THIS->parser_error (_f ("not a duration: %d", $1));
1775                 else
1776                         l =  intlog2 ($1);
1777
1778                 $$ = Duration (l, $2).smobbed_copy ();
1779         }
1780         | DURATION_IDENTIFIER dots      {
1781                 Duration *d =unsmob_duration ($1);
1782                 Duration k (d->duration_log (),d->dot_count () + $2);
1783
1784                 *d = k;
1785                 $$ = $1;
1786         }
1787         ;
1788
1789
1790
1791
1792 multiplied_duration:
1793         steno_duration {
1794                 $$ = $1;
1795         }
1796         | multiplied_duration '*' bare_unsigned {
1797                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1798         }
1799         | multiplied_duration '*' FRACTION {
1800                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1801
1802                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1803         }
1804         ;
1805
1806 fraction:
1807         FRACTION { $$ = $1; }
1808         | UNSIGNED '/' UNSIGNED {
1809                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1810         }
1811         ;
1812
1813 dots:
1814         /* empty */     {
1815                 $$ = 0;
1816         }
1817         | dots '.' {
1818                 $$ ++;
1819         }
1820         ;
1821
1822
1823 tremolo_type:
1824         ':'     {
1825                 $$ =0;
1826         }
1827         | ':' bare_unsigned {
1828                 if (!is_duration_b ($2))
1829                         THIS->parser_error (_f ("not a duration: %d", $2));
1830                 $$ = $2;
1831         }
1832         ;
1833
1834
1835
1836 /*****************************************************************
1837                 BASS FIGURES
1838 *****************************************************************/
1839 bass_number:
1840         DIGIT   {
1841                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1842         }
1843         | UNSIGNED {
1844                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1845         }
1846         | STRING { $$ =  $1; }
1847         ;
1848
1849 bass_mod:
1850         '-'     { $$ = -2; }
1851         | '+'   { $$ = 2; }
1852         | '!'   { $$ = 0; }
1853         ;
1854
1855 bass_figure:
1856         FIGURE_SPACE {
1857                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1858                 $$ = bfr->self_scm();
1859                 scm_gc_unprotect_object ($$);
1860         }
1861         | bass_number  {
1862                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1863                 $$ = bfr->self_scm();
1864
1865                 bfr->set_mus_property ("figure", $1);
1866
1867                 scm_gc_unprotect_object ($$);
1868         }
1869         | bass_figure bass_mod {
1870                 Music *m = unsmob_music ($1);
1871                 if ($2) {
1872                         SCM salter =m->get_mus_property ("alteration");
1873                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1874                         m->set_mus_property ("alteration",
1875                                 gh_int2scm (alter + $2));
1876                 } else {
1877                         m->set_mus_property ("alteration", gh_int2scm (0));
1878                 }
1879         }
1880         ;
1881
1882 br_bass_figure:
1883         '[' bass_figure {
1884                 $$ = $2;
1885                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1886         }
1887         | bass_figure   {
1888                 $$ = $1;
1889         }
1890         | br_bass_figure ']' {
1891                 $$ = $1;
1892                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1893         }
1894         ;
1895
1896 figure_list:
1897         /**/            {
1898                 $$ = SCM_EOL;
1899         }
1900         | figure_list br_bass_figure {
1901                 $$ = scm_cons ($2, $1);
1902         }
1903         ;
1904
1905 figure_spec:
1906         FIGURE_OPEN figure_list FIGURE_CLOSE {
1907                 Music * m = MY_MAKE_MUSIC("EventChord");
1908                 $2 = scm_reverse_x ($2, SCM_EOL);
1909                 m->set_mus_property ("elements",  $2);
1910                 $$ = m->self_scm ();
1911         }
1912         ;
1913
1914
1915 optional_rest:
1916         /**/   { $$ = 0; }
1917         | REST { $$ = 1; }
1918         ;
1919
1920 simple_element:
1921         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1922
1923                 Input i = THIS->pop_spot ();
1924                 if (!THIS->lexer_->note_state_b ())
1925                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1926
1927                 Music *n = 0;
1928                 if ($6)
1929                         n =  MY_MAKE_MUSIC("RestEvent");
1930                 else
1931                         n =  MY_MAKE_MUSIC("NoteEvent");
1932
1933                 n->set_mus_property ("pitch", $1);
1934                 n->set_mus_property ("duration", $5);
1935
1936                 if (gh_number_p ($4))
1937                 {
1938                         int q = gh_scm2int ($4);
1939                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1940                 }
1941
1942                 if ($3 % 2)
1943                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1944                 if ($2 % 2 || $3 % 2)
1945                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1946
1947                 Music *v = MY_MAKE_MUSIC("EventChord");
1948                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1949                 scm_gc_unprotect_object (n->self_scm());
1950
1951                 v->set_spot (i);
1952                 n->set_spot (i);
1953                 $$ = v;
1954         }
1955         | DRUM_PITCH optional_notemode_duration {
1956                 Input i = THIS->pop_spot ();
1957
1958                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1959                 n->set_mus_property ("duration" ,$2);
1960                 n->set_mus_property ("drum-type" , $1);
1961
1962                 Music *v = MY_MAKE_MUSIC("EventChord");
1963                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1964                 scm_gc_unprotect_object (n->self_scm());
1965                 v->set_spot (i);
1966                 n->set_spot (i);
1967                 $$ = v;
1968
1969         }
1970         | figure_spec optional_notemode_duration {
1971                 Music * m = unsmob_music ($1);
1972                 Input i = THIS->pop_spot ();
1973                 m->set_spot (i);
1974                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
1975                 {
1976                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
1977                 }
1978                 $$ = m;
1979         }
1980         | RESTNAME optional_notemode_duration           {
1981
1982                 Input i = THIS->pop_spot ();
1983                 Music * ev = 0;
1984                 if (ly_scm2string ($1) =="s") {
1985                         /* Space */
1986                         ev = MY_MAKE_MUSIC("SkipEvent");
1987                   }
1988                 else {
1989                         ev = MY_MAKE_MUSIC("RestEvent");
1990
1991                     }
1992                 ev->set_mus_property ("duration" ,$2);
1993                 ev->set_spot (i);
1994                 Music * velt = MY_MAKE_MUSIC("EventChord");
1995                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
1996                 velt->set_spot (i);
1997
1998                 scm_gc_unprotect_object (ev->self_scm());
1999
2000                 $$ = velt;
2001         }
2002         | MULTI_MEASURE_REST optional_notemode_duration         {
2003                 THIS->pop_spot ();
2004
2005                 static SCM proc ;
2006                 if (!proc)
2007                         proc = scm_c_eval_string ("make-multi-measure-rest");
2008
2009                 SCM mus = scm_call_2 (proc, $2,
2010                         make_input (THIS->here_input()));
2011                 scm_gc_protect_object (mus);
2012                 $$ = unsmob_music (mus);
2013         }
2014
2015         | lyric_element optional_notemode_duration      {
2016                 Input i = THIS->pop_spot ();
2017                 if (!THIS->lexer_->lyric_state_b ())
2018                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2019
2020                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2021                 lreq->set_mus_property ("text", $1);
2022                 lreq->set_mus_property ("duration",$2);
2023                 lreq->set_spot (i);
2024                 Music * velt = MY_MAKE_MUSIC("EventChord");
2025                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2026
2027                 $$= velt;
2028         }
2029         | new_chord {
2030                 THIS->pop_spot ();
2031
2032                 if (!THIS->lexer_->chord_state_b ())
2033                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2034                 $$ = unsmob_music ($1);
2035         }
2036         ;
2037
2038 lyric_element:
2039         full_markup { $$ = $1; }
2040         | STRING {  $$ = $1 ; }
2041         ;
2042
2043 new_chord:
2044         steno_tonic_pitch optional_notemode_duration   {
2045                 $$ = make_chord ($1, $2, SCM_EOL);
2046         }
2047         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2048                 SCM its = scm_reverse_x ($4, SCM_EOL);
2049                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2050         }
2051         ;
2052
2053 chord_items:
2054         /**/ {
2055                 $$ = SCM_EOL;
2056         }
2057         | chord_items chord_item {
2058                 $$ = gh_cons ($2, $$);
2059         }
2060         ;
2061
2062 chord_separator:
2063         CHORD_COLON {
2064                 $$ = ly_symbol2scm ("chord-colon");
2065         }
2066         | CHORD_CARET {
2067                 $$ = ly_symbol2scm ("chord-caret");
2068         }
2069         | CHORD_SLASH steno_tonic_pitch {
2070                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2071         }
2072         | CHORD_BASS steno_tonic_pitch {
2073                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2074         }
2075         ;
2076
2077 chord_item:
2078         chord_separator {
2079                 $$ = $1;
2080         }
2081         | step_numbers {
2082                 $$ = scm_reverse_x ($1, SCM_EOL);
2083         }
2084         | CHORD_MODIFIER  {
2085                 $$ = $1;
2086         }
2087         ;
2088
2089 step_numbers:
2090         step_number { $$ = gh_cons ($1, SCM_EOL); }
2091         | step_numbers '.' step_number {
2092                 $$ = gh_cons ($3, $$);
2093         }
2094         ;
2095
2096 step_number:
2097         bare_unsigned {
2098                 $$ = make_chord_step ($1, 0);
2099         }
2100         | bare_unsigned '+' {
2101                 $$ = make_chord_step ($1, SHARP);
2102         }
2103         | bare_unsigned CHORD_MINUS {
2104                 $$ = make_chord_step ($1, FLAT);
2105         }
2106         ;
2107
2108 /*
2109         UTILITIES
2110
2111 TODO: should deprecate in favor of Scheme?
2112
2113  */
2114 number_expression:
2115         number_expression '+' number_term {
2116                 $$ = scm_sum ($1, $3);
2117         }
2118         | number_expression '-' number_term {
2119                 $$ = scm_difference ($1, $3);
2120         }
2121         | number_term
2122         ;
2123
2124 number_term:
2125         number_factor {
2126                 $$ = $1;
2127         }
2128         | number_factor '*' number_factor {
2129                 $$ = scm_product ($1, $3);
2130         }
2131         | number_factor '/' number_factor {
2132                 $$ = scm_divide ($1, $3);
2133         }
2134         ;
2135
2136 number_factor:
2137         '-'  number_factor { /* %prec UNARY_MINUS */
2138                 $$ = scm_difference ($2, SCM_UNDEFINED);
2139         }
2140         | bare_number
2141         ;
2142
2143
2144 bare_number:
2145         UNSIGNED        {
2146                 $$ = gh_int2scm ($1);
2147         }
2148         | REAL          {
2149                 $$ = $1;
2150         }
2151         | NUMBER_IDENTIFIER             {
2152                 $$ = $1;
2153         }
2154         | REAL NUMBER_IDENTIFIER        {
2155                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2156         }
2157         | UNSIGNED NUMBER_IDENTIFIER    {
2158                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2159         }
2160         ;
2161
2162
2163 bare_unsigned:
2164         UNSIGNED {
2165                         $$ = $1;
2166         }
2167         | DIGIT {
2168                 $$ = $1;
2169         }
2170         ;
2171
2172 bare_int:
2173         bare_number {
2174                 if (scm_integer_p ($1) == SCM_BOOL_T)
2175                 {
2176                         int k = gh_scm2int ($1);
2177                         $$ = k;
2178                 } else
2179                 {
2180                         THIS->parser_error (_ ("need integer number arg"));
2181                         $$ = 0;
2182                 }
2183         }
2184         | '-' bare_int {
2185                 $$ = -$2;
2186         }
2187         ;
2188
2189
2190 string:
2191         STRING          {
2192                 $$ = $1;
2193         }
2194         | STRING_IDENTIFIER     {
2195                 $$ = $1;
2196         }
2197         | string '+' string {
2198                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2199         }
2200         ;
2201
2202
2203 exclamations:
2204                 { $$ = 0; }
2205         | exclamations '!'      { $$ ++; }
2206         ;
2207
2208 questions:
2209                 { $$ = 0; }
2210         | questions '?' { $$ ++; }
2211         ;
2212
2213
2214
2215 full_markup:
2216         MARKUP_IDENTIFIER {
2217                 $$ = $1;
2218         }
2219         | MARKUP
2220                 { THIS->lexer_->push_markup_state (); }
2221         markup
2222                 { $$ = $3;
2223                   THIS->lexer_->pop_state ();
2224                 }
2225         ;
2226
2227
2228 /*
2229 This should be done more dynamically if possible.
2230 */
2231 markup:
2232         STRING {
2233                 $$ = make_simple_markup ($1);
2234         }
2235         | MARKUP_HEAD_EMPTY {
2236                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2237         }
2238         | MARKUP_HEAD_MARKUP0 markup {
2239                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2240         }
2241         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2242                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2243         }
2244         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2245                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2246         }
2247         | markup_line {
2248                 $$ = $1;
2249         }
2250         | MARKUP_HEAD_LIST0 markup_list {
2251                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2252         }
2253         | MARKUP_HEAD_SCM0 embedded_scm {
2254                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2255         }
2256         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2257                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2258         }
2259         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2260                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2261         }
2262         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2263                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2264         }
2265         | MARKUP_IDENTIFIER {
2266                 $$ = $1;
2267         }
2268
2269         ;
2270
2271 markup_list:
2272         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2273         ;
2274
2275 markup_line:
2276         '{' markup_list_body '}' {
2277                 static SCM line ;
2278                 if (!line)
2279                         line = scm_c_eval_string ("line-markup");
2280
2281                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2282         }
2283         ;
2284
2285 markup_list_body:
2286         /**/ {  $$ = SCM_EOL; }
2287         | markup_list_body markup {
2288                 $$ = gh_cons ($2, $1) ;
2289         }
2290         ;
2291
2292
2293 %%
2294
2295 void
2296 My_lily_parser::set_yydebug (bool )
2297 {
2298 #if 0
2299         yydebug = 1;
2300 #endif
2301 }
2302
2303 extern My_lily_parser * current_parser;
2304
2305 void
2306 My_lily_parser::do_yyparse ()
2307 {
2308         current_parser = this;;
2309         yyparse ((void*)this);
2310 }
2311
2312
2313 /*
2314 Should make this optional?    It will also complain when you do
2315
2316         [s4]
2317
2318 which is entirely legitimate.
2319
2320 Or we can scrap it. Barchecks should detect wrong durations, and
2321 skipTypesetting speeds it up a lot.
2322 */
2323
2324 void
2325 My_lily_parser::beam_check (SCM dur)
2326 {
2327   Duration *d = unsmob_duration (dur);
2328   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2329     {
2330       Music * m = unsmob_music (last_beam_start_);
2331       m->origin ()->warning (_("Suspect duration found following this beam"));
2332     }
2333   last_beam_start_ = SCM_EOL;
2334 }
2335
2336
2337
2338
2339 /*
2340
2341 It is a little strange to have this function in this file, but
2342 otherwise, we have to import music classes into the lexer.
2343
2344 */
2345 int
2346 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2347 {
2348         if (gh_string_p (sid)) {
2349                 *destination = sid;
2350                 return STRING_IDENTIFIER;
2351         } else if (gh_number_p (sid)) {
2352                 *destination = sid;
2353                 return NUMBER_IDENTIFIER;
2354         } else if (unsmob_context_def (sid)) {
2355                 *destination = unsmob_context_def (sid)->clone_scm();
2356                 return TRANSLATOR_IDENTIFIER;
2357         } else if (unsmob_score (sid)) {
2358                 Score *sc =  new Score (*unsmob_score (sid));
2359                 *destination =sc->self_scm ();
2360                 return SCORE_IDENTIFIER;
2361         } else if (Music * mus =unsmob_music (sid)) {
2362                 *destination = unsmob_music (sid)->clone ()->self_scm();
2363                 unsmob_music (*destination)->
2364                         set_mus_property ("origin", make_input (last_input_));
2365                 return dynamic_cast<Event*> (mus)
2366                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2367         } else if (unsmob_duration (sid)) {
2368                 *destination = unsmob_duration (sid)->smobbed_copy();
2369                 return DURATION_IDENTIFIER;
2370         } else if (unsmob_music_output_def (sid)) {
2371                 Music_output_def *p = unsmob_music_output_def (sid);
2372                 p = p->clone ();
2373
2374                 *destination = p->self_scm();
2375                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2376         } else if (Text_item::markup_p (sid)) {
2377                 *destination = sid;
2378                 return MARKUP_IDENTIFIER;
2379         }
2380
2381         return -1;
2382 }
2383
2384 Music *
2385 property_op_to_music (SCM op)
2386 {
2387         Music * m = 0;
2388         SCM tag = gh_car (op);
2389         SCM symbol  = gh_cadr (op);
2390         SCM args = gh_cddr (op);
2391         SCM grob_val = SCM_UNDEFINED;
2392         SCM grob_sym = SCM_UNDEFINED;
2393         SCM val = SCM_UNDEFINED;
2394
2395         if (tag == ly_symbol2scm ("assign"))
2396                 {
2397                 m =  MY_MAKE_MUSIC("PropertySet");
2398                 val = gh_car (args);
2399                 }
2400         else if (tag == ly_symbol2scm ("unset"))
2401                 m =  MY_MAKE_MUSIC("PropertyUnset");
2402         else if (tag == ly_symbol2scm ("poppush")
2403                  || tag == ly_symbol2scm ("push"))
2404                 {
2405                 m  = MY_MAKE_MUSIC("OverrideProperty");
2406                 grob_sym = gh_car (args);
2407                 grob_val = gh_cadr (args);
2408                 }
2409         else if (tag == ly_symbol2scm ("pop")) {
2410                 m = MY_MAKE_MUSIC("RevertProperty");
2411                 grob_sym = gh_car (args);
2412                 }
2413
2414         m->set_mus_property ("symbol", symbol);
2415
2416         if (val != SCM_UNDEFINED)
2417                 m->set_mus_property ("value", val);
2418         if (grob_val != SCM_UNDEFINED)
2419                 m->set_mus_property ("grob-value", grob_val);
2420
2421         if (grob_sym != SCM_UNDEFINED)
2422                 {
2423                 bool itc = internal_type_checking_global_b;
2424                 /* UGH.
2425                 */
2426                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2427                 if (autobeam)
2428                         internal_type_checking_global_b = false;
2429                 m->set_mus_property ("grob-property", grob_sym);
2430                 if (autobeam)
2431                         internal_type_checking_global_b = itc;
2432                 }
2433
2434         if (op == ly_symbol2scm ("poppush"))
2435                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2436
2437
2438         return m;
2439 }
2440
2441 Music*
2442 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2443 {
2444         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2445
2446         csm->set_mus_property ("element", m->self_scm ());
2447         scm_gc_unprotect_object (m->self_scm ());
2448
2449         csm->set_mus_property ("context-type", scm_string_to_symbol (type));
2450         csm->set_mus_property ("property-operations", ops);
2451
2452         if (gh_string_p (id))
2453                 csm->set_mus_property ("context-id", id);
2454         return csm;
2455 }
2456
2457
2458 SCM
2459 get_next_unique_context ()
2460 {
2461         static int new_context_count;
2462
2463         char s[1024];
2464         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2465
2466         return scm_makfrom0str (s);
2467 }
2468