lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for lilypond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13   Four shift/reduce problems:
  14
  15 1.      foo = bar.
  16
  17         "bar" -> String -> Lyric -> Music -> music-assignment
  18
  19         "bar" -> String -> string-assignment
  20
  21
  22 Similar problem for
  23
  24  * \markup identifier.
  25  * \markup { }
  26
  27
  28 2.  \repeat
  29         \repeat .. \alternative
  30
  31
  32     \repeat { \repeat .. \alternative }
  33
  34 or
  35
  36     \repeat { \repeat } \alternative
  37
  38 )
  39
  40 --hwn
  41
  42  */
  43
  44 /*
  45
  46 TODO:
  47
  48 * The rules for who is protecting what are very shady. Uniformise
  49   this.
  50
  51 * There are too many lexical modes?
  52
  53 */
  54
  55 #include <ctype.h>
  56 #include <stdlib.h>
  57 #include <stdio.h>
  58
  59
  60 #include "scm-option.hh"
  61 #include "context-def.hh"
  62 #include "lily-guile.hh"
  63 #include "misc.hh"
  64 #include "my-lily-lexer.hh"
  65 #include "paper-def.hh"
  66 #include "midi-def.hh"
  67 #include "main.hh"
  68 #include "file-path.hh"
  69 #include "warn.hh"
  70 #include "dimensions.hh"
  71 #include "my-lily-parser.hh"
  72 #include "score.hh"
  73 #include "input-file-results.hh"
  74 #include "input.hh"
  75 #include "lilypond-input-version.hh"
  76 #include "scm-hash.hh"
  77 #include "ly-modules.hh"
  78 #include "music-sequence.hh"
  79 #include "input-smob.hh"
  80 #include "event.hh"
  81 #include "text-item.hh"
  82 #include "music-list.hh"
  83
  84 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  85
  86 Music *property_op_to_music (SCM op);
  87 Music *context_spec_music (SCM type, SCM id, Music * m, SCM ops_);
  88 SCM get_next_unique_context ();
  89
  90 #define YYERROR_VERBOSE 1
  91
  92 My_lily_parser* my_lily_parser;
  93 #define YYPARSE_PARAM my_lily_parser
  94 #define YYLEX_PARAM my_lily_parser
  95 #define THIS\
  96         ((My_lily_parser *) my_lily_parser)
  97
  98 #define yyerror THIS->parser_error
  99
 100 /*
 101   Add symbols to the  TAGS field of a music object.
 102 */
 103
 104 void
 105 tag_music (Music*m,  SCM tag, Input ip)
 106 {
 107         SCM tags = m->get_mus_property ("tags");
 108         if (gh_symbol_p (tag))
 109                 tags = scm_cons (tag, tags);
 110         else if (gh_list_p (tag))
 111                 tags = gh_append2 (tag, tags);
 112         else
 113                 ip.warning (_("Tag must be symbol or list of symbols."));
 114
 115         m->set_mus_property ("tags", tags);
 116 }
 117
 118
 119
 120 bool
 121 regular_identifier_b (SCM id)
 122 {
 123   String str = ly_scm2string (id);
 124   char const *s = str.to_str0 () ;
 125
 126   bool v = true;
 127   while (*s && v)
 128    {
 129         v = v && isalpha (*s);
 130         s++;
 131    }
 132   return v;
 133 }
 134
 135 SCM
 136 make_simple_markup (SCM a)
 137 {
 138         static SCM simple;
 139         if (!simple)
 140         simple = scm_c_eval_string ("simple-markup");
 141
 142         return scm_list_n (simple, a, SCM_UNDEFINED);
 143 }
 144
 145
 146 bool
 147 is_duration_b (int t)
 148 {
 149   return t && t == 1 << intlog2 (t);
 150 }
 151
 152 void
 153 set_music_properties (Music *p, SCM a)
 154 {
 155   for (SCM k = a; gh_pair_p (k); k = ly_cdr (k))
 156         {
 157         p->internal_set_mus_property (ly_caar (k), ly_cdar (k));
 158         }
 159 }
 160
 161 SCM
 162 make_chord_step (int step, int alter)
 163 {
 164         if (step == 7)
 165                 alter += FLAT;
 166
 167         while(step < 0)
 168                 step += 7;
 169         Pitch m((step -1) / 7 , (step - 1) % 7, alter);
 170         return m.smobbed_copy ();
 171 }
 172
 173
 174 SCM
 175 make_chord (SCM pitch, SCM dur, SCM modification_list)
 176 {
 177         static SCM chord_ctor;
 178         if (!chord_ctor)
 179                 chord_ctor= scm_c_eval_string ("construct-chord");
 180         SCM ch=  scm_call_3 (chord_ctor, pitch, dur, modification_list);
 181         scm_gc_protect_object (ch);
 182         return ch;
 183 }
 184
 185 /*
 186   Todo: actually also use apply iso. call too ...
 187 */
 188 bool
 189 ly_input_procedure_p (SCM x)
 190 {
 191         return gh_procedure_p (x)
 192                 || (gh_pair_p (x) && gh_procedure_p (gh_car (x)));
 193 }
 194
 195 Music*
 196 set_property_music (SCM sym, SCM value)
 197 {
 198         Music * p = MY_MAKE_MUSIC("PropertySet");
 199         p->set_mus_property ("symbol", sym);
 200         p->set_mus_property ("value", value);
 201         return p;
 202 }
 203
 204 %}
 205
 206 /* We use SCMs to do strings, because it saves us the trouble of
 207 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 208 of the parse stack onto the heap. */
 209
 210
 211 %union {
 212         String * string;
 213     Music *music;
 214     Score *score;
 215     Music_output_def * outputdef;
 216     SCM scm;
 217     int i;
 218 }
 219 %{
 220
 221 int
 222 yylex (YYSTYPE *s,  void * v)
 223 {
 224         My_lily_parser   *pars = (My_lily_parser*) v;
 225         My_lily_lexer * lex = pars->lexer_;
 226
 227         lex->lexval = (void*) s;
 228         lex->prepare_for_next_token();
 229         return lex->yylex ();
 230 }
 231
 232
 233 %}
 234
 235 %pure_parser
 236
 237
 238 %token ACCEPTS
 239 %token ADDLYRICS
 240 %token NEWADDLYRICS
 241 %token ALIAS
 242 %token ALTERNATIVE
 243 %token APPLY
 244 %token APPLYCONTEXT
 245 %token APPLYOUTPUT
 246 %token AUTOCHANGE
 247 %token BAR
 248 %token BREATHE
 249 %token CHANGE
 250 %token CHORDMODIFIERS
 251 %token CHORDS
 252 %token LESSLESS
 253 %token MOREMORE
 254 %token CLEF
 255 %token COMMANDSPANREQUEST
 256 %token CONSISTS
 257 %token CONSISTSEND
 258 %token CONTEXT
 259 %token DEFAULT
 260 %token DENIES
 261 %token DESCRIPTION
 262 %token EXTENDER
 263 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 264 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 265 %token GRACE
 266 %token ACCIACCATURA
 267 %token APPOGGIATURA
 268 %token GROBDESCRIPTIONS
 269 %token HEADER
 270 %token HYPHEN
 271 %token INVALID
 272 %token KEY
 273 %token LYRICS
 274 %token MARK
 275 %token MIDI
 276 %token MULTI_MEASURE_REST
 277 %token NAME
 278 %token NEWCONTEXT
 279 %token NOTES
 280 %token OCTAVE
 281 %token ONCE
 282 %token OVERRIDE SET REVERT
 283 %token PAPER
 284 %token PARTCOMBINE
 285 %token PARTIAL
 286 %token RELATIVE
 287 %token REMOVE
 288 %token REPEAT
 289 %token REST
 290 %token SCM_T
 291 %token SCORE
 292 %token SEQUENTIAL
 293 %token SIMULTANEOUS
 294 %token SKIP
 295 %token SPANREQUEST
 296 %token TAG
 297 %token TEMPO
 298 %token TIMES
 299 %token TIME_T
 300 %token TRANSLATOR
 301 %token TRANSPOSE
 302 %token TYPE
 303 %token UNSET
 304 %token WITH
 305
 306 /* escaped */
 307 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 308 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 309 %token E_BACKSLASH
 310 %token <i> E_UNSIGNED
 311 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 312 %token FIGURE_SPACE
 313
 314 %type <i>       exclamations questions dots optional_rest
 315 %type <i>        bass_mod
 316 %type <scm>     grace_head
 317 %type <scm>     oct_check
 318 %type <scm>     context_mod_list
 319 %type <scm>     lyric_element
 320 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 321 %token <i>      DIGIT
 322 %token <scm>    NOTENAME_PITCH
 323 %token <scm>    TONICNAME_PITCH
 324 %token <scm>    CHORDMODIFIER_PITCH
 325 %token <scm>    DURATION_IDENTIFIER
 326 %token <scm>    FRACTION
 327 %token <id>     IDENTIFIER
 328 %token DRUMS
 329 %token <scm>    DRUM_PITCH
 330 %token <scm>    CHORD_MODIFIER
 331 %token <scm>    SCORE_IDENTIFIER
 332 %token <scm>    MUSIC_OUTPUT_DEF_IDENTIFIER
 333 %token <scm>    NUMBER_IDENTIFIER
 334 %token <scm>    EVENT_IDENTIFIER
 335 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 336 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm>    STRING
 339 %token <scm>    SCM_T
 340 %token <i>      UNSIGNED
 341 %token <scm>   REAL
 342
 343 %token MARKUP
 344 %token <scm> MARKUP_HEAD_MARKUP0
 345 %token <scm> MARKUP_HEAD_EMPTY
 346 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 347 %token <scm> MARKUP_HEAD_SCM0
 348 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 349 %token <scm> MARKUP_HEAD_SCM0_SCM1
 350 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 351 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 352
 353 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 354 %type <scm> markup markup_line markup_list  markup_list_body full_markup
 355
 356 %type <outputdef> output_def
 357 %type <scm>     lilypond_header lilypond_header_body
 358 %type <music>   open_event close_event
 359 %type <i>       sub_quotes sup_quotes
 360 %type <music>   simple_element  event_chord command_element Simple_music  Composite_music
 361 %type <music>   Repeated_music
 362 %type <scm>     Alternative_music
 363 %type <i>       tremolo_type
 364 %type <i>       bare_int  bare_unsigned
 365 %type <i>       script_dir
 366 %type <scm>     identifier_init
 367
 368 %type <music> note_chord_element chord_body chord_body_element
 369 %type <scm>  chord_body_elements
 370 %type <scm> steno_duration optional_notemode_duration multiplied_duration
 371
 372 %type <scm>   post_events
 373 %type <music> gen_text_def direction_less_event direction_reqd_event
 374 %type <scm>   steno_pitch pitch absolute_pitch pitch_also_in_chords
 375 %type <scm>    steno_tonic_pitch
 376 %type <scm>     duration_length fraction
 377
 378 %type <scm> new_chord step_number chord_items chord_item chord_separator step_numbers
 379
 380 %type <scm>  embedded_scm scalar
 381 %type <music>   Music Sequential_music Simultaneous_music
 382 %type <music>   relative_music re_rhythmed_music
 383 %type <music>   music_property_def context_change
 384 %type <scm> context_prop_spec
 385 %type <scm> Music_list
 386 %type <scm> property_operation context_mod translator_mod optional_context_mod
 387 %type <outputdef>  music_output_def_body music_output_def_head
 388 %type <music>   post_event tagged_post_event
 389 %type <music> command_req
 390 %type <music> string_number_event
 391 %type <scm>     string bare_number number_expression number_term number_factor
 392 %type <score>   score_block score_body
 393
 394 %type <scm>     translator_spec_block translator_spec_body
 395 %type <music>   tempo_event
 396 %type <scm>     script_abbreviation
 397
 398
 399
 400 %left '-' '+'
 401
 402 /* We don't assign precedence to / and *, because we might need varied
 403 prec levels in different prods */
 404
 405 %left UNARY_MINUS
 406
 407 %%
 408
 409 lilypond:       /* empty */
 410         | lilypond toplevel_expression {}
 411         | lilypond assignment  { }
 412         | lilypond error {
 413                 THIS->error_level_  = 1;
 414         }
 415         | lilypond INVALID      {
 416                 THIS->error_level_  = 1;
 417         }
 418         ;
 419
 420 toplevel_expression:
 421         lilypond_header {
 422                 THIS->input_file_->header_ = $1;
 423         }
 424         | score_block {
 425                 Score * sc = $1;
 426
 427                 SCM head = ly_module_p (sc->header_) ? sc->header_ : THIS->input_file_->header_.to_SCM ();
 428
 429                 Path p = split_path (THIS->output_basename_);
 430                 int *c =  &THIS->input_file_->score_count_;
 431                 if (*c)
 432                         {
 433                         p.base += "-" + to_string (*c);
 434                         }
 435
 436                 (*c)++;
 437                 SCM outname = scm_makfrom0str (p.to_string ().to_str0());
 438
 439                 for (int i=0; i < sc->defs_.size (); i++)
 440                         default_rendering (sc->music_, sc->defs_[i]->self_scm(),head, outname);
 441
 442                 if (sc->defs_.is_empty ())
 443                 {
 444                    Music_output_def *id =
 445                         unsmob_music_output_def (THIS->lexer_->lookup_identifier
 446                                 ("$defaultpaper"));
 447
 448                    id = id ? id->clone () : new Paper_def;
 449
 450                    default_rendering (sc->music_, id->self_scm(), head, outname);
 451
 452                    scm_gc_unprotect_object (id->self_scm ());
 453                 }
 454                 scm_gc_unprotect_object (sc->self_scm());
 455         }
 456         | output_def {
 457                 SCM id = SCM_EOL;
 458                 if (dynamic_cast<Paper_def*> ($1))
 459                         id = scm_makfrom0str ("$defaultpaper");
 460                 else if (dynamic_cast<Midi_def*> ($1))
 461                         id = scm_makfrom0str ("$defaultmidi");
 462                 THIS->lexer_->set_identifier (id,   $1->self_scm ());
 463                 scm_gc_unprotect_object ($1->self_scm ());
 464         }
 465         ;
 466
 467 embedded_scm:
 468         SCM_T
 469         | SCM_IDENTIFIER
 470         ;
 471
 472
 473
 474
 475 lilypond_header_body:
 476         {
 477                 $$ = ly_make_anonymous_module ();
 478                 THIS->lexer_->add_scope ($$);
 479         }
 480         | lilypond_header_body assignment  {
 481
 482         }
 483         ;
 484
 485 lilypond_header:
 486         HEADER '{' lilypond_header_body '}'     {
 487                 $$ = THIS->lexer_-> remove_scope();
 488         }
 489         ;
 490
 491
 492 /*
 493         DECLARATIONS
 494 */
 495 assignment:
 496         STRING {
 497                 THIS->push_spot ();
 498         }
 499         /* cont */ '=' identifier_init  {
 500
 501         /*
 502                 Should find generic way of associating input with objects.
 503         */
 504                 Input ip = THIS->pop_spot ();
 505
 506                 if (! regular_identifier_b ($1))
 507                 {
 508                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 509                 }
 510
 511                 THIS->lexer_->set_identifier ($1, $4);
 512
 513 /*
 514  TODO: devise standard for protection in parser.
 515
 516   The parser stack lives on the C-stack, which means that
 517 all objects can be unprotected as soon as they're here.
 518
 519 */
 520         }
 521         | embedded_scm { }
 522         ;
 523
 524
 525 identifier_init:
 526         score_block {
 527                 $$ = $1->self_scm ();
 528                 scm_gc_unprotect_object ($$);
 529         }
 530         | full_markup {
 531                 $$ = $1;
 532         }
 533         | output_def {
 534                 $$ = $1->self_scm ();
 535                 scm_gc_unprotect_object ($$);
 536         }
 537         | translator_spec_block {
 538                 $$ = $1;
 539         }
 540         | Music  {
 541                 $$ = $1->self_scm ();
 542                 scm_gc_unprotect_object ($$);
 543         }
 544         | post_event {
 545                 $$ = $1->self_scm ();
 546                 scm_gc_unprotect_object ($$);
 547         }
 548         | number_expression {
 549                 $$ = $1;
 550         }
 551         | string {
 552                 $$ = $1;
 553         }
 554         | embedded_scm  {
 555                 $$ = $1;
 556         }
 557         ;
 558
 559 translator_spec_block:
 560         TRANSLATOR '{' translator_spec_body '}'
 561                 {
 562                 $$ = $3;
 563         }
 564         ;
 565
 566 translator_spec_body:
 567         /**/ {
 568                 $$ = Context_def::make_scm ();
 569                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 570         }
 571         | TRANSLATOR_IDENTIFIER {
 572                 $$ = $1;
 573                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 574         }
 575         | translator_spec_body GROBDESCRIPTIONS embedded_scm {
 576                 Context_def*td = unsmob_context_def($$);
 577
 578                 for (SCM p = $3; gh_pair_p (p); p = ly_cdr (p)) {
 579                         SCM tag = gh_caar (p);
 580
 581                         /* TODO: should make new tag "grob-definition" ? */
 582                         td->add_context_mod (scm_list_n (ly_symbol2scm ("assign"),
 583                                                         tag, gh_cons (ly_cdar (p), SCM_EOL), SCM_UNDEFINED));
 584                 }
 585         }
 586         | translator_spec_body context_mod {
 587                 unsmob_context_def ($$)->add_context_mod ($2);
 588         }
 589         ;
 590
 591 /*
 592         SCORE
 593 */
 594 score_block:
 595         SCORE {
 596                 THIS->push_spot ();
 597         }
 598         /*cont*/ '{' score_body '}'     {
 599                 THIS->pop_spot ();
 600                 $$ = $4;
 601
 602         }
 603         ;
 604
 605 score_body:
 606         Music   {
 607                 $$ = new Score;
 608
 609                 $$->set_spot (THIS->here_input ());
 610                 SCM m = $1->self_scm ();
 611                 scm_gc_unprotect_object (m);
 612
 613                 /*
 614                         guh.
 615                 */
 616                 SCM check_funcs = scm_c_eval_string ("toplevel-music-functions");
 617                 for (; gh_pair_p (check_funcs); check_funcs = gh_cdr (check_funcs))
 618                         m = gh_call1 (gh_car (check_funcs), m);
 619                 $$->music_ = m;
 620
 621         }
 622         | SCORE_IDENTIFIER {
 623                 $$ = new Score ( *unsmob_score ($1));
 624                 $$->set_spot (THIS->here_input ());
 625         }
 626         | score_body lilypond_header    {
 627                 $$->header_ = $2;
 628         }
 629         | score_body output_def {
 630                 $$->defs_.push ($2);
 631                 scm_gc_unprotect_object ($2->self_scm ());
 632         }
 633         | score_body error {
 634
 635         }
 636         ;
 637
 638
 639 /*
 640         MIDI
 641 */
 642 output_def:
 643         music_output_def_body '}' {
 644                 $$ = $1;
 645                 THIS-> lexer_-> remove_scope ();
 646         }
 647         ;
 648
 649 music_output_def_head:
 650         MIDI    {
 651                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultmidi"));
 652
 653
 654                 Midi_def* p =0;
 655                 if (id)
 656                         p = dynamic_cast<Midi_def*> (id->clone ());
 657                 else
 658                         p = new Midi_def;
 659
 660                 $$ = p;
 661                 THIS->lexer_->add_scope (p->scope_);
 662         }
 663         | PAPER         {
 664                 Music_output_def *id = unsmob_music_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"));
 665                   Paper_def *p = 0;
 666                 if (id)
 667                         p = dynamic_cast<Paper_def*> (id->clone ());
 668                 else
 669                         p = new Paper_def;
 670
 671                 THIS->lexer_->add_scope (p->scope_);
 672                 $$ = p;
 673         }
 674         ;
 675
 676
 677 music_output_def_body:
 678         music_output_def_head '{' {
 679
 680         }
 681         | music_output_def_head '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 682                 scm_gc_unprotect_object ($1->self_scm ());
 683                 Music_output_def * o =  unsmob_music_output_def ($3);
 684                 $$ = o;
 685                 THIS->lexer_->remove_scope ();
 686                 THIS->lexer_->add_scope (o->scope_);
 687         }
 688         | music_output_def_body assignment  {
 689
 690         }
 691         | music_output_def_body translator_spec_block   {
 692                 $$->assign_translator ($2);
 693         }
 694         | music_output_def_body tempo_event  {
 695                 /*
 696                         junk this ? there already is tempo stuff in
 697                         music.
 698                 */
 699                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 700                 Duration *d = unsmob_duration ($2->get_mus_property ("tempo-unit"));
 701                 Midi_def * md = dynamic_cast<Midi_def*> ($$);
 702                 if (md)
 703                         md->set_tempo (d->get_length (), m);
 704                 scm_gc_unprotect_object ($2->self_scm ());
 705         }
 706         | music_output_def_body error {
 707
 708         }
 709         ;
 710
 711 tempo_event:
 712         TEMPO steno_duration '=' bare_unsigned  {
 713                 $$ = MY_MAKE_MUSIC("MetronomeChangeEvent");
 714                 $$->set_mus_property ("tempo-unit", $2);
 715                 $$->set_mus_property ("metronome-count", gh_int2scm ( $4));
 716         }
 717         ;
 718
 719 /*
 720 The representation of a  list is the
 721
 722   (LIST . LAST-CONS)
 723
 724  to have  efficient append.
 725 */
 726 Music_list:
 727         /* empty */ {
 728                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 729         }
 730         | Music_list Music {
 731                 SCM s = $$;
 732                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 733                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 734                 if (gh_pair_p (ly_cdr (s)))
 735                         gh_set_cdr_x (ly_cdr (s), c); /* append */
 736                 else
 737                         gh_set_car_x (s, c); /* set first cons */
 738                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 739         }
 740         | Music_list error {
 741         }
 742         ;
 743
 744
 745 Music:
 746         Simple_music
 747         | Composite_music
 748         ;
 749
 750 Alternative_music:
 751         /* empty */ {
 752                 $$ = SCM_EOL;
 753         }
 754         | ALTERNATIVE '{' Music_list '}' {
 755                 $$ = $3;
 756         }
 757         ;
 758
 759 Repeated_music:
 760         REPEAT string bare_unsigned Music Alternative_music
 761         {
 762                 Music *beg = $4;
 763                 int times = $3;
 764                 SCM alts = gh_pair_p ($5) ? gh_car ($5) : SCM_EOL;
 765                 if (times < scm_ilength (alts)) {
 766                   unsmob_music (gh_car (alts))
 767                     ->origin ()->warning (
 768                     _("More alternatives than repeats.  Junking excess alternatives."));
 769                   alts = ly_truncate_list (times, alts);
 770                 }
 771
 772
 773                 static SCM proc;
 774                 if (!proc)
 775                         proc = scm_c_eval_string ("make-repeated-music");
 776
 777                 SCM mus = scm_call_1 (proc, $2);
 778                 scm_gc_protect_object (mus); // UGH.
 779                 Music *r =unsmob_music (mus);
 780                 if (beg)
 781                         {
 782                         r-> set_mus_property ("element", beg->self_scm ());
 783                         scm_gc_unprotect_object (beg->self_scm ());
 784                         }
 785                 r->set_mus_property ("repeat-count", gh_int2scm (times >? 1));
 786
 787                 r-> set_mus_property ("elements",alts);
 788                 if (gh_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 789                         /*
 790                         we can not get durations and other stuff correct down the line, so we have to
 791                         add to the duration log here.
 792                         */
 793                         static SCM func;
 794
 795                         if (!func)
 796                                 func = scm_primitive_eval (ly_symbol2scm ("shift-duration-log"));
 797
 798                         int dots = ($3 % 3) ? 0 : 1;
 799                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 800
 801                         Sequential_music * seq = dynamic_cast<Sequential_music*> ($4);
 802
 803                         if (seq) {
 804                                 int list_len =scm_ilength (seq->music_list ());
 805                                 if (list_len != 2)
 806                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 807                                 shift -= 1;
 808                                 r->compress (Moment (Rational (1,list_len)));
 809                                 }
 810                         gh_call3 (func, r->self_scm (), gh_int2scm(shift),gh_int2scm(dots));
 811
 812                 }
 813                 r->set_spot (*$4->origin ());
 814
 815                 $$ = r;
 816         }
 817         ;
 818
 819 Sequential_music:
 820         SEQUENTIAL '{' Music_list '}'           {
 821                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 822                 $$->set_mus_property ("elements", ly_car ($3));
 823                 $$->set_spot(THIS->here_input());
 824         }
 825         | '{' Music_list '}'            {
 826                 $$ = MY_MAKE_MUSIC("SequentialMusic");
 827                 $$->set_mus_property ("elements", ly_car ($2));
 828                 $$->set_spot(THIS->here_input());
 829         }
 830         ;
 831
 832 Simultaneous_music:
 833         SIMULTANEOUS '{' Music_list '}'{
 834                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 835                 $$->set_mus_property ("elements", ly_car ($3));
 836                 $$->set_spot(THIS->here_input());
 837
 838         }
 839         | simul_open Music_list simul_close     {
 840                 $$ = MY_MAKE_MUSIC("SimultaneousMusic");
 841                 $$->set_mus_property ("elements", ly_car ($2));
 842                 $$->set_spot(THIS->here_input());
 843         }
 844         ;
 845
 846 Simple_music:
 847         event_chord             { $$ = $1; }
 848         | APPLYOUTPUT embedded_scm {
 849                 if (!ly_input_procedure_p ($2))
 850                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 851                 $$ = MY_MAKE_MUSIC ("ApplyOutputEvent");
 852                 $$->set_mus_property ("procedure", $2);
 853                 $$->set_spot (THIS->here_input());
 854         }
 855         | APPLYCONTEXT embedded_scm {
 856                 if (!ly_input_procedure_p ($2))
 857                         THIS->parser_error (_ ("\\applycontext takes function argument"));
 858                 $$ = MY_MAKE_MUSIC ("ApplyContext");
 859                 $$->set_mus_property ("procedure", $2);
 860                 $$->set_spot (THIS->here_input());
 861         }
 862         | MUSIC_IDENTIFIER {
 863                 $$ = unsmob_music ($1);
 864         }
 865         | music_property_def
 866         | context_change
 867         ;
 868
 869
 870 optional_context_mod:
 871         /**/ { $$ = SCM_EOL; }
 872         | WITH '{' context_mod_list '}'  { $$ = $3; }
 873         ;
 874
 875 grace_head:
 876         GRACE  { $$ = scm_makfrom0str ("Grace"); }
 877         | ACCIACCATURA { $$ = scm_makfrom0str ("Acciaccatura"); }
 878         | APPOGGIATURA { $$ = scm_makfrom0str ("Appoggiatura"); }
 879         ;
 880
 881 context_mod_list:
 882         /* */  { $$ = SCM_EOL; }
 883         | context_mod_list context_mod  {
 884                  $$ = gh_cons ($2, $1);
 885         }
 886         ;
 887
 888 Composite_music:
 889         AUTOCHANGE Music        {
 890                 static SCM proc ;
 891                 if (!proc)
 892                         proc = scm_c_eval_string ("make-autochange-music");
 893
 894                 SCM res = scm_call_1 (proc,  $2->self_scm ());
 895                 scm_gc_unprotect_object ($2->self_scm ());
 896                 $$ = unsmob_music (res);
 897                 scm_gc_protect_object (res);
 898                 $$->set_spot (THIS->here_input());
 899         }
 900         | PARTCOMBINE Music Music {
 901                 static SCM proc;
 902                 if (!proc)
 903                         proc = scm_c_eval_string ("make-part-combine-music");
 904
 905                 SCM res = scm_call_1 (proc, gh_list ($2->self_scm (),
 906                         $3->self_scm (), SCM_UNDEFINED));
 907                 scm_gc_unprotect_object ($3->self_scm ());
 908                 scm_gc_unprotect_object ($2->self_scm ());
 909                 $$ = unsmob_music (res);
 910                 scm_gc_protect_object (res);
 911                 $$->set_spot (THIS->here_input());
 912         }
 913         | grace_head Music {
 914 #if 1
 915         /*
 916                 The other version is for easier debugging  of
 917                 Sequential_music_iterator in combination with grace notes.
 918         */
 919
 920 /*
 921
 922 TODO: should distinguish between both grace types in the
 923 basic music objects too, since the meaning is different.
 924
 925 */
 926
 927                 String start_str = "start" + ly_scm2string ($1) + "Music";
 928                 String stop_str = "stop" + ly_scm2string ($1) + "Music";
 929
 930                 SCM start = THIS->lexer_->lookup_identifier (start_str);
 931                 SCM stop = THIS->lexer_->lookup_identifier (stop_str);
 932
 933                 Music *startm = unsmob_music (start);
 934                 Music *stopm = unsmob_music (stop);
 935
 936                 SCM ms = SCM_EOL;
 937                 if (stopm) {
 938                         stopm = stopm->clone ();
 939                         ms = scm_cons (stopm->self_scm (), ms);
 940                         scm_gc_unprotect_object (stopm->self_scm ());
 941                 }
 942                 ms = scm_cons ($2->self_scm (), ms);
 943                 scm_gc_unprotect_object ($2->self_scm());
 944                 if (startm) {
 945                         startm = startm->clone ();
 946                         ms = scm_cons (startm->self_scm () , ms);
 947                         scm_gc_unprotect_object (startm->self_scm ());
 948                 }
 949
 950                 Music* seq = MY_MAKE_MUSIC("SequentialMusic");
 951                 seq->set_mus_property ("elements", ms);
 952
 953
 954                 $$ = MY_MAKE_MUSIC("GraceMusic");
 955                 $$->set_mus_property ("element", seq->self_scm ());
 956                 scm_gc_unprotect_object (seq->self_scm ());
 957 #else
 958                 $$ = MY_MAKE_MUSIC("GraceMusic");
 959                 $$->set_mus_property ("element", $2->self_scm ());
 960                 scm_gc_unprotect_object ($2->self_scm ());
 961 #endif
 962         }
 963         | CONTEXT string '=' string optional_context_mod Music {
 964                 $$ = context_spec_music ($2, $4, $6, $5);
 965
 966         }
 967         | CONTEXT STRING optional_context_mod Music {
 968                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
 969         }
 970         | NEWCONTEXT string optional_context_mod Music {
 971                 $$ = context_spec_music ($2, get_next_unique_context (),
 972                                          $4, $3);
 973         }
 974
 975         | TIMES {
 976                 THIS->push_spot ();
 977         }
 978         /* CONTINUED */
 979                 fraction Music
 980
 981         {
 982                 int n = gh_scm2int (ly_car ($3)); int d = gh_scm2int (ly_cdr ($3));
 983                 Music *mp = $4;
 984
 985                 $$= MY_MAKE_MUSIC("TimeScaledMusic");
 986                 $$->set_spot (THIS->pop_spot ());
 987
 988                 $$->set_mus_property ("element", mp->self_scm ());
 989                 scm_gc_unprotect_object (mp->self_scm ());
 990                 $$->set_mus_property ("numerator", gh_int2scm (n));
 991                 $$->set_mus_property ("denominator", gh_int2scm (d));
 992                 $$->compress (Moment (Rational (n,d)));
 993
 994         }
 995         | Repeated_music                { $$ = $1; }
 996         | Simultaneous_music            { $$ = $1; }
 997         | Sequential_music              { $$ = $1; }
 998         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
 999                 $$ = MY_MAKE_MUSIC("TransposedMusic");
1000                 Music *p = $4;
1001                 Pitch from = *unsmob_pitch ($2);
1002                 Pitch to = *unsmob_pitch ($3);
1003
1004                 p->transpose (interval (from, to));
1005                 $$->set_mus_property ("element", p->self_scm ());
1006                 scm_gc_unprotect_object (p->self_scm ());
1007         }
1008         | APPLY embedded_scm Music  {
1009                 if (!ly_input_procedure_p ($2))
1010                         {
1011                         THIS->parser_error (_ ("\\apply takes function argument"));
1012                         $$ = $3;
1013                         }
1014                 else
1015                         {
1016                         SCM ret = gh_call1 ($2, $3->self_scm ());
1017                         Music *m = unsmob_music (ret);
1018                         if (!m) {
1019                                 THIS->parser_error ("\\apply must return a Music");
1020                                 m = MY_MAKE_MUSIC("Music");
1021                                 }
1022                         $$ = m;
1023                         }
1024         }
1025         | NOTES
1026                 {
1027                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1028                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1029         }
1030         Music
1031                 { $$ = $3;
1032                   THIS->lexer_->pop_state ();
1033                 }
1034         | DRUMS
1035                 {
1036                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1037                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1038         }
1039         Music
1040                 { $$ = $3;
1041                   THIS->lexer_->pop_state ();
1042                 }
1043         | FIGURES
1044                 { THIS->lexer_->push_figuredbass_state (); }
1045         Music
1046                 {
1047                   Music * chm = MY_MAKE_MUSIC("UntransposableMusic");
1048                   chm->set_mus_property ("element", $3->self_scm ());
1049                   $$ = chm;
1050                   scm_gc_unprotect_object ($3->self_scm());
1051
1052                   THIS->lexer_->pop_state ();
1053         }
1054         | CHORDS {
1055                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1056                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1057                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1058                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1059
1060         } Music {
1061                   Music * chm = MY_MAKE_MUSIC("UnrelativableMusic");
1062                   chm->set_mus_property ("element", $3->self_scm ());
1063                   scm_gc_unprotect_object ($3->self_scm());
1064                   $$ = chm;
1065
1066                   THIS->lexer_->pop_state ();
1067         }
1068         | LYRICS
1069                 { THIS->lexer_->push_lyric_state (); }
1070         Music
1071                 {
1072                   $$ = $3;
1073                   THIS->lexer_->pop_state ();
1074         }
1075         | relative_music        { $$ = $1; }
1076         | re_rhythmed_music     { $$ = $1; }
1077         | TAG embedded_scm Music {
1078                 tag_music ($3, $2, THIS->here_input ());
1079                 $$ = $3;
1080         }
1081         ;
1082
1083 relative_music:
1084         RELATIVE absolute_pitch Music {
1085                 Music * p = $3;
1086                 Pitch pit = *unsmob_pitch ($2);
1087                 $$ = MY_MAKE_MUSIC("RelativeOctaveMusic");
1088
1089                 $$->set_mus_property ("element", p->self_scm ());
1090                 scm_gc_unprotect_object (p->self_scm ());
1091
1092
1093                 Pitch retpitch = p->to_relative_octave (pit);
1094                 if (lily_1_8_relative)
1095                         $$->set_mus_property ("last-pitch", retpitch.smobbed_copy ());
1096         }
1097         ;
1098
1099 re_rhythmed_music:
1100         ADDLYRICS Music Music {
1101         Music*l =MY_MAKE_MUSIC("LyricCombineMusic");
1102           l->set_mus_property ("elements", gh_list ($2->self_scm (), $3->self_scm (), SCM_UNDEFINED));
1103           scm_gc_unprotect_object ($3->self_scm ());
1104           scm_gc_unprotect_object ($2->self_scm ());
1105           $$ = l;
1106         }
1107         | NEWADDLYRICS string Music {
1108           Music*l =MY_MAKE_MUSIC("NewLyricCombineMusic");
1109           l->set_mus_property ("element", $3->self_scm ());
1110           scm_gc_unprotect_object ($3->self_scm ());
1111           $$ = l;
1112           l->set_mus_property ("associated-context", $2);
1113         }
1114         ;
1115
1116 context_change:
1117         CHANGE STRING '=' STRING  {
1118                 Music*t= MY_MAKE_MUSIC("TranslatorChange");
1119                 t-> set_mus_property ("change-to-type", scm_string_to_symbol ($2));
1120                 t-> set_mus_property ("change-to-id", $4);
1121
1122                 $$ = t;
1123                 $$->set_spot (THIS->here_input ());
1124         }
1125         ;
1126
1127 property_operation:
1128         STRING '='  scalar {
1129                 $$ = scm_list_n (ly_symbol2scm ("assign"),
1130                         scm_string_to_symbol ($1), $3, SCM_UNDEFINED);
1131         }
1132         | UNSET STRING {
1133                 $$ = scm_list_n (ly_symbol2scm ("unset"),
1134                         scm_string_to_symbol ($2), SCM_UNDEFINED);
1135         }
1136         | OVERRIDE STRING embedded_scm '=' embedded_scm {
1137                 $$ = scm_list_n (ly_symbol2scm ("push"),
1138                         scm_string_to_symbol ($2), $3, $5, SCM_UNDEFINED);
1139         }
1140         | REVERT STRING embedded_scm {
1141                 $$ = scm_list_n (ly_symbol2scm ("pop"),
1142                         scm_string_to_symbol ($2), $3, SCM_UNDEFINED);
1143         }
1144         ;
1145
1146 translator_mod:
1147         CONSISTSEND { $$ = ly_symbol2scm ("consists-end"); }
1148         | CONSISTS { $$ = ly_symbol2scm ("consists"); }
1149         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1150
1151         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1152         | DENIES { $$ = ly_symbol2scm ("denies"); }
1153
1154         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1155         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1156         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1157         | NAME { $$ = ly_symbol2scm ("context-name"); }
1158         ;
1159
1160 context_mod:
1161         property_operation { $$ = $1; }
1162         | translator_mod STRING {
1163                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
1164         }
1165         ;
1166
1167 context_prop_spec:
1168         STRING  {
1169                 $$ = scm_list_n (ly_symbol2scm ("Bottom"), scm_string_to_symbol ($1), SCM_UNDEFINED);
1170         }
1171         | STRING '.' STRING {
1172                 $$ = scm_list_n (scm_string_to_symbol ($1), scm_string_to_symbol ($3), SCM_UNDEFINED);
1173         }
1174         ;
1175
1176 music_property_def:
1177         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1178                 $$ = property_op_to_music (scm_list_n (
1179                         ly_symbol2scm ("poppush"),
1180                         gh_cadr ($2),
1181                         $3, $5, SCM_UNDEFINED));
1182                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1183         }
1184         | REVERT context_prop_spec embedded_scm {
1185                 $$ = property_op_to_music (scm_list_n (
1186                         ly_symbol2scm ("pop"),
1187                         gh_cadr ($2),
1188                         $3, SCM_UNDEFINED));
1189
1190                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1191         }
1192         | SET context_prop_spec '=' scalar {
1193                 $$ = property_op_to_music (scm_list_n (
1194                         ly_symbol2scm ("assign"),
1195                         gh_cadr ($2),
1196                         $4, SCM_UNDEFINED));
1197                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1198         }
1199         | UNSET context_prop_spec {
1200                 $$ = property_op_to_music (scm_list_n (
1201                         ly_symbol2scm ("unset"),
1202                         gh_cadr ($2)));
1203                 $$= context_spec_music (gh_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1204         }
1205         | ONCE music_property_def {
1206                 SCM e = $2->get_mus_property ("element");
1207                 unsmob_music (e)->set_mus_property ("once", SCM_BOOL_T);
1208                 $$ = $2;
1209
1210         }
1211         ;
1212
1213
1214
1215 scalar:
1216         string          { $$ = $1; }
1217         | bare_int      { $$ = gh_int2scm ($1); }
1218         | embedded_scm  { $$ = $1; }
1219         | full_markup {  $$ = $1; }
1220         | DIGIT { $$ = gh_int2scm ($1); }
1221         ;
1222
1223 /*
1224 This is a trick:
1225
1226 Adding pre_events to the simple_element
1227 makes the choice between
1228
1229   string:  STRING
1230
1231 and
1232
1233   simple_element: STRING
1234
1235 a single shift/reduction conflict.
1236
1237 nevertheless, this is not very clean, and we should find a different
1238 solution.
1239
1240 */
1241 pre_events: {
1242                 THIS->push_spot ();
1243         }
1244         ;
1245
1246 event_chord:
1247         pre_events simple_element post_events   {
1248                 SCM elts = $2-> get_mus_property ("elements");
1249
1250                 elts = gh_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1251
1252                 $2->set_mus_property ("elements", elts);
1253                 $$ = $2;
1254         }
1255         | command_element
1256         | note_chord_element
1257         ;
1258
1259
1260 note_chord_element:
1261         chord_body optional_notemode_duration post_events
1262         {
1263                 SCM dur = unsmob_duration ($2)->smobbed_copy();
1264                 SCM es = $1->get_mus_property ("elements");
1265                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1266
1267                 for (SCM s = es; gh_pair_p (s); s = gh_cdr (s))
1268                   unsmob_music (gh_car(s))->set_mus_property ("duration", dur);
1269                 es = gh_append2 (es, postevs);
1270
1271                 $1-> set_mus_property ("elements", es);
1272                 $$ = $1;
1273         }
1274         ;
1275
1276 chord_open: '<'
1277         ;
1278
1279 chord_close: '>'
1280         ;
1281
1282 simul_open: LESSLESS
1283         ;
1284
1285 simul_close: MOREMORE
1286         ;
1287
1288 chord_body:
1289         chord_open chord_body_elements chord_close
1290         {
1291                 $$ = MY_MAKE_MUSIC("EventChord");
1292                 $$->set_mus_property ("elements",
1293                         scm_reverse_x ($2, SCM_EOL));
1294         }
1295         ;
1296
1297 chord_body_elements:
1298         /* empty */             { $$ = SCM_EOL; }
1299         | chord_body_elements chord_body_element {
1300                 $$ = gh_cons ($2->self_scm(), $1);
1301                 scm_gc_unprotect_object ($2->self_scm());
1302         }
1303         ;
1304
1305 chord_body_element:
1306         pitch exclamations questions post_events
1307         {
1308                 Music * n = MY_MAKE_MUSIC("NoteEvent");
1309                 n->set_mus_property ("pitch", $1);
1310                 if ($3 % 2)
1311                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1312                 if ($2 % 2 || $3 % 2)
1313                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1314
1315                 if (gh_pair_p ($4)) {
1316                         SCM arts = scm_reverse_x ($4, SCM_EOL);
1317                         n->set_mus_property ("articulations", arts);
1318                 }
1319                 $$ = n;
1320         }
1321         | DRUM_PITCH post_events {
1322                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1323                 n->set_mus_property ("duration" ,$2);
1324                 n->set_mus_property ("drum-type" , $1);
1325                 n->set_spot (THIS->here_input());
1326
1327                 if (gh_pair_p ($2)) {
1328                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1329                         n->set_mus_property ("articulations", arts);
1330                 }
1331                 $$ = n;
1332         }
1333         ;
1334
1335 command_element:
1336         command_req {
1337                 $$ = MY_MAKE_MUSIC("EventChord");
1338                 $$->set_mus_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1339                 scm_gc_unprotect_object ($1->self_scm());
1340
1341                 $$-> set_spot (THIS->here_input ());
1342                 $1-> set_spot (THIS->here_input ());
1343         }
1344         | SKIP duration_length {
1345                 Music * skip = MY_MAKE_MUSIC("SkipMusic");
1346                 skip->set_mus_property ("duration", $2);
1347
1348                 $$ = skip;
1349         }
1350         | OCTAVE { THIS->push_spot (); }
1351           pitch {
1352                 Music *l = MY_MAKE_MUSIC("RelativeOctaveCheck");
1353                 $$ = l;
1354                 $$->set_spot (THIS->pop_spot ());
1355                 $$->set_mus_property ("pitch", $3);
1356         }
1357         | E_LEFTSQUARE {
1358                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1359                 l->set_mus_property ("span-direction", gh_int2scm (START));
1360                 l->set_spot (THIS->here_input ());
1361
1362                 $$ = MY_MAKE_MUSIC("EventChord");
1363                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1364                 scm_gc_unprotect_object (l->self_scm());
1365                 $$->set_spot (THIS->here_input ());
1366         }
1367         | E_RIGHTSQUARE {
1368                 Music *l = MY_MAKE_MUSIC("LigatureEvent");
1369                 l->set_mus_property ("span-direction", gh_int2scm (STOP));
1370                 l->set_spot (THIS->here_input ());
1371
1372                 $$ = MY_MAKE_MUSIC("EventChord");
1373                 $$->set_mus_property ("elements", scm_cons (l->self_scm (), SCM_EOL));
1374                 $$->set_spot (THIS->here_input ());
1375                 scm_gc_unprotect_object (l->self_scm());
1376         }
1377         | E_BACKSLASH {
1378                 $$ = MY_MAKE_MUSIC("VoiceSeparator");
1379                 $$->set_spot (THIS->here_input ());
1380         }
1381         | '|'      {
1382
1383                 $$ = MY_MAKE_MUSIC("BarCheck");
1384                 $$->set_spot (THIS->here_input ());
1385         }
1386         | BAR STRING                    {
1387                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1388
1389                 Music *csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
1390                 csm->set_mus_property ("element", t->self_scm ());
1391                 scm_gc_unprotect_object (t->self_scm ());
1392
1393                 $$ = csm;
1394                 $$->set_spot (THIS->here_input ());
1395
1396                 csm->set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1397         }
1398         | PARTIAL duration_length       {
1399                 Moment m = - unsmob_duration ($2)->get_length ();
1400                 Music * p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1401
1402                 Music * sp = MY_MAKE_MUSIC("ContextSpeccedMusic");
1403                 sp->set_mus_property ("element", p->self_scm ());
1404                 scm_gc_unprotect_object (p->self_scm ());
1405
1406                 $$ =sp ;
1407                 sp-> set_mus_property ("context-type", ly_symbol2scm ("Timing"));
1408         }
1409         | CLEF STRING  {
1410                 static SCM proc ;
1411                 if (!proc)
1412                         proc = scm_c_eval_string ("make-clef-set");
1413
1414                 SCM result = scm_call_1 (proc, $2);
1415                 scm_gc_protect_object (result);
1416                 $$ = unsmob_music (result);
1417         }
1418         | TIME_T fraction  {
1419                 static SCM proc;
1420                 if (!proc)
1421                         proc = scm_c_eval_string ("make-time-signature-set");
1422
1423                 SCM result = scm_apply_2   (proc, gh_car ($2), gh_cdr ($2), SCM_EOL);
1424                 scm_gc_protect_object (result);
1425                 $$ = unsmob_music (result);
1426         }
1427         | MARK scalar {
1428                 static SCM proc;
1429                 if (!proc)
1430                         proc = scm_c_eval_string ("make-mark-set");
1431
1432                 SCM result = scm_call_1 (proc, $2);
1433                 scm_gc_protect_object (result);
1434                 $$ = unsmob_music (result);
1435         }
1436         ;
1437
1438 command_req:
1439         BREATHE {
1440                 $$ = MY_MAKE_MUSIC("BreathingSignEvent");
1441         }
1442         | E_TILDE {
1443                 $$ = MY_MAKE_MUSIC("PesOrFlexaEvent");
1444         }
1445         | MARK DEFAULT  {
1446                 Music * m = MY_MAKE_MUSIC("MarkEvent");
1447                 $$ = m;
1448         }
1449         | tempo_event {
1450                 $$ = $1;
1451         }
1452         | KEY DEFAULT {
1453                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1454                 $$ = key;
1455         }
1456         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1457
1458                 Music *key= MY_MAKE_MUSIC("KeyChangeEvent");
1459                 if (scm_ilength ($3) > 0)
1460                 {
1461                         key->set_mus_property ("pitch-alist", $3);
1462                         key->set_mus_property ("tonic", Pitch (0,0,0).smobbed_copy());
1463                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1464                 } else {
1465                         THIS->parser_error (_("Second argument must be pitch list."));
1466                 }
1467
1468                 $$ = key;
1469         }
1470         ;
1471
1472 post_events:
1473         /* empty */ {
1474                 $$ = SCM_EOL;
1475         }
1476         | post_events post_event {
1477                 $2->set_spot (THIS->here_input ());
1478                 $$ = gh_cons ($2->self_scm(), $$);
1479                 scm_gc_unprotect_object ($2->self_scm());
1480         }
1481         | post_events tagged_post_event {
1482                 $2 -> set_spot (THIS->here_input ());
1483                 $$ = scm_cons ($2->self_scm(), $$);
1484                 scm_gc_unprotect_object ($2->self_scm());
1485         }
1486         ;
1487
1488
1489 tagged_post_event:
1490         '-' TAG embedded_scm post_event {
1491                 tag_music ($4, $3, THIS->here_input ());
1492                 $$ = $4;
1493         }
1494         ;
1495
1496 post_event:
1497         direction_less_event {
1498                 $$ = $1;
1499         }
1500         | HYPHEN {
1501                 if (!THIS->lexer_->lyric_state_b ())
1502                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1503                 $$ = MY_MAKE_MUSIC("HyphenEvent");
1504         }
1505         | EXTENDER {
1506                 if (!THIS->lexer_->lyric_state_b ())
1507                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1508                 $$ = MY_MAKE_MUSIC("ExtenderEvent");
1509         }
1510         | script_dir direction_reqd_event {
1511                 if ($1)
1512                         $2->set_mus_property ("direction", gh_int2scm ($1));
1513                 $$ = $2;
1514         }
1515         | script_dir direction_less_event {
1516                 if ($1)
1517                         $2->set_mus_property ("direction", gh_int2scm ($1));
1518                 $$ = $2;
1519         }
1520         | string_number_event
1521         ;
1522
1523 string_number_event:
1524         E_UNSIGNED {
1525                 Music * s = MY_MAKE_MUSIC("StringNumberEvent");
1526                 s->set_mus_property ("string-number",  gh_int2scm($1));
1527                 s->set_spot (THIS->here_input ());
1528                 $$ = s;
1529         }
1530         ;
1531
1532
1533 direction_less_event:
1534         '['  {
1535
1536
1537 /*
1538
1539 TODO: should take all these defs out of the parser, adn make use
1540 configurable, i.e.
1541
1542
1543 (set-articulation '~ "trill")
1544
1545 */
1546                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1547                 m->set_spot (THIS->here_input());
1548                 m->set_mus_property ("span-direction" , gh_int2scm (START));
1549                 $$ = m;
1550         }
1551         | ']'  {
1552                 Music * m = MY_MAKE_MUSIC ("BeamEvent");
1553                 m->set_spot (THIS->here_input());
1554                 m->set_mus_property ("span-direction" , gh_int2scm (STOP));
1555                 $$ = m;
1556         }
1557         | '~' {
1558                 Music * m = MY_MAKE_MUSIC ("TieEvent");
1559                 m->set_spot (THIS->here_input());
1560                 $$ = m;
1561         }
1562         | close_event {
1563                 $$ = $1;
1564                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1565                         gh_int2scm (START));
1566         }
1567         | open_event {
1568                 $$ = $1;
1569                 dynamic_cast<Music *> ($$)->set_mus_property ("span-direction",
1570                         gh_int2scm (STOP));
1571         }
1572         | EVENT_IDENTIFIER      {
1573                 $$ = unsmob_music ($1);
1574         }
1575         | tremolo_type  {
1576                Music * a = MY_MAKE_MUSIC("TremoloEvent");
1577                a->set_spot (THIS->here_input ());
1578                a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1579                $$ = a;
1580         }
1581         ;
1582
1583 direction_reqd_event:
1584         gen_text_def {
1585                 $$ = $1;
1586         }
1587         | script_abbreviation {
1588                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1589                 Music *a = MY_MAKE_MUSIC("ArticulationEvent");
1590                 if (gh_string_p (s))
1591                         a->set_mus_property ("articulation-type", s);
1592                 else THIS->parser_error (_ ("Expecting string as script definition"));
1593                 $$ = a;
1594         }
1595         ;
1596
1597 oct_check:
1598         /**/ { $$ = SCM_EOL; }
1599         | '='  { $$ = gh_int2scm (0); }
1600         | '=' sub_quotes { $$ = gh_int2scm ($2); }
1601         | '=' sup_quotes { $$ = gh_int2scm ($2); }
1602         ;
1603
1604 sup_quotes:
1605         '\'' {
1606                 $$ = 1;
1607         }
1608         | sup_quotes '\'' {
1609                 $$ ++;
1610         }
1611         ;
1612
1613 sub_quotes:
1614         ',' {
1615                 $$ = 1;
1616         }
1617         | sub_quotes ',' {
1618                 $$ ++ ;
1619         }
1620         ;
1621
1622 steno_pitch:
1623         NOTENAME_PITCH  {
1624                 $$ = $1;
1625         }
1626         | NOTENAME_PITCH sup_quotes     {
1627                 Pitch p = *unsmob_pitch ($1);
1628                 p = p.transposed (Pitch ($2,0,0));
1629                 $$ = p.smobbed_copy ();
1630         }
1631         | NOTENAME_PITCH sub_quotes      {
1632                 Pitch p =* unsmob_pitch ($1);
1633                 p = p.transposed (Pitch (-$2,0,0));
1634                 $$ = p.smobbed_copy ();
1635         }
1636         ;
1637
1638 /*
1639 ugh. duplication
1640 */
1641
1642 steno_tonic_pitch:
1643         TONICNAME_PITCH {
1644                 $$ = $1;
1645         }
1646         | TONICNAME_PITCH sup_quotes    {
1647                 Pitch p = *unsmob_pitch ($1);
1648                 p = p.transposed (Pitch ($2,0,0));
1649                 $$ = p.smobbed_copy ();
1650         }
1651         | TONICNAME_PITCH sub_quotes     {
1652                 Pitch p =* unsmob_pitch ($1);
1653
1654                 p = p.transposed (Pitch (-$2,0,0));
1655                 $$ = p.smobbed_copy ();
1656         }
1657         ;
1658
1659 pitch:
1660         steno_pitch {
1661                 $$ = $1;
1662         }
1663         ;
1664
1665 pitch_also_in_chords:
1666         pitch
1667         | steno_tonic_pitch
1668         ;
1669
1670 close_event:
1671         '('     {
1672                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1673                 $$ = s;
1674                 s->set_spot (THIS->here_input());
1675         }
1676         | E_OPEN        {
1677                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1678                 $$ = s;
1679                 s->set_spot (THIS->here_input());
1680         }
1681         | E_SMALLER {
1682                 Music *s =MY_MAKE_MUSIC("CrescendoEvent");
1683                 $$ = s;
1684                 s->set_spot (THIS->here_input());
1685         }
1686         | E_BIGGER {
1687                 Music *s =MY_MAKE_MUSIC("DecrescendoEvent");
1688                 $$ = s;
1689                 s->set_spot (THIS->here_input());
1690         }
1691         ;
1692
1693
1694 open_event:
1695         E_EXCLAMATION   {
1696                 Music *s =  MY_MAKE_MUSIC("CrescendoEvent");
1697                 s->set_spot (THIS->here_input());
1698
1699                 $$ = s;
1700         }
1701         | ')'   {
1702                 Music * s= MY_MAKE_MUSIC("SlurEvent");
1703                 $$ = s;
1704                 s->set_spot (THIS->here_input());
1705
1706         }
1707         | E_CLOSE       {
1708                 Music * s= MY_MAKE_MUSIC("PhrasingSlurEvent");
1709                 $$ = s;
1710                 s->set_mus_property ("span-type", scm_makfrom0str ( "phrasing-slur"));
1711                 s->set_spot (THIS->here_input());
1712         }
1713         ;
1714
1715 gen_text_def:
1716         full_markup {
1717                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1718                 t->set_mus_property ("text", $1);
1719                 t->set_spot (THIS->here_input ());
1720                 $$ = t;
1721         }
1722         | string {
1723                 Music *t = MY_MAKE_MUSIC("TextScriptEvent");
1724                 t->set_mus_property ("text", make_simple_markup ($1));
1725                 t->set_spot (THIS->here_input ());
1726                 $$ = t;
1727
1728         }
1729         | DIGIT {
1730                 Music * t = MY_MAKE_MUSIC("FingerEvent");
1731                 t->set_mus_property ("digit",  gh_int2scm ($1));
1732                 t->set_spot (THIS->here_input ());
1733                 $$ = t;
1734         }
1735         ;
1736
1737 script_abbreviation:
1738         '^'             {
1739                 $$ = scm_makfrom0str ("Hat");
1740         }
1741         | '+'           {
1742                 $$ = scm_makfrom0str ("Plus");
1743         }
1744         | '-'           {
1745                 $$ = scm_makfrom0str ("Dash");
1746         }
1747         | '|'           {
1748                 $$ = scm_makfrom0str ("Bar");
1749         }
1750         | '>'           {
1751                 $$ = scm_makfrom0str ("Larger");
1752         }
1753         | '.'           {
1754                 $$ = scm_makfrom0str ("Dot");
1755         }
1756         | '_' {
1757                 $$ = scm_makfrom0str ("Underscore");
1758         }
1759         ;
1760
1761 script_dir:
1762         '_'     { $$ = DOWN; }
1763         | '^'   { $$ = UP; }
1764         | '-'   { $$ = CENTER; }
1765         ;
1766
1767
1768 absolute_pitch:
1769         steno_pitch     {
1770                 $$ = $1;
1771         }
1772         ;
1773
1774 duration_length:
1775         multiplied_duration {
1776                 $$ = $1;
1777         }
1778         ;
1779
1780 optional_notemode_duration:
1781         {
1782                 Duration dd = THIS->default_duration_;
1783                 $$ = dd.smobbed_copy ();
1784
1785                 THIS->beam_check ($$);
1786         }
1787         | multiplied_duration   {
1788                 $$ = $1;
1789                 THIS->default_duration_ = *unsmob_duration ($$);
1790
1791                 THIS->beam_check ($$);
1792         }
1793         ;
1794
1795 steno_duration:
1796         bare_unsigned dots              {
1797                 int l = 0;
1798                 if (!is_duration_b ($1))
1799                         THIS->parser_error (_f ("not a duration: %d", $1));
1800                 else
1801                         l =  intlog2 ($1);
1802
1803                 $$ = Duration (l, $2).smobbed_copy ();
1804         }
1805         | DURATION_IDENTIFIER dots      {
1806                 Duration *d =unsmob_duration ($1);
1807                 Duration k (d->duration_log (),d->dot_count () + $2);
1808
1809                 *d = k;
1810                 $$ = $1;
1811         }
1812         ;
1813
1814
1815
1816
1817 multiplied_duration:
1818         steno_duration {
1819                 $$ = $1;
1820         }
1821         | multiplied_duration '*' bare_unsigned {
1822                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
1823         }
1824         | multiplied_duration '*' FRACTION {
1825                 Rational  m (gh_scm2int (ly_car ($3)), gh_scm2int (ly_cdr ($3)));
1826
1827                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
1828         }
1829         ;
1830
1831 fraction:
1832         FRACTION { $$ = $1; }
1833         | UNSIGNED '/' UNSIGNED {
1834                 $$ = scm_cons (gh_int2scm ($1), gh_int2scm ($3));
1835         }
1836         ;
1837
1838 dots:
1839         /* empty */     {
1840                 $$ = 0;
1841         }
1842         | dots '.' {
1843                 $$ ++;
1844         }
1845         ;
1846
1847
1848 tremolo_type:
1849         ':'     {
1850                 $$ =0;
1851         }
1852         | ':' bare_unsigned {
1853                 if (!is_duration_b ($2))
1854                         THIS->parser_error (_f ("not a duration: %d", $2));
1855                 $$ = $2;
1856         }
1857         ;
1858
1859
1860
1861 /*****************************************************************
1862                 BASS FIGURES
1863 *****************************************************************/
1864 bass_number:
1865         DIGIT   {
1866                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1867         }
1868         | UNSIGNED {
1869                 $$ = scm_number_to_string (gh_int2scm ($1), gh_int2scm (10));
1870         }
1871         | STRING { $$ =  $1; }
1872         ;
1873
1874 bass_mod:
1875         '-'     { $$ = -2; }
1876         | '+'   { $$ = 2; }
1877         | '!'   { $$ = 0; }
1878         ;
1879
1880 bass_figure:
1881         FIGURE_SPACE {
1882                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1883                 $$ = bfr->self_scm();
1884                 scm_gc_unprotect_object ($$);
1885         }
1886         | bass_number  {
1887                 Music *bfr = MY_MAKE_MUSIC("BassFigureEvent");
1888                 $$ = bfr->self_scm();
1889
1890                 bfr->set_mus_property ("figure", $1);
1891
1892                 scm_gc_unprotect_object ($$);
1893         }
1894         | bass_figure bass_mod {
1895                 Music *m = unsmob_music ($1);
1896                 if ($2) {
1897                         SCM salter =m->get_mus_property ("alteration");
1898                         int alter = gh_number_p ( salter) ? gh_scm2int (salter) : 0;
1899                         m->set_mus_property ("alteration",
1900                                 gh_int2scm (alter + $2));
1901                 } else {
1902                         m->set_mus_property ("alteration", gh_int2scm (0));
1903                 }
1904         }
1905         ;
1906
1907 br_bass_figure:
1908         '[' bass_figure {
1909                 $$ = $2;
1910                 unsmob_music ($$)->set_mus_property ("bracket-start", SCM_BOOL_T);
1911         }
1912         | bass_figure   {
1913                 $$ = $1;
1914         }
1915         | br_bass_figure ']' {
1916                 $$ = $1;
1917                 unsmob_music ($1)->set_mus_property ("bracket-stop", SCM_BOOL_T);
1918         }
1919         ;
1920
1921 figure_list:
1922         /**/            {
1923                 $$ = SCM_EOL;
1924         }
1925         | figure_list br_bass_figure {
1926                 $$ = scm_cons ($2, $1);
1927         }
1928         ;
1929
1930 figure_spec:
1931         FIGURE_OPEN figure_list FIGURE_CLOSE {
1932                 Music * m = MY_MAKE_MUSIC("EventChord");
1933                 $2 = scm_reverse_x ($2, SCM_EOL);
1934                 m->set_mus_property ("elements",  $2);
1935                 $$ = m->self_scm ();
1936         }
1937         ;
1938
1939
1940 optional_rest:
1941         /**/   { $$ = 0; }
1942         | REST { $$ = 1; }
1943         ;
1944
1945 simple_element:
1946         pitch exclamations questions oct_check optional_notemode_duration optional_rest {
1947
1948                 Input i = THIS->pop_spot ();
1949                 if (!THIS->lexer_->note_state_b ())
1950                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1951
1952                 Music *n = 0;
1953                 if ($6)
1954                         n =  MY_MAKE_MUSIC("RestEvent");
1955                 else
1956                         n =  MY_MAKE_MUSIC("NoteEvent");
1957
1958                 n->set_mus_property ("pitch", $1);
1959                 n->set_mus_property ("duration", $5);
1960
1961                 if (gh_number_p ($4))
1962                 {
1963                         int q = gh_scm2int ($4);
1964                         n->set_mus_property ("absolute-octave", gh_int2scm (q-1));
1965                 }
1966
1967                 if ($3 % 2)
1968                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1969                 if ($2 % 2 || $3 % 2)
1970                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1971
1972                 Music *v = MY_MAKE_MUSIC("EventChord");
1973                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1974                 scm_gc_unprotect_object (n->self_scm());
1975
1976                 v->set_spot (i);
1977                 n->set_spot (i);
1978                 $$ = v;
1979         }
1980         | DRUM_PITCH optional_notemode_duration {
1981                 Input i = THIS->pop_spot ();
1982
1983                 Music *n =  MY_MAKE_MUSIC("NoteEvent");
1984                 n->set_mus_property ("duration" ,$2);
1985                 n->set_mus_property ("drum-type" , $1);
1986
1987                 Music *v = MY_MAKE_MUSIC("EventChord");
1988                 v->set_mus_property ("elements", scm_list_n (n->self_scm (), SCM_UNDEFINED));
1989                 scm_gc_unprotect_object (n->self_scm());
1990                 v->set_spot (i);
1991                 n->set_spot (i);
1992                 $$ = v;
1993
1994         }
1995         | figure_spec optional_notemode_duration {
1996                 Music * m = unsmob_music ($1);
1997                 Input i = THIS->pop_spot ();
1998                 m->set_spot (i);
1999                 for (SCM s = m->get_mus_property ("elements"); gh_pair_p (s); s = ly_cdr (s))
2000                 {
2001                         unsmob_music (ly_car (s))->set_mus_property ("duration", $2);
2002                 }
2003                 $$ = m;
2004         }
2005         | RESTNAME optional_notemode_duration           {
2006
2007                 Input i = THIS->pop_spot ();
2008                 Music * ev = 0;
2009                 if (ly_scm2string ($1) =="s") {
2010                         /* Space */
2011                         ev = MY_MAKE_MUSIC("SkipEvent");
2012                   }
2013                 else {
2014                         ev = MY_MAKE_MUSIC("RestEvent");
2015
2016                     }
2017                 ev->set_mus_property ("duration" ,$2);
2018                 ev->set_spot (i);
2019                 Music * velt = MY_MAKE_MUSIC("EventChord");
2020                 velt->set_mus_property ("elements", scm_list_n (ev->self_scm (),SCM_UNDEFINED));
2021                 velt->set_spot (i);
2022
2023                 scm_gc_unprotect_object (ev->self_scm());
2024
2025                 $$ = velt;
2026         }
2027         | MULTI_MEASURE_REST optional_notemode_duration         {
2028                 THIS->pop_spot ();
2029
2030                 static SCM proc ;
2031                 if (!proc)
2032                         proc = scm_c_eval_string ("make-multi-measure-rest");
2033
2034                 SCM mus = scm_call_2 (proc, $2,
2035                         make_input (THIS->here_input()));
2036                 scm_gc_protect_object (mus);
2037                 $$ = unsmob_music (mus);
2038         }
2039
2040         | lyric_element optional_notemode_duration      {
2041                 Input i = THIS->pop_spot ();
2042                 if (!THIS->lexer_->lyric_state_b ())
2043                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2044
2045                 Music * lreq = MY_MAKE_MUSIC("LyricEvent");
2046                 lreq->set_mus_property ("text", $1);
2047                 lreq->set_mus_property ("duration",$2);
2048                 lreq->set_spot (i);
2049                 Music * velt = MY_MAKE_MUSIC("EventChord");
2050                 velt->set_mus_property ("elements", scm_list_n (lreq->self_scm (), SCM_UNDEFINED));
2051
2052                 $$= velt;
2053         }
2054         | new_chord {
2055                 THIS->pop_spot ();
2056
2057                 if (!THIS->lexer_->chord_state_b ())
2058                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2059                 $$ = unsmob_music ($1);
2060         }
2061         ;
2062
2063 lyric_element:
2064         full_markup { $$ = $1; }
2065         | STRING {  $$ = $1 ; }
2066         ;
2067
2068 new_chord:
2069         steno_tonic_pitch optional_notemode_duration   {
2070                 $$ = make_chord ($1, $2, SCM_EOL);
2071         }
2072         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2073                 SCM its = scm_reverse_x ($4, SCM_EOL);
2074                 $$ = make_chord ($1, $2, gh_cons ($3, its));
2075         }
2076         ;
2077
2078 chord_items:
2079         /**/ {
2080                 $$ = SCM_EOL;
2081         }
2082         | chord_items chord_item {
2083                 $$ = gh_cons ($2, $$);
2084         }
2085         ;
2086
2087 chord_separator:
2088         CHORD_COLON {
2089                 $$ = ly_symbol2scm ("chord-colon");
2090         }
2091         | CHORD_CARET {
2092                 $$ = ly_symbol2scm ("chord-caret");
2093         }
2094         | CHORD_SLASH steno_tonic_pitch {
2095                 $$ = scm_list_n (ly_symbol2scm ("chord-slash"), $2, SCM_UNDEFINED);
2096         }
2097         | CHORD_BASS steno_tonic_pitch {
2098                 $$ = scm_list_n (ly_symbol2scm ("chord-bass"), $2, SCM_UNDEFINED);
2099         }
2100         ;
2101
2102 chord_item:
2103         chord_separator {
2104                 $$ = $1;
2105         }
2106         | step_numbers {
2107                 $$ = scm_reverse_x ($1, SCM_EOL);
2108         }
2109         | CHORD_MODIFIER  {
2110                 $$ = $1;
2111         }
2112         ;
2113
2114 step_numbers:
2115         step_number { $$ = gh_cons ($1, SCM_EOL); }
2116         | step_numbers '.' step_number {
2117                 $$ = gh_cons ($3, $$);
2118         }
2119         ;
2120
2121 step_number:
2122         bare_unsigned {
2123                 $$ = make_chord_step ($1, 0);
2124         }
2125         | bare_unsigned '+' {
2126                 $$ = make_chord_step ($1, SHARP);
2127         }
2128         | bare_unsigned CHORD_MINUS {
2129                 $$ = make_chord_step ($1, FLAT);
2130         }
2131         ;
2132
2133 /*
2134         UTILITIES
2135
2136 TODO: should deprecate in favor of Scheme?
2137
2138  */
2139 number_expression:
2140         number_expression '+' number_term {
2141                 $$ = scm_sum ($1, $3);
2142         }
2143         | number_expression '-' number_term {
2144                 $$ = scm_difference ($1, $3);
2145         }
2146         | number_term
2147         ;
2148
2149 number_term:
2150         number_factor {
2151                 $$ = $1;
2152         }
2153         | number_factor '*' number_factor {
2154                 $$ = scm_product ($1, $3);
2155         }
2156         | number_factor '/' number_factor {
2157                 $$ = scm_divide ($1, $3);
2158         }
2159         ;
2160
2161 number_factor:
2162         '-'  number_factor { /* %prec UNARY_MINUS */
2163                 $$ = scm_difference ($2, SCM_UNDEFINED);
2164         }
2165         | bare_number
2166         ;
2167
2168
2169 bare_number:
2170         UNSIGNED        {
2171                 $$ = gh_int2scm ($1);
2172         }
2173         | REAL          {
2174                 $$ = $1;
2175         }
2176         | NUMBER_IDENTIFIER             {
2177                 $$ = $1;
2178         }
2179         | REAL NUMBER_IDENTIFIER        {
2180                 $$ = gh_double2scm (gh_scm2double ($1) * gh_scm2double ($2));
2181         }
2182         | UNSIGNED NUMBER_IDENTIFIER    {
2183                 $$ = gh_double2scm ($1 * gh_scm2double ($2));
2184         }
2185         ;
2186
2187
2188 bare_unsigned:
2189         UNSIGNED {
2190                         $$ = $1;
2191         }
2192         | DIGIT {
2193                 $$ = $1;
2194         }
2195         ;
2196
2197 bare_int:
2198         bare_number {
2199                 if (scm_integer_p ($1) == SCM_BOOL_T)
2200                 {
2201                         int k = gh_scm2int ($1);
2202                         $$ = k;
2203                 } else
2204                 {
2205                         THIS->parser_error (_ ("need integer number arg"));
2206                         $$ = 0;
2207                 }
2208         }
2209         | '-' bare_int {
2210                 $$ = -$2;
2211         }
2212         ;
2213
2214
2215 string:
2216         STRING          {
2217                 $$ = $1;
2218         }
2219         | STRING_IDENTIFIER     {
2220                 $$ = $1;
2221         }
2222         | string '+' string {
2223                 $$ = scm_string_append (scm_list_n ($1, $3, SCM_UNDEFINED));
2224         }
2225         ;
2226
2227
2228 exclamations:
2229                 { $$ = 0; }
2230         | exclamations '!'      { $$ ++; }
2231         ;
2232
2233 questions:
2234                 { $$ = 0; }
2235         | questions '?' { $$ ++; }
2236         ;
2237
2238
2239
2240 full_markup:
2241         MARKUP_IDENTIFIER {
2242                 $$ = $1;
2243         }
2244         | MARKUP
2245                 { THIS->lexer_->push_markup_state (); }
2246         markup
2247                 { $$ = $3;
2248                   THIS->lexer_->pop_state ();
2249                 }
2250         ;
2251
2252
2253 /*
2254 This should be done more dynamically if possible.
2255 */
2256 markup:
2257         STRING {
2258                 $$ = make_simple_markup ($1);
2259         }
2260         | MARKUP_HEAD_EMPTY {
2261                 $$ = scm_list_n ($1, SCM_UNDEFINED);
2262         }
2263         | MARKUP_HEAD_MARKUP0 markup {
2264                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2265         }
2266         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2267                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2268         }
2269         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2270                 $$  = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2271         }
2272         | markup_line {
2273                 $$ = $1;
2274         }
2275         | MARKUP_HEAD_LIST0 markup_list {
2276                 $$ = scm_list_n ($1,$2, SCM_UNDEFINED);
2277         }
2278         | MARKUP_HEAD_SCM0 embedded_scm {
2279                 $$ = scm_list_n ($1, $2, SCM_UNDEFINED);
2280         }
2281         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2282                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2283         }
2284         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2285                 $$ = scm_list_n ($1, $2, $3, $4, SCM_UNDEFINED);
2286         }
2287         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2288                 $$ = scm_list_n ($1, $2, $3, SCM_UNDEFINED);
2289         }
2290         | MARKUP_IDENTIFIER {
2291                 $$ = $1;
2292         }
2293
2294         ;
2295
2296 markup_list:
2297         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2298         ;
2299
2300 markup_line:
2301         '{' markup_list_body '}' {
2302                 static SCM line ;
2303                 if (!line)
2304                         line = scm_c_eval_string ("line-markup");
2305
2306                 $$ = scm_list_n (line, scm_reverse_x ($2, SCM_EOL), SCM_UNDEFINED);
2307         }
2308         ;
2309
2310 markup_list_body:
2311         /**/ {  $$ = SCM_EOL; }
2312         | markup_list_body markup {
2313                 $$ = gh_cons ($2, $1) ;
2314         }
2315         ;
2316
2317
2318 %%
2319
2320 void
2321 My_lily_parser::set_yydebug (bool )
2322 {
2323 #if 0
2324         yydebug = 1;
2325 #endif
2326 }
2327
2328 extern My_lily_parser * current_parser;
2329
2330 void
2331 My_lily_parser::do_yyparse ()
2332 {
2333         current_parser = this;;
2334         yyparse ((void*)this);
2335 }
2336
2337
2338 /*
2339 Should make this optional?    It will also complain when you do
2340
2341         [s4]
2342
2343 which is entirely legitimate.
2344
2345 Or we can scrap it. Barchecks should detect wrong durations, and
2346 skipTypesetting speeds it up a lot.
2347 */
2348
2349 void
2350 My_lily_parser::beam_check (SCM dur)
2351 {
2352   Duration *d = unsmob_duration (dur);
2353   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2354     {
2355       Music * m = unsmob_music (last_beam_start_);
2356       m->origin ()->warning (_("Suspect duration found following this beam"));
2357     }
2358   last_beam_start_ = SCM_EOL;
2359 }
2360
2361
2362
2363
2364 /*
2365
2366 It is a little strange to have this function in this file, but
2367 otherwise, we have to import music classes into the lexer.
2368
2369 */
2370 int
2371 My_lily_lexer::try_special_identifiers (SCM * destination, SCM sid)
2372 {
2373         if (gh_string_p (sid)) {
2374                 *destination = sid;
2375                 return STRING_IDENTIFIER;
2376         } else if (gh_number_p (sid)) {
2377                 *destination = sid;
2378                 return NUMBER_IDENTIFIER;
2379         } else if (unsmob_context_def (sid)) {
2380                 *destination = unsmob_context_def (sid)->clone_scm();
2381                 return TRANSLATOR_IDENTIFIER;
2382         } else if (unsmob_score (sid)) {
2383                 Score *sc =  new Score (*unsmob_score (sid));
2384                 *destination =sc->self_scm ();
2385                 return SCORE_IDENTIFIER;
2386         } else if (Music * mus =unsmob_music (sid)) {
2387                 *destination = unsmob_music (sid)->clone ()->self_scm();
2388                 unsmob_music (*destination)->
2389                         set_mus_property ("origin", make_input (last_input_));
2390                 return dynamic_cast<Event*> (mus)
2391                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2392         } else if (unsmob_duration (sid)) {
2393                 *destination = unsmob_duration (sid)->smobbed_copy();
2394                 return DURATION_IDENTIFIER;
2395         } else if (unsmob_music_output_def (sid)) {
2396                 Music_output_def *p = unsmob_music_output_def (sid);
2397                 p = p->clone ();
2398
2399                 *destination = p->self_scm();
2400                 return MUSIC_OUTPUT_DEF_IDENTIFIER;
2401         } else if (Text_item::markup_p (sid)) {
2402                 *destination = sid;
2403                 return MARKUP_IDENTIFIER;
2404         }
2405
2406         return -1;
2407 }
2408
2409 Music *
2410 property_op_to_music (SCM op)
2411 {
2412         Music * m = 0;
2413         SCM tag = gh_car (op);
2414         SCM symbol  = gh_cadr (op);
2415         SCM args = gh_cddr (op);
2416         SCM grob_val = SCM_UNDEFINED;
2417         SCM grob_sym = SCM_UNDEFINED;
2418         SCM val = SCM_UNDEFINED;
2419
2420         if (tag == ly_symbol2scm ("assign"))
2421                 {
2422                 m =  MY_MAKE_MUSIC("PropertySet");
2423                 val = gh_car (args);
2424                 }
2425         else if (tag == ly_symbol2scm ("unset"))
2426                 m =  MY_MAKE_MUSIC("PropertyUnset");
2427         else if (tag == ly_symbol2scm ("poppush")
2428                  || tag == ly_symbol2scm ("push"))
2429                 {
2430                 m  = MY_MAKE_MUSIC("OverrideProperty");
2431                 grob_sym = gh_car (args);
2432                 grob_val = gh_cadr (args);
2433                 }
2434         else if (tag == ly_symbol2scm ("pop")) {
2435                 m = MY_MAKE_MUSIC("RevertProperty");
2436                 grob_sym = gh_car (args);
2437                 }
2438
2439         m->set_mus_property ("symbol", symbol);
2440
2441         if (val != SCM_UNDEFINED)
2442                 m->set_mus_property ("value", val);
2443         if (grob_val != SCM_UNDEFINED)
2444                 m->set_mus_property ("grob-value", grob_val);
2445
2446         if (grob_sym != SCM_UNDEFINED)
2447                 {
2448                 bool itc = internal_type_checking_global_b;
2449                 /* UGH.
2450                 */
2451                 bool autobeam = gh_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2452                 if (autobeam)
2453                         internal_type_checking_global_b = false;
2454                 m->set_mus_property ("grob-property", grob_sym);
2455                 if (autobeam)
2456                         internal_type_checking_global_b = itc;
2457                 }
2458
2459         if (op == ly_symbol2scm ("poppush"))
2460                 m->set_mus_property ("pop-first", SCM_BOOL_T);
2461
2462
2463         return m;
2464 }
2465
2466 Music*
2467 context_spec_music (SCM type, SCM id, Music * m, SCM ops)
2468 {
2469         Music * csm = MY_MAKE_MUSIC("ContextSpeccedMusic");
2470
2471         csm->set_mus_property ("element", m->self_scm ());
2472         scm_gc_unprotect_object (m->self_scm ());
2473
2474         csm->set_mus_property ("context-type",
2475                 gh_symbol_p (type) ? type : scm_string_to_symbol (type));
2476         csm->set_mus_property ("property-operations", ops);
2477
2478         if (gh_string_p (id))
2479                 csm->set_mus_property ("context-id", id);
2480         return csm;
2481 }
2482
2483
2484 SCM
2485 get_next_unique_context ()
2486 {
2487         static int new_context_count;
2488
2489         char s[1024];
2490         snprintf (s, 1024, "uniqueContext%d", new_context_count ++);
2491
2492         return scm_makfrom0str (s);
2493 }
2494