lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2004 Han-Wen Nienhuys <hanwen@cs.uu.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13
  14 TODO:
  15
  16 * The rules for who is protecting what are very shady. Uniformise
  17   this.
  18
  19 * There are too many lexical modes?
  20
  21 */
  22
  23 #include <ctype.h>
  24 #include <stdlib.h>
  25 #include <stdio.h>
  26
  27
  28 #include "book.hh"
  29
  30 #include "context-def.hh"
  31 #include "dimensions.hh"
  32 #include "event.hh"
  33 #include "file-path.hh"
  34 #include "input-smob.hh"
  35 #include "input.hh"
  36 #include "lily-guile.hh"
  37 #include "lilypond-input-version.hh"
  38 #include "ly-module.hh"
  39 #include "main.hh"
  40 #include "misc.hh"
  41 #include "music-list.hh"
  42 #include "music-sequence.hh"
  43 #include "my-lily-lexer.hh"
  44 #include "my-lily-parser.hh"
  45 #include "paper-book.hh"
  46 #include "output-def.hh"
  47 #include "scm-hash.hh"
  48 #include "scm-option.hh"
  49 #include "score.hh"
  50 #include "text-item.hh"
  51 #include "warn.hh"
  52
  53 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  54
  55 Music *property_op_to_music (SCM op);
  56 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops_);
  57 SCM get_next_unique_context ();
  58
  59 #define YYERROR_VERBOSE 1
  60
  61 #define YYPARSE_PARAM my_lily_parser
  62 #define YYLEX_PARAM my_lily_parser
  63 #define THIS\
  64         ((My_lily_parser *) my_lily_parser)
  65
  66 #define yyerror THIS->parser_error
  67
  68 /* Add symbols to the TAGS field of a music object.  */
  69
  70 void
  71 tag_music (Music *m, SCM tag, Input ip)
  72 {
  73         SCM tags = m->get_property ("tags");
  74         if (ly_c_symbol_p (tag))
  75                 tags = scm_cons (tag, tags);
  76         else if (ly_c_list_p (tag))
  77                 tags = ly_append2 (tag, tags);
  78         else
  79                 ip.warning (_ ("Tag must be symbol or list of symbols."));
  80
  81         m->set_property ("tags", tags);
  82 }
  83
  84 bool
  85 is_regular_identifier (SCM id)
  86 {
  87   String str = ly_scm2string (id);
  88   char const *s = str.to_str0 ();
  89
  90   bool v = true;
  91 #if 0
  92   isalpha (*s);
  93   s++;
  94 #endif
  95   while (*s && v)
  96    {
  97         v = v && isalnum (*s);
  98         s++;
  99    }
 100   return v;
 101 }
 102
 103 SCM
 104 make_simple_markup (SCM encoding, SCM a)
 105 {
 106         SCM simple = ly_scheme_function ("simple-markup");
 107         if (ly_c_symbol_p (encoding))
 108                 return scm_list_3 (ly_scheme_function ("encoded-simple-markup"),
 109                            encoding, a);
 110         return scm_list_2 (simple, a);
 111 }
 112
 113 bool
 114 is_duration (int t)
 115 {
 116   return t && t == 1 << intlog2 (t);
 117 }
 118
 119 void
 120 set_music_properties (Music *p, SCM a)
 121 {
 122   for (SCM k = a; ly_c_pair_p (k); k = ly_cdr (k))
 123         p->internal_set_property (ly_caar (k), ly_cdar (k));
 124 }
 125
 126 SCM
 127 make_chord_step (int step, int alter)
 128 {
 129         if (step == 7)
 130                 alter += FLAT;
 131
 132         while (step < 0)
 133                 step += 7;
 134         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 135         return m.smobbed_copy ();
 136 }
 137
 138
 139 SCM
 140 make_chord (SCM pitch, SCM dur, SCM modification_list)
 141 {
 142         SCM chord_ctor = ly_scheme_function ("construct-chord");
 143         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 144         scm_gc_protect_object (ch);
 145         return ch;
 146 }
 147
 148 /* Todo: actually also use apply iso. call too ...  */
 149 bool
 150 ly_input_procedure_p (SCM x)
 151 {
 152         return ly_c_procedure_p (x)
 153                 || (ly_c_pair_p (x) && ly_c_procedure_p (ly_car (x)));
 154 }
 155
 156 Music*
 157 set_property_music (SCM sym, SCM value)
 158 {
 159         Music *p = MY_MAKE_MUSIC ("PropertySet");
 160         p->set_property ("symbol", sym);
 161         p->set_property ("value", value);
 162         return p;
 163 }
 164
 165 Music*
 166 make_music_relative (Pitch start, Music *music)
 167 {
 168         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 169         relative->set_property ("element", music->self_scm ());
 170
 171         Pitch last = music->to_relative_octave (start);
 172         if (lily_1_8_relative)
 173                 music->set_property ("last-pitch", last.smobbed_copy ());
 174         return relative;
 175 }
 176
 177 Music*
 178 make_lyric_combine_music (SCM name, Music *music)
 179 {
 180         Music *combine = MY_MAKE_MUSIC ("NewLyricCombineMusic");
 181         combine->set_property ("element", music->self_scm ());
 182         combine->set_property ("associated-context", name);
 183         return combine;
 184 }
 185
 186 %}
 187
 188 /* We use SCMs to do strings, because it saves us the trouble of
 189 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 190 of the parse stack onto the heap. */
 191
 192 %left NEWLYRICS
 193
 194 %union {
 195         Book *book;
 196         Output_def *outputdef;
 197         SCM scm;
 198         String *string;
 199         Music *music;
 200         Score *score;
 201         int i;
 202 }
 203 %{
 204
 205 int
 206 yylex (YYSTYPE *s, void *v)
 207 {
 208         My_lily_parser *pars = (My_lily_parser*) v;
 209         My_lily_lexer *lex = pars->lexer_;
 210
 211         lex->lexval = (void*) s;
 212         lex->prepare_for_next_token ();
 213         return lex->yylex ();
 214 }
 215
 216
 217 %}
 218
 219 %expect 3
 220
 221 /*
 222   Three shift/reduce problems:
 223
 224 2. \markup identifier.
 225
 226   (what? --hwn)
 227
 228 3. \markup { }
 229
 230   (what? --hwn)
 231
 232
 233 4.  \repeat
 234         \repeat .. \alternative
 235
 236
 237     \repeat { \repeat .. \alternative }
 238
 239 or
 240
 241     \repeat { \repeat } \alternative
 242
 243 )
 244  */
 245
 246
 247 %pure_parser
 248
 249 %token ACCEPTS
 250 %token ADDQUOTE
 251 %token LYRICSTO
 252 %token ALIAS
 253 %token ALTERNATIVE
 254 %token BAR
 255 %token BOOK
 256 %token BOOKPAPER
 257 %token CHANGE
 258 %token CHORDMODIFIERS
 259 %token CHORDS
 260 %token DOUBLE_ANGLE_OPEN
 261 %token DOUBLE_ANGLE_CLOSE
 262 %token CLEF
 263 %token COMMANDSPANREQUEST
 264 %token CONSISTS
 265 %token CONTEXT
 266 %token DEFAULT
 267 %token DENIES
 268 %token DESCRIPTION
 269 %token EXTENDER
 270 %token FIGURES FIGURE_OPEN FIGURE_CLOSE
 271 %token FIGURE_BRACKET_CLOSE FIGURE_BRACKET_OPEN
 272 %token GROBDESCRIPTIONS
 273 %token HEADER
 274 %token HYPHEN
 275 %token INVALID
 276 %token KEY
 277 %token LYRICS
 278 %token MARK
 279 %token MIDI
 280 %token MULTI_MEASURE_REST
 281 %token NAME
 282 %token NEWCONTEXT
 283 %token NOTES
 284 %token OCTAVE
 285 %token ONCE
 286 %token OVERRIDE SET REVERT
 287 %token PAPER
 288 %token PARTIAL
 289 %token QUOTE
 290 %token RELATIVE
 291 %token REMOVE
 292 %token REPEAT
 293 %token REST
 294 %token SCM_T
 295 %token SCORE
 296 %token SEQUENTIAL
 297 %token NEWLYRICS
 298 %token SIMULTANEOUS
 299 %token SKIP
 300 %token SPANREQUEST
 301 %token TAG
 302 %token TEMPO
 303 %token TIMES
 304 %token TIME_T
 305 %token TRANSPOSE
 306 %token TRANSPOSITION
 307 %token TYPE
 308 %token UNSET
 309 %token WITH
 310 %token MARKUP
 311
 312 /* escaped */
 313 /* FIXME: this sucks.  The user will get to see these names:
 314     syntax error, unexpected E_CHAR:
 315                 \
 316                  %%
 317   */
 318
 319 %token E_CHAR E_EXCLAMATION E_SMALLER E_BIGGER E_OPEN E_CLOSE
 320 %token E_LEFTSQUARE E_RIGHTSQUARE E_TILDE
 321 %token E_BACKSLASH
 322 %token CHORD_BASS CHORD_COLON CHORD_MINUS CHORD_CARET  CHORD_SLASH
 323 %token FIGURE_SPACE
 324
 325 %token <i>      DIGIT
 326 %token <i>      UNSIGNED
 327 %token <i> E_UNSIGNED
 328 %token <id>     IDENTIFIER
 329 %token <scm>    CHORDMODIFIER_PITCH
 330 %token <scm>    DRUM_PITCH
 331 %token <scm>    DURATION_IDENTIFIER
 332 %token <scm>    EVENT_IDENTIFIER
 333 %token <scm>    MUSIC_IDENTIFIER CONTEXT_DEF_IDENTIFIER
 334 %token <scm>    NOTENAME_PITCH
 335 %token <scm>    NUMBER_IDENTIFIER
 336 %token <scm>    OUTPUT_DEF_IDENTIFIER
 337 %token <scm>    RESTNAME
 338 %token <scm> LYRICS_STRING
 339 %token <scm>    SCM_T
 340 %token <scm>    SCORE_IDENTIFIER
 341 %token <scm>    STRING
 342 %token <scm>    STRING_IDENTIFIER SCM_IDENTIFIER
 343 %token <scm>    TONICNAME_PITCH
 344 %token <scm>    CHORD_MODIFIER
 345 %token <scm>    FRACTION
 346 %token <scm>   REAL
 347 %token <scm> MARKUP_HEAD_EMPTY
 348 %token <scm> MARKUP_HEAD_MARKUP0
 349 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 350 %token <scm> MARKUP_HEAD_SCM0
 351 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 352 %token <scm> MARKUP_HEAD_SCM0_SCM1
 353 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 354 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 355 %token <scm> MARKUP_IDENTIFIER MARKUP_HEAD_LIST0
 356 %token <scm> MUSIC_FUNCTION
 357 %token <scm> MUSIC_FUNCTION_MUSIC
 358 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 359 %token <scm> MUSIC_FUNCTION_SCM
 360 %token <scm> MUSIC_FUNCTION_SCM_SCM
 361 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 362 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 363 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 364 %token DRUMS
 365
 366
 367
 368 %type <book>    book_block book_body
 369 %type <i>       bare_int  bare_unsigned
 370 %type <i>       exclamations questions dots optional_rest
 371 %type <i>       script_dir
 372 %type <i>       sub_quotes sup_quotes
 373 %type <i>       tremolo_type
 374 %type <i>       bass_mod
 375
 376 %type <music>   Composite_music Simple_music Prefix_composite_music Generic_prefix_music
 377 %type <music>   Grouped_music_list
 378 %type <music>   Music Sequential_music Simultaneous_music
 379 %type <music>   Repeated_music
 380 %type <music>   command_req
 381 %type <music>   gen_text_def direction_less_event direction_reqd_event
 382 %type <music>   music_property_def context_change
 383 %type <music>   note_chord_element chord_body chord_body_element
 384 %type <music>   open_event close_event
 385 %type <music>   post_event tagged_post_event
 386 %type <music>   relative_music re_rhythmed_music
 387 %type <music>   simple_element event_chord command_element
 388 %type <music>   string_number_event
 389 %type <music>   toplevel_music
 390 %type <music>   tempo_event
 391
 392 %type <outputdef>       output_def_body output_def_head
 393 %type <outputdef> output_def book_paper_block
 394
 395 %type <scm>     Music_list
 396 %type <scm>     chord_body_elements
 397 %type <scm>     chord_item chord_items chord_separator new_chord
 398 %type <scm>     context_def_spec_block context_def_spec_body
 399 %type <scm>     context_mod context_def_mod optional_context_mod
 400 %type <scm>     context_prop_spec
 401 %type <scm>     duration_length fraction
 402 %type <scm>     embedded_scm scalar
 403 %type <scm>     identifier_init
 404 %type <scm>     lilypond_header lilypond_header_body
 405 %type <scm>     new_lyrics
 406 %type <scm>     post_events
 407 %type <scm>     property_operation
 408 %type <scm>     script_abbreviation
 409 %type <scm>     simple_string
 410 %type <scm>     steno_pitch pitch absolute_pitch pitch_also_in_chords
 411 %type <scm>     steno_tonic_pitch
 412 %type <scm>     step_number step_numbers
 413 %type <scm>     string bare_number number_expression number_term number_factor
 414 %type <scm>     bass_number br_bass_figure bass_figure figure_list figure_spec
 415 %type <scm>     context_mod_list
 416 %type <scm>     octave_check
 417 %type <scm>     steno_duration optional_notemode_duration multiplied_duration
 418 %type <scm>     Generic_prefix_music_scm
 419 %type <scm>     lyric_element
 420 %type <scm>     Alternative_music
 421 %type <scm>     markup markup_line markup_list markup_list_body full_markup
 422
 423 %type <score>   score_block score_body
 424
 425
 426 %left '-' '+'
 427
 428 /* We don't assign precedence to / and *, because we might need varied
 429 prec levels in different prods */
 430
 431 %left UNARY_MINUS
 432
 433 %%
 434
 435 lilypond:       /* empty */
 436         | lilypond toplevel_expression {
 437         }
 438         | lilypond assignment {
 439         }
 440         | lilypond error {
 441                 THIS->error_level_ = 1;
 442         }
 443         | lilypond INVALID      {
 444                 THIS->error_level_ = 1;
 445         }
 446         ;
 447
 448 toplevel_expression:
 449         lilypond_header {
 450                 THIS->lexer_->set_identifier (ly_symbol2scm ("$globalheader"), $1);
 451         }
 452         | add_quote {
 453
 454         }
 455         | book_block {
 456                 Book *book = $1;
 457                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 458                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 459                 scm_gc_unprotect_object (book->self_scm ());
 460         }
 461         | score_block {
 462                 Score *score = $1;
 463
 464                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 465                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 466                 scm_gc_unprotect_object (score->self_scm ());
 467         }
 468         | toplevel_music {
 469                 Music *music = $1;
 470                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 471                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 472                 scm_gc_unprotect_object (music->self_scm ());
 473         }
 474         | output_def {
 475                 SCM id = SCM_EOL;
 476                 Output_def * od = $1;
 477
 478                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 479                         id = ly_symbol2scm ("$defaultpaper");
 480                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 481                         id = ly_symbol2scm ("$defaultmidi");
 482                 else if ($1->c_variable ("is-bookpaper") == SCM_BOOL_T)
 483                         id = ly_symbol2scm ("$defaultbookpaper");
 484
 485                 THIS->lexer_->set_identifier (id, od->self_scm ());
 486                 scm_gc_unprotect_object (od->self_scm ());
 487         }
 488         ;
 489
 490 toplevel_music:
 491         Composite_music {
 492         }
 493         ;
 494
 495 embedded_scm:
 496         SCM_T
 497         | SCM_IDENTIFIER
 498         ;
 499
 500
 501 lilypond_header_body:
 502         {
 503                 $$ = ly_make_anonymous_module (safe_global_b);
 504                 THIS->lexer_->add_scope ($$);
 505         }
 506         | lilypond_header_body assignment  {
 507
 508         }
 509         ;
 510
 511 lilypond_header:
 512         HEADER '{' lilypond_header_body '}'     {
 513                 $$ = THIS->lexer_->remove_scope ();
 514         }
 515         ;
 516
 517
 518 /*
 519         DECLARATIONS
 520 */
 521 assignment:
 522         STRING {
 523                 THIS->push_spot ();
 524         }
 525         /* cont */ '=' identifier_init  {
 526
 527         /*
 528                 Should find generic way of associating input with objects.
 529         */
 530                 Input ip = THIS->pop_spot ();
 531
 532                 if (! is_regular_identifier ($1))
 533                 {
 534                         ip.warning (_ ("Identifier should have alphabetic characters only"));
 535                 }
 536
 537                 THIS->lexer_->set_identifier ($1, $4);
 538
 539 /*
 540  TODO: devise standard for protection in parser.
 541
 542   The parser stack lives on the C-stack, which means that
 543 all objects can be unprotected as soon as they're here.
 544
 545 */
 546         }
 547         | embedded_scm { }
 548         ;
 549
 550
 551 identifier_init:
 552         score_block {
 553                 $$ = $1->self_scm ();
 554                 scm_gc_unprotect_object ($$);
 555         }
 556         | output_def {
 557                 $$ = $1->self_scm ();
 558                 scm_gc_unprotect_object ($$);
 559         }
 560         | context_def_spec_block {
 561                 $$ = $1;
 562         }
 563         | Music  {
 564                 $$ = $1->self_scm ();
 565                 scm_gc_unprotect_object ($$);
 566         }
 567         | post_event {
 568                 $$ = $1->self_scm ();
 569                 scm_gc_unprotect_object ($$);
 570         }
 571         | number_expression {
 572                 $$ = $1;
 573         }
 574         | string {
 575                 $$ = $1;
 576         }
 577         | embedded_scm {
 578                 $$ = $1;
 579         }
 580         | full_markup {
 581                 $$ = $1;
 582         }
 583         | DIGIT {
 584                 $$ = scm_int2num ($1);
 585         }
 586         ;
 587
 588 context_def_spec_block:
 589         CONTEXT '{' context_def_spec_body '}'
 590                 {
 591                 $$ = $3;
 592         }
 593         ;
 594
 595 context_def_spec_body:
 596         /**/ {
 597                 $$ = Context_def::make_scm ();
 598                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 599         }
 600         | CONTEXT_DEF_IDENTIFIER {
 601                 $$ = $1;
 602                 unsmob_context_def ($$)->set_spot (THIS->here_input ());
 603         }
 604         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 605                 Context_def*td = unsmob_context_def ($$);
 606
 607                 for (SCM p = $3; ly_c_pair_p (p); p = ly_cdr (p)) {
 608                         SCM tag = ly_caar (p);
 609
 610                         /* TODO: should make new tag "grob-definition" ? */
 611                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 612                                                         tag, scm_cons (ly_cdar (p), SCM_EOL)));
 613                 }
 614         }
 615         | context_def_spec_body context_mod {
 616                 unsmob_context_def ($$)->add_context_mod ($2);
 617         }
 618         ;
 619
 620
 621
 622 book_block:
 623         BOOK {
 624                 THIS->push_spot ();
 625         }
 626         /*cont*/ '{' book_body '}'      {
 627                 THIS->pop_spot ();
 628                 $$ = $4;
 629         }
 630         ;
 631
 632 /* FIXME:
 633    * Use 'handlers' like for toplevel-* stuff?
 634    * grok \paper and \midi?  */
 635 book_body:
 636         {
 637                 $$ = new Book;
 638                 $$->set_spot (THIS->here_input ());
 639                 $$->bookpaper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultbookpaper"))->clone ());
 640                 scm_gc_unprotect_object ($$->bookpaper_->self_scm ());
 641                 $$->header_ = THIS->lexer_->lookup_identifier ("$globalheader");
 642         }
 643         | book_body book_paper_block {
 644                 $$->bookpaper_ = $2;
 645                 scm_gc_unprotect_object ($2->self_scm ());
 646         }
 647         | book_body score_block {
 648                 Score *score = $2;
 649                 $$->scores_.push (score);
 650                 scm_gc_unprotect_object (score->self_scm ());
 651         }
 652         | book_body Composite_music {
 653                 Music *music = $2;
 654                 Score *score
 655                         = unsmob_score (ly_music_scorify (music->self_scm ()));
 656                 $$->scores_.push (score);
 657                 scm_gc_unprotect_object (music->self_scm ());
 658         }
 659         | book_body lilypond_header {
 660                 $$->header_ = $2;
 661         }
 662         | book_body error {
 663
 664         }
 665         ;
 666
 667 score_block:
 668         SCORE {
 669                 THIS->push_spot ();
 670         }
 671         /*cont*/ '{' score_body '}'     {
 672                 THIS->pop_spot ();
 673                 $$ = $4;
 674         }
 675         ;
 676
 677 score_body:
 678         /**/    {
 679                 $$ = new Score;
 680
 681                 $$->set_spot (THIS->here_input ());
 682         }
 683         | SCORE_IDENTIFIER {
 684                 $$ = new Score ( *unsmob_score ($1));
 685                 $$->set_spot (THIS->here_input ());
 686         }
 687         | score_body Music {
 688                 SCM m = $2->self_scm ();
 689                 scm_gc_unprotect_object (m);
 690
 691                 /*
 692                         guh.
 693                 */
 694                 SCM check_funcs = ly_scheme_function ("toplevel-music-functions");
 695                 for (; ly_c_pair_p (check_funcs); check_funcs = ly_cdr (check_funcs))
 696                         m = scm_call_1 (ly_car (check_funcs), m);
 697                 if (unsmob_music ($$->music_))
 698                 {
 699                         THIS->parser_error (_("Already have music in score"));
 700                         unsmob_music ($$->music_)->origin ()->error (_("This is the previous music"));
 701                 }
 702                 $$->music_ = m;
 703         }
 704         | score_body lilypond_header    {
 705                 $$->header_ = $2;
 706         }
 707         | score_body output_def {
 708                 $$->defs_.push ($2);
 709                 scm_gc_unprotect_object ($2->self_scm ());
 710         }
 711         | score_body error {
 712
 713         }
 714         ;
 715
 716
 717 /*
 718         OUTPUT DEF
 719 */
 720
 721 book_paper_block:
 722         output_def {
 723                 $$ = $1;
 724                 if ($$->lookup_variable (ly_symbol2scm ("is-bookpaper")) != SCM_BOOL_T)
 725                 {
 726                         THIS->parser_error (_("Need \\bookpaper for bookpaper block."));
 727                         $$ = get_bookpaper (THIS);
 728                 }
 729         }
 730         ;
 731
 732
 733 output_def:
 734         output_def_body '}' {
 735                 $$ = $1;
 736                 if ($1->parent_)
 737                         THIS->lexer_->remove_scope ();
 738
 739                 THIS->lexer_->remove_scope ();
 740                 THIS->lexer_->pop_state ();
 741         }
 742         ;
 743
 744 output_def_head:
 745         BOOKPAPER {
 746                 $$ = get_bookpaper (THIS);
 747                 $$->input_origin_ = THIS->here_input ();
 748                 THIS->lexer_->add_scope ($$->scope_);
 749         }
 750         | MIDI    {
 751                 Output_def *p = get_midi (THIS);
 752                 $$ = p;
 753                 THIS->lexer_->add_scope (p->scope_);
 754         }
 755         | PAPER         {
 756                 Output_def* p = get_paper (THIS);
 757
 758                 if (p->parent_)
 759                         THIS->lexer_->add_scope (p->parent_->scope_);
 760
 761                 THIS->lexer_->add_scope (p->scope_);
 762                 $$ = p;
 763         }
 764         ;
 765
 766
 767 output_def_body:
 768         output_def_head '{' {
 769                 $$ = $1;
 770                 $$->input_origin_.set_spot (THIS->here_input ());
 771                 THIS->lexer_->push_initial_state ();
 772         }
 773         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 774                 scm_gc_unprotect_object ($1->self_scm ());
 775                 Output_def *o = unsmob_output_def ($3);
 776                 o->input_origin_.set_spot (THIS->here_input ());
 777                 $$ = o;
 778                 THIS->lexer_->remove_scope ();
 779                 THIS->lexer_->add_scope (o->scope_);
 780                 THIS->lexer_->push_initial_state ();
 781         }
 782         | output_def_body assignment  {
 783
 784         }
 785         | output_def_body context_def_spec_block        {
 786                 assign_context_def ($$, $2);
 787         }
 788         | output_def_body tempo_event  {
 789                 /*
 790                         junk this ? there already is tempo stuff in
 791                         music.
 792                 */
 793                 int m = ly_scm2int ($2->get_property ("metronome-count"));
 794                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 795                 set_tempo ($$, d->get_length (), m);
 796                 scm_gc_unprotect_object ($2->self_scm ());
 797         }
 798         | output_def_body error {
 799
 800         }
 801         ;
 802
 803 tempo_event:
 804         TEMPO steno_duration '=' bare_unsigned  {
 805                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 806                 $$->set_property ("tempo-unit", $2);
 807                 $$->set_property ("metronome-count", scm_int2num ( $4));
 808         }
 809         ;
 810
 811 /*
 812 The representation of a  list is the
 813
 814   (LIST . LAST-CONS)
 815
 816  to have  efficient append.
 817 */
 818 Music_list:
 819         /* empty */ {
 820                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 821         }
 822         | Music_list Music {
 823                 SCM s = $$;
 824                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 825                 scm_gc_unprotect_object ($2->self_scm ()); /* UGH */
 826                 if (ly_c_pair_p (ly_cdr (s)))
 827                         scm_set_cdr_x (ly_cdr (s), c); /* append */
 828                 else
 829                         scm_set_car_x (s, c); /* set first cons */
 830                 scm_set_cdr_x (s, c);  /* remember last cell */
 831         }
 832         | Music_list embedded_scm {
 833         }
 834         | Music_list error {
 835         }
 836         ;
 837
 838
 839 Music:
 840         Simple_music
 841         | Composite_music
 842         ;
 843
 844 Alternative_music:
 845         /* empty */ {
 846                 $$ = SCM_EOL;
 847         }
 848         | ALTERNATIVE '{' Music_list '}' {
 849                 $$ = $3;
 850         }
 851         ;
 852
 853
 854 Repeated_music:
 855         REPEAT simple_string bare_unsigned Music Alternative_music
 856         {
 857                 Music *beg = $4;
 858                 int times = $3;
 859                 SCM alts = ly_c_pair_p ($5) ? ly_car ($5) : SCM_EOL;
 860                 if (times < scm_ilength (alts)) {
 861                   unsmob_music (ly_car (alts))
 862                     ->origin ()->warning (
 863                     _ ("More alternatives than repeats.  Junking excess alternatives."));
 864                   alts = ly_truncate_list (times, alts);
 865                 }
 866
 867
 868                 SCM proc = ly_scheme_function ("make-repeated-music");
 869
 870                 SCM mus = scm_call_1 (proc, $2);
 871                 scm_gc_protect_object (mus); // UGH.
 872                 Music *r = unsmob_music (mus);
 873                 if (beg)
 874                         {
 875                         r-> set_property ("element", beg->self_scm ());
 876                         scm_gc_unprotect_object (beg->self_scm ());
 877                         }
 878                 r->set_property ("repeat-count", scm_int2num (times >? 1));
 879
 880                 r-> set_property ("elements",alts);
 881                 if (ly_c_equal_p ($2, scm_makfrom0str ("tremolo"))) {
 882                         /*
 883                         TODO: move this code to Scheme.
 884                         */
 885
 886                         /*
 887                         we can not get durations and other stuff correct down the line, so we have to
 888                         add to the duration log here.
 889                         */
 890                         SCM func = ly_scheme_function ("shift-duration-log");
 891
 892                         int dots = ($3 % 3) ? 0 : 1;
 893                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
 894
 895                         Sequential_music *seq = dynamic_cast<Sequential_music*> ($4);
 896
 897                         if (seq) {
 898                                 int list_len = scm_ilength (seq->music_list ());
 899                                 if (list_len != 2)
 900                                         seq->origin ()->warning ("Chord tremolo must have 2 elements.");
 901                                 shift -= 1;
 902                                 r->compress (Moment (Rational (1, list_len)));
 903                                 }
 904                         scm_call_3 (func, r->self_scm (), scm_int2num (shift),scm_int2num (dots));
 905
 906                 }
 907                 r->set_spot (*$4->origin ());
 908
 909                 $$ = r;
 910         }
 911         ;
 912
 913 Sequential_music:
 914         SEQUENTIAL '{' Music_list '}'           {
 915                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 916                 $$->set_property ("elements", ly_car ($3));
 917                 $$->set_spot (THIS->here_input ());
 918         }
 919         | '{' Music_list '}'            {
 920                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
 921                 $$->set_property ("elements", ly_car ($2));
 922                 $$->set_spot (THIS->here_input ());
 923         }
 924         ;
 925
 926 Simultaneous_music:
 927         SIMULTANEOUS '{' Music_list '}'{
 928                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 929                 $$->set_property ("elements", ly_car ($3));
 930                 $$->set_spot (THIS->here_input ());
 931
 932         }
 933         | simul_open Music_list simul_close     {
 934                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
 935                 $$->set_property ("elements", ly_car ($2));
 936                 $$->set_spot (THIS->here_input ());
 937         }
 938         ;
 939
 940 Simple_music:
 941         event_chord             { $$ = $1; }
 942         | MUSIC_IDENTIFIER {
 943                 $$ = unsmob_music ($1);
 944         }
 945         | music_property_def
 946         | context_change
 947         ;
 948
 949
 950 optional_context_mod:
 951         /**/ { $$ = SCM_EOL; }
 952         | WITH { THIS->lexer_->push_initial_state (); }
 953         '{' context_mod_list '}'
 954         {
 955                 THIS->lexer_->pop_state ();
 956                 $$ = $4;
 957         }
 958         ;
 959
 960 context_mod_list:
 961         /* */  { $$ = SCM_EOL; }
 962         | context_mod_list context_mod  {
 963                  $$ = scm_cons ($2, $1);
 964         }
 965         ;
 966
 967
 968 Composite_music:
 969         Prefix_composite_music { $$ = $1; }
 970         | Grouped_music_list { $$ = $1; }
 971         ;
 972
 973 Grouped_music_list:
 974         Simultaneous_music              { $$ = $1; }
 975         | Sequential_music              { $$ = $1; }
 976         ;
 977
 978 Generic_prefix_music_scm:
 979         MUSIC_FUNCTION {
 980                 $$ = scm_list_2 ($1, make_input (THIS->here_input ()));
 981         }
 982         | MUSIC_FUNCTION_SCM {
 983                 THIS->push_spot ();
 984         } embedded_scm {
 985                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3);
 986         }
 987         | MUSIC_FUNCTION_MUSIC {
 988                 THIS->push_spot ();
 989         } Music {
 990                 $$ = scm_list_3 ($1, make_input (THIS->pop_spot ()), $3->self_scm ());
 991                 scm_gc_unprotect_object ($3->self_scm ());
 992         }
 993         | MUSIC_FUNCTION_SCM_MUSIC {
 994                 THIS->push_spot ();
 995         }  embedded_scm Music {
 996                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4->self_scm ());
 997                 scm_gc_unprotect_object ($4->self_scm ());
 998         }
 999         | MUSIC_FUNCTION_SCM_SCM {
1000                 THIS->push_spot ();
1001         }  embedded_scm embedded_scm {
1002                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3, $4);
1003         }
1004         | MUSIC_FUNCTION_MUSIC_MUSIC {
1005                 THIS->push_spot ();
1006         }  Music  Music {
1007                 $$ = scm_list_4 ($1, make_input (THIS->pop_spot ()), $3->self_scm (), $4->self_scm ());
1008                 scm_gc_unprotect_object ($3->self_scm ());
1009                 scm_gc_unprotect_object ($4->self_scm ());
1010         }
1011         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC {
1012                 THIS->push_spot ();
1013         } embedded_scm Music Music {
1014                 $$ = scm_list_5 ($1, make_input (THIS->pop_spot ()),
1015                         $3, $4->self_scm (), $5->self_scm ());
1016                 scm_gc_unprotect_object ($5->self_scm ());
1017                 scm_gc_unprotect_object ($4->self_scm ());
1018         }
1019         ;
1020
1021 Generic_prefix_music:
1022         Generic_prefix_music_scm {
1023                 SCM func = ly_car ($1);
1024                 Input *loc = unsmob_input (ly_cadr ($1));
1025                 SCM args = ly_cddr ($1);
1026                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1027                 int k = 0;
1028                 bool ok  = true;
1029                 for (SCM s = sig, t = args;
1030                         ok && ly_c_pair_p (s) && ly_c_pair_p (t);
1031                         s = ly_cdr (s), t = ly_cdr (t)) {
1032                         k++;
1033                         if (scm_call_1 (ly_car (s), ly_car (t)) != SCM_BOOL_T)
1034                         {
1035                                 loc->error (_f ("Argument %d failed typecheck", k));
1036                                 THIS->error_level_ = 1;
1037                                 ok = false;
1038                         }
1039                 }
1040                 SCM m = SCM_EOL;
1041                 if (ok)
1042                         m = scm_apply_0 (func, ly_cdr ($1));
1043                 if (unsmob_music (m))
1044                         {
1045                         $$ = unsmob_music (m);
1046                         scm_gc_protect_object (m);
1047                         }
1048                 else
1049                         {
1050                         if (ok)
1051                                 loc->error (_ ("Music head function should return Music object."));
1052                         $$ = MY_MAKE_MUSIC ("Music");
1053                         }
1054                 $$->set_spot (*loc);
1055         }
1056         ;
1057
1058
1059 Prefix_composite_music:
1060         Generic_prefix_music {
1061                 $$ = $1;
1062         }
1063         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1064                 $$ = context_spec_music ($2, $4, $6, $5);
1065
1066         }
1067         | CONTEXT simple_string optional_context_mod Music {
1068                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1069         }
1070         | NEWCONTEXT simple_string optional_context_mod Music {
1071                 $$ = context_spec_music ($2, get_next_unique_context (), $4,
1072                         $3);
1073         }
1074
1075         | TIMES {
1076                 THIS->push_spot ();
1077         }
1078         /* CONTINUED */
1079                 fraction Music
1080
1081         {
1082                 int n = ly_scm2int (ly_car ($3)); int d = ly_scm2int (ly_cdr ($3));
1083                 Music *mp = $4;
1084
1085                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1086                 $$->set_spot (THIS->pop_spot ());
1087
1088                 $$->set_property ("element", mp->self_scm ());
1089                 scm_gc_unprotect_object (mp->self_scm ());
1090                 $$->set_property ("numerator", scm_int2num (n));
1091                 $$->set_property ("denominator", scm_int2num (d));
1092                 $$->compress (Moment (Rational (n,d)));
1093
1094         }
1095         | Repeated_music                { $$ = $1; }
1096         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1097                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1098                 Music *p = $4;
1099                 Pitch from = *unsmob_pitch ($2);
1100                 Pitch to = *unsmob_pitch ($3);
1101
1102                 p->transpose (interval (from, to));
1103                 $$->set_property ("element", p->self_scm ());
1104                 scm_gc_unprotect_object (p->self_scm ());
1105         }
1106         | NOTES
1107                 {
1108                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1109                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1110         }
1111         Grouped_music_list
1112                 { $$ = $3;
1113                   THIS->lexer_->pop_state ();
1114                 }
1115         | DRUMS
1116                 {
1117                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1118                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1119         }
1120         Grouped_music_list
1121                 { $$ = $3;
1122                   THIS->lexer_->pop_state ();
1123                 }
1124         | FIGURES
1125                 { THIS->lexer_->push_figuredbass_state (); }
1126         Grouped_music_list
1127                 {
1128                   Music *chm = MY_MAKE_MUSIC ("UntransposableMusic");
1129                   chm->set_property ("element", $3->self_scm ());
1130                   $$ = chm;
1131                   scm_gc_unprotect_object ($3->self_scm ());
1132
1133                   THIS->lexer_->pop_state ();
1134         }
1135         | CHORDS {
1136                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1137                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1138                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1139                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1140
1141         }
1142         Grouped_music_list
1143         {
1144                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1145                   chm->set_property ("element", $3->self_scm ());
1146                   scm_gc_unprotect_object ($3->self_scm ());
1147                   $$ = chm;
1148
1149                   THIS->lexer_->pop_state ();
1150         }
1151         | LYRICS
1152                 { THIS->lexer_->push_lyric_state (); }
1153         Grouped_music_list
1154                 {
1155                   $$ = $3;
1156                   THIS->lexer_->pop_state ();
1157         }
1158         | relative_music        { $$ = $1; }
1159         | re_rhythmed_music     { $$ = $1; }
1160         | TAG embedded_scm Music {
1161                 tag_music ($3, $2, THIS->here_input ());
1162                 $$ = $3;
1163         }
1164         ;
1165
1166 relative_music:
1167         RELATIVE absolute_pitch Music {
1168                 Music *m = $3;
1169                 Pitch start = *unsmob_pitch ($2);
1170                 $$ = make_music_relative (start, m);
1171                 scm_gc_unprotect_object (m->self_scm ());
1172         }
1173         | RELATIVE Composite_music {
1174                 Music *m = $2;
1175
1176                 Pitch middle_c (0, 0, 0);
1177                 $$ = make_music_relative (middle_c, m);
1178                 scm_gc_unprotect_object (m->self_scm ());
1179         }
1180         ;
1181
1182 new_lyrics:
1183         NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1184         /*cont */
1185         Grouped_music_list {
1186         /* Can also use Music at the expensive of two S/Rs similar to
1187            \repeat \alternative */
1188                 THIS->lexer_->pop_state ();
1189 #if 0
1190                 Music *music = MY_MAKE_MUSIC ("SimultaneousMusic");
1191                 music->set_property ("elements", scm_list_1 ($3->self_scm ()));
1192                 $$ = music;
1193 #else
1194                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1195 #endif
1196         }
1197         | new_lyrics NEWLYRICS { THIS->lexer_->push_lyric_state (); }
1198         Grouped_music_list {
1199                 THIS->lexer_->pop_state ();
1200                 $$ = scm_cons ($4->self_scm (), $1);
1201         }
1202         ;
1203
1204 re_rhythmed_music:
1205         Grouped_music_list new_lyrics {
1206
1207                 /* FIXME: should find out uniqueXXX name from music */
1208                 SCM name = $1->get_property ("context-id");
1209                 //if (name == SCM_EOL)
1210                 if (!ly_c_string_p (name))
1211                         name = scm_makfrom0str ("");
1212
1213                 SCM context = scm_makfrom0str ("Lyrics");
1214                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1215
1216                 SCM lst = SCM_EOL;
1217                 for (SCM s = $2; ly_c_pair_p (s); s = ly_cdr (s))
1218                 {
1219                         Music *music = unsmob_music (ly_car (s));
1220                         Music *com = make_lyric_combine_music (name, music);
1221                         Music *csm = context_spec_music (context,
1222                                 get_next_unique_context (), com, SCM_EOL);
1223                         lst = scm_cons (csm->self_scm (), lst);
1224                 }
1225                 /* FIXME: only first lyric music is accepted,
1226                           the rest is junked */
1227                 all->set_property ("elements", scm_cons ($1->self_scm (),
1228                         lst));
1229                 $$ = all;
1230                 scm_gc_unprotect_object ($1->self_scm ());
1231         }
1232         | LYRICSTO {
1233                 THIS->lexer_->push_lyric_state ();
1234         } simple_string Music {
1235                 THIS->lexer_->pop_state ();
1236                 Music *music = $4;
1237                 SCM name = $3;
1238                 $$ = make_lyric_combine_music (name, music);
1239                 scm_gc_unprotect_object (music->self_scm ());
1240         }
1241         ;
1242
1243 context_change:
1244         CHANGE STRING '=' STRING  {
1245                 Music*t= MY_MAKE_MUSIC ("ContextChange");
1246                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1247                 t-> set_property ("change-to-id", $4);
1248
1249                 $$ = t;
1250                 $$->set_spot (THIS->here_input ());
1251         }
1252         ;
1253
1254 property_operation:
1255         STRING '=' scalar {
1256                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1257                         scm_string_to_symbol ($1), $3);
1258         }
1259         | UNSET simple_string {
1260                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1261                         scm_string_to_symbol ($2));
1262         }
1263         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1264                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1265                         scm_string_to_symbol ($2), $3, $5);
1266         }
1267         | REVERT simple_string embedded_scm {
1268                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1269                         scm_string_to_symbol ($2), $3);
1270         }
1271         ;
1272
1273 context_def_mod:
1274         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1275         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1276
1277         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1278         | DENIES { $$ = ly_symbol2scm ("denies"); }
1279
1280         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1281         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1282         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1283         | NAME { $$ = ly_symbol2scm ("context-name"); }
1284         ;
1285
1286 context_mod:
1287         property_operation { $$ = $1; }
1288         | context_def_mod STRING {
1289                 $$ = scm_list_2 ($1, $2);
1290         }
1291         ;
1292
1293 context_prop_spec:
1294         simple_string {
1295                 if (!is_regular_identifier ($1))
1296                 {
1297                         THIS->here_input ().error (_("Grob name should be alphanumeric"));
1298                 }
1299
1300                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1301                         scm_string_to_symbol ($1));
1302         }
1303         | simple_string '.' simple_string {
1304                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1305                         scm_string_to_symbol ($3));
1306         }
1307         ;
1308
1309 music_property_def:
1310         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1311                 $$ = property_op_to_music (scm_list_4 (
1312                         ly_symbol2scm ("poppush"),
1313                         ly_cadr ($2),
1314                         $3, $5));
1315                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1316         }
1317         | REVERT context_prop_spec embedded_scm {
1318                 $$ = property_op_to_music (scm_list_3 (
1319                         ly_symbol2scm ("pop"),
1320                         ly_cadr ($2),
1321                         $3));
1322
1323                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1324         }
1325         | SET context_prop_spec '=' scalar {
1326                 $$ = property_op_to_music (scm_list_3 (
1327                         ly_symbol2scm ("assign"),
1328                         ly_cadr ($2),
1329                         $4));
1330                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1331         }
1332         | UNSET context_prop_spec {
1333                 $$ = property_op_to_music (scm_list_2 (
1334                         ly_symbol2scm ("unset"),
1335                         ly_cadr ($2)));
1336                 $$= context_spec_music (ly_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1337         }
1338         | ONCE music_property_def {
1339                 SCM e = $2->get_property ("element");
1340                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1341                 $$ = $2;
1342
1343         }
1344         ;
1345
1346
1347 string:
1348         STRING {
1349                 $$ = $1;
1350         }
1351         | STRING_IDENTIFIER {
1352                 $$ = $1;
1353         }
1354         | string '+' string {
1355                 $$ = scm_string_append (scm_list_2 ($1, $3));
1356         }
1357         ;
1358
1359 simple_string: STRING {
1360                 $$ = $1;
1361         }
1362         | LYRICS_STRING {
1363                 $$ = $1;
1364         }
1365         ;
1366
1367 scalar: string {
1368                 $$ = $1;
1369         }
1370         | LYRICS_STRING {
1371                 $$ = $1;
1372         }
1373         | bare_int {
1374                 $$ = scm_int2num ($1);
1375         }
1376         | embedded_scm {
1377                 $$ = $1;
1378         }
1379         | full_markup {
1380                 $$ = $1;
1381         }
1382         | DIGIT {
1383                 $$ = scm_int2num ($1);
1384         }
1385         ;
1386
1387 /*
1388
1389 pre_events doesn't contain anything. It is a trick:
1390
1391 Adding pre_events to the simple_element
1392 makes the choice between
1393
1394   string:  STRING
1395
1396 and
1397
1398   simple_element: STRING
1399
1400 a single shift/reduction conflict.
1401
1402 nevertheless, this is not very clean, and we should find a different
1403 solution.
1404
1405 */
1406 pre_events: {
1407                 THIS->push_spot ();
1408         }
1409         ;
1410
1411 event_chord:
1412         pre_events simple_element post_events   {
1413                 SCM elts = $2-> get_property ("elements");
1414
1415                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1416
1417                 $2->set_property ("elements", elts);
1418                 $$ = $2;
1419         }
1420         | command_element
1421         | note_chord_element
1422         ;
1423
1424
1425 note_chord_element:
1426         chord_body optional_notemode_duration post_events
1427         {
1428                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1429                 SCM es = $1->get_property ("elements");
1430                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1431
1432                 for (SCM s = es; ly_c_pair_p (s); s = ly_cdr (s))
1433                   unsmob_music (ly_car (s))->set_property ("duration", dur);
1434                 es = ly_append2 (es, postevs);
1435
1436                 $1-> set_property ("elements", es);
1437                 $$ = $1;
1438         }
1439         ;
1440
1441 chord_open: '<'
1442         ;
1443
1444 chord_close: '>'
1445         ;
1446
1447 simul_open: DOUBLE_ANGLE_OPEN
1448         ;
1449
1450 simul_close: DOUBLE_ANGLE_CLOSE
1451         ;
1452
1453 chord_body:
1454         chord_open chord_body_elements chord_close
1455         {
1456                 $$ = MY_MAKE_MUSIC ("EventChord");
1457                 $$->set_property ("elements",
1458                         scm_reverse_x ($2, SCM_EOL));
1459         }
1460         ;
1461
1462 chord_body_elements:
1463         /* empty */             { $$ = SCM_EOL; }
1464         | chord_body_elements chord_body_element {
1465                 $$ = scm_cons ($2->self_scm (), $1);
1466                 scm_gc_unprotect_object ($2->self_scm ());
1467         }
1468         ;
1469
1470 chord_body_element:
1471         pitch  exclamations questions octave_check post_events
1472         {
1473                 int q = $3;
1474                 int ex = $2;
1475                 SCM check = $4;
1476                 SCM post = $5;
1477
1478                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1479                 n->set_property ("pitch", $1);
1480                 if (q % 2)
1481                         n->set_property ("cautionary", SCM_BOOL_T);
1482                 if (ex % 2 || q % 2)
1483                         n->set_property ("force-accidental", SCM_BOOL_T);
1484
1485                 if (ly_c_pair_p (post)) {
1486                         SCM arts = scm_reverse_x (post, SCM_EOL);
1487                         n->set_property ("articulations", arts);
1488                 }
1489                 if (ly_c_number_p (check))
1490                 {
1491                         int q = ly_scm2int (check);
1492                         n->set_property ("absolute-octave", scm_int2num (q-1));
1493                 }
1494
1495
1496                 $$ = n;
1497         }
1498         | DRUM_PITCH post_events {
1499                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1500                 n->set_property ("duration", $2);
1501                 n->set_property ("drum-type", $1);
1502                 n->set_spot (THIS->here_input ());
1503
1504                 if (ly_c_pair_p ($2)) {
1505                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1506                         n->set_property ("articulations", arts);
1507                 }
1508                 $$ = n;
1509         }
1510         ;
1511
1512 add_quote:
1513         ADDQUOTE string Music {
1514                 SCM adder = ly_scheme_function ("add-quotable");
1515
1516                 scm_call_2 (adder, $2, $3->self_scm ());
1517                 scm_gc_unprotect_object ($3->self_scm ());
1518         }
1519         ;
1520
1521 command_element:
1522         command_req {
1523                 $$ = MY_MAKE_MUSIC ("EventChord");
1524                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1525                 scm_gc_unprotect_object ($1->self_scm ());
1526
1527                 $$-> set_spot (THIS->here_input ());
1528                 $1-> set_spot (THIS->here_input ());
1529         }
1530         | SKIP duration_length {
1531                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1532                 skip->set_property ("duration", $2);
1533
1534                 $$ = skip;
1535         }
1536         | QUOTE STRING duration_length {
1537                 SCM tab = THIS->lexer_->lookup_identifier ("musicQuotes");
1538                 SCM evs = SCM_EOL;
1539                 if (scm_hash_table_p (tab) == SCM_BOOL_T)
1540                 {
1541                         SCM key = $2; // use symbol?
1542                         evs = scm_hash_ref (tab, key, SCM_BOOL_F);
1543                 }
1544                 Music *quote = 0;
1545                 if (ly_c_vector_p (evs))
1546                 {
1547                         quote = MY_MAKE_MUSIC ("QuoteMusic");
1548                         quote->set_property ("duration", $3);
1549                         quote->set_property ("quoted-events", evs);
1550                 } else {
1551                         THIS->here_input ().warning (_f ("Can\'t find music"));
1552                         quote = MY_MAKE_MUSIC ("Event");
1553                 }
1554                 quote->set_spot (THIS->here_input ());
1555                 $$ = quote;
1556         }
1557         | OCTAVE { THIS->push_spot (); }
1558           pitch {
1559                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1560                 $$ = m;
1561                 $$->set_spot (THIS->pop_spot ());
1562                 $$->set_property ("pitch", $3);
1563         }
1564         | E_LEFTSQUARE {
1565                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1566                 m->set_property ("span-direction", scm_int2num (START));
1567                 m->set_spot (THIS->here_input ());
1568
1569                 $$ = MY_MAKE_MUSIC ("EventChord");
1570                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1571                 scm_gc_unprotect_object (m->self_scm ());
1572                 $$->set_spot (THIS->here_input ());
1573         }
1574         | E_RIGHTSQUARE {
1575                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1576                 m->set_property ("span-direction", scm_int2num (STOP));
1577                 m->set_spot (THIS->here_input ());
1578
1579                 $$ = MY_MAKE_MUSIC ("EventChord");
1580                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1581                 $$->set_spot (THIS->here_input ());
1582                 scm_gc_unprotect_object (m->self_scm ());
1583         }
1584         | E_BACKSLASH {
1585                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1586                 $$->set_spot (THIS->here_input ());
1587         }
1588         | '|'      {
1589                 SCM pipe =THIS->lexer_->lookup_identifier ("pipeSymbol");
1590
1591                 if (Music * m = unsmob_music (pipe))
1592                         $$ = m->clone ();
1593                 else
1594                         $$ = MY_MAKE_MUSIC ("BarCheck");
1595
1596                 $$->set_spot (THIS->here_input ());
1597         }
1598         | TRANSPOSITION pitch {
1599                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1600                                         $2);
1601                 $$->set_spot (THIS-> here_input ());
1602                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1603                         $$, SCM_EOL);
1604         }
1605         | BAR STRING                    {
1606                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1607
1608                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1609                                         t, SCM_EOL);
1610                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1611                 $$->set_spot (THIS->here_input ());
1612                 t->set_spot (THIS->here_input ());
1613         }
1614         | PARTIAL duration_length       {
1615                 Moment m = - unsmob_duration ($2)->get_length ();
1616                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1617                 p->set_spot (THIS->here_input ());
1618                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1619                                         p, SCM_EOL);
1620                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1621                                         p, SCM_EOL);
1622                 $$ = p;
1623         }
1624         | CLEF STRING  {
1625                 SCM proc = ly_scheme_function ("make-clef-set");
1626
1627                 SCM result = scm_call_1 (proc, $2);
1628                 scm_gc_protect_object (result);
1629                 $$ = unsmob_music (result);
1630         }
1631         | TIME_T fraction  {
1632                 SCM proc= ly_scheme_function ("make-time-signature-set");
1633
1634                 SCM result = scm_apply_2   (proc, ly_car ($2), ly_cdr ($2), SCM_EOL);
1635                 scm_gc_protect_object (result);
1636                 $$ = unsmob_music (result);
1637         }
1638         | MARK scalar {
1639                 SCM proc = ly_scheme_function ("make-mark-set");
1640
1641                 SCM result = scm_call_1 (proc, $2);
1642                 scm_gc_protect_object (result);
1643                 $$ = unsmob_music (result);
1644         }
1645         ;
1646
1647 command_req:
1648         E_TILDE {
1649                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1650         }
1651         | MARK DEFAULT  {
1652                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1653                 $$ = m;
1654         }
1655         | tempo_event {
1656                 $$ = $1;
1657         }
1658         | KEY DEFAULT {
1659                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1660                 $$ = key;
1661         }
1662         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1663
1664                 Music *key= MY_MAKE_MUSIC ("KeyChangeEvent");
1665                 if (scm_ilength ($3) > 0)
1666                 {
1667                         key->set_property ("pitch-alist", $3);
1668                         key->set_property ("tonic", Pitch (0,0,0).smobbed_copy ());
1669                         ((Music*)key)->transpose (* unsmob_pitch ($2));
1670                 } else {
1671                         THIS->parser_error (_ ("Second argument must be pitch list."));
1672                 }
1673
1674                 $$ = key;
1675         }
1676         ;
1677
1678 post_events:
1679         /* empty */ {
1680                 $$ = SCM_EOL;
1681         }
1682         | post_events post_event {
1683                 $2->set_spot (THIS->here_input ());
1684                 $$ = scm_cons ($2->self_scm (), $$);
1685                 scm_gc_unprotect_object ($2->self_scm ());
1686         }
1687         | post_events tagged_post_event {
1688                 $2 -> set_spot (THIS->here_input ());
1689                 $$ = scm_cons ($2->self_scm (), $$);
1690                 scm_gc_unprotect_object ($2->self_scm ());
1691         }
1692         ;
1693
1694
1695 tagged_post_event:
1696         '-' TAG embedded_scm post_event {
1697                 tag_music ($4, $3, THIS->here_input ());
1698                 $$ = $4;
1699         }
1700         ;
1701
1702 post_event:
1703         direction_less_event {
1704                 $$ = $1;
1705         }
1706         | HYPHEN {
1707                 if (!THIS->lexer_->is_lyric_state ())
1708                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1709                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1710         }
1711         | EXTENDER {
1712                 if (!THIS->lexer_->is_lyric_state ())
1713                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
1714                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1715         }
1716         | script_dir direction_reqd_event {
1717                 if ($1)
1718                         $2->set_property ("direction", scm_int2num ($1));
1719                 $$ = $2;
1720         }
1721         | script_dir direction_less_event {
1722                 if ($1)
1723                         $2->set_property ("direction", scm_int2num ($1));
1724                 $$ = $2;
1725         }
1726         | string_number_event
1727         ;
1728
1729 string_number_event:
1730         E_UNSIGNED {
1731                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1732                 s->set_property ("string-number", scm_int2num ($1));
1733                 s->set_spot (THIS->here_input ());
1734                 $$ = s;
1735         }
1736         ;
1737
1738
1739 direction_less_event:
1740         '['  {
1741
1742
1743 /*
1744
1745 TODO: should take all these defs out of the parser, adn make use
1746 configurable, i.e.
1747
1748
1749 (set-articulation '~ "trill")
1750
1751 */
1752                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1753                 m->set_spot (THIS->here_input ());
1754                 m->set_property ("span-direction", scm_int2num (START));
1755                 $$ = m;
1756         }
1757         | ']'  {
1758                 Music *m = MY_MAKE_MUSIC ("BeamEvent");
1759                 m->set_spot (THIS->here_input ());
1760                 m->set_property ("span-direction", scm_int2num (STOP));
1761                 $$ = m;
1762         }
1763         | '~' {
1764                 Music *m = MY_MAKE_MUSIC ("TieEvent");
1765                 m->set_spot (THIS->here_input ());
1766                 $$ = m;
1767         }
1768         | close_event {
1769                 $$ = $1;
1770                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1771                         scm_int2num (START));
1772         }
1773         | open_event {
1774                 $$ = $1;
1775                 dynamic_cast<Music *> ($$)->set_property ("span-direction",
1776                         scm_int2num (STOP));
1777         }
1778         | EVENT_IDENTIFIER      {
1779                 $$ = unsmob_music ($1);
1780         }
1781         | tremolo_type  {
1782                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1783                a->set_spot (THIS->here_input ());
1784                a->set_property ("tremolo-type", scm_int2num ($1));
1785                $$ = a;
1786         }
1787         ;
1788
1789 direction_reqd_event:
1790         gen_text_def {
1791                 $$ = $1;
1792         }
1793         | script_abbreviation {
1794                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1795                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1796                 if (ly_c_string_p (s))
1797                         a->set_property ("articulation-type", s);
1798                 else THIS->parser_error (_ ("Expecting string as script definition"));
1799                 $$ = a;
1800         }
1801         ;
1802
1803 octave_check:
1804         /**/ { $$ = SCM_EOL; }
1805         | '='  { $$ = scm_int2num (0); }
1806         | '=' sub_quotes { $$ = scm_int2num ($2); }
1807         | '=' sup_quotes { $$ = scm_int2num ($2); }
1808         ;
1809
1810 sup_quotes:
1811         '\'' {
1812                 $$ = 1;
1813         }
1814         | sup_quotes '\'' {
1815                 $$ ++;
1816         }
1817         ;
1818
1819 sub_quotes:
1820         ',' {
1821                 $$ = 1;
1822         }
1823         | sub_quotes ',' {
1824                 $$++;
1825         }
1826         ;
1827
1828 steno_pitch:
1829         NOTENAME_PITCH  {
1830                 $$ = $1;
1831         }
1832         | NOTENAME_PITCH sup_quotes     {
1833                 Pitch p = *unsmob_pitch ($1);
1834                 p = p.transposed (Pitch ($2,0,0));
1835                 $$ = p.smobbed_copy ();
1836         }
1837         | NOTENAME_PITCH sub_quotes      {
1838                 Pitch p =* unsmob_pitch ($1);
1839                 p = p.transposed (Pitch (-$2,0,0));
1840                 $$ = p.smobbed_copy ();
1841         }
1842         ;
1843
1844 /*
1845 ugh. duplication
1846 */
1847
1848 steno_tonic_pitch:
1849         TONICNAME_PITCH {
1850                 $$ = $1;
1851         }
1852         | TONICNAME_PITCH sup_quotes    {
1853                 Pitch p = *unsmob_pitch ($1);
1854                 p = p.transposed (Pitch ($2,0,0));
1855                 $$ = p.smobbed_copy ();
1856         }
1857         | TONICNAME_PITCH sub_quotes     {
1858                 Pitch p =* unsmob_pitch ($1);
1859
1860                 p = p.transposed (Pitch (-$2,0,0));
1861                 $$ = p.smobbed_copy ();
1862         }
1863         ;
1864
1865 pitch:
1866         steno_pitch {
1867                 $$ = $1;
1868         }
1869         ;
1870
1871 pitch_also_in_chords:
1872         pitch
1873         | steno_tonic_pitch
1874         ;
1875
1876 close_event:
1877         '('     {
1878                 Music *s = MY_MAKE_MUSIC ("SlurEvent");
1879                 $$ = s;
1880                 s->set_spot (THIS->here_input ());
1881         }
1882         | E_OPEN        {
1883                 Music *s = MY_MAKE_MUSIC ("PhrasingSlurEvent");
1884                 $$ = s;
1885                 s->set_spot (THIS->here_input ());
1886         }
1887         | E_SMALLER {
1888                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1889                 $$ = s;
1890                 s->set_spot (THIS->here_input ());
1891         }
1892         | E_BIGGER {
1893                 Music *s = MY_MAKE_MUSIC ("DecrescendoEvent");
1894                 $$ = s;
1895                 s->set_spot (THIS->here_input ());
1896         }
1897         ;
1898
1899
1900 open_event:
1901         E_EXCLAMATION   {
1902                 Music *s = MY_MAKE_MUSIC ("CrescendoEvent");
1903                 s->set_spot (THIS->here_input ());
1904
1905                 $$ = s;
1906         }
1907         | ')'   {
1908                 Music *s= MY_MAKE_MUSIC ("SlurEvent");
1909                 $$ = s;
1910                 s->set_spot (THIS->here_input ());
1911
1912         }
1913         | E_CLOSE       {
1914                 Music *s= MY_MAKE_MUSIC ("PhrasingSlurEvent");
1915                 $$ = s;
1916                 s->set_property ("span-type",
1917                         scm_makfrom0str ("phrasing-slur"));
1918                 s->set_spot (THIS->here_input ());
1919         }
1920         ;
1921
1922 gen_text_def:
1923         full_markup {
1924                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1925                 t->set_property ("text", $1);
1926                 t->set_spot (THIS->here_input ());
1927                 $$ = t;
1928         }
1929         | string {
1930                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
1931                 t->set_property ("text",
1932                         make_simple_markup (THIS->lexer_->encoding (), $1));
1933                 t->set_spot (THIS->here_input ());
1934                 $$ = t;
1935
1936         }
1937         | DIGIT {
1938                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
1939                 t->set_property ("digit", scm_int2num ($1));
1940                 t->set_spot (THIS->here_input ());
1941                 $$ = t;
1942         }
1943         ;
1944
1945 script_abbreviation:
1946         '^'             {
1947                 $$ = scm_makfrom0str ("Hat");
1948         }
1949         | '+'           {
1950                 $$ = scm_makfrom0str ("Plus");
1951         }
1952         | '-'           {
1953                 $$ = scm_makfrom0str ("Dash");
1954         }
1955         | '|'           {
1956                 $$ = scm_makfrom0str ("Bar");
1957         }
1958         | '>'           {
1959                 $$ = scm_makfrom0str ("Larger");
1960         }
1961         | '.'           {
1962                 $$ = scm_makfrom0str ("Dot");
1963         }
1964         | '_' {
1965                 $$ = scm_makfrom0str ("Underscore");
1966         }
1967         ;
1968
1969 script_dir:
1970         '_'     { $$ = DOWN; }
1971         | '^'   { $$ = UP; }
1972         | '-'   { $$ = CENTER; }
1973         ;
1974
1975
1976 absolute_pitch:
1977         steno_pitch     {
1978                 $$ = $1;
1979         }
1980         ;
1981
1982 duration_length:
1983         multiplied_duration {
1984                 $$ = $1;
1985         }
1986         ;
1987
1988 optional_notemode_duration:
1989         {
1990                 Duration dd = THIS->default_duration_;
1991                 $$ = dd.smobbed_copy ();
1992
1993                 THIS->beam_check ($$);
1994         }
1995         | multiplied_duration   {
1996                 $$ = $1;
1997                 THIS->default_duration_ = *unsmob_duration ($$);
1998
1999                 THIS->beam_check ($$);
2000         }
2001         ;
2002
2003 steno_duration:
2004         bare_unsigned dots              {
2005                 int len = 0;
2006                 if (!is_duration ($1))
2007                         THIS->parser_error (_f ("not a duration: %d", $1));
2008                 else
2009                         len = intlog2 ($1);
2010
2011                 $$ = Duration (len, $2).smobbed_copy ();
2012         }
2013         | DURATION_IDENTIFIER dots      {
2014                 Duration *d = unsmob_duration ($1);
2015                 Duration k (d->duration_log (), d->dot_count () + $2);
2016                 *d = k;
2017                 $$ = $1;
2018         }
2019         ;
2020
2021 multiplied_duration:
2022         steno_duration {
2023                 $$ = $1;
2024         }
2025         | multiplied_duration '*' bare_unsigned {
2026                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2027         }
2028         | multiplied_duration '*' FRACTION {
2029                 Rational  m (ly_scm2int (ly_car ($3)), ly_scm2int (ly_cdr ($3)));
2030
2031                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2032         }
2033         ;
2034
2035 fraction:
2036         FRACTION { $$ = $1; }
2037         | UNSIGNED '/' UNSIGNED {
2038                 $$ = scm_cons (scm_int2num ($1), scm_int2num ($3));
2039         }
2040         ;
2041
2042 dots:
2043         /* empty */     {
2044                 $$ = 0;
2045         }
2046         | dots '.' {
2047                 $$ ++;
2048         }
2049         ;
2050
2051 tremolo_type:
2052         ':'     {
2053                 $$ = 0;
2054         }
2055         | ':' bare_unsigned {
2056                 if (!is_duration ($2))
2057                         THIS->parser_error (_f ("not a duration: %d", $2));
2058                 $$ = $2;
2059         }
2060         ;
2061
2062 bass_number:
2063         DIGIT   {
2064                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2065                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2066                                 $$);
2067         }
2068         | UNSIGNED {
2069                 $$ = scm_number_to_string (scm_int2num ($1), scm_int2num (10));
2070                 $$ = scm_list_2 (ly_scheme_function ("number-markup"),
2071                                 $$);
2072         }
2073         | STRING { $$ = $1; }
2074         ;
2075
2076 bass_mod:
2077         '-'     { $$ = -2; }
2078         | '+'   { $$ = 2; }
2079         | '!'   { $$ = 0; }
2080         ;
2081
2082 bass_figure:
2083         FIGURE_SPACE {
2084                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2085                 $$ = bfr->self_scm ();
2086                 scm_gc_unprotect_object ($$);
2087         }
2088         | bass_number  {
2089                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2090                 $$ = bfr->self_scm ();
2091
2092                 bfr->set_property ("figure", $1);
2093
2094                 scm_gc_unprotect_object ($$);
2095         }
2096         | bass_figure bass_mod {
2097                 Music *m = unsmob_music ($1);
2098                 if ($2) {
2099                         SCM salter = m->get_property ("alteration");
2100                         int alter = ly_c_number_p (salter) ? ly_scm2int (salter) : 0;
2101                         m->set_property ("alteration",
2102                                 scm_int2num (alter + $2));
2103                 } else {
2104                         m->set_property ("alteration", scm_int2num (0));
2105                 }
2106         }
2107         ;
2108
2109 br_bass_figure:
2110         '[' bass_figure {
2111                 $$ = $2;
2112                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2113         }
2114         | bass_figure   {
2115                 $$ = $1;
2116         }
2117         | br_bass_figure ']' {
2118                 $$ = $1;
2119                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2120         }
2121         ;
2122
2123 figure_list:
2124         /**/            {
2125                 $$ = SCM_EOL;
2126         }
2127         | figure_list br_bass_figure {
2128                 $$ = scm_cons ($2, $1);
2129         }
2130         ;
2131
2132 figure_spec:
2133         FIGURE_OPEN figure_list FIGURE_CLOSE {
2134                 Music *m = MY_MAKE_MUSIC ("EventChord");
2135                 $2 = scm_reverse_x ($2, SCM_EOL);
2136                 m->set_property ("elements", $2);
2137                 $$ = m->self_scm ();
2138         }
2139         ;
2140
2141
2142 optional_rest:
2143         /**/   { $$ = 0; }
2144         | REST { $$ = 1; }
2145         ;
2146
2147 simple_element:
2148         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2149
2150                 Input i = THIS->pop_spot ();
2151                 if (!THIS->lexer_->is_note_state ())
2152                         THIS->parser_error (_ ("Have to be in Note mode for notes"));
2153
2154                 Music *n = 0;
2155                 if ($6)
2156                         n = MY_MAKE_MUSIC ("RestEvent");
2157                 else
2158                         n = MY_MAKE_MUSIC ("NoteEvent");
2159
2160                 n->set_property ("pitch", $1);
2161                 n->set_property ("duration", $5);
2162
2163                 if (ly_c_number_p ($4))
2164                 {
2165                         int q = ly_scm2int ($4);
2166                         n->set_property ("absolute-octave", scm_int2num (q-1));
2167                 }
2168
2169                 if ($3 % 2)
2170                         n->set_property ("cautionary", SCM_BOOL_T);
2171                 if ($2 % 2 || $3 % 2)
2172                         n->set_property ("force-accidental", SCM_BOOL_T);
2173
2174                 Music *v = MY_MAKE_MUSIC ("EventChord");
2175                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2176                 scm_gc_unprotect_object (n->self_scm ());
2177
2178                 v->set_spot (i);
2179                 n->set_spot (i);
2180                 $$ = v;
2181         }
2182         | DRUM_PITCH optional_notemode_duration {
2183                 Input i = THIS->pop_spot ();
2184
2185                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2186                 n->set_property ("duration", $2);
2187                 n->set_property ("drum-type", $1);
2188
2189                 Music *v = MY_MAKE_MUSIC ("EventChord");
2190                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2191                 scm_gc_unprotect_object (n->self_scm ());
2192                 v->set_spot (i);
2193                 n->set_spot (i);
2194                 $$ = v;
2195
2196         }
2197         | figure_spec optional_notemode_duration {
2198                 Music *m = unsmob_music ($1);
2199                 Input i = THIS->pop_spot ();
2200                 m->set_spot (i);
2201                 for (SCM s = m->get_property ("elements"); ly_c_pair_p (s); s = ly_cdr (s))
2202                 {
2203                         unsmob_music (ly_car (s))->set_property ("duration", $2);
2204                 }
2205                 $$ = m;
2206         }
2207         | RESTNAME optional_notemode_duration           {
2208
2209                 Input i = THIS->pop_spot ();
2210                 Music *ev = 0;
2211                 if (ly_scm2string ($1) == "s") {
2212                         /* Space */
2213                         ev = MY_MAKE_MUSIC ("SkipEvent");
2214                   }
2215                 else {
2216                         ev = MY_MAKE_MUSIC ("RestEvent");
2217
2218                     }
2219                 ev->set_property ("duration", $2);
2220                 ev->set_spot (i);
2221                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2222                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2223                 velt->set_spot (i);
2224
2225                 scm_gc_unprotect_object (ev->self_scm ());
2226
2227                 $$ = velt;
2228         }
2229         | MULTI_MEASURE_REST optional_notemode_duration         {
2230                 THIS->pop_spot ();
2231
2232                 SCM proc = ly_scheme_function ("make-multi-measure-rest");
2233                 SCM mus = scm_call_2 (proc, $2,
2234                         make_input (THIS->here_input ()));
2235                 scm_gc_protect_object (mus);
2236                 $$ = unsmob_music (mus);
2237         }
2238
2239         | lyric_element optional_notemode_duration      {
2240                 Input i = THIS->pop_spot ();
2241                 if (!THIS->lexer_->is_lyric_state ())
2242                         THIS->parser_error (_ ("Have to be in Lyric mode for lyrics"));
2243
2244                 Music *lreq = MY_MAKE_MUSIC ("LyricEvent");
2245                 lreq->set_property ("text", $1);
2246                 lreq->set_property ("duration",$2);
2247                 lreq->set_spot (i);
2248                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2249                 velt->set_property ("elements", scm_list_1 (lreq->self_scm ()));
2250
2251                 $$= velt;
2252         }
2253         | new_chord {
2254                 THIS->pop_spot ();
2255
2256                 if (!THIS->lexer_->is_chord_state ())
2257                         THIS->parser_error (_ ("Have to be in Chord mode for chords"));
2258                 $$ = unsmob_music ($1);
2259         }
2260         ;
2261
2262 lyric_element:
2263         /* FIXME: lyric flavoured markup would be better */
2264         full_markup {
2265         }
2266         | LYRICS_STRING {
2267         }
2268         ;
2269
2270 new_chord:
2271         steno_tonic_pitch optional_notemode_duration   {
2272                 $$ = make_chord ($1, $2, SCM_EOL);
2273         }
2274         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2275                 SCM its = scm_reverse_x ($4, SCM_EOL);
2276                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2277         }
2278         ;
2279
2280 chord_items:
2281         /**/ {
2282                 $$ = SCM_EOL;
2283         }
2284         | chord_items chord_item {
2285                 $$ = scm_cons ($2, $$);
2286         }
2287         ;
2288
2289 chord_separator:
2290         CHORD_COLON {
2291                 $$ = ly_symbol2scm ("chord-colon");
2292         }
2293         | CHORD_CARET {
2294                 $$ = ly_symbol2scm ("chord-caret");
2295         }
2296         | CHORD_SLASH steno_tonic_pitch {
2297                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2298         }
2299         | CHORD_BASS steno_tonic_pitch {
2300                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2301         }
2302         ;
2303
2304 chord_item:
2305         chord_separator {
2306                 $$ = $1;
2307         }
2308         | step_numbers {
2309                 $$ = scm_reverse_x ($1, SCM_EOL);
2310         }
2311         | CHORD_MODIFIER  {
2312                 $$ = $1;
2313         }
2314         ;
2315
2316 step_numbers:
2317         step_number { $$ = scm_cons ($1, SCM_EOL); }
2318         | step_numbers '.' step_number {
2319                 $$ = scm_cons ($3, $$);
2320         }
2321         ;
2322
2323 step_number:
2324         bare_unsigned {
2325                 $$ = make_chord_step ($1, 0);
2326         }
2327         | bare_unsigned '+' {
2328                 $$ = make_chord_step ($1, SHARP);
2329         }
2330         | bare_unsigned CHORD_MINUS {
2331                 $$ = make_chord_step ($1, FLAT);
2332         }
2333         ;
2334
2335 /*
2336         UTILITIES
2337
2338 TODO: should deprecate in favor of Scheme?
2339
2340  */
2341 number_expression:
2342         number_expression '+' number_term {
2343                 $$ = scm_sum ($1, $3);
2344         }
2345         | number_expression '-' number_term {
2346                 $$ = scm_difference ($1, $3);
2347         }
2348         | number_term
2349         ;
2350
2351 number_term:
2352         number_factor {
2353                 $$ = $1;
2354         }
2355         | number_factor '*' number_factor {
2356                 $$ = scm_product ($1, $3);
2357         }
2358         | number_factor '/' number_factor {
2359                 $$ = scm_divide ($1, $3);
2360         }
2361         ;
2362
2363 number_factor:
2364         '-'  number_factor { /* %prec UNARY_MINUS */
2365                 $$ = scm_difference ($2, SCM_UNDEFINED);
2366         }
2367         | bare_number
2368         ;
2369
2370
2371 bare_number:
2372         UNSIGNED        {
2373                 $$ = scm_int2num ($1);
2374         }
2375         | REAL          {
2376                 $$ = $1;
2377         }
2378         | NUMBER_IDENTIFIER             {
2379                 $$ = $1;
2380         }
2381         | REAL NUMBER_IDENTIFIER        {
2382                 $$ = scm_make_real (ly_scm2double ($1) *ly_scm2double ($2));
2383         }
2384         | UNSIGNED NUMBER_IDENTIFIER    {
2385                 $$ = scm_make_real ($1 *ly_scm2double ($2));
2386         }
2387         ;
2388
2389
2390 bare_unsigned:
2391         UNSIGNED {
2392                         $$ = $1;
2393         }
2394         | DIGIT {
2395                 $$ = $1;
2396         }
2397         ;
2398
2399 bare_int:
2400         bare_number {
2401                 if (scm_integer_p ($1) == SCM_BOOL_T)
2402                 {
2403                         int k = ly_scm2int ($1);
2404                         $$ = k;
2405                 } else
2406                 {
2407                         THIS->parser_error (_ ("need integer number arg"));
2408                         $$ = 0;
2409                 }
2410         }
2411         | '-' bare_int {
2412                 $$ = -$2;
2413         }
2414         ;
2415
2416 exclamations:
2417                 { $$ = 0; }
2418         | exclamations '!'      { $$ ++; }
2419         ;
2420
2421 questions:
2422                 { $$ = 0; }
2423         | questions '?' { $$ ++; }
2424         ;
2425
2426
2427
2428 full_markup:
2429         MARKUP_IDENTIFIER {
2430                 $$ = $1;
2431         }
2432         | MARKUP
2433                 { THIS->lexer_->push_markup_state (); }
2434         markup
2435                 { $$ = $3;
2436                   THIS->lexer_->pop_state ();
2437                 }
2438         ;
2439
2440
2441 /*
2442 This should be done more dynamically if possible.
2443 */
2444 markup:
2445         STRING {
2446                 $$ = make_simple_markup (THIS->lexer_->encoding (), $1);
2447         }
2448         | MARKUP_HEAD_EMPTY {
2449                 $$ = scm_list_1 ($1);
2450         }
2451         | MARKUP_HEAD_MARKUP0 markup {
2452                 $$ = scm_list_2 ($1, $2);
2453         }
2454         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2455                 $$ = scm_list_3 ($1, $2, $3);
2456         }
2457         | MARKUP_HEAD_SCM0_MARKUP1 SCM_T markup {
2458                 $$ = scm_list_3 ($1, $2, $3);
2459         }
2460         | markup_line {
2461                 $$ = $1;
2462         }
2463         | MARKUP_HEAD_LIST0 markup_list {
2464                 $$ = scm_list_2 ($1,$2);
2465         }
2466         | MARKUP_HEAD_SCM0 embedded_scm {
2467                 $$ = scm_list_2 ($1, $2);
2468         }
2469         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm markup {
2470                 $$ = scm_list_4 ($1, $2, $3, $4);
2471         }
2472         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2473                 $$ = scm_list_4 ($1, $2, $3, $4);
2474         }
2475         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2476                 $$ = scm_list_3 ($1, $2, $3);
2477         }
2478         | MARKUP_IDENTIFIER {
2479                 $$ = $1;
2480         }
2481         | STRING_IDENTIFIER {
2482                 $$ = $1;
2483         }
2484         | SCORE {
2485                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2486                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2487         } '{' score_body '}' {
2488                 Score * sc = $4;
2489                 $$ = scm_list_2 (ly_scheme_function ("score-markup"), sc->self_scm ());
2490                 scm_gc_unprotect_object (sc->self_scm ());
2491                 THIS->lexer_->pop_state ();
2492         }
2493         ;
2494
2495 markup_list:
2496         chord_open markup_list_body chord_close { $$ = scm_reverse_x ($2, SCM_EOL); }
2497         ;
2498
2499 markup_line:
2500         '{' markup_list_body '}' {
2501                 SCM line = ly_scheme_function ("line-markup");
2502
2503                 $$ = scm_list_2 (line, scm_reverse_x ($2, SCM_EOL));
2504         }
2505         ;
2506
2507 markup_list_body:
2508         /**/ {  $$ = SCM_EOL; }
2509         | markup_list_body markup {
2510                 $$ = scm_cons ($2, $1);
2511         }
2512         ;
2513
2514
2515 %%
2516
2517 void
2518 My_lily_parser::set_yydebug (bool )
2519 {
2520 #if 0
2521         yydebug = 1;
2522 #endif
2523 }
2524
2525 void
2526 My_lily_parser::do_yyparse ()
2527 {
2528         yyparse ((void*)this);
2529 }
2530
2531
2532 /*
2533 Should make this optional?    It will also complain when you do
2534
2535         [s4]
2536
2537 which is entirely legitimate.
2538
2539 Or we can scrap it. Barchecks should detect wrong durations, and
2540 skipTypesetting speeds it up a lot.
2541 */
2542
2543 void
2544 My_lily_parser::beam_check (SCM dur)
2545 {
2546   Duration *d = unsmob_duration (dur);
2547   if (unsmob_music (last_beam_start_) && d->duration_log () <= 2)
2548     {
2549       Music *m = unsmob_music (last_beam_start_);
2550       m->origin ()->warning (_ ("Suspect duration found following this beam"));
2551     }
2552   last_beam_start_ = SCM_EOL;
2553 }
2554
2555
2556
2557
2558 /*
2559
2560 It is a little strange to have this function in this file, but
2561 otherwise, we have to import music classes into the lexer.
2562
2563 */
2564 int
2565 My_lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2566 {
2567         if (ly_c_string_p (sid)) {
2568                 *destination = sid;
2569                 return STRING_IDENTIFIER;
2570         } else if (ly_c_number_p (sid)) {
2571                 *destination = sid;
2572                 return NUMBER_IDENTIFIER;
2573         } else if (unsmob_context_def (sid)) {
2574                 *destination = unsmob_context_def (sid)->clone_scm ();
2575                 return CONTEXT_DEF_IDENTIFIER;
2576         } else if (unsmob_score (sid)) {
2577                 Score *score = new Score (*unsmob_score (sid));
2578                 *destination = score->self_scm ();
2579                 return SCORE_IDENTIFIER;
2580         } else if (Music *mus = unsmob_music (sid)) {
2581                 mus = mus->clone ();
2582                 *destination = mus->self_scm ();
2583                 unsmob_music (*destination)->
2584                         set_property ("origin", make_input (last_input_));
2585                 return dynamic_cast<Event*> (mus)
2586                         ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2587         } else if (unsmob_duration (sid)) {
2588                 *destination = unsmob_duration (sid)->smobbed_copy ();
2589                 return DURATION_IDENTIFIER;
2590         } else if (unsmob_output_def (sid)) {
2591                 Output_def *p = unsmob_output_def (sid);
2592                 p = p->clone ();
2593
2594                 *destination = p->self_scm ();
2595                 return OUTPUT_DEF_IDENTIFIER;
2596         } else if (Text_item::markup_p (sid)) {
2597                 *destination = sid;
2598                 return MARKUP_IDENTIFIER;
2599         }
2600
2601         return -1;
2602 }
2603
2604 Music *
2605 property_op_to_music (SCM op)
2606 {
2607         Music *m = 0;
2608         SCM tag = ly_car (op);
2609         SCM symbol = ly_cadr (op);
2610         SCM args = ly_cddr (op);
2611         SCM grob_val = SCM_UNDEFINED;
2612         SCM grob_sym = SCM_UNDEFINED;
2613         SCM val = SCM_UNDEFINED;
2614
2615         if (tag == ly_symbol2scm ("assign"))
2616                 {
2617                 m = MY_MAKE_MUSIC ("PropertySet");
2618                 val = ly_car (args);
2619                 }
2620         else if (tag == ly_symbol2scm ("unset"))
2621                 m = MY_MAKE_MUSIC ("PropertyUnset");
2622         else if (tag == ly_symbol2scm ("poppush")
2623                  || tag == ly_symbol2scm ("push"))
2624                 {
2625                 m = MY_MAKE_MUSIC ("OverrideProperty");
2626                 grob_sym = ly_car (args);
2627                 grob_val = ly_cadr (args);
2628                 }
2629         else if (tag == ly_symbol2scm ("pop")) {
2630                 m = MY_MAKE_MUSIC ("RevertProperty");
2631                 grob_sym = ly_car (args);
2632                 }
2633
2634         m->set_property ("symbol", symbol);
2635
2636         if (val != SCM_UNDEFINED)
2637                 m->set_property ("value", val);
2638         if (grob_val != SCM_UNDEFINED)
2639                 m->set_property ("grob-value", grob_val);
2640
2641         if (grob_sym != SCM_UNDEFINED)
2642                 {
2643                 bool itc = internal_type_checking_global_b;
2644                 /* UGH.
2645                 */
2646                 bool autobeam = ly_c_equal_p (symbol, ly_symbol2scm ("autoBeamSettings"));
2647                 if (autobeam)
2648                         internal_type_checking_global_b = false;
2649                 m->set_property ("grob-property", grob_sym);
2650                 if (autobeam)
2651                         internal_type_checking_global_b = itc;
2652                 }
2653
2654         if (tag == ly_symbol2scm ("poppush"))
2655                 m->set_property ("pop-first", SCM_BOOL_T);
2656
2657
2658         return m;
2659 }
2660
2661 Music*
2662 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2663 {
2664         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2665
2666         csm->set_property ("element", m->self_scm ());
2667         scm_gc_unprotect_object (m->self_scm ());
2668
2669         csm->set_property ("context-type",
2670                 ly_c_symbol_p (type) ? type : scm_string_to_symbol (type));
2671         csm->set_property ("property-operations", ops);
2672
2673         if (ly_c_string_p (id))
2674                 csm->set_property ("context-id", id);
2675         return csm;
2676 }
2677
2678 SCM
2679 get_next_unique_context ()
2680 {
2681         static int new_context_count;
2682         char s[1024];
2683         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2684         return scm_makfrom0str (s);
2685 }
2686