lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for mudela
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c)  1997--2000 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9            Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 #include <iostream.h>
  13 #include "translator-def.hh"
  14 #include "lily-guile.hh"
  15
  16 #include "lookup.hh"
  17 #include "misc.hh"
  18 #include "my-lily-lexer.hh"
  19 #include "paper-def.hh"
  20 #include "midi-def.hh"
  21 #include "main.hh"
  22 #include "file-path.hh"
  23 #include "debug.hh"
  24 #include "dimensions.hh"
  25 #include "identifier.hh"
  26 #include "command-request.hh"
  27 #include "musical-request.hh"
  28 #include "my-lily-parser.hh"
  29 #include "context-specced-music.hh"
  30 #include "score.hh"
  31 #include "music-list.hh"
  32
  33 #include "file-results.hh"
  34 #include "input.hh"
  35 #include "scope.hh"
  36 #include "relative-music.hh"
  37 #include "lyric-combine-music.hh"
  38 #include "transposed-music.hh"
  39 #include "time-scaled-music.hh"
  40 #include "repeated-music.hh"
  41 #include "mudela-version.hh"
  42 #include "grace-music.hh"
  43 #include "auto-change-music.hh"
  44 #include "part-combine-music.hh"
  45
  46 #include "chord.hh"
  47
  48 bool
  49 is_duration_b (int t)
  50 {
  51   return t && t == 1 << intlog2(t);
  52 }
  53
  54
  55 // mmm JUNKME ?
  56 Mudela_version oldest_version ("1.3.59");
  57
  58 void
  59 print_mudela_versions (ostream &os)
  60 {
  61   os << _f ("Oldest supported input version: %s", oldest_version.str ())
  62     << endl;
  63 }
  64
  65
  66 // needed for bison.simple's malloc() and free()
  67 #include <malloc.h>
  68
  69 #ifndef NDEBUG
  70 #define YYDEBUG 1
  71 #endif
  72
  73 #define YYERROR_VERBOSE 1
  74
  75 #define YYPARSE_PARAM my_lily_parser_l
  76 #define YYLEX_PARAM my_lily_parser_l
  77 #define THIS ((My_lily_parser *) my_lily_parser_l)
  78
  79 #define yyerror THIS->parser_error
  80 #define ARRAY_SIZE(a,s)   if (a.size () != s) THIS->parser_error (_f ("Expecting %d arguments", s))
  81
  82 %}
  83
  84
  85 %union {
  86     Array<Musical_pitch> *pitch_arr;
  87     Link_array<Request> *reqvec;
  88     Duration *duration;
  89     Identifier *id;
  90     String * string;
  91     Music *music;
  92     Score *score;
  93     Scope *scope;
  94
  95     Musical_req* musreq;
  96     Music_output_def * outputdef;
  97     Musical_pitch * pitch;
  98     Midi_def* midi;
  99     Real real;
 100     Request * request;
 101
 102     /* We use SCMs to do strings, because it saves us the trouble of
 103 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 104 of the parse stack onto the heap. */
 105
 106     SCM scm;
 107
 108     Tempo_req *tempo;
 109     int i;
 110 }
 111 %{
 112
 113 int
 114 yylex (YYSTYPE *s,  void * v_l)
 115 {
 116         My_lily_parser   *pars_l = (My_lily_parser*) v_l;
 117         My_lily_lexer * lex_l = pars_l->lexer_p_;
 118
 119         lex_l->lexval_l = (void*) s;
 120         return lex_l->yylex ();
 121 }
 122
 123
 124 %}
 125
 126 %pure_parser
 127
 128 /* tokens which are not keywords */
 129 %token AUTOCHANGE
 130 %token APPLY
 131 %token ARPEGGIO
 132 %token DYNAMICSCRIPT
 133 %token TEXTSCRIPT
 134 %token ACCEPTS
 135 %token ALTERNATIVE
 136 %token BAR
 137 %token BREATHE
 138 %token CHORDMODIFIERS
 139 %token CHORDS
 140 %token CHAR_T
 141 %token CLEF
 142 %token CM_T
 143 %token CONSISTS
 144 %token SEQUENTIAL
 145 %token ELEMENTDESCRIPTIONS
 146 %token SIMULTANEOUS
 147 %token CONSISTSEND
 148 %token DENIES
 149 %token DURATION
 150 %token EXTENDER
 151 %token FONT
 152 %token GRACE
 153 %token HEADER
 154 %token HYPHEN
 155 %token IN_T
 156 %token INVALID
 157 %token KEY
 158 %token LYRICS
 159 %token MARK
 160 %token MEASURES
 161 %token MIDI
 162 %token MM_T
 163 %token MUSICAL_PITCH
 164 %token NAME
 165 %token NOTENAMES
 166 %token NOTES
 167 %token PAPER
 168 %token PARTIAL
 169 %token PENALTY
 170 %token PROPERTY
 171 %token PUSH POP
 172 %token PT_T
 173 %token RELATIVE
 174 %token REMOVE
 175 %token REPEAT
 176 %token ADDLYRICS
 177 %token PARTCOMBINE
 178 %token SCM_T
 179 %token SCORE
 180 %token SCRIPT
 181 %token SKIP
 182 %token SPANREQUEST
 183 %token STYLESHEET
 184 %token COMMANDSPANREQUEST
 185 %token TEMPO
 186 %token OUTPUTPROPERTY
 187 %token TIME_T
 188 %token TIMES
 189 %token TRANSLATOR
 190 %token TRANSPOSE
 191 %token TYPE
 192 %token CONTEXT
 193
 194 /* escaped */
 195 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER
 196 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET
 197
 198 %type <i>       exclamations questions
 199 %token <i>      DIGIT
 200 %token <pitch>  NOTENAME_PITCH
 201 %token <pitch>  TONICNAME_PITCH
 202 %token <pitch>  CHORDMODIFIER_PITCH
 203 %token <id>     DURATION_IDENTIFIER
 204 %token <id>     IDENTIFIER
 205
 206
 207 %token <id>     SCORE_IDENTIFIER
 208 %token <id>     MUSIC_OUTPUT_DEF_IDENTIFIER
 209
 210 %token <scm>    NUMBER_IDENTIFIER
 211 %token <scm>    REQUEST_IDENTIFIER
 212 %token <scm>    MUSIC_IDENTIFIER TRANSLATOR_IDENTIFIER
 213 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 214 %token <scm>    DURATION RESTNAME
 215 %token <scm>    STRING
 216 %token <scm>    SCM_T
 217 %token <i>      UNSIGNED
 218 %token <real>   REAL
 219
 220 %type <outputdef> output_def
 221 %type <scope>   mudela_header mudela_header_body
 222 %type <request> open_request_parens close_request_parens open_request close_request
 223 %type <request> request_with_dir request_that_take_dir verbose_request
 224 %type <i>       sub_quotes sup_quotes
 225 %type <music>   simple_element  request_chord command_element Simple_music  Composite_music
 226 %type <music>   Alternative_music Repeated_music
 227 %type <i>       tremolo_type
 228 %type <i>       bare_int  bare_unsigned
 229 %type <i>       script_dir
 230
 231 %type <scm>     identifier_init
 232
 233 %type <duration> steno_duration optional_notemode_duration
 234 %type <duration> entered_notemode_duration explicit_duration
 235
 236 %type <reqvec>  pre_requests post_requests
 237 %type <request> gen_text_def
 238 %type <pitch>   steno_musical_pitch musical_pitch absolute_musical_pitch
 239 %type <pitch>   steno_tonic_pitch
 240
 241 %type <pitch_arr>       chord_additions chord_subtractions chord_notes chord_step
 242 %type <music>   chord
 243 %type <pitch>   chord_note chord_inversion chord_bass
 244 %type <duration>        duration_length
 245
 246 %type <scm>  embedded_scm scalar
 247 %type <music>   Music Sequential_music Simultaneous_music Music_sequence
 248 %type <music>   relative_music re_rhythmed_music part_combined_music
 249 %type <music>   property_def translator_change
 250 %type <scm> Music_list
 251 %type <outputdef>  music_output_def_body
 252 %type <request> shorthand_command_req
 253 %type <request> post_request
 254 %type <request> command_req verbose_command_req
 255 %type <request> extender_req
 256 %type <request> hyphen_req
 257 %type <scm>     string bare_number number_expression
 258 %type <score>   score_block score_body
 259
 260 %type <scm>     translator_spec_block translator_spec_body
 261 %type <tempo>   tempo_request
 262 %type <scm> notenames_body notenames_block chordmodifiers_block
 263 %type <scm>     script_abbreviation
 264
 265
 266
 267 %left '-' '+'
 268 %left '*' '/'
 269 %left UNARY_MINUS
 270
 271 %%
 272
 273 mudela: /* empty */
 274         | mudela toplevel_expression {}
 275         | mudela assignment  { }
 276         | mudela error {
 277                 THIS->error_level_i_  = 1;
 278                 //THIS->parser_error (_ ("ly invalid"));
 279         }
 280         | mudela INVALID        {
 281                 THIS->error_level_i_  = 1;
 282                 //THIS->parser_error (_ ("ly invalid"));
 283         }
 284         ;
 285
 286 toplevel_expression:
 287         notenames_block                 {
 288                 THIS->lexer_p_->pitchname_tab_ =  $1;
 289         }
 290         | chordmodifiers_block                  {
 291                 THIS->lexer_p_->chordmodifier_tab_  = $1;
 292         }
 293         | mudela_header {
 294                 delete header_global_p;
 295                 header_global_p = $1;
 296         }
 297         | score_block {
 298                 score_global_array.push ($1);
 299         }
 300         | output_def {
 301                 Identifier * id = new
 302                         Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER);
 303                 if (dynamic_cast<Paper_def*> ($1))
 304                         THIS->lexer_p_->set_identifier ("$defaultpaper", id->self_scm ());
 305                 else if (dynamic_cast<Midi_def*> ($1))
 306                         THIS->lexer_p_->set_identifier ("$defaultmidi", id->self_scm ());
 307         }
 308         | embedded_scm {
 309                 // junk value
 310         }
 311         ;
 312
 313 embedded_scm:
 314         SCM_T
 315         | SCM_IDENTIFIER
 316         ;
 317
 318
 319 chordmodifiers_block:
 320         CHORDMODIFIERS notenames_body   {  $$ = $2; }
 321         ;
 322
 323
 324 notenames_block:
 325         NOTENAMES notenames_body   {  $$ = $2; }
 326         ;
 327
 328
 329
 330 notenames_body:
 331         embedded_scm    {
 332           int i = scm_ilength ($1);
 333
 334           SCM tab = scm_make_vector (gh_int2scm (i), SCM_EOL);
 335           for (SCM s = $1; s != SCM_EOL; s = gh_cdr (s)) {
 336                 SCM pt = gh_cdar (s);
 337                 if (scm_ilength (pt) != 3)
 338                         THIS->parser_error ("Need three args");
 339                 scm_hashq_set_x (tab, gh_caar(s), pt);
 340           }
 341
 342           $$ = tab;
 343         }
 344         ;
 345
 346 mudela_header_body:
 347         {
 348                 $$ = new Scope;
 349                 THIS->lexer_p_-> scope_l_arr_.push ($$);
 350         }
 351         | mudela_header_body assignment semicolon {
 352
 353         }
 354         ;
 355
 356 mudela_header:
 357         HEADER '{' mudela_header_body '}'       {
 358                 $$ = $3;
 359                 THIS->lexer_p_-> scope_l_arr_.pop ();
 360         }
 361         ;
 362
 363
 364 /*
 365         DECLARATIONS
 366 */
 367 assignment:
 368         STRING {
 369                 THIS->remember_spot ();
 370         }
 371         /* cont */ '=' identifier_init  {
 372                 THIS->lexer_p_->set_identifier (ly_scm2string ($1), $4);
 373
 374 /*
 375  TODO: devise standard for protection in parser.
 376
 377   The parser stack lives on the C-stack, which means that
 378 all objects can be unprotected as soon as they're here.
 379
 380 */
 381                 Identifier * id =unsmob_identifier ($4);
 382                 Input spot = THIS->pop_spot ();
 383                 if (id) id->set_spot (spot);
 384         }
 385         ;
 386
 387
 388
 389 identifier_init:
 390         score_block {
 391                 $$ = (new Score_identifier ($1, SCORE_IDENTIFIER))->self_scm();
 392         }
 393         | output_def {
 394                 $$ = (new Music_output_def_identifier ($1, MUSIC_OUTPUT_DEF_IDENTIFIER))->self_scm();
 395         }
 396         | translator_spec_block {
 397                 $$ = $1;
 398         }
 399         | Music  {
 400                 $$ = $1->self_scm ();
 401                 scm_unprotect_object ($$);
 402         }
 403         | post_request {
 404                 $$ = $1->self_scm ();
 405                 scm_unprotect_object ($$);
 406         }
 407         | explicit_duration {
 408                 $$ = (new Duration_identifier ($1, DURATION_IDENTIFIER))->self_scm ();
 409         }
 410         | number_expression {
 411                 $$ = $1;
 412         }
 413         | string {
 414                 $$ = $1;
 415         }
 416         | embedded_scm  {
 417                 $$ = $1;
 418         }
 419         ;
 420
 421 translator_spec_block:
 422         TRANSLATOR '{' translator_spec_body '}'
 423                 {
 424                 $$ = $3;
 425         }
 426         ;
 427
 428 translator_spec_body:
 429         TRANSLATOR_IDENTIFIER   {
 430                 $$ = unsmob_translator_def ($1)->clone_scm ();
 431                 unsmob_translator_def ($$)-> set_spot (THIS->here_input ());
 432         }
 433         | TYPE STRING semicolon {
 434                 $$ = Translator_def::make_scm ();
 435                 Translator_def*td =  unsmob_translator_def ($$);
 436                 td->translator_group_type_ = $2;
 437                 td->set_spot (THIS->here_input ());
 438         }
 439         | translator_spec_body STRING '=' embedded_scm                  {
 440                 unsmob_translator_def ($$)->add_property_assign ($2, $4);
 441         }
 442         | translator_spec_body STRING PUSH embedded_scm '=' embedded_scm {
 443                 unsmob_translator_def ($$)
 444                         ->add_push_property (scm_string_to_symbol ($2), $4, $6);
 445         }
 446         | translator_spec_body STRING POP embedded_scm  {
 447           unsmob_translator_def($$)->add_pop_property (
 448                 scm_string_to_symbol ($2), $4);
 449         }
 450         | translator_spec_body STRING '=' identifier_init semicolon     {
 451                 SCM v = gh_int2scm (0);
 452                 if (gh_string_p ($4) || gh_number_p ($4) || gh_boolean_p ($4))
 453                         v = $4;
 454                 else
 455                         THIS->parser_error (_("Wrong type for property value"));
 456
 457                 /* ugh*/
 458                 unsmob_translator_def($$)->add_property_assign ($2, v);
 459         }
 460         | translator_spec_body NAME STRING semicolon {
 461                 unsmob_translator_def ($$)->type_name_ = $3;
 462         }
 463         | translator_spec_body CONSISTS STRING semicolon {
 464                 unsmob_translator_def ($$)->add_element ($3);
 465         }
 466         | translator_spec_body ELEMENTDESCRIPTIONS embedded_scm {
 467                 for (SCM p = $3; gh_pair_p (p); p = gh_cdr (p))
 468                         unsmob_translator_def ($$)
 469                         ->add_property_assign (scm_symbol_to_string (gh_caar (p)), gh_cdar (p));
 470
 471         }
 472         | translator_spec_body CONSISTSEND STRING semicolon {
 473                 unsmob_translator_def ($$)->add_last_element ( $3);
 474         }
 475         | translator_spec_body ACCEPTS STRING semicolon {
 476                 unsmob_translator_def ($$)->set_acceptor ($3,true);
 477         }
 478         | translator_spec_body DENIES STRING semicolon {
 479                 unsmob_translator_def ($$)->set_acceptor ($3,false);
 480         }
 481         | translator_spec_body REMOVE STRING semicolon {
 482                 unsmob_translator_def ($$)->remove_element ($3);
 483         }
 484         ;
 485
 486 /*
 487         SCORE
 488 */
 489 score_block:
 490         SCORE {
 491                 THIS->remember_spot ();
 492         }
 493         /*cont*/ '{' score_body '}'     {
 494                 THIS->pop_spot ();
 495                 $$ = $4;
 496                 if (!$$->def_p_arr_.size ())
 497                 {
 498                   Identifier *id =
 499                         unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 500                   $$->add_output (id ? id->access_content_Music_output_def (true) : new Paper_def );
 501                 }
 502         }
 503 /*
 504         | SCORE '{' score_body error {
 505                 $$ = $3
 506                 $$->set_spot (THIS->here_input ());
 507                 // THIS->here_input ().error ("SCORE INVALID");
 508                 $$->error ("SCORE INVALID");
 509                 THIS->parser_error (_f ("SCORE ERROR"));
 510         }
 511 */
 512         ;
 513
 514 score_body:
 515         Music   {
 516                 $$ = new Score;
 517
 518                 $$->set_spot (THIS->here_input ());
 519                 SCM m = $1->self_scm ();
 520                 scm_unprotect_object (m);
 521                 $$->music_ = m;
 522         }
 523         | SCORE_IDENTIFIER {
 524                 $$ = $1->access_content_Score (true);
 525         }
 526         | score_body mudela_header      {
 527                 $$->header_p_ = $2;
 528         }
 529         | score_body output_def {
 530                 $$->add_output ($2);
 531         }
 532         | score_body error {
 533
 534         }
 535         ;
 536
 537
 538 /*
 539         MIDI
 540 */
 541 output_def:
 542         music_output_def_body '}' {
 543                 $$ = $1;
 544                 THIS-> lexer_p_-> scope_l_arr_.pop();
 545         }
 546         ;
 547
 548 music_output_def_body:
 549         MIDI '{'    {
 550          Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultmidi"));
 551
 552
 553          Midi_def* p =0;
 554         if (id)
 555                 p = dynamic_cast<Midi_def*> (id->access_content_Music_output_def (true));
 556         else
 557                 p = new Midi_def;
 558
 559          $$ = p;
 560          THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 561         }
 562         | PAPER '{'     {
 563                   Identifier *id = unsmob_identifier (THIS->lexer_p_->lookup_identifier ("$defaultpaper"));
 564                   Paper_def *p = 0;
 565                 if (id)
 566                         p = dynamic_cast<Paper_def*> (id->access_content_Music_output_def (true));
 567                 else
 568                         p = new Paper_def;
 569                 THIS-> lexer_p_-> scope_l_arr_.push (p->scope_p_);
 570                 $$ = p;
 571         }
 572         | PAPER '{' MUSIC_OUTPUT_DEF_IDENTIFIER         {
 573                 Music_output_def *p = $3->access_content_Music_output_def (true);
 574                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 575                 $$ = p;
 576         }
 577         | MIDI '{' MUSIC_OUTPUT_DEF_IDENTIFIER  {
 578                 Music_output_def *p = $3->access_content_Music_output_def (true);
 579                 THIS->lexer_p_->scope_l_arr_.push (p->scope_p_);
 580                 $$ = p;
 581         }
 582         | music_output_def_body assignment semicolon {
 583
 584         }
 585         | music_output_def_body translator_spec_block   {
 586                 $$->assign_translator ($2);
 587         }
 588         | music_output_def_body STYLESHEET embedded_scm {
 589                 dynamic_cast<Paper_def*> ($$)-> style_sheet_ = $3;
 590         }
 591         | music_output_def_body tempo_request semicolon {
 592                 /*
 593                         junk this ? there already is tempo stuff in
 594                         music.
 595                 */
 596                 int m = gh_scm2int ( $2->get_mus_property ("metronome-count"));
 597                 dynamic_cast<Midi_def*> ($$)->set_tempo ($2->dur_.length_mom (), m);
 598         }
 599         | music_output_def_body error {
 600
 601         }
 602         ;
 603
 604 tempo_request:
 605         TEMPO steno_duration '=' bare_unsigned  {
 606                 $$ = new Tempo_req;
 607                 $$->dur_ = *$2;
 608                 delete $2;
 609                 $$-> set_mus_property ("metronome-count", gh_int2scm ( $4));
 610         }
 611         ;
 612
 613 Music_list: /* empty */ {
 614                 $$ = gh_cons (SCM_EOL, SCM_EOL);
 615         }
 616         | Music_list Music {
 617                 SCM s = $$;
 618                 SCM c = gh_cons ($2->self_scm (), SCM_EOL);
 619                 scm_unprotect_object ($2->self_scm ()); /* UGH */
 620
 621
 622                 if (gh_pair_p (gh_cdr (s)))
 623                         gh_set_cdr_x (gh_cdr (s), c); /* append */
 624                 else
 625                         gh_set_car_x (s, c); /* set first cons */
 626                 gh_set_cdr_x (s, c) ;  /* remember last cell */
 627         }
 628         | Music_list error {
 629         }
 630         ;
 631
 632
 633 Music:
 634         Simple_music
 635         | Composite_music
 636         ;
 637
 638 Alternative_music:
 639         /* empty */ {
 640                 $$ = 0;
 641         }
 642         | ALTERNATIVE Music_sequence {
 643                 $$ = $2;
 644                 $2->set_spot (THIS->here_input ());
 645         }
 646         ;
 647
 648
 649
 650
 651 Repeated_music:
 652         REPEAT STRING bare_unsigned Music Alternative_music
 653         {
 654                 Music_sequence* m = dynamic_cast <Music_sequence*> ($5);
 655                 if (m && $3 < m->length_i ())
 656                         $5->origin ()->warning (_ ("More alternatives than repeats.  Junking excess alternatives."));
 657
 658                 Repeated_music * r = new Repeated_music ($4, $3 >? 1, m);
 659                 $$ = r;
 660                 r->type_ = ly_scm2string ($2);
 661                 r->fold_b_ = (r->type_ == "fold");
 662                 r->volta_fold_b_ =  (r->type_ == "volta");
 663                 r->set_spot (*$4->origin ());
 664         }
 665         ;
 666
 667 Music_sequence: '{' Music_list '}'      {
 668                 $$ = new Music_sequence (gh_car ($2));
 669         }
 670         ;
 671
 672 Sequential_music:
 673         SEQUENTIAL '{' Music_list '}'           {
 674                 $$ = new Sequential_music (gh_car ($3));
 675         }
 676         | '{' Music_list '}'            {
 677                 $$ = new Sequential_music (gh_car ($2));
 678         }
 679         ;
 680
 681 Simultaneous_music:
 682         SIMULTANEOUS '{' Music_list '}'{
 683                 $$ = new Simultaneous_music (gh_car ($3));
 684         }
 685         | '<' Music_list '>'    {
 686                 $$ = new Simultaneous_music (gh_car ($2));
 687         }
 688         ;
 689
 690 Simple_music:
 691         request_chord           { $$ = $1; }
 692         | OUTPUTPROPERTY embedded_scm embedded_scm '=' embedded_scm     {
 693                 SCM pred = $2;
 694                 if (!gh_symbol_p ($3))
 695                 {
 696                         THIS->parser_error (_("Second argument must be a symbol"));
 697                 }
 698                 /*hould check # args */
 699                 if (!gh_procedure_p (pred))
 700                 {
 701                         THIS->parser_error (_("First argument must be a procedure taking 1 argument"));
 702                 }
 703
 704           Music *m = new Music;
 705           m->set_mus_property ("predicate", pred);
 706           m->set_mus_property ("symbol", $3);
 707           m->set_mus_property ("value",  $5);
 708           m->set_mus_property ("type", ly_symbol2scm ("output-property"));
 709
 710                 $$ = m;
 711         }
 712         | MUSIC_IDENTIFIER {
 713                 $$ = unsmob_music ($1)->clone ();
 714         }
 715         | property_def
 716         | translator_change
 717         | Simple_music '*' bare_unsigned '/' bare_unsigned      {
 718                 $$ = $1;
 719                 $$->compress (Moment($3, $5 ));
 720         }
 721         | Simple_music '*' bare_unsigned                 {
 722                 $$ = $1;
 723                 $$->compress (Moment ($3, 1));
 724         }
 725         ;
 726
 727
 728 Composite_music:
 729         CONTEXT STRING Music    {
 730                 Context_specced_music *csm =  new Context_specced_music ($3);
 731
 732                 csm->translator_type_str_ = ly_scm2string ($2);
 733                 csm->translator_id_str_ = "";
 734
 735
 736                 $$ = csm;
 737         }
 738         | AUTOCHANGE STRING Music       {
 739                 Auto_change_music * chm = new Auto_change_music ($3);
 740                 chm->set_mus_property ("what", $2);
 741
 742                 $$ = chm;
 743                 chm->set_spot (*$3->origin ());
 744         }
 745         | GRACE Music {
 746                 $$ = new Grace_music ($2);
 747         }
 748         | CONTEXT STRING '=' STRING Music {
 749                 Context_specced_music *csm =  new Context_specced_music ($5);
 750
 751                 csm->translator_type_str_ = ly_scm2string ($2);
 752                 csm->translator_id_str_ = ly_scm2string ($4);
 753
 754                 $$ = csm;
 755         }
 756         | TIMES {
 757                 THIS->remember_spot ();
 758         }
 759         /* CONTINUED */
 760                 bare_unsigned '/' bare_unsigned Music
 761
 762         {
 763                 $$ = new Time_scaled_music ($3, $5, $6);
 764                 $$->set_spot (THIS->pop_spot ());
 765         }
 766         | Repeated_music                { $$ = $1; }
 767         | Simultaneous_music            { $$ = $1; }
 768         | Sequential_music              { $$ = $1; }
 769         | TRANSPOSE musical_pitch Music {
 770                 $$ = new Transposed_music ($3, *$2);
 771                 delete $2; // ugh
 772         }
 773         | TRANSPOSE steno_tonic_pitch Music {
 774                 $$ = new Transposed_music ($3, *$2);
 775                 delete $2; // ugh
 776         }
 777         | APPLY embedded_scm Music  {
 778                 SCM ret = gh_call1 ($2, $3->self_scm ());
 779                 Music *m = unsmob_music (ret);
 780                 if (!m) {
 781                         THIS->parser_error ("\\apply must return a Music");
 782                         m = new Music ();
 783                         }
 784                 $$ = m;
 785         }
 786         | NOTES
 787                 { THIS->lexer_p_->push_note_state (); }
 788         Music
 789                 { $$ = $3;
 790                   THIS->lexer_p_->pop_state ();
 791                 }
 792         | CHORDS
 793                 { THIS->lexer_p_->push_chord_state (); }
 794         Music
 795                 {
 796                   $$ = $3;
 797                   THIS->lexer_p_->pop_state ();
 798         }
 799         | LYRICS
 800                 { THIS->lexer_p_->push_lyric_state (); }
 801         Music
 802                 {
 803                   $$ = $3;
 804                   THIS->lexer_p_->pop_state ();
 805         }
 806         | relative_music        { $$ = $1; }
 807         | re_rhythmed_music     { $$ = $1; }
 808         | part_combined_music   { $$ = $1; }
 809         ;
 810
 811 relative_music:
 812         RELATIVE absolute_musical_pitch Music {
 813                 $$ = new Relative_octave_music ($3, *$2);
 814                 delete $2; // ugh
 815         }
 816         ;
 817
 818 re_rhythmed_music:
 819         ADDLYRICS Music Music {
 820                 Lyric_combine_music * l = new Lyric_combine_music ($2, $3);
 821                 $$ = l;
 822         }
 823         ;
 824
 825 part_combined_music:
 826         PARTCOMBINE STRING Music Music {
 827                 Part_combine_music * p = new Part_combine_music ($2, $3, $4);
 828                 $$ = p;
 829         }
 830         ;
 831
 832 translator_change:
 833         TRANSLATOR STRING '=' STRING  {
 834                 Music * t = new Music;
 835                 t->set_mus_property ("type",
 836                         ly_symbol2scm ("change-translator"));
 837                 t-> set_mus_property ("change-to-type", $2);
 838                 t-> set_mus_property ("change-to-id", $4);
 839
 840                 $$ = t;
 841                 $$->set_spot (THIS->here_input ());
 842         }
 843         ;
 844
 845 property_def:
 846         PROPERTY STRING '.' STRING '='  scalar {
 847                 Music *t = new Music;
 848
 849                 t->set_mus_property ("type", ly_symbol2scm ("property-set"));
 850                 t->set_mus_property ("symbol", scm_string_to_symbol ($4));
 851                 t->set_mus_property ("value", $6);
 852
 853                 Context_specced_music *csm = new Context_specced_music (t);
 854                 $$ = csm;
 855                 $$->set_spot (THIS->here_input ());
 856
 857                 csm-> translator_type_str_ = ly_scm2string ($2);
 858         }
 859         | PROPERTY STRING '.' STRING PUSH embedded_scm '=' embedded_scm {
 860                 Music *t = new Music;
 861                 t->set_mus_property ("type", ly_symbol2scm ("property-push"));
 862                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 863                 t->set_mus_property ("element-property", $6);
 864                 t->set_mus_property ("element-value", $8);
 865                 Context_specced_music *csm = new Context_specced_music (t);
 866                 $$ = csm;
 867                 $$->set_spot (THIS->here_input ());
 868
 869                 csm-> translator_type_str_ = ly_scm2string ($2);
 870         }
 871         | PROPERTY STRING '.' STRING POP embedded_scm {
 872                 Music *t = new Music;
 873                 t->set_mus_property ("type", ly_symbol2scm ("property-pop"));
 874                 t->set_mus_property ("symbols", scm_string_to_symbol ($4));
 875                 t->set_mus_property ("element-property", $6);
 876
 877                 Context_specced_music *csm = new Context_specced_music (t);
 878                 $$ = csm;
 879                 $$->set_spot (THIS->here_input ());
 880
 881                 csm-> translator_type_str_ = ly_scm2string ($2);
 882         }
 883         ;
 884
 885 scalar:
 886         string          { $$ = $1; }
 887         | bare_int      { $$ = gh_int2scm ($1); }
 888         | embedded_scm  { $$ = $1; }
 889         ;
 890
 891
 892 request_chord:
 893         pre_requests simple_element post_requests       {
 894                 Music_sequence *l = dynamic_cast<Music_sequence*>($2);
 895                 if (l) {
 896                         for (int i=0; i < $1->size(); i++)
 897                                 l->append_music ($1->elem(i));
 898                         for (int i=0; i < $3->size(); i++)
 899                                 l->append_music ($3->elem(i));
 900                         }
 901                 else
 902                         programming_error ("Need Sequence to add music to");
 903                 $$ = $2;
 904
 905         }
 906         | command_element
 907         ;
 908
 909 command_element:
 910         command_req {
 911                 $$ = new Request_chord (gh_cons ($1->self_scm (), SCM_EOL));
 912                 $$-> set_spot (THIS->here_input ());
 913                 $1-> set_spot (THIS->here_input ());
 914         }
 915         | PARTIAL duration_length ';'   {
 916                 Music * p = new Music;
 917                 p->set_mus_property ("symbol", ly_symbol2scm ( "measurePosition"));
 918                 p->set_mus_property ("type", ly_symbol2scm ("property-set"));
 919
 920                 Moment m = - $2->length_mom ();
 921                 p->set_mus_property ("value", m.make_scm());
 922                 delete $2; // ugh
 923                 Context_specced_music * sp = new Context_specced_music (p);
 924                 $$ =sp ;
 925                 sp-> translator_type_str_ = "Score";
 926         }
 927         ;
 928
 929 command_req:
 930         shorthand_command_req
 931         | verbose_command_req semicolon { $$ = $1; }
 932         ;
 933
 934 shorthand_command_req:
 935         extender_req {
 936                 $$ = $1;
 937         }
 938         | hyphen_req {
 939                 $$ = $1;
 940         }
 941         | '|'                           {
 942                 $$ = new Barcheck_req;
 943         }
 944         | '~'   {
 945                 $$ = new Tie_req;
 946         }
 947         | '['           {
 948                 Span_req*b= new Span_req;
 949                 b->set_span_dir(START);
 950                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
 951                 $$ =b;
 952         }
 953         | ']'           {
 954                 Span_req*b= new Span_req;
 955                 b->set_span_dir( STOP);
 956                 b->set_mus_property ("span-type", ly_str02scm ("beam"));
 957                 $$ = b;
 958         }
 959         | BREATHE {
 960                 $$ = new Breathing_sign_req;
 961         }
 962         ;
 963
 964
 965 verbose_command_req:
 966
 967         BAR STRING                      {
 968                 $$ = new Bar_req (ly_scm2string ($2));
 969         }
 970         | COMMANDSPANREQUEST bare_int STRING {
 971                 Span_req * sp_p = new Span_req;
 972                 sp_p-> set_span_dir ( Direction($2));
 973                 sp_p->set_mus_property ("span-type",$3);
 974                 sp_p->set_spot (THIS->here_input ());
 975                 $$ = sp_p;
 976         }
 977         | MARK  {
 978                 Mark_req * m = new Mark_req;
 979                 $$ = m;
 980         }
 981         | MARK STRING {
 982                 Mark_req *m = new Mark_req;
 983                 m->set_mus_property ("label", $2);
 984                 $$ = m;
 985
 986         }
 987         | MARK bare_unsigned {
 988                 Mark_req *m = new Mark_req;
 989                 m->set_mus_property ("label",  gh_int2scm ($2));
 990                 $$ = m;
 991         }
 992
 993         | TIME_T bare_unsigned '/' bare_unsigned        {
 994                 Time_signature_change_req *m = new Time_signature_change_req;
 995                 m->set_mus_property ("beats", gh_int2scm ( $2));
 996                 m->set_mus_property ("one-beat", gh_int2scm ($4));
 997                 $$ = m;
 998         }
 999         | PENALTY bare_int      {
1000                 Break_req * b = new Break_req;
1001                 b->set_mus_property ("penalty", gh_double2scm ( $2 / 100.0));
1002                 b->set_spot (THIS->here_input ());
1003                 $$ = b;
1004         }
1005         | SKIP duration_length {
1006                 Skip_req * skip_p = new Skip_req;
1007                 skip_p->duration_ = *$2;
1008                 delete $2; // ugh
1009                 $$ = skip_p;
1010         }
1011         | tempo_request {
1012                 $$ = $1;
1013         }
1014         | CLEF STRING {
1015                 $$ = new Clef_change_req;
1016                 $$->set_mus_property ("clef-type", $2);
1017
1018         }
1019         | KEY {
1020                 Key_change_req *key_p= new Key_change_req;
1021                 $$ = key_p;
1022         }
1023         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1024                 Key_change_req *key_p= new Key_change_req;
1025
1026                 key_p->set_mus_property ("pitch-alist", $3);
1027                 ((Music* )key_p)->transpose (* $2);
1028                 $$ = key_p;
1029         }
1030         ;
1031
1032 post_requests:
1033         {
1034                 $$ = new Link_array<Request>;
1035         }
1036         | post_requests post_request {
1037                 $2->set_spot (THIS->here_input ());
1038                 $$->push ($2);
1039         }
1040         ;
1041
1042 post_request:
1043         verbose_request
1044         | request_with_dir
1045         | close_request
1046         ;
1047
1048
1049 request_that_take_dir:
1050         gen_text_def
1051         | verbose_request
1052         | script_abbreviation {
1053                 SCM s = THIS->lexer_p_->lookup_identifier ("dash-" + ly_scm2string ($1));
1054                 Articulation_req *a = new Articulation_req;
1055                 if (gh_string_p (s))
1056                         a->set_mus_property ("articulation-type", s);
1057                 else THIS->parser_error (_ ("Expecting string as script definition"));
1058                 $$ = a;
1059         }
1060         ;
1061
1062 request_with_dir:
1063         script_dir request_that_take_dir        {
1064                 if (Script_req * gs = dynamic_cast<Script_req*> ($2))
1065                         gs->set_direction (Direction ($1));
1066                 else if ($1)
1067                         $2->origin ()->warning (_ ("Can't specify direction for this request"));
1068                 $$ = $2;
1069         }
1070         ;
1071
1072 verbose_request:
1073         REQUEST_IDENTIFIER      {
1074                 $$ = dynamic_cast<Request*> (unsmob_music ($1)->clone ());
1075                 $$->set_spot (THIS->here_input ());
1076         }
1077         | DYNAMICSCRIPT embedded_scm {
1078                 /*
1079                         TODO: junkme, use text-type == dynamic
1080                 */
1081                 Text_script_req *d = new Text_script_req;
1082                 d->set_mus_property ("text-type" , ly_symbol2scm ("dynamic"));
1083                 d->set_mus_property ("text", $2);
1084                 d->set_spot (THIS->here_input ());
1085                 $$ = d;
1086         }
1087         | TEXTSCRIPT embedded_scm {
1088                 Text_script_req *t = new Text_script_req;
1089                 t->set_mus_property ("text", $2);
1090                 t->set_spot (THIS->here_input ());
1091                 $$ = t;
1092         }
1093         | SPANREQUEST bare_int STRING {
1094                 Span_req * sp_p = new Span_req;
1095                 sp_p->set_span_dir( Direction($2));
1096                 sp_p->set_mus_property ("span-type", $3);
1097                 sp_p->set_spot (THIS->here_input ());
1098                 $$ = sp_p;
1099         }
1100         | tremolo_type  {
1101                 Tremolo_req* a = new Tremolo_req;
1102                 a->set_spot (THIS->here_input ());
1103                 a->set_mus_property ("tremolo-type", gh_int2scm ($1));
1104                 $$ = a;
1105         }
1106         | SCRIPT STRING         {
1107                 Articulation_req * a = new Articulation_req;
1108                 a->set_mus_property ("articulation-type", $2);
1109                 a->set_spot (THIS->here_input ());
1110                 $$ = a;
1111         }
1112         | ARPEGGIO {
1113                 Arpeggio_req *a = new Arpeggio_req;
1114                 a->set_spot (THIS->here_input ());
1115                 $$ = a;
1116         }
1117         ;
1118
1119 sup_quotes:
1120         '\'' {
1121                 $$ = 1;
1122         }
1123         | sup_quotes '\'' {
1124                 $$ ++;
1125         }
1126         ;
1127
1128 sub_quotes:
1129         ',' {
1130                 $$ = 1;
1131         }
1132         | sub_quotes ',' {
1133                 $$ ++ ;
1134         }
1135         ;
1136
1137 steno_musical_pitch:
1138         NOTENAME_PITCH  {
1139                 $$ = $1;
1140         }
1141         | NOTENAME_PITCH sup_quotes     {
1142                 $$ = $1;
1143                 $$->octave_i_ +=  $2;
1144         }
1145         | NOTENAME_PITCH sub_quotes      {
1146                 $$ = $1;
1147                 $$->octave_i_ += - $2;
1148         }
1149         ;
1150
1151 steno_tonic_pitch:
1152         TONICNAME_PITCH {
1153                 $$ = $1;
1154         }
1155         | TONICNAME_PITCH sup_quotes    {
1156                 $$ = $1;
1157                 $$->octave_i_ +=  $2;
1158         }
1159         | TONICNAME_PITCH sub_quotes     {
1160                 $$ = $1;
1161                 $$->octave_i_ += - $2;
1162         }
1163         ;
1164
1165 musical_pitch:
1166         steno_musical_pitch {
1167                 $$ = $1;
1168         }
1169         | MUSICAL_PITCH embedded_scm {
1170                 int sz = scm_ilength ($2);
1171                 if (sz != 3) {
1172                         THIS->parser_error (_f ("Expecting %d arguments", 3));
1173                         $2 = gh_list (gh_int2scm (0), gh_int2scm (0), gh_int2scm (0), SCM_UNDEFINED);
1174                 }
1175                 $$ = new Musical_pitch ($2);
1176         }
1177         ;
1178
1179 explicit_duration:
1180         DURATION embedded_scm   {
1181                 $$ = new Duration;
1182                 if (scm_ilength ($2) == 2)
1183                         {
1184                         $$-> durlog_i_ = gh_scm2int (gh_car($2));
1185                         $$-> dots_i_ = gh_scm2int (gh_cadr($2));
1186                         }
1187                 else
1188                         THIS->parser_error (_("Must have 2 arguments for duration"));
1189         }
1190         ;
1191
1192 extender_req:
1193         EXTENDER {
1194                 if (!THIS->lexer_p_->lyric_state_b ())
1195                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1196                 $$ = new Extender_req;
1197         }
1198         ;
1199
1200 hyphen_req:
1201         HYPHEN {
1202                 if (!THIS->lexer_p_->lyric_state_b ())
1203                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1204                 $$ = new Hyphen_req;
1205         }
1206         ;
1207
1208 close_request:
1209         close_request_parens {
1210                 $$ = $1;
1211                 dynamic_cast<Span_req*> ($$)->set_span_dir ( START);
1212         }
1213
1214 close_request_parens:
1215         '('     {
1216                 Span_req* s= new Span_req;
1217                 $$ = s;
1218                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1219         }
1220         | E_SMALLER {
1221                 Span_req*s =new Span_req;
1222                 $$ = s;
1223                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1224         }
1225         | E_BIGGER {
1226                 Span_req*s =new Span_req;
1227                 $$ = s;
1228                 s->set_mus_property ("span-type", ly_str02scm ("decrescendo"));
1229         }
1230         ;
1231
1232
1233 open_request:
1234         open_request_parens {
1235                 $$ = $1;
1236                 dynamic_cast<Span_req*> ($$)->set_span_dir (STOP);
1237         }
1238         ;
1239
1240 open_request_parens:
1241         E_EXCLAMATION   {
1242                 Span_req *s =  new Span_req;
1243                 s->set_mus_property ("span-type", ly_str02scm ( "crescendo"));
1244
1245                 $$ = s;
1246         }
1247         | ')'   {
1248                 Span_req* s= new Span_req;
1249                 $$ = s;
1250                 s->set_mus_property ("span-type", ly_str02scm( "slur"));
1251         }
1252         ;
1253
1254 gen_text_def:
1255         embedded_scm {
1256                 Text_script_req *t = new Text_script_req;
1257                 t->set_mus_property ("text", $1);
1258                 t->set_spot (THIS->here_input ());
1259                 $$ = t;
1260         }
1261         | string {
1262                 Text_script_req *t = new Text_script_req;
1263                 t->set_mus_property ("text", $1);
1264                 t->set_spot (THIS->here_input ());
1265                 $$ = t;
1266         }
1267         | DIGIT {
1268                 String ds = to_str ($1);
1269                 Text_script_req* t = new Text_script_req;
1270
1271                 t->set_mus_property ("text",  ly_str02scm (ds.ch_C()));
1272                 t->set_mus_property ("text-type" , ly_symbol2scm ("finger"));
1273                 t->set_spot (THIS->here_input ());
1274                 $$ = t;
1275         }
1276         ;
1277
1278 script_abbreviation:
1279         '^'             {
1280                 $$ = gh_str02scm  ("hat");
1281         }
1282         | '+'           {
1283                 $$ = gh_str02scm("plus");
1284         }
1285         | '-'           {
1286                 $$ = gh_str02scm ("dash");
1287         }
1288         | '|'           {
1289                 $$ = gh_str02scm ("bar");
1290         }
1291         | '>'           {
1292                 $$ = gh_str02scm ("larger");
1293         }
1294         | '.'           {
1295                 $$ = gh_str02scm ("dot");
1296         }
1297         ;
1298
1299
1300 script_dir:
1301         '_'     { $$ = DOWN; }
1302         | '^'   { $$ = UP; }
1303         | '-'   { $$ = CENTER; }
1304         ;
1305
1306 pre_requests:
1307         {
1308                 $$ = new Link_array<Request>;
1309         }
1310         | pre_requests open_request {
1311                 $$->push ($2);
1312         }
1313         ;
1314
1315 absolute_musical_pitch:
1316         steno_musical_pitch     {
1317                 $$ = $1;
1318         }
1319         ;
1320
1321 duration_length:
1322         steno_duration {
1323                 $$ = $1;
1324         }
1325         | duration_length '*' bare_unsigned {
1326                 $$->tuplet_iso_i_ *= $3;
1327         }
1328         | duration_length '/' bare_unsigned {
1329                 $$->tuplet_type_i_ *= $3;
1330         }
1331         ;
1332
1333 entered_notemode_duration:
1334         steno_duration  {
1335                 THIS->set_last_duration ($1);
1336         }
1337         ;
1338
1339 optional_notemode_duration:
1340         {
1341                 $$ = new Duration (THIS->default_duration_);
1342         }
1343         | entered_notemode_duration {
1344                 $$ = $1;
1345         }
1346         ;
1347
1348 steno_duration:
1349         bare_unsigned           {
1350                 $$ = new Duration;
1351                 if (!is_duration_b ($1))
1352                         THIS->parser_error (_f ("not a duration: %d", $1));
1353                 else {
1354                         $$->durlog_i_ = intlog2 ($1);
1355                      }
1356         }
1357         | DURATION_IDENTIFIER   {
1358                 $$ = $1->access_content_Duration (true);
1359         }
1360         | steno_duration '.'    {
1361                 $$->dots_i_ ++;
1362         }
1363         ;
1364
1365
1366 tremolo_type:
1367         ':'     {
1368                 $$ =0;
1369         }
1370         | ':' bare_unsigned {
1371                 if (!is_duration_b ($2))
1372                         THIS->parser_error (_f ("not a duration: %d", $2));
1373                 $$ = $2;
1374         }
1375         ;
1376
1377
1378 simple_element:
1379         musical_pitch exclamations questions optional_notemode_duration {
1380                 if (!THIS->lexer_p_->note_state_b ())
1381                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
1382
1383
1384                 Note_req *n = new Note_req;
1385
1386                 n->pitch_ = *$1;
1387                 n->duration_ = *$4;
1388
1389                 if ($3 % 2)
1390                         n->set_mus_property ("cautionary", SCM_BOOL_T);
1391                 if ( $2 % 2 || $3 % 2)
1392                         n->set_mus_property ("force-accidental", SCM_BOOL_T);
1393
1394
1395                 Simultaneous_music*v = new Request_chord (gh_list (n->self_scm (), SCM_UNDEFINED));
1396                 v->set_spot ($1->spot ());
1397                 n->set_spot ($1->spot ());
1398                 $$ = v;
1399
1400                 delete $1;
1401                 delete $4;
1402         }
1403         | RESTNAME optional_notemode_duration           {
1404
1405                 SCM e = SCM_UNDEFINED;
1406                   if (ly_scm2string ($1) =="s")
1407                     { /* Space */
1408                       Skip_req * skip_p = new Skip_req;
1409                       skip_p->duration_ = *$2;
1410
1411                       skip_p->set_spot (THIS->here_input());
1412                         e = skip_p->self_scm ();
1413                     }
1414                   else
1415                     {
1416                       Rest_req * rest_req_p = new Rest_req;
1417                       rest_req_p->duration_ = *$2;
1418                       rest_req_p->set_spot (THIS->here_input());
1419                         e = rest_req_p->self_scm ();
1420                     }
1421                   Simultaneous_music* velt_p = new Request_chord (gh_list (e,SCM_UNDEFINED));
1422                   velt_p->set_spot (THIS->here_input());
1423
1424                   delete $2; // ugh
1425                   $$ = velt_p;
1426         }
1427         | MEASURES optional_notemode_duration   {
1428                 Skip_req * sk = new Skip_req;
1429                 sk->duration_ = *$2;
1430
1431
1432                 Span_req *sp1 = new Span_req;
1433                 Span_req *sp2 = new Span_req;
1434                 sp1-> set_span_dir ( START);
1435                 sp2-> set_span_dir ( STOP);
1436                 SCM r = ly_str02scm ("rest");
1437                 sp1->set_mus_property ("span-type", r);
1438                 sp2->set_mus_property ("span-type", r);
1439
1440                 Request_chord * rqc1 = new Request_chord (gh_list (sp1->self_scm (), SCM_UNDEFINED));
1441                 Request_chord * rqc2 = new Request_chord (gh_list (sk->self_scm (), SCM_UNDEFINED));;
1442                 Request_chord * rqc3 = new Request_chord(gh_list (sp2->self_scm (), SCM_UNDEFINED));;
1443
1444                 SCM ms = gh_list (rqc1->self_scm (), rqc2->self_scm (), rqc3->self_scm (), SCM_UNDEFINED);
1445
1446                 $$ = new Sequential_music (ms);
1447         }
1448         | STRING {
1449                 THIS->remember_spot ();
1450         }
1451         /* cont */
1452         optional_notemode_duration      {
1453                 if (!THIS->lexer_p_->lyric_state_b ()) {
1454                         THIS->pop_spot ().error (_ ("Have to be in Lyric mode for lyrics"));
1455                         THIS->error_level_i_  = 1;
1456                         THIS->parser_error (_ ("Giving up"));
1457                 }
1458                 else
1459                         THIS->pop_spot ();
1460                 Lyric_req* lreq_p = new Lyric_req;
1461                 lreq_p->set_mus_property ("text", $1);
1462                 lreq_p->duration_ = *$3;
1463                 lreq_p->set_spot (THIS->here_input());
1464                 Simultaneous_music* velt_p = new Request_chord (gh_list (lreq_p->self_scm (), SCM_UNDEFINED));
1465
1466                 delete  $3; // ugh
1467                 $$= velt_p;
1468
1469         }
1470         | chord {
1471                 if (!THIS->lexer_p_->chord_state_b ())
1472                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
1473                 $$ = $1;
1474         }
1475         ;
1476
1477
1478 chord:
1479         steno_tonic_pitch optional_notemode_duration chord_additions chord_subtractions chord_inversion chord_bass {
1480                 $$ = get_chord (*$1, $3, $4, $5, $6, *$2);
1481                 $$->set_spot (THIS->here_input ());
1482         };
1483
1484 chord_additions:
1485         {
1486                 $$ = new Array<Musical_pitch>;
1487         }
1488         | CHORD_COLON chord_notes {
1489                 $$ = $2;
1490         }
1491         ;
1492
1493 chord_notes:
1494         chord_step {
1495                 $$ = $1
1496         }
1497         | chord_notes '.' chord_step {
1498                 $$ = $1;
1499                 $$->concat (*$3);
1500         }
1501         ;
1502
1503 chord_subtractions:
1504         {
1505                 $$ = new Array<Musical_pitch>;
1506         }
1507         | CHORD_CARET chord_notes {
1508                 $$ = $2;
1509         }
1510         ;
1511
1512
1513 chord_inversion:
1514         {
1515                 $$ = 0;
1516         }
1517         | '/' steno_tonic_pitch {
1518                 $$ = $2;
1519                 $$->set_spot (THIS->here_input ());
1520         }
1521         ;
1522
1523 chord_bass:
1524         {
1525                 $$ = 0;
1526         }
1527         | CHORD_BASS steno_tonic_pitch {
1528                 $$ = $2;
1529                 $$->set_spot (THIS->here_input ());
1530         }
1531         ;
1532
1533 chord_step:
1534         chord_note {
1535                 $$ = new Array<Musical_pitch>;
1536                 $$->push (*$1);
1537         }
1538         | CHORDMODIFIER_PITCH {
1539                 $$ = new Array<Musical_pitch>;
1540                 $$->push (*$1);
1541         }
1542         | CHORDMODIFIER_PITCH chord_note { /* Ugh. */
1543                 $$ = new Array<Musical_pitch>;
1544                 $$->push (*$1);
1545                 $$->push (*$2);
1546         }
1547         ;
1548
1549 chord_note:
1550         bare_unsigned {
1551                 $$ = new Musical_pitch;
1552                 $$->notename_i_ = ($1 - 1) % 7;
1553                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1554                 $$->accidental_i_ = 0;
1555         }
1556         | bare_unsigned '+' {
1557                 $$ = new Musical_pitch;
1558                 $$->notename_i_ = ($1 - 1) % 7;
1559                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1560                 $$->accidental_i_ = 1;
1561         }
1562         | bare_unsigned CHORD_MINUS {
1563                 $$ = new Musical_pitch;
1564                 $$->notename_i_ = ($1 - 1) % 7;
1565                 $$->octave_i_ = $1 > 7 ? 1 : 0;
1566                 $$->accidental_i_ = -1;
1567         }
1568         ;
1569
1570 /*
1571         UTILITIES
1572  */
1573 number_expression:
1574         bare_number {
1575                 $$ = $1;
1576         }
1577         | '-'  number_expression %prec UNARY_MINUS {
1578                 $$ = scm_difference ($2, SCM_UNDEFINED);
1579         }
1580         | number_expression '*' number_expression {
1581                 $$ = scm_product ($1, $3);
1582         }
1583         | number_expression '/' number_expression {
1584                 $$ = scm_divide ($1, $3);
1585         }
1586         | number_expression '+' number_expression {
1587                 $$ = scm_sum ($1, $3);
1588         }
1589         | number_expression '-' number_expression {
1590                 $$ = scm_difference ($1, $3);
1591         }
1592         | '(' number_expression ')'     {
1593                 $$ = $2;
1594         }
1595         ;
1596
1597 bare_number:
1598         UNSIGNED        {
1599                 $$ = gh_int2scm ($1);
1600         }
1601         | DIGIT         {
1602                 $$ = gh_int2scm ($1);
1603         }
1604         | REAL          {
1605                 $$ = gh_double2scm ($1);
1606         }
1607         | NUMBER_IDENTIFIER             {
1608                 $$ = $1;
1609         }
1610         | REAL CM_T     {
1611                 $$ = gh_double2scm ($1 CM);
1612         }
1613         | REAL PT_T     {
1614                 $$ = gh_double2scm ($1 PT);
1615         }
1616         | REAL IN_T     {
1617                 $$ = gh_double2scm ($1 INCH);
1618         }
1619         | REAL MM_T     {
1620                 $$ = gh_double2scm ($1 MM);
1621         }
1622         | REAL CHAR_T   {
1623                 $$ = gh_double2scm ($1 CHAR);
1624         }
1625         ;
1626
1627
1628 bare_unsigned:
1629         bare_number {
1630                 if (scm_integer_p ($1) == SCM_BOOL_T) {
1631                         $$ = gh_scm2int ($1);
1632
1633                 } else {
1634                         THIS->parser_error (_("need integer number arg"));
1635                         $$ = 0;
1636                 }
1637                 if ($$ < 0) {
1638                         THIS->parser_error (_("Must be positive integer"));
1639                         $$ = -$$;
1640                         }
1641
1642         }
1643         ;
1644 bare_int:
1645         bare_number {
1646                 if (scm_integer_p ($1) == SCM_BOOL_T)
1647                 {
1648                         int k = gh_scm2int ($1);
1649                         $$ = k;
1650                 } else
1651                 {
1652                         THIS->parser_error (_("need integer number arg"));
1653                         $$ = 0;
1654                 }
1655         }
1656         | '-' bare_int {
1657                 $$ = -$2;
1658         }
1659         ;
1660
1661
1662 string:
1663         STRING          {
1664                 $$ = $1;
1665         }
1666         | STRING_IDENTIFIER     {
1667                 $$ = $1;
1668         }
1669         | string '+' string {
1670                 $$ = scm_string_append (scm_listify ($1, $3, SCM_UNDEFINED));
1671         }
1672         ;
1673
1674
1675 exclamations:
1676                 { $$ = 0; }
1677         | exclamations '!'      { $$ ++; }
1678         ;
1679
1680 questions:
1681                 { $$ = 0; }
1682         | questions '?' { $$ ++; }
1683         ;
1684
1685
1686 semicolon:
1687         ';'
1688         ;
1689
1690 %%
1691
1692 void
1693 My_lily_parser::set_yydebug (bool b)
1694 {
1695 #ifdef YYDEBUG
1696         yydebug = b;
1697 #endif
1698 }
1699
1700 extern My_lily_parser * current_parser;
1701
1702 void
1703 My_lily_parser::do_yyparse ()
1704 {
1705
1706         current_parser = this;;
1707         yyparse ((void*)this);
1708 }
1709
1710