lily/parser.yy

   1 %{ // -*-Fundamental-*-
   2
   3 /*
   4   parser.yy -- Bison/C++ parser for LilyPond
   5
   6   source file of the GNU LilyPond music typesetter
   7
   8   (c) 1997--2005 Han-Wen Nienhuys <hanwen@xs4all.nl>
   9                  Jan Nieuwenhuizen <janneke@gnu.org>
  10 */
  11
  12 /*
  13 FIXME:
  14
  15    * The rules for who is protecting what are very shady.  Uniformise
  16      this.
  17
  18    * There are too many lexical modes?
  19 */
  20
  21 #include "config.hh"
  22
  23 #include <cctype>
  24 #include <cstdlib>
  25 #include <cstdio>
  26 using namespace std;
  27
  28 #include "book.hh"
  29 #include "context-def.hh"
  30 #include "dimensions.hh"
  31 #include "music.hh"
  32 #include "file-path.hh"
  33 #include "input-smob.hh"
  34 #include "input.hh"
  35 #include "lily-guile.hh"
  36 #include "lilypond-input-version.hh"
  37 #include "main.hh"
  38 #include "misc.hh"
  39 #include "lily-lexer.hh"
  40 #include "lily-parser.hh"
  41 #include "paper-book.hh"
  42 #include "output-def.hh"
  43 #include "scm-hash.hh"
  44 #include "program-option.hh"
  45 #include "score.hh"
  46 #include "text-interface.hh"
  47 #include "warn.hh"
  48 #include "music.hh"
  49
  50 #define MY_MAKE_MUSIC(x)  make_music_by_name (ly_symbol2scm (x))
  51
  52 Music *property_op_to_music (SCM op);
  53 Music *context_spec_music (SCM type, SCM id, Music *m, SCM ops);
  54 SCM get_next_unique_context_id ();
  55 SCM get_next_unique_lyrics_context_id ();
  56
  57 #undef _
  58 #if !HAVE_GETTEXT
  59 #define _(x) x
  60 #else
  61 #include <libintl.h>
  62 #define _(x) gettext (x)
  63 #endif
  64
  65 #define YYERROR_VERBOSE 1
  66
  67 #define YYPARSE_PARAM my_lily_parser
  68 #define YYLEX_PARAM my_lily_parser
  69 #define THIS\
  70         ((Lily_parser *) my_lily_parser)
  71
  72 #define yyerror THIS->parser_error
  73
  74 /* We use custom location type: Input objects */
  75 #define YYLTYPE Input
  76 #define YYLLOC_DEFAULT(Current,Rhs,N) \
  77         ((Current).set_location ((Rhs)[1], (Rhs)[N]))
  78
  79
  80 /* Add symbols to the TAGS field of a music object.  */
  81
  82 void
  83 tag_music (Music *m, SCM tag, Input ip)
  84 {
  85         SCM tags = m->get_property ("tags");
  86         if (scm_is_symbol (tag))
  87                 tags = scm_cons (tag, tags);
  88         else if (ly_is_list (tag))
  89                 tags = ly_append2 (tag, tags);
  90         else
  91                 ip.warning (_ ("tag must be symbol or list of symbols"));
  92
  93         m->set_property ("tags", tags);
  94 }
  95
  96 bool
  97 is_regular_identifier (SCM id)
  98 {
  99   String str = ly_scm2string (id);
 100   char const *s = str.to_str0 ();
 101
 102   bool v = true;
 103 #if 0
 104   isalpha (*s);
 105   s++;
 106 #endif
 107   while (*s && v)
 108    {
 109         v = v && isalnum (*s);
 110         s++;
 111    }
 112   return v;
 113 }
 114
 115
 116 SCM
 117 get_first_context_id (SCM type, Music *m)
 118 {
 119         SCM id = m->get_property ("context-id");
 120         if (SCM_BOOL_T == scm_equal_p (m->get_property ("context-type"), type)
 121             && scm_is_string (m->get_property ("context-id"))
 122             && scm_c_string_length (id) > 0)
 123         {
 124                 return id;
 125         }
 126         return SCM_EOL;
 127 }
 128
 129 SCM
 130 make_simple_markup (SCM a)
 131 {
 132         return a;
 133 }
 134
 135 bool
 136 is_duration (int t)
 137 {
 138   return t && t == 1 << intlog2 (t);
 139 }
 140
 141 void
 142 set_music_properties (Music *p, SCM a)
 143 {
 144   for (SCM k = a; scm_is_pair (k); k = scm_cdr (k))
 145         p->internal_set_property (scm_caar (k), scm_cdar (k));
 146 }
 147
 148 SCM
 149 make_chord_step (int step, int alter)
 150 {
 151         if (step == 7)
 152                 alter += FLAT;
 153
 154         while (step < 0)
 155                 step += 7;
 156         Pitch m ((step -1) / 7, (step - 1) % 7, alter);
 157         return m.smobbed_copy ();
 158 }
 159
 160
 161 SCM
 162 make_chord (SCM pitch, SCM dur, SCM modification_list)
 163 {
 164         SCM chord_ctor = ly_lily_module_constant ("construct-chord");
 165         SCM ch = scm_call_3 (chord_ctor, pitch, dur, modification_list);
 166
 167         unsmob_music (ch)->protect();
 168         return ch;
 169 }
 170
 171 /* Todo: actually also use apply iso. call too ...  */
 172 bool
 173 ly_input_procedure_p (SCM x)
 174 {
 175         return ly_is_procedure (x)
 176                 || (scm_is_pair (x) && ly_is_procedure (scm_car (x)));
 177 }
 178
 179 Music*
 180 set_property_music (SCM sym, SCM value)
 181 {
 182         Music *p = MY_MAKE_MUSIC ("PropertySet");
 183         p->set_property ("symbol", sym);
 184         p->set_property ("value", value);
 185         return p;
 186 }
 187
 188 Music*
 189 make_music_relative (Pitch start, Music *music)
 190 {
 191         Music *relative = MY_MAKE_MUSIC ("RelativeOctaveMusic");
 192         relative->set_property ("element", music->self_scm ());
 193
 194         Pitch last = music->to_relative_octave (start);
 195         if (lily_1_8_relative)
 196                 music->set_property ("last-pitch", last.smobbed_copy ());
 197         return relative;
 198 }
 199
 200 Music*
 201 make_lyric_combine_music (SCM name, Music *music)
 202 {
 203         Music *combine = MY_MAKE_MUSIC ("LyricCombineMusic");
 204         combine->set_property ("element", music->self_scm ());
 205         combine->set_property ("associated-context", name);
 206         return combine;
 207 }
 208
 209 %}
 210
 211 /* We use SCMs to do strings, because it saves us the trouble of
 212 deleting them.  Let's hope that a stack overflow doesnt trigger a move
 213 of the parse stack onto the heap. */
 214
 215 %left PREC_TOP
 216 %left ADDLYRICS
 217 %left PREC_BOT
 218
 219 %union {
 220         Book *book;
 221         Output_def *outputdef;
 222         SCM scm;
 223         String *string;
 224         Music *music;
 225         Score *score;
 226         int i;
 227 }
 228 %{
 229
 230 int
 231 yylex (YYSTYPE *s, YYLTYPE *loc, void *v)
 232 {
 233         Lily_parser *pars = (Lily_parser*) v;
 234         Lily_lexer *lex = pars->lexer_;
 235
 236         lex->lexval = (void*) s;
 237         lex->lexloc = loc;
 238         lex->prepare_for_next_token ();
 239         return lex->yylex ();
 240 }
 241
 242
 243 %}
 244
 245 %expect 1
 246
 247 /* One shift/reduce problem
 248
 249 1.  \repeat
 250         \repeat .. \alternative
 251
 252     \repeat { \repeat .. \alternative }
 253
 254 or
 255
 256     \repeat { \repeat } \alternative
 257 */
 258
 259
 260 %pure_parser
 261 %locations
 262
 263 /* The third option is an alias that will be used to display the
 264    syntax error.  Bison CVS now correctly handles backslash escapes.
 265
 266    FIXME: Bison needs to translate some of these, eg, STRING.
 267
 268 */
 269
 270 /* Keyword tokens with plain escaped name.  */
 271 %token ACCEPTS "\\accepts"
 272 %token ADDLYRICS "\\addlyrics"
 273 %token ADDQUOTE "\\addquote"
 274 %token ALIAS "\\alias"
 275 %token ALTERNATIVE "\\alternative"
 276 %token BAR "\\bar"
 277 %token BOOK "\book"
 278 %token CHANGE "\\change"
 279 %token CHORDMODE "\\chordmode"
 280 %token CHORDS "\\chords"
 281 %token CLEF "\\clef"
 282 %token CONSISTS "\\consists"
 283 %token CONTEXT "\\context"
 284 %token DEFAULT "\\default"
 285 %token DEFAULTCHILD "\\defaultchild"
 286 %token DENIES "\\denies"
 287 %token DESCRIPTION "\\description"
 288 %token DRUMMODE "\\drummode"
 289 %token DRUMS "\\drums"
 290 %token FIGUREMODE "\\figuremode"
 291 %token FIGURES "\\figures"
 292 %token GROBDESCRIPTIONS "\\grobdescriptions"
 293 %token HEADER "\\header"
 294 %token INVALID "\\invalid"
 295 %token KEY "\\key"
 296 %token LAYOUT "\\layout"
 297 %token LYRICMODE "\\lyricmode"
 298 %token LYRICS "\\lyrics"
 299 %token LYRICSTO "\\lyricsto"
 300 %token MARK "\\mark"
 301 %token MARKUP "\\markup"
 302 %token MIDI "\\midi"
 303 %token NAME "\\name"
 304 %token NOTEMODE "\\notemode"
 305 %token OBJECTID "\\objectid"
 306 %token OCTAVE "\\octave"
 307 %token ONCE "\\once"
 308 %token OVERRIDE "\\override"
 309 %token PAPER "\\paper"
 310 %token PARTIAL "\\partial"
 311 %token RELATIVE "\\relative"
 312 %token REMOVE "\\remove"
 313 %token REPEAT "\\repeat"
 314 %token REST "\\rest"
 315 %token REVERT "\\revert"
 316 %token SCORE "\\score"
 317 %token SEQUENTIAL "\\sequential"
 318 %token SET "\\set"
 319 %token SIMULTANEOUS "\\simultaneous"
 320 %token SKIP "\\skip"
 321 %token TAG "\\tag"
 322 %token TEMPO "\\tempo"
 323 %token TIMES "\\times"
 324 %token TRANSPOSE "\\transpose"
 325 %token TRANSPOSITION "\\transposition"
 326 %token TYPE "\\type"
 327 %token UNSET "\\unset"
 328 %token WITH "\\with"
 329
 330 /* Keyword token exceptions.  */
 331 %token TIME_T "\\time"
 332 %token NEWCONTEXT "\\new"
 333
 334
 335 /* Other string tokens.  */
 336
 337 %token CHORD_BASS "/+"
 338 %token CHORD_CARET "^"
 339 %token CHORD_COLON ":"
 340 %token CHORD_MINUS "-"
 341 %token CHORD_SLASH "/"
 342 %token DOUBLE_ANGLE_CLOSE ">>"
 343 %token DOUBLE_ANGLE_OPEN "<<"
 344 %token E_BACKSLASH "\\"
 345 %token E_ANGLE_CLOSE "\\>"
 346 %token E_CHAR "\\C[haracter]"
 347 %token E_CLOSE "\\)"
 348 %token E_EXCLAMATION "\\!"
 349 %token E_BRACKET_OPEN "\\["
 350 %token E_OPEN "\\("
 351 %token E_BRACKET_CLOSE "\\]"
 352 %token E_ANGLE_OPEN "\\<"
 353 %token E_PLUS "\\+"
 354 %token E_TILDE "\\~"
 355 %token EXTENDER "__"
 356
 357 /*
 358 If we give names, Bison complains.
 359 */
 360 %token FIGURE_CLOSE /* "\\>" */
 361 %token FIGURE_OPEN /* "\\<" */
 362 %token FIGURE_SPACE "_"
 363 %token HYPHEN "--"
 364
 365 %token CHORDMODIFIERS
 366 %token LYRIC_MARKUP
 367 %token MULTI_MEASURE_REST
 368 %token SCM_T
 369
 370
 371 %token <i> DIGIT
 372 %token <i> E_UNSIGNED
 373 %token <i> UNSIGNED
 374
 375 %token <id> IDENTIFIER
 376
 377 %token <scm> CHORDMODIFIER_PITCH
 378 %token <scm> CHORD_MODIFIER
 379 %token <scm> CONTEXT_DEF_IDENTIFIER
 380 %token <scm> DRUM_PITCH
 381 %token <scm> DURATION_IDENTIFIER
 382 %token <scm> EVENT_IDENTIFIER
 383 %token <scm> FRACTION
 384 %token <scm> LYRICS_STRING
 385 %token <scm> LYRIC_MARKUP_IDENTIFIER
 386 %token <scm> MARKUP_HEAD_EMPTY
 387 %token <scm> MARKUP_HEAD_LIST0
 388 %token <scm> MARKUP_HEAD_MARKUP0
 389 %token <scm> MARKUP_HEAD_MARKUP0_MARKUP1
 390 %token <scm> MARKUP_HEAD_SCM0
 391 %token <scm> MARKUP_HEAD_SCM0_MARKUP1
 392 %token <scm> MARKUP_HEAD_SCM0_SCM1
 393 %token <scm> MARKUP_HEAD_SCM0_SCM1_MARKUP2
 394 %token <scm> MARKUP_HEAD_SCM0_SCM1_SCM2
 395 %token <scm> MARKUP_IDENTIFIER
 396 %token <scm> MUSIC_FUNCTION
 397 %token <scm> MUSIC_FUNCTION_MARKUP
 398 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP
 399 %token <scm> MUSIC_FUNCTION_MARKUP_MARKUP_MUSIC
 400 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC
 401 %token <scm> MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC
 402 %token <scm> MUSIC_FUNCTION_MUSIC
 403 %token <scm> MUSIC_FUNCTION_MUSIC_MUSIC
 404 %token <scm> MUSIC_FUNCTION_SCM
 405 %token <scm> MUSIC_FUNCTION_SCM_MUSIC
 406 %token <scm> MUSIC_FUNCTION_SCM_MUSIC_MUSIC
 407 %token <scm> MUSIC_FUNCTION_SCM_SCM
 408 %token <scm> MUSIC_FUNCTION_SCM_SCM_MUSIC
 409 %token <scm> MUSIC_FUNCTION_SCM_SCM_SCM
 410 %token <scm> MUSIC_IDENTIFIER
 411 %token <scm> NOTENAME_PITCH
 412 %token <scm> NUMBER_IDENTIFIER
 413 %token <scm> OUTPUT_DEF_IDENTIFIER
 414 %token <scm> REAL
 415 %token <scm> RESTNAME
 416 %token <scm> SCM_IDENTIFIER
 417 %token <scm> SCM_T
 418 %token <scm> SCORE_IDENTIFIER
 419 %token <scm> STRING
 420 %token <scm> STRING_IDENTIFIER
 421 %token <scm> TONICNAME_PITCH
 422
 423
 424 %type <book> book_block
 425 %type <book> book_body
 426
 427 %type <i> bare_unsigned
 428 %type <i> figured_bass_alteration
 429 %type <i> dots
 430 %type <i> exclamations
 431 %type <i> optional_rest
 432 %type <i> questions
 433 %type <i> script_dir
 434 %type <i> sub_quotes
 435 %type <i> sup_quotes
 436 %type <i> tremolo_type
 437
 438 %type <music> Composite_music
 439 %type <music> Generic_prefix_music
 440 %type <music> Grouped_music_list
 441 %type <music> Music
 442 %type <music> Prefix_composite_music
 443 %type <music> Repeated_music
 444 %type <music> Sequential_music
 445 %type <music> Simple_music
 446 %type <music> Simultaneous_music
 447 %type <music> chord_body
 448 %type <music> chord_body_element
 449 %type <music> command_element
 450 %type <music> command_event
 451 %type <music> context_change
 452 %type <music> direction_less_event
 453 %type <music> direction_reqd_event
 454 %type <music> event_chord
 455 %type <music> gen_text_def
 456 %type <music> music_property_def
 457 %type <music> note_chord_element
 458 %type <music> post_event
 459 %type <music> re_rhythmed_music
 460 %type <music> relative_music
 461 %type <music> simple_element
 462 %type <music> string_number_event
 463 %type <music> tagged_post_event
 464 %type <music> tempo_event
 465 %type <music> toplevel_music
 466
 467 %type <outputdef> output_def_body
 468 %type <outputdef> output_def_head
 469 %type <outputdef> output_def
 470 %type <outputdef> paper_block
 471
 472 %type <scm> Alternative_music
 473 %type <scm> Generic_prefix_music_scm
 474 %type <scm> Music_list
 475 %type <scm> absolute_pitch
 476 %type <scm> assignment_id
 477 %type <scm> bare_number
 478 %type <scm> bass_figure
 479 %type <scm> figured_bass_modification
 480 %type <scm> br_bass_figure
 481 %type <scm> bass_number
 482 %type <scm> chord_body_elements
 483 %type <scm> chord_item
 484 %type <scm> chord_items
 485 %type <scm> chord_separator
 486 %type <scm> context_def_mod
 487 %type <scm> context_def_spec_block
 488 %type <scm> context_def_spec_body
 489 %type <scm> context_mod
 490 %type <scm> context_mod_list
 491 %type <scm> context_prop_spec
 492 %type <scm> direction_less_char
 493 %type <scm> duration_length
 494 %type <scm> embedded_scm
 495 %type <scm> figure_list
 496 %type <scm> figure_spec
 497 %type <scm> fraction
 498 %type <scm> full_markup
 499 %type <scm> identifier_init
 500 %type <scm> lilypond_header
 501 %type <scm> lilypond_header_body
 502 %type <scm> lyric_element
 503 %type <scm> lyric_markup
 504 %type <scm> markup
 505 %type <scm> markup_braced_list
 506 %type <scm> markup_braced_list_body
 507 %type <scm> markup_composed_list
 508 %type <scm> markup_head_1_item
 509 %type <scm> markup_head_1_list
 510 %type <scm> markup_list
 511 %type <scm> markup_top
 512 %type <scm> mode_changing_head
 513 %type <scm> mode_changing_head_with_context
 514 %type <scm> multiplied_duration
 515 %type <scm> new_chord
 516 %type <scm> new_lyrics
 517 %type <scm> number_expression
 518 %type <scm> number_factor
 519 %type <scm> number_term
 520 %type <scm> object_id_setting
 521 %type <scm> octave_check
 522 %type <scm> optional_context_mod
 523 %type <scm> optional_notemode_duration
 524 %type <scm> pitch
 525 %type <scm> pitch_also_in_chords
 526 %type <scm> post_events
 527 %type <scm> property_operation
 528 %type <scm> scalar
 529 %type <scm> script_abbreviation
 530 %type <scm> simple_markup
 531 %type <scm> simple_string
 532 %type <scm> steno_duration
 533 %type <scm> steno_pitch
 534 %type <scm> steno_tonic_pitch
 535 %type <scm> step_number
 536 %type <scm> step_numbers
 537 %type <scm> string
 538
 539 %type <score> score_block
 540 %type <score> score_body
 541
 542
 543 %left '-' '+'
 544
 545 /* We don't assign precedence to / and *, because we might need varied
 546 prec levels in different prods */
 547
 548 %left UNARY_MINUS
 549
 550 %%
 551
 552 lilypond:       /* empty */
 553         | lilypond toplevel_expression {
 554         }
 555         | lilypond assignment {
 556         }
 557         | lilypond error {
 558                 THIS->error_level_ = 1;
 559         }
 560         | lilypond INVALID      {
 561                 THIS->error_level_ = 1;
 562         }
 563         ;
 564
 565
 566 object_id_setting:
 567         OBJECTID STRING { $$ = $2; }
 568         ;
 569
 570 toplevel_expression:
 571         lilypond_header {
 572                 THIS->lexer_->set_identifier (ly_symbol2scm ("$defaultheader"), $1);
 573         }
 574         | add_quote {
 575
 576         }
 577         | book_block {
 578                 Book *book = $1;
 579                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-book-handler");
 580                 scm_call_2 (proc, THIS->self_scm (), book->self_scm ());
 581                 book->unprotect ();
 582         }
 583         | score_block {
 584                 Score *score = $1;
 585
 586                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-score-handler");
 587                 scm_call_2 (proc, THIS->self_scm (), score->self_scm ());
 588                 score->unprotect ();
 589         }
 590         | toplevel_music {
 591                 Music *music = $1;
 592                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-music-handler");
 593                 scm_call_2 (proc, THIS->self_scm (), music->self_scm ());
 594                 music->unprotect ();
 595         }
 596         | full_markup {
 597                 SCM proc = THIS->lexer_->lookup_identifier ("toplevel-text-handler");
 598                 scm_call_2 (proc, THIS->self_scm (), $1);
 599         }
 600         | output_def {
 601                 SCM id = SCM_EOL;
 602                 Output_def * od = $1;
 603
 604                 if ($1->c_variable ("is-paper") == SCM_BOOL_T)
 605                         id = ly_symbol2scm ("$defaultpaper");
 606                 else if ($1->c_variable ("is-midi") == SCM_BOOL_T)
 607                         id = ly_symbol2scm ("$defaultmidi");
 608                 else if ($1->c_variable ("is-layout") == SCM_BOOL_T)
 609                         id = ly_symbol2scm ("$defaultlayout");
 610
 611                 THIS->lexer_->set_identifier (id, od->self_scm ());
 612                 od->unprotect();
 613         }
 614         ;
 615
 616 toplevel_music:
 617         Composite_music {
 618         }
 619         ;
 620
 621 embedded_scm:
 622         SCM_T
 623         | SCM_IDENTIFIER
 624         ;
 625
 626
 627 lilypond_header_body:
 628         {
 629                 $$ = get_header(THIS);
 630                 THIS->lexer_->add_scope ($$);
 631         }
 632         | lilypond_header_body assignment  {
 633
 634         }
 635         ;
 636
 637 lilypond_header:
 638         HEADER '{' lilypond_header_body '}'     {
 639                 $$ = THIS->lexer_->remove_scope ();
 640         }
 641         ;
 642
 643 /*
 644         DECLARATIONS
 645 */
 646 assignment_id:
 647         STRING          { $$ = $1; }
 648         | LYRICS_STRING { $$ = $1; }
 649         ;
 650
 651 assignment:
 652         assignment_id '=' identifier_init  {
 653                 if (! is_regular_identifier ($1))
 654                 {
 655                         @1.warning (_ ("identifier should have alphabetic characters only"));
 656                 }
 657
 658                 THIS->lexer_->set_identifier ($1, $3);
 659
 660 /*
 661  TODO: devise standard for protection in parser.
 662
 663   The parser stack lives on the C-stack, which means that
 664 all objects can be unprotected as soon as they're here.
 665
 666 */
 667         }
 668         | embedded_scm { }
 669         ;
 670
 671
 672 identifier_init:
 673         score_block {
 674                 $$ = $1->self_scm ();
 675                 $1->unprotect ();
 676         }
 677         | output_def {
 678                 $$ = $1->self_scm ();
 679                 $1->unprotect ();
 680         }
 681         | context_def_spec_block {
 682                 $$ = $1;
 683         }
 684         | Music  {
 685                 $$ = $1->self_scm ();
 686                 $1->unprotect();
 687         }
 688         | post_event {
 689                 $$ = $1->self_scm ();
 690                 $1->unprotect();
 691         }
 692         | number_expression {
 693                 $$ = $1;
 694         }
 695         | string {
 696                 $$ = $1;
 697         }
 698         | embedded_scm {
 699                 $$ = $1;
 700         }
 701         | full_markup {
 702                 $$ = $1;
 703         }
 704         | DIGIT {
 705                 $$ = scm_from_int ($1);
 706         }
 707         ;
 708
 709 context_def_spec_block:
 710         CONTEXT '{' context_def_spec_body '}'
 711                 {
 712                 $$ = $3;
 713         }
 714         ;
 715
 716 context_def_spec_body:
 717         /**/ {
 718                 $$ = Context_def::make_scm ();
 719                 unsmob_context_def ($$)->set_spot (@$);
 720         }
 721         | CONTEXT_DEF_IDENTIFIER {
 722                 $$ = $1;
 723                 unsmob_context_def ($$)->set_spot (@$);
 724         }
 725         | context_def_spec_body GROBDESCRIPTIONS embedded_scm {
 726                 Context_def*td = unsmob_context_def ($$);
 727
 728                 for (SCM p = $3; scm_is_pair (p); p = scm_cdr (p)) {
 729                         SCM tag = scm_caar (p);
 730
 731                         /* TODO: should make new tag "grob-definition" ? */
 732                         td->add_context_mod (scm_list_3 (ly_symbol2scm ("assign"),
 733                                                         tag, scm_cons (scm_cdar (p), SCM_EOL)));
 734                 }
 735         }
 736         | context_def_spec_body context_mod {
 737                 unsmob_context_def ($$)->add_context_mod ($2);
 738         }
 739         ;
 740
 741
 742
 743 book_block:
 744         BOOK '{' book_body '}'  {
 745                 $$ = $3;
 746         }
 747         ;
 748
 749 /* FIXME:
 750    * Use 'handlers' like for toplevel-* stuff?
 751    * grok \layout and \midi?  */
 752 book_body:
 753         {
 754                 $$ = new Book;
 755                 $$->set_spot (@$);
 756                 $$->paper_ = dynamic_cast<Output_def*> (unsmob_output_def (THIS->lexer_->lookup_identifier ("$defaultpaper"))->clone ());
 757                 $$->paper_->unprotect ();
 758                 $$->header_ = THIS->lexer_->lookup_identifier ("$defaultheader");
 759         }
 760         | book_body paper_block {
 761                 $$->paper_ = $2;
 762                 $2->unprotect ();
 763         }
 764         | book_body score_block {
 765                 SCM s = $2->self_scm ();
 766                 $$->add_score (s);
 767                 $2->unprotect();
 768         }
 769         | book_body full_markup {
 770                 $$->add_score ($2);
 771         }
 772         | book_body lilypond_header {
 773                 $$->header_ = $2;
 774         }
 775         | book_body error {
 776                 $$->paper_ = 0;
 777                 $$->scores_ = SCM_EOL;
 778         }
 779         | book_body object_id_setting {
 780                 $$->user_key_ = ly_scm2string ($2);
 781         }
 782         ;
 783
 784 score_block:
 785         SCORE '{' score_body '}'        {
 786                 $$ = $3;
 787         }
 788         ;
 789
 790 score_body:
 791         Music {
 792                 SCM m = $1->self_scm ();
 793                 $1->unprotect();
 794                 SCM scorify = ly_lily_module_constant ("scorify-music");
 795                 SCM score = scm_call_2 (scorify, m, THIS->self_scm ());
 796
 797                 // pass ownernship to C++ again.
 798                 $$ = unsmob_score (score);
 799                 $$->protect ();
 800                 $$->set_spot (@$);
 801         }
 802         | SCORE_IDENTIFIER {
 803                 $$ = unsmob_score ($1);
 804                 $$->set_spot (@$);
 805         }
 806         | score_body object_id_setting {
 807                 $$->user_key_ = ly_scm2string ($2);
 808         }
 809         | score_body lilypond_header    {
 810                 $$->header_ = $2;
 811         }
 812         | score_body output_def {
 813                 if ($2->lookup_variable (ly_symbol2scm ("is-paper")) == SCM_BOOL_T)
 814                 {
 815                         THIS->parser_error (@2, _("\\paper cannot be used in \\score, use \\layout instead"));
 816
 817                 }
 818                 else
 819                 {
 820                         $$->defs_.push ($2);
 821                 }
 822                 $2->unprotect ();
 823         }
 824         | score_body error {
 825                 $$->error_found_ = true;
 826         }
 827         ;
 828
 829
 830 /*
 831         OUTPUT DEF
 832 */
 833
 834 paper_block:
 835         output_def {
 836                 $$ = $1;
 837                 if ($$->lookup_variable (ly_symbol2scm ("is-paper")) != SCM_BOOL_T)
 838                 {
 839                         THIS->parser_error (@1, _ ("need \\paper for paper block"));
 840                         $$ = get_paper (THIS);
 841                 }
 842         }
 843         ;
 844
 845
 846 output_def:
 847         output_def_body '}' {
 848                 $$ = $1;
 849
 850                 THIS->lexer_->remove_scope ();
 851                 THIS->lexer_->pop_state ();
 852         }
 853         ;
 854
 855 output_def_head:
 856         PAPER {
 857                 $$ = get_paper (THIS);
 858                 $$->input_origin_ = @$;
 859                 THIS->lexer_->add_scope ($$->scope_);
 860         }
 861         | MIDI    {
 862                 Output_def *p = get_midi (THIS);
 863                 $$ = p;
 864                 THIS->lexer_->add_scope (p->scope_);
 865         }
 866         | LAYOUT        {
 867                 Output_def *p = get_layout (THIS);
 868
 869                 THIS->lexer_->add_scope (p->scope_);
 870                 $$ = p;
 871         }
 872         ;
 873
 874
 875 output_def_body:
 876         output_def_head '{' {
 877                 $$ = $1;
 878                 $$->input_origin_.set_spot (@$);
 879                 THIS->lexer_->push_initial_state ();
 880         }
 881         | output_def_head '{' OUTPUT_DEF_IDENTIFIER     {
 882                 $1->unprotect ();
 883                 Output_def *o = unsmob_output_def ($3);
 884                 o->input_origin_.set_spot (@$);
 885                 $$ = o;
 886                 THIS->lexer_->remove_scope ();
 887                 THIS->lexer_->add_scope (o->scope_);
 888                 THIS->lexer_->push_initial_state ();
 889         }
 890         | output_def_body assignment  {
 891
 892         }
 893         | output_def_body context_def_spec_block        {
 894                 assign_context_def ($$, $2);
 895         }
 896         | output_def_body tempo_event  {
 897                 /*
 898                         junk this ? there already is tempo stuff in
 899                         music.
 900                 */
 901                 int m = scm_to_int ($2->get_property ("metronome-count"));
 902                 Duration *d = unsmob_duration ($2->get_property ("tempo-unit"));
 903                 set_tempo ($$, d->get_length (), m);
 904                 $2->unprotect ();
 905         }
 906         | output_def_body error {
 907
 908         }
 909         ;
 910
 911 tempo_event:
 912         TEMPO steno_duration '=' bare_unsigned  {
 913                 $$ = MY_MAKE_MUSIC ("MetronomeChangeEvent");
 914                 $$->set_property ("tempo-unit", $2);
 915                 $$->set_property ("metronome-count", scm_from_int ( $4));
 916         }
 917         ;
 918
 919 /*
 920 The representation of a  list is the
 921
 922   (LIST . LAST-CONS)
 923
 924  to have efficient append.  */
 925
 926 Music_list:
 927         /* empty */ {
 928                 $$ = scm_cons (SCM_EOL, SCM_EOL);
 929         }
 930         | Music_list Music {
 931                 SCM s = $$;
 932                 SCM c = scm_cons ($2->self_scm (), SCM_EOL);
 933                 $2->unprotect (); /* UGH */
 934
 935                 if (scm_is_pair (scm_cdr (s)))
 936                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 937                 else
 938                         scm_set_car_x (s, c); /* set first cons */
 939                 scm_set_cdr_x (s, c);  /* remember last cell */
 940         }
 941         | Music_list embedded_scm {
 942
 943         }
 944         | Music_list error {
 945                 Music * m = MY_MAKE_MUSIC("Music");
 946                 // ugh. code dup
 947                 m->set_property ("error-found", SCM_BOOL_T);
 948                 SCM s = $$;
 949                 SCM c = scm_cons (m->self_scm (), SCM_EOL);
 950                 m->unprotect (); /* UGH */
 951
 952                 if (scm_is_pair (scm_cdr (s)))
 953                         scm_set_cdr_x (scm_cdr (s), c); /* append */
 954                 else
 955                         scm_set_car_x (s, c); /* set first cons */
 956                 scm_set_cdr_x (s, c);  /* remember last cell */
 957         }
 958         ;
 959
 960 Music:
 961         Simple_music
 962         | Composite_music
 963         ;
 964
 965 Alternative_music:
 966         /* empty */ {
 967                 $$ = SCM_EOL;
 968         }
 969         | ALTERNATIVE '{' Music_list '}' {
 970                 $$ = $3;
 971         }
 972         ;
 973
 974
 975 Repeated_music:
 976         REPEAT simple_string bare_unsigned Music Alternative_music
 977         {
 978                 Music *beg = $4;
 979                 int times = $3;
 980                 SCM alts = scm_is_pair ($5) ? scm_car ($5) : SCM_EOL;
 981                 if (times < scm_ilength (alts)) {
 982                   unsmob_music (scm_car (alts))
 983                     ->origin ()->warning (
 984                     _ ("more alternatives than repeats"));
 985                     warning ("junking excess alternatives");
 986                   alts = ly_truncate_list (times, alts);
 987                 }
 988
 989
 990                 SCM proc = ly_lily_module_constant ("make-repeated-music");
 991
 992                 SCM mus = scm_call_1 (proc, $2);
 993                 Music *r = unsmob_music (mus);
 994                 r->protect ();
 995                 if (beg)
 996                         {
 997                         r-> set_property ("element", beg->self_scm ());
 998                         beg->unprotect ();
 999                         }
1000                 r->set_property ("repeat-count", scm_from_int (max (times, 1)));
1001
1002                 r-> set_property ("elements",alts);
1003                 if (ly_is_equal ($2, scm_makfrom0str ("tremolo"))) {
1004                         /*
1005                         TODO: move this code to Scheme.
1006                         */
1007
1008                         /* we cannot get durations and other stuff
1009                            correct down the line,
1010                            so we have to add to the duration log here. */
1011                         SCM func = ly_lily_module_constant ("shift-duration-log");
1012
1013                         int dots = ($3 % 3) ? 0 : 1;
1014                         int shift = -intlog2 ((dots) ? ($3*2/3) : $3);
1015
1016
1017                         if ($4->is_mus_type ("sequential-music"))
1018                         {
1019                                 int list_len = scm_ilength ($4->get_property ("elements"));
1020                                 if (list_len != 2)
1021                                         $4->origin ()->warning (_f ("expect 2 elements for Chord tremolo, found %d", list_len));
1022                                 shift -= 1;
1023                                 r->compress (Moment (Rational (1, list_len)));
1024                         }
1025                         scm_call_3 (func, r->self_scm (), scm_from_int (shift), scm_from_int (dots));
1026
1027                 }
1028                 r->set_spot (*$4->origin ());
1029
1030                 $$ = r;
1031         }
1032         ;
1033
1034 Sequential_music:
1035         SEQUENTIAL '{' Music_list '}'           {
1036                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
1037                 $$->set_property ("elements", scm_car ($3));
1038                 $$->set_spot (@$);
1039         }
1040         | '{' Music_list '}'            {
1041                 $$ = MY_MAKE_MUSIC ("SequentialMusic");
1042                 $$->set_property ("elements", scm_car ($2));
1043                 $$->set_spot (@$);
1044         }
1045         ;
1046
1047 Simultaneous_music:
1048         SIMULTANEOUS '{' Music_list '}'{
1049                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
1050                 $$->set_property ("elements", scm_car ($3));
1051                 $$->set_spot (@$);
1052
1053         }
1054         | simul_open Music_list simul_close     {
1055                 $$ = MY_MAKE_MUSIC ("SimultaneousMusic");
1056                 $$->set_property ("elements", scm_car ($2));
1057                 $$->set_spot (@$);
1058         }
1059         ;
1060
1061 Simple_music:
1062         event_chord             { $$ = $1; }
1063         | MUSIC_IDENTIFIER {
1064                 $$ = unsmob_music ($1);
1065         }
1066         | music_property_def
1067         | context_change
1068         ;
1069
1070
1071 optional_context_mod:
1072         /**/ { $$ = SCM_EOL; }
1073         | WITH { THIS->lexer_->push_initial_state (); }
1074         '{' context_mod_list '}'
1075         {
1076                 THIS->lexer_->pop_state ();
1077                 $$ = $4;
1078         }
1079         ;
1080
1081 context_mod_list:
1082         /* */  { $$ = SCM_EOL; }
1083         | context_mod_list context_mod  {
1084                  $$ = scm_cons ($2, $1);
1085         }
1086         ;
1087
1088
1089 Composite_music:
1090         Prefix_composite_music { $$ = $1; }
1091         | Grouped_music_list { $$ = $1; }
1092         ;
1093
1094 Grouped_music_list:
1095         Simultaneous_music              { $$ = $1; }
1096         | Sequential_music              { $$ = $1; }
1097         ;
1098
1099 Generic_prefix_music_scm:
1100         MUSIC_FUNCTION {
1101                 $$ = scm_list_2 ($1, make_input (@$));
1102         }
1103         | MUSIC_FUNCTION_SCM embedded_scm {
1104                 $$ = scm_list_3 ($1, make_input (@$), $2);
1105         }
1106         | MUSIC_FUNCTION_MARKUP full_markup {
1107                 $$ = scm_list_3 ($1, make_input (@$), $2);
1108         }
1109         | MUSIC_FUNCTION_MUSIC Music {
1110                 $$ = scm_list_3 ($1, make_input (@$), $2->self_scm ());
1111                 $2->unprotect ();
1112         }
1113         | MUSIC_FUNCTION_SCM_MUSIC embedded_scm Music {
1114                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1115                 $3->unprotect ();
1116         }
1117         | MUSIC_FUNCTION_SCM_SCM embedded_scm embedded_scm {
1118                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1119         }
1120         | MUSIC_FUNCTION_SCM_SCM_SCM embedded_scm embedded_scm embedded_scm {
1121                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4);
1122         }
1123         | MUSIC_FUNCTION_SCM_SCM_MUSIC embedded_scm embedded_scm Music {
1124                 $$ = scm_list_5 ($1, make_input (@$), $2, $3, $4->self_scm ());
1125         }
1126         | MUSIC_FUNCTION_MARKUP_MUSIC full_markup Music {
1127                 $$ = scm_list_4 ($1, make_input (@$), $2, $3->self_scm ());
1128                 $3->unprotect ();
1129         }
1130         | MUSIC_FUNCTION_MARKUP_MARKUP full_markup full_markup {
1131                 $$ = scm_list_4 ($1, make_input (@$), $2, $3);
1132         }
1133         | MUSIC_FUNCTION_MUSIC_MUSIC Music Music {
1134                 $$ = scm_list_4 ($1, make_input (@$), $2->self_scm (), $3->self_scm ());
1135                 $2->unprotect ();
1136                 $3->unprotect ();
1137         }
1138         | MUSIC_FUNCTION_SCM_MUSIC_MUSIC embedded_scm Music Music {
1139                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1140                 $4->unprotect ();
1141                 $3->unprotect ();
1142         }
1143         | MUSIC_FUNCTION_MARKUP_MUSIC_MUSIC full_markup Music Music {
1144                 $$ = scm_list_5 ($1, make_input (@$), $2, $3->self_scm (), $4->self_scm ());
1145                 $3->unprotect ();
1146                 $4->unprotect ();
1147         }
1148         ;
1149
1150 Generic_prefix_music:
1151         Generic_prefix_music_scm {
1152                 SCM func = scm_car ($1);
1153                 Input *loc = unsmob_input (scm_cadr ($1));
1154                 SCM args = scm_cddr ($1);
1155                 SCM sig = scm_object_property (func, ly_symbol2scm ("music-function-signature"));
1156
1157                 SCM type_check_proc = ly_lily_module_constant ("type-check-list");
1158                 bool ok  = true;
1159
1160                 if (!to_boolean (scm_call_3  (type_check_proc, scm_cadr ($1), sig, args)))
1161                 {
1162                         THIS->error_level_ = 1;
1163                         ok = false;
1164                 }
1165
1166                 SCM m = SCM_EOL;
1167                 if (ok)
1168                         m = scm_apply_0 (func, scm_cons (THIS->self_scm(),
1169                                                          scm_cdr ($1)));
1170
1171                 if (unsmob_music (m))
1172                         {
1173                         $$ = unsmob_music (m);
1174                         $$->protect ();
1175                         }
1176                 else
1177                         {
1178                         if (ok)
1179                                 loc->error (_ ("music head function must return Music object"));
1180                         $$ = MY_MAKE_MUSIC ("Music");
1181                         }
1182                 $$->set_spot (*loc);
1183         }
1184         ;
1185
1186
1187 Prefix_composite_music:
1188         Generic_prefix_music {
1189                 $$ = $1;
1190         }
1191         | CONTEXT simple_string '=' simple_string optional_context_mod Music {
1192                 $$ = context_spec_music ($2, $4, $6, $5);
1193
1194         }
1195         | CONTEXT simple_string optional_context_mod Music {
1196                 $$ = context_spec_music ($2, SCM_UNDEFINED, $4, $3);
1197         }
1198         | NEWCONTEXT simple_string optional_context_mod Music {
1199                 $$ = context_spec_music ($2, get_next_unique_context_id (), $4,
1200                         $3);
1201         }
1202
1203         | TIMES fraction Music
1204
1205         {
1206                 int n = scm_to_int (scm_car ($2)); int d = scm_to_int (scm_cdr ($2));
1207                 Music *mp = $3;
1208
1209                 $$= MY_MAKE_MUSIC ("TimeScaledMusic");
1210                 $$->set_spot (@$);
1211
1212                 $$->set_property ("element", mp->self_scm ());
1213                 mp->unprotect();
1214                 $$->set_property ("numerator", scm_from_int (n));
1215                 $$->set_property ("denominator", scm_from_int (d));
1216                 $$->compress (Moment (Rational (n,d)));
1217
1218         }
1219         | Repeated_music                { $$ = $1; }
1220         | TRANSPOSE pitch_also_in_chords pitch_also_in_chords Music {
1221                 $$ = MY_MAKE_MUSIC ("TransposedMusic");
1222                 Music *p = $4;
1223                 Pitch from = *unsmob_pitch ($2);
1224                 Pitch to = *unsmob_pitch ($3);
1225
1226                 p->transpose (pitch_interval (from, to));
1227                 $$->set_property ("element", p->self_scm ());
1228                 p->unprotect();
1229         }
1230         | mode_changing_head Grouped_music_list {
1231                 if ($1 == ly_symbol2scm ("chords"))
1232                 {
1233                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1234                   chm->set_property ("element", $2->self_scm ());
1235                   $$ = chm;
1236                   $2->unprotect();
1237                 }
1238                 else
1239                 {
1240                   $$ = $2;
1241                 }
1242                 THIS->lexer_->pop_state ();
1243         }
1244         | mode_changing_head_with_context optional_context_mod Grouped_music_list {
1245                 $$ = context_spec_music ($1, get_next_unique_context_id (),
1246                                          $3, $2);
1247                 if ($1 == ly_symbol2scm ("ChordNames"))
1248                 {
1249                   Music *chm = MY_MAKE_MUSIC ("UnrelativableMusic");
1250                   chm->set_property ("element", $$->self_scm ());
1251                   $$->unprotect();
1252                   $$ = chm;
1253                 }
1254                 THIS->lexer_->pop_state ();
1255         }
1256         | relative_music        { $$ = $1; }
1257         | re_rhythmed_music     { $$ = $1; }
1258         | TAG embedded_scm Music {
1259                 tag_music ($3, $2, @$);
1260                 $$ = $3;
1261         }
1262         ;
1263
1264 mode_changing_head:
1265         NOTEMODE {
1266                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
1267                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1268
1269                 $$ = ly_symbol2scm ("notes");
1270         }
1271         | DRUMMODE
1272                 {
1273                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1274                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1275
1276                 $$ = ly_symbol2scm ("drums");
1277         }
1278         | FIGUREMODE {
1279                 THIS->lexer_->push_figuredbass_state ();
1280
1281                 $$ = ly_symbol2scm ("figures");
1282         }
1283         | CHORDMODE {
1284                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1285                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1286                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1287                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1288                 $$ = ly_symbol2scm ("chords");
1289
1290         }
1291         | LYRICMODE
1292                 { THIS->lexer_->push_lyric_state ();
1293                 $$ = ly_symbol2scm ("lyrics");
1294         }
1295         ;
1296
1297 mode_changing_head_with_context:
1298         DRUMS {
1299                 SCM nn = THIS->lexer_->lookup_identifier ("drumPitchNames");
1300                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
1301
1302                 $$ = ly_symbol2scm ("DrumStaff");
1303         }
1304         | FIGURES {
1305                 THIS->lexer_->push_figuredbass_state ();
1306
1307                 $$ = ly_symbol2scm ("FiguredBass");
1308         }
1309         | CHORDS {
1310                 SCM nn = THIS->lexer_->lookup_identifier ("chordmodifiers");
1311                 THIS->lexer_->chordmodifier_tab_ = alist_to_hashq (nn);
1312                 nn = THIS->lexer_->lookup_identifier ("pitchnames");
1313                 THIS->lexer_->push_chord_state (alist_to_hashq (nn));
1314                 $$ = ly_symbol2scm ("ChordNames");
1315         }
1316         | LYRICS
1317                 { THIS->lexer_->push_lyric_state ();
1318                 $$ = ly_symbol2scm ("Lyrics");
1319         }
1320         ;
1321
1322
1323 relative_music:
1324         RELATIVE absolute_pitch Music {
1325                 Music *m = $3;
1326                 Pitch start = *unsmob_pitch ($2);
1327                 $$ = make_music_relative (start, m);
1328                 m->unprotect();
1329         }
1330         | RELATIVE Composite_music {
1331                 Music *m = $2;
1332
1333                 Pitch middle_c (0, 0, 0);
1334                 $$ = make_music_relative (middle_c, m);
1335                 m->unprotect();
1336         }
1337         ;
1338
1339 new_lyrics:
1340         ADDLYRICS { THIS->lexer_->push_lyric_state (); }
1341         /*cont */
1342         Grouped_music_list {
1343         /* Can also use Music at the expensive of two S/Rs similar to
1344            \repeat \alternative */
1345                 THIS->lexer_->pop_state ();
1346
1347                 $$ = scm_cons ($3->self_scm (), SCM_EOL);
1348         }
1349         | new_lyrics ADDLYRICS {
1350                 THIS->lexer_->push_lyric_state ();
1351         } Grouped_music_list {
1352                 THIS->lexer_->pop_state ();
1353                 $$ = scm_cons ($4->self_scm (), $1);
1354         }
1355         ;
1356
1357 re_rhythmed_music:
1358         Grouped_music_list new_lyrics {
1359                 Music * voice = $1;
1360                 SCM name = get_first_context_id (scm_makfrom0str ("Voice"), voice);
1361                 if (!scm_is_string (name))
1362                 {
1363                         name = get_next_unique_lyrics_context_id ();
1364                         voice = context_spec_music (scm_makfrom0str ("Voice"),
1365                                                     name,
1366                                                     voice, SCM_EOL);
1367                 }
1368
1369                 SCM context = scm_makfrom0str ("Lyrics");
1370                 Music *all = MY_MAKE_MUSIC ("SimultaneousMusic");
1371
1372                 SCM lst = SCM_EOL;
1373                 for (SCM s = $2; scm_is_pair (s); s = scm_cdr (s))
1374                 {
1375                         Music *music = unsmob_music (scm_car (s));
1376                         Music *com = make_lyric_combine_music (name, music);
1377                         Music *csm = context_spec_music (context,
1378                                 get_next_unique_context_id (), com, SCM_EOL);
1379                         lst = scm_cons (csm->self_scm (), lst);
1380                 }
1381                 all->set_property ("elements", scm_cons (voice->self_scm (),
1382                         lst));
1383                 $$ = all;
1384                 voice->unprotect ();
1385         }
1386         | LYRICSTO simple_string {
1387                 THIS->lexer_->push_lyric_state ();
1388         } Music {
1389                 THIS->lexer_->pop_state ();
1390                 Music *music = $4;
1391                 SCM name = $2;
1392                 $$ = make_lyric_combine_music (name, music);
1393                 music->unprotect();
1394         }
1395         ;
1396
1397 context_change:
1398         CHANGE STRING '=' STRING  {
1399                 Music*t = MY_MAKE_MUSIC ("ContextChange");
1400                 t-> set_property ("change-to-type", scm_string_to_symbol ($2));
1401                 t-> set_property ("change-to-id", $4);
1402
1403                 $$ = t;
1404                 $$->set_spot (@$);
1405         }
1406         ;
1407
1408 property_operation:
1409         STRING '=' scalar {
1410                 $$ = scm_list_3 (ly_symbol2scm ("assign"),
1411                         scm_string_to_symbol ($1), $3);
1412         }
1413         | UNSET simple_string {
1414                 $$ = scm_list_2 (ly_symbol2scm ("unset"),
1415                         scm_string_to_symbol ($2));
1416         }
1417         | OVERRIDE simple_string embedded_scm '=' embedded_scm {
1418                 $$ = scm_list_4 (ly_symbol2scm ("push"),
1419                         scm_string_to_symbol ($2), $5, $3);
1420         }
1421         | OVERRIDE simple_string embedded_scm embedded_scm '=' embedded_scm {
1422                 $$ = scm_list_5 (ly_symbol2scm ("push"),
1423                                 scm_string_to_symbol ($2), $6, $4, $3);
1424         }
1425         | REVERT simple_string embedded_scm {
1426                 $$ = scm_list_3 (ly_symbol2scm ("pop"),
1427                         scm_string_to_symbol ($2), $3);
1428         }
1429         ;
1430
1431 context_def_mod:
1432         CONSISTS { $$ = ly_symbol2scm ("consists"); }
1433         | REMOVE { $$ = ly_symbol2scm ("remove"); }
1434
1435         | ACCEPTS { $$ = ly_symbol2scm ("accepts"); }
1436         | DEFAULTCHILD { $$ = ly_symbol2scm ("default-child"); }
1437         | DENIES { $$ = ly_symbol2scm ("denies"); }
1438
1439         | ALIAS { $$ = ly_symbol2scm ("alias"); }
1440         | TYPE { $$ = ly_symbol2scm ("translator-type"); }
1441         | DESCRIPTION { $$ = ly_symbol2scm ("description"); }
1442         | NAME { $$ = ly_symbol2scm ("context-name"); }
1443         ;
1444
1445 context_mod:
1446         property_operation { $$ = $1; }
1447         | context_def_mod STRING {
1448                 $$ = scm_list_2 ($1, $2);
1449         }
1450         ;
1451
1452 context_prop_spec:
1453         simple_string {
1454                 if (!is_regular_identifier ($1))
1455                 {
1456                         @$.error (_("Grob name should be alphanumeric"));
1457                 }
1458
1459                 $$ = scm_list_2 (ly_symbol2scm ("Bottom"),
1460                         scm_string_to_symbol ($1));
1461         }
1462         | simple_string '.' simple_string {
1463                 $$ = scm_list_2 (scm_string_to_symbol ($1),
1464                         scm_string_to_symbol ($3));
1465         }
1466         ;
1467
1468 music_property_def:
1469         OVERRIDE context_prop_spec embedded_scm '=' scalar {
1470                 $$ = property_op_to_music (scm_list_4 (
1471                         ly_symbol2scm ("push"),
1472                         scm_cadr ($2),
1473                         $5, $3));
1474                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1475         }
1476         | OVERRIDE context_prop_spec embedded_scm  embedded_scm '=' scalar {
1477                 $$ = property_op_to_music (scm_list_5 (
1478                         ly_symbol2scm ("push"),
1479                         scm_cadr ($2),
1480                         $6, $4, $3));
1481                 $$ = context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1482         }
1483         | REVERT context_prop_spec embedded_scm {
1484                 $$ = property_op_to_music (scm_list_3 (
1485                         ly_symbol2scm ("pop"),
1486                         scm_cadr ($2),
1487                         $3));
1488
1489                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1490         }
1491         | SET context_prop_spec '=' scalar {
1492                 $$ = property_op_to_music (scm_list_3 (
1493                         ly_symbol2scm ("assign"),
1494                         scm_cadr ($2),
1495                         $4));
1496                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1497         }
1498         | UNSET context_prop_spec {
1499                 $$ = property_op_to_music (scm_list_2 (
1500                         ly_symbol2scm ("unset"),
1501                         scm_cadr ($2)));
1502                 $$= context_spec_music (scm_car ($2), SCM_UNDEFINED, $$, SCM_EOL);
1503         }
1504         | ONCE music_property_def {
1505                 SCM e = $2->get_property ("element");
1506                 unsmob_music (e)->set_property ("once", SCM_BOOL_T);
1507                 $$ = $2;
1508
1509         }
1510         ;
1511
1512
1513 string:
1514         STRING {
1515                 $$ = $1;
1516         }
1517         | STRING_IDENTIFIER {
1518                 $$ = $1;
1519         }
1520         | string '+' string {
1521                 $$ = scm_string_append (scm_list_2 ($1, $3));
1522         }
1523         ;
1524
1525 simple_string: STRING {
1526                 $$ = $1;
1527         }
1528         | LYRICS_STRING {
1529                 $$ = $1;
1530         }
1531         | STRING_IDENTIFIER {
1532                 $$ = $1;
1533         }
1534         ;
1535
1536 scalar: string {
1537                 $$ = $1;
1538         }
1539         | LYRICS_STRING {
1540                 $$ = $1;
1541         }
1542         | bare_number {
1543                 $$ = $1;
1544         }
1545         | embedded_scm {
1546                 $$ = $1;
1547         }
1548         | full_markup {
1549                 $$ = $1;
1550         }
1551         | DIGIT {
1552                 $$ = scm_from_int ($1);
1553         }
1554         ;
1555
1556 /*
1557
1558 pre_events doesn't contain anything. It is a trick:
1559
1560 Adding pre_events to the simple_element
1561 makes the choice between
1562
1563   string:  STRING
1564
1565 and
1566
1567   simple_element: STRING
1568
1569 a single shift/reduction conflict.
1570
1571 nevertheless, this is not very clean, and we should find a different
1572 solution.
1573
1574 */
1575 pre_events: /* empty */
1576         ;
1577
1578 event_chord:
1579         pre_events simple_element post_events   {
1580                 SCM elts = $2-> get_property ("elements");
1581
1582                 elts = ly_append2 (elts, scm_reverse_x ($3, SCM_EOL));
1583
1584                 $2->set_property ("elements", elts);
1585                 /* why is this giving wrong start location? -ns
1586                  * $2->set_spot (@$); */
1587                 Input i;
1588                 i.set_location (@2, @3);
1589                 $2->set_spot (i);
1590                 $$ = $2;
1591         }
1592         | command_element
1593         | note_chord_element
1594         ;
1595
1596
1597 note_chord_element:
1598         chord_body optional_notemode_duration post_events
1599         {
1600                 SCM dur = unsmob_duration ($2)->smobbed_copy ();
1601                 SCM es = $1->get_property ("elements");
1602                 SCM postevs = scm_reverse_x ($3, SCM_EOL);
1603
1604                 for (SCM s = es; scm_is_pair (s); s = scm_cdr (s))
1605                   unsmob_music (scm_car (s))->set_property ("duration", dur);
1606                 es = ly_append2 (es, postevs);
1607
1608                 $1-> set_property ("elements", es);
1609                 $1->set_spot (@$);
1610                 $$ = $1;
1611         }
1612         ;
1613
1614 chord_open: '<'
1615         ;
1616
1617 chord_close: '>'
1618         ;
1619
1620 simul_open: DOUBLE_ANGLE_OPEN
1621         ;
1622
1623 simul_close: DOUBLE_ANGLE_CLOSE
1624         ;
1625
1626 chord_body:
1627         chord_open chord_body_elements chord_close
1628         {
1629                 $$ = MY_MAKE_MUSIC ("EventChord");
1630                 $$->set_spot (@$);
1631                 $$->set_property ("elements",
1632                         scm_reverse_x ($2, SCM_EOL));
1633         }
1634         ;
1635
1636 chord_body_elements:
1637         /* empty */             { $$ = SCM_EOL; }
1638         | chord_body_elements chord_body_element {
1639                 $$ = scm_cons ($2->self_scm (), $1);
1640                 $2->unprotect ();
1641         }
1642         ;
1643
1644 chord_body_element:
1645         pitch exclamations questions octave_check post_events
1646         {
1647                 int q = $3;
1648                 int ex = $2;
1649                 SCM check = $4;
1650                 SCM post = $5;
1651
1652                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1653                 n->set_property ("pitch", $1);
1654                 n->set_spot (@$);
1655                 if (q % 2)
1656                         n->set_property ("cautionary", SCM_BOOL_T);
1657                 if (ex % 2 || q % 2)
1658                         n->set_property ("force-accidental", SCM_BOOL_T);
1659
1660                 if (scm_is_pair (post)) {
1661                         SCM arts = scm_reverse_x (post, SCM_EOL);
1662                         n->set_property ("articulations", arts);
1663                 }
1664                 if (scm_is_number (check))
1665                 {
1666                         int q = scm_to_int (check);
1667                         n->set_property ("absolute-octave", scm_from_int (q-1));
1668                 }
1669
1670
1671                 $$ = n;
1672         }
1673         | DRUM_PITCH post_events {
1674                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
1675                 n->set_property ("duration", $2);
1676                 n->set_property ("drum-type", $1);
1677                 n->set_spot (@$);
1678
1679                 if (scm_is_pair ($2)) {
1680                         SCM arts = scm_reverse_x ($2, SCM_EOL);
1681                         n->set_property ("articulations", arts);
1682                 }
1683                 $$ = n;
1684         }
1685         ;
1686
1687 add_quote:
1688         ADDQUOTE string Music {
1689                 SCM adder = ly_lily_module_constant ("add-quotable");
1690
1691                 scm_call_2 (adder, $2, $3->self_scm ());
1692                 $3->unprotect();
1693         }
1694         ;
1695
1696 command_element:
1697         command_event {
1698                 $$ = MY_MAKE_MUSIC ("EventChord");
1699                 $$->set_property ("elements", scm_cons ($1->self_scm (), SCM_EOL));
1700                 $1->unprotect();
1701
1702                 $$-> set_spot (@$);
1703                 $1-> set_spot (@$);
1704         }
1705         | SKIP duration_length {
1706                 Music *skip = MY_MAKE_MUSIC ("SkipMusic");
1707                 skip->set_property ("duration", $2);
1708                 skip->set_spot (@$);
1709                 $$ = skip;
1710         }
1711         | OCTAVE pitch {
1712                 Music *m = MY_MAKE_MUSIC ("RelativeOctaveCheck");
1713                 $$ = m;
1714                 $$->set_spot (@$);
1715                 $$->set_property ("pitch", $2);
1716         }
1717         | E_BRACKET_OPEN {
1718                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1719                 m->set_property ("span-direction", scm_from_int (START));
1720                 m->set_spot (@$);
1721
1722                 $$ = MY_MAKE_MUSIC ("EventChord");
1723                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1724                 m->unprotect();
1725                 $$->set_spot (@$);
1726         }
1727         | E_BRACKET_CLOSE {
1728                 Music *m = MY_MAKE_MUSIC ("LigatureEvent");
1729                 m->set_property ("span-direction", scm_from_int (STOP));
1730                 m->set_spot (@$);
1731
1732                 $$ = MY_MAKE_MUSIC ("EventChord");
1733                 $$->set_property ("elements", scm_cons (m->self_scm (), SCM_EOL));
1734                 $$->set_spot (@$);
1735                 m->unprotect ();
1736         }
1737         | E_BACKSLASH {
1738                 $$ = MY_MAKE_MUSIC ("VoiceSeparator");
1739                 $$->set_spot (@$);
1740         }
1741         | '|'      {
1742                 SCM pipe = THIS->lexer_->lookup_identifier ("pipeSymbol");
1743
1744                 if (Music * m = unsmob_music (pipe))
1745                         $$ = m->clone ();
1746                 else
1747                         $$ = MY_MAKE_MUSIC ("BarCheck");
1748
1749                 $$->set_spot (@$);
1750         }
1751         | TRANSPOSITION pitch {
1752                 Pitch middle_c;
1753                 Pitch sounds_as_c = pitch_interval (*unsmob_pitch ($2), middle_c);
1754                 $$ = set_property_music (ly_symbol2scm ("instrumentTransposition"),
1755                                          sounds_as_c.smobbed_copy());
1756                 $$->set_spot (@$);
1757                 $$ = context_spec_music (ly_symbol2scm ("Staff"), SCM_UNDEFINED,
1758                         $$, SCM_EOL);
1759         }
1760         | BAR STRING                    {
1761                 Music *t = set_property_music (ly_symbol2scm ("whichBar"), $2);
1762
1763                 Music *csm = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1764                                         t, SCM_EOL);
1765                 $$ = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED, csm, SCM_EOL);
1766                 $$->set_spot (@$);
1767                 t->set_spot (@$);
1768         }
1769         | PARTIAL duration_length       {
1770                 Moment m = - unsmob_duration ($2)->get_length ();
1771                 Music *p = set_property_music (ly_symbol2scm ( "measurePosition"),m.smobbed_copy ());
1772                 p->set_spot (@$);
1773                 p = context_spec_music (ly_symbol2scm ("Timing"), SCM_UNDEFINED,
1774                                         p, SCM_EOL);
1775                 p = context_spec_music (ly_symbol2scm ("Score"), SCM_UNDEFINED,
1776                                         p, SCM_EOL);
1777                 $$ = p;
1778         }
1779         | CLEF STRING  {
1780                 SCM proc = ly_lily_module_constant ("make-clef-set");
1781
1782                 SCM result = scm_call_1 (proc, $2);
1783                 $$ = unsmob_music (result);
1784                 $$->protect ();
1785         }
1786         | TIME_T fraction  {
1787                 SCM proc = ly_lily_module_constant ("make-time-signature-set");
1788
1789                 SCM result = scm_apply_2   (proc, scm_car ($2), scm_cdr ($2), SCM_EOL);
1790                 $$ = unsmob_music (result);
1791                 $$->protect ();
1792         }
1793         | MARK scalar {
1794                 SCM proc = ly_lily_module_constant ("make-mark-set");
1795
1796                 SCM result = scm_call_1 (proc, $2);
1797                 $$ = unsmob_music (result);
1798                 $$->protect ();
1799         }
1800         ;
1801
1802 command_event:
1803         E_TILDE {
1804                 $$ = MY_MAKE_MUSIC ("PesOrFlexaEvent");
1805         }
1806         | MARK DEFAULT  {
1807                 Music *m = MY_MAKE_MUSIC ("MarkEvent");
1808                 $$ = m;
1809         }
1810         | tempo_event {
1811                 $$ = $1;
1812         }
1813         | KEY DEFAULT {
1814                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1815                 $$ = key;
1816         }
1817         | KEY NOTENAME_PITCH SCM_IDENTIFIER     {
1818
1819                 Music *key = MY_MAKE_MUSIC ("KeyChangeEvent");
1820                 if (scm_ilength ($3) > 0)
1821                 {
1822                         key->set_property ("pitch-alist", $3);
1823                         key->set_property ("tonic", Pitch (0, 0, 0).smobbed_copy ());
1824                         key->transpose (* unsmob_pitch ($2));
1825                 } else {
1826                         THIS->parser_error (@3, _ ("second argument must be pitch list"));
1827                 }
1828
1829                 $$ = key;
1830         }
1831         ;
1832
1833
1834 post_events:
1835         /* empty */ {
1836                 $$ = SCM_EOL;
1837         }
1838         | post_events post_event {
1839                 $2->set_spot (@2);
1840                 $$ = scm_cons ($2->self_scm (), $$);
1841                 $2->unprotect ();
1842         }
1843         | post_events tagged_post_event {
1844                 $2 -> set_spot (@2);
1845                 $$ = scm_cons ($2->self_scm (), $$);
1846                 $2->unprotect ();
1847         }
1848         ;
1849
1850
1851 tagged_post_event:
1852         '-' TAG embedded_scm post_event {
1853                 tag_music ($4, $3, @$);
1854                 $$ = $4;
1855         }
1856         ;
1857
1858
1859 post_event:
1860         direction_less_event {
1861                 $$ = $1;
1862         }
1863         | HYPHEN {
1864                 if (!THIS->lexer_->is_lyric_state ())
1865                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1866                 $$ = MY_MAKE_MUSIC ("HyphenEvent");
1867         }
1868         | EXTENDER {
1869                 if (!THIS->lexer_->is_lyric_state ())
1870                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
1871                 $$ = MY_MAKE_MUSIC ("ExtenderEvent");
1872         }
1873         | script_dir direction_reqd_event {
1874                 if ($1)
1875                         $2->set_property ("direction", scm_from_int ($1));
1876                 $$ = $2;
1877         }
1878         | script_dir direction_less_event {
1879                 if ($1)
1880                         $2->set_property ("direction", scm_from_int ($1));
1881                 $$ = $2;
1882         }
1883         | string_number_event
1884         ;
1885
1886 string_number_event:
1887         E_UNSIGNED {
1888                 Music *s = MY_MAKE_MUSIC ("StringNumberEvent");
1889                 s->set_property ("string-number", scm_from_int ($1));
1890                 s->set_spot (@$);
1891                 $$ = s;
1892         }
1893         ;
1894
1895 direction_less_char:
1896         '['  {
1897                 $$ = ly_symbol2scm ("bracketOpenSymbol");
1898         }
1899         | ']'  {
1900                 $$ = ly_symbol2scm ("bracketCloseSymbol");
1901         }
1902         | '~'  {
1903                 $$ = ly_symbol2scm ("tildeSymbol");
1904         }
1905         | '('  {
1906                 $$ = ly_symbol2scm ("parenthesisOpenSymbol");
1907         }
1908         | ')'  {
1909                 $$ = ly_symbol2scm ("parenthesisCloseSymbol");
1910         }
1911         | E_EXCLAMATION  {
1912                 $$ = ly_symbol2scm ("escapedExclamationSymbol");
1913         }
1914         | E_OPEN  {
1915                 $$ = ly_symbol2scm ("escapedParenthesisOpenSymbol");
1916         }
1917         | E_CLOSE  {
1918                 $$ = ly_symbol2scm ("escapedParenthesisCloseSymbol");
1919         }
1920         | E_ANGLE_CLOSE  {
1921                 $$ = ly_symbol2scm ("escapedBiggerSymbol");
1922         }
1923         | E_ANGLE_OPEN  {
1924                 $$ = ly_symbol2scm ("escapedSmallerSymbol");
1925         }
1926         ;
1927
1928 direction_less_event:
1929         direction_less_char {
1930                 SCM predefd = THIS->lexer_->lookup_identifier_symbol ($1);
1931                 Music * m = 0;
1932                 if (unsmob_music (predefd))
1933                 {
1934                         m = unsmob_music (predefd)->clone ();
1935                 }
1936                 else
1937                 {
1938                         m = MY_MAKE_MUSIC ("Music");
1939                 }
1940                 m->set_spot (@$);
1941                 $$ = m;
1942         }
1943         | EVENT_IDENTIFIER      {
1944                 $$ = unsmob_music ($1);
1945         }
1946         | tremolo_type  {
1947                Music *a = MY_MAKE_MUSIC ("TremoloEvent");
1948                a->set_spot (@$);
1949                a->set_property ("tremolo-type", scm_from_int ($1));
1950                $$ = a;
1951         }
1952         ;
1953
1954 direction_reqd_event:
1955         gen_text_def {
1956                 $$ = $1;
1957         }
1958         | script_abbreviation {
1959                 SCM s = THIS->lexer_->lookup_identifier ("dash" + ly_scm2string ($1));
1960                 Music *a = MY_MAKE_MUSIC ("ArticulationEvent");
1961                 if (scm_is_string (s))
1962                         a->set_property ("articulation-type", s);
1963                 else THIS->parser_error (@1, _ ("expecting string as script definition"));
1964                 $$ = a;
1965         }
1966         ;
1967
1968 octave_check:
1969         /**/ { $$ = SCM_EOL; }
1970         | '='  { $$ = scm_from_int (0); }
1971         | '=' sub_quotes { $$ = scm_from_int ($2); }
1972         | '=' sup_quotes { $$ = scm_from_int ($2); }
1973         ;
1974
1975 sup_quotes:
1976         '\'' {
1977                 $$ = 1;
1978         }
1979         | sup_quotes '\'' {
1980                 $$ ++;
1981         }
1982         ;
1983
1984 sub_quotes:
1985         ',' {
1986                 $$ = 1;
1987         }
1988         | sub_quotes ',' {
1989                 $$++;
1990         }
1991         ;
1992
1993 steno_pitch:
1994         NOTENAME_PITCH  {
1995                 $$ = $1;
1996         }
1997         | NOTENAME_PITCH sup_quotes     {
1998                 Pitch p = *unsmob_pitch ($1);
1999                 p = p.transposed (Pitch ($2,0,0));
2000                 $$ = p.smobbed_copy ();
2001         }
2002         | NOTENAME_PITCH sub_quotes      {
2003                 Pitch p =* unsmob_pitch ($1);
2004                 p = p.transposed (Pitch (-$2,0,0));
2005                 $$ = p.smobbed_copy ();
2006         }
2007         ;
2008
2009 /*
2010 ugh. duplication
2011 */
2012
2013 steno_tonic_pitch:
2014         TONICNAME_PITCH {
2015                 $$ = $1;
2016         }
2017         | TONICNAME_PITCH sup_quotes    {
2018                 Pitch p = *unsmob_pitch ($1);
2019                 p = p.transposed (Pitch ($2,0,0));
2020                 $$ = p.smobbed_copy ();
2021         }
2022         | TONICNAME_PITCH sub_quotes     {
2023                 Pitch p =* unsmob_pitch ($1);
2024
2025                 p = p.transposed (Pitch (-$2,0,0));
2026                 $$ = p.smobbed_copy ();
2027         }
2028         ;
2029
2030 pitch:
2031         steno_pitch {
2032                 $$ = $1;
2033         }
2034         ;
2035
2036 pitch_also_in_chords:
2037         pitch
2038         | steno_tonic_pitch
2039         ;
2040
2041 gen_text_def:
2042         full_markup {
2043                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
2044                 t->set_property ("text", $1);
2045                 t->set_spot (@$);
2046                 $$ = t;
2047         }
2048         | string {
2049                 Music *t = MY_MAKE_MUSIC ("TextScriptEvent");
2050                 t->set_property ("text",
2051                         make_simple_markup ($1));
2052                 t->set_spot (@$);
2053                 $$ = t;
2054
2055         }
2056         | DIGIT {
2057                 Music *t = MY_MAKE_MUSIC ("FingerEvent");
2058                 t->set_property ("digit", scm_from_int ($1));
2059                 t->set_spot (@$);
2060                 $$ = t;
2061         }
2062         ;
2063
2064 script_abbreviation:
2065         '^'             {
2066                 $$ = scm_makfrom0str ("Hat");
2067         }
2068         | '+'           {
2069                 $$ = scm_makfrom0str ("Plus");
2070         }
2071         | '-'           {
2072                 $$ = scm_makfrom0str ("Dash");
2073         }
2074         | '|'           {
2075                 $$ = scm_makfrom0str ("Bar");
2076         }
2077         | '>'           {
2078                 $$ = scm_makfrom0str ("Larger");
2079         }
2080         | '.'           {
2081                 $$ = scm_makfrom0str ("Dot");
2082         }
2083         | '_' {
2084                 $$ = scm_makfrom0str ("Underscore");
2085         }
2086         ;
2087
2088 script_dir:
2089         '_'     { $$ = DOWN; }
2090         | '^'   { $$ = UP; }
2091         | '-'   { $$ = CENTER; }
2092         ;
2093
2094
2095 absolute_pitch:
2096         steno_pitch     {
2097                 $$ = $1;
2098         }
2099         ;
2100
2101 duration_length:
2102         multiplied_duration {
2103                 $$ = $1;
2104         }
2105         ;
2106
2107 optional_notemode_duration:
2108         {
2109                 Duration dd = THIS->default_duration_;
2110                 $$ = dd.smobbed_copy ();
2111         }
2112         | multiplied_duration   {
2113                 $$ = $1;
2114                 THIS->default_duration_ = *unsmob_duration ($$);
2115         }
2116         ;
2117
2118 steno_duration:
2119         bare_unsigned dots              {
2120                 int len = 0;
2121                 if (!is_duration ($1))
2122                         THIS->parser_error (@1, _f ("not a duration: %d", $1));
2123                 else
2124                         len = intlog2 ($1);
2125
2126                 $$ = Duration (len, $2).smobbed_copy ();
2127         }
2128         | DURATION_IDENTIFIER dots      {
2129                 Duration *d = unsmob_duration ($1);
2130                 Duration k (d->duration_log (), d->dot_count () + $2);
2131                 *d = k;
2132                 $$ = $1;
2133         }
2134         ;
2135
2136 multiplied_duration:
2137         steno_duration {
2138                 $$ = $1;
2139         }
2140         | multiplied_duration '*' bare_unsigned {
2141                 $$ = unsmob_duration ($$)->compressed ( $3) .smobbed_copy ();
2142         }
2143         | multiplied_duration '*' FRACTION {
2144                 Rational  m (scm_to_int (scm_car ($3)), scm_to_int (scm_cdr ($3)));
2145
2146                 $$ = unsmob_duration ($$)->compressed (m).smobbed_copy ();
2147         }
2148         ;
2149
2150 fraction:
2151         FRACTION { $$ = $1; }
2152         | UNSIGNED '/' UNSIGNED {
2153                 $$ = scm_cons (scm_from_int ($1), scm_from_int ($3));
2154         }
2155         ;
2156
2157 dots:
2158         /* empty */     {
2159                 $$ = 0;
2160         }
2161         | dots '.' {
2162                 $$ ++;
2163         }
2164         ;
2165
2166 tremolo_type:
2167         ':'     {
2168                 $$ = 0;
2169         }
2170         | ':' bare_unsigned {
2171                 if (!is_duration ($2))
2172                         THIS->parser_error (@2, _f ("not a duration: %d", $2));
2173                 $$ = $2;
2174         }
2175         ;
2176
2177 bass_number:
2178         DIGIT   {
2179                 $$ = scm_from_int ($1);
2180         }
2181         | UNSIGNED {
2182                 $$ = scm_from_int ($1);
2183         }
2184         | STRING { $$ = $1; }
2185         | full_markup { $$ = $1; }
2186         ;
2187
2188 figured_bass_alteration:
2189         '-'     { $$ = -2; }
2190         | '+'   { $$ = 2; }
2191         | '!'   { $$ = 0; }
2192         ;
2193
2194 bass_figure:
2195         FIGURE_SPACE {
2196                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2197                 $$ = bfr->self_scm ();
2198                 bfr->unprotect ();
2199         }
2200         | bass_number  {
2201                 Music *bfr = MY_MAKE_MUSIC ("BassFigureEvent");
2202                 $$ = bfr->self_scm ();
2203
2204                 if (scm_is_number ($1))
2205                         bfr->set_property ("figure", $1);
2206                 else if (Text_interface::is_markup ($1))
2207                         bfr->set_property ("text", $1);
2208
2209                 bfr->unprotect ();
2210         }
2211         | bass_figure ']' {
2212                 $$ = $1;
2213                 unsmob_music ($1)->set_property ("bracket-stop", SCM_BOOL_T);
2214         }
2215         | bass_figure figured_bass_alteration {
2216                 Music *m = unsmob_music ($1);
2217                 if ($2) {
2218                         SCM salter = m->get_property ("alteration");
2219                         int alter = scm_is_number (salter) ? scm_to_int (salter) : 0;
2220                         m->set_property ("alteration",
2221                                 scm_from_int (alter + $2));
2222                 } else {
2223                         m->set_property ("alteration", scm_from_int (0));
2224                 }
2225         }
2226         | bass_figure figured_bass_modification  {
2227                 Music *m = unsmob_music ($1);
2228                 if ($2 == ly_symbol2scm ("plus"))
2229                         {
2230                         m->set_property ("augmented", SCM_BOOL_T);
2231                         }
2232                 else if ($2 == ly_symbol2scm ("slash"))
2233                         {
2234                         m->set_property ("diminished", SCM_BOOL_T);
2235                         }
2236                 else if ($2 == ly_symbol2scm ("exclamation"))
2237                         {
2238                         m->set_property ("no-continuation", SCM_BOOL_T);
2239                         }
2240         }
2241         ;
2242
2243
2244 figured_bass_modification:
2245         E_PLUS          {
2246                 $$ = ly_symbol2scm ("plus");
2247         }
2248         | E_EXCLAMATION {
2249                 $$ = ly_symbol2scm ("exclamation");
2250         }
2251         | '/'           {
2252                 $$ = ly_symbol2scm ("slash");
2253         }
2254         ;
2255
2256 br_bass_figure:
2257         bass_figure {
2258                 $$ = $1;
2259         }
2260         | '[' bass_figure {
2261                 $$ = $2;
2262                 unsmob_music ($$)->set_property ("bracket-start", SCM_BOOL_T);
2263         }
2264         ;
2265
2266 figure_list:
2267         /**/            {
2268                 $$ = SCM_EOL;
2269         }
2270         | figure_list br_bass_figure {
2271                 $$ = scm_cons ($2, $1);
2272         }
2273         ;
2274
2275 figure_spec:
2276         FIGURE_OPEN figure_list FIGURE_CLOSE {
2277                 Music *m = MY_MAKE_MUSIC ("EventChord");
2278                 $2 = scm_reverse_x ($2, SCM_EOL);
2279                 m->set_property ("elements", $2);
2280                 $$ = m->self_scm ();
2281         }
2282         ;
2283
2284
2285 optional_rest:
2286         /**/   { $$ = 0; }
2287         | REST { $$ = 1; }
2288         ;
2289
2290 simple_element:
2291         pitch exclamations questions octave_check optional_notemode_duration optional_rest {
2292                 if (!THIS->lexer_->is_note_state ())
2293                         THIS->parser_error (@1, _ ("have to be in Note mode for notes"));
2294
2295                 Music *n = 0;
2296                 if ($6)
2297                         n = MY_MAKE_MUSIC ("RestEvent");
2298                 else
2299                         n = MY_MAKE_MUSIC ("NoteEvent");
2300
2301                 n->set_property ("pitch", $1);
2302                 n->set_property ("duration", $5);
2303
2304                 if (scm_is_number ($4))
2305                 {
2306                         int q = scm_to_int ($4);
2307                         n->set_property ("absolute-octave", scm_from_int (q-1));
2308                 }
2309
2310                 if ($3 % 2)
2311                         n->set_property ("cautionary", SCM_BOOL_T);
2312                 if ($2 % 2 || $3 % 2)
2313                         n->set_property ("force-accidental", SCM_BOOL_T);
2314
2315                 Music *v = MY_MAKE_MUSIC ("EventChord");
2316                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2317                 n->unprotect ();
2318
2319                 v->set_spot (@$);
2320                 n->set_spot (@$);
2321                 $$ = v;
2322         }
2323         | DRUM_PITCH optional_notemode_duration {
2324                 Music *n = MY_MAKE_MUSIC ("NoteEvent");
2325                 n->set_property ("duration", $2);
2326                 n->set_property ("drum-type", $1);
2327
2328                 Music *v = MY_MAKE_MUSIC ("EventChord");
2329                 v->set_property ("elements", scm_list_1 (n->self_scm ()));
2330                 n->unprotect ();
2331                 v->set_spot (@$);
2332                 n->set_spot (@$);
2333                 $$ = v;
2334
2335         }
2336         | figure_spec optional_notemode_duration {
2337                 Music *m = unsmob_music ($1);
2338                 m->set_spot (@$);
2339                 for (SCM s = m->get_property ("elements"); scm_is_pair (s); s = scm_cdr (s))
2340                 {
2341                         unsmob_music (scm_car (s))->set_property ("duration", $2);
2342                 }
2343                 $$ = m;
2344         }
2345         | RESTNAME optional_notemode_duration           {
2346                 Music *ev = 0;
2347                 if (ly_scm2string ($1) == "s") {
2348                         /* Space */
2349                         ev = MY_MAKE_MUSIC ("SkipEvent");
2350                   }
2351                 else {
2352                         ev = MY_MAKE_MUSIC ("RestEvent");
2353
2354                     }
2355                 ev->set_property ("duration", $2);
2356                 ev->set_spot (@$);
2357                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2358                 velt->set_property ("elements", scm_list_1 (ev->self_scm ()));
2359                 velt->set_spot (@$);
2360
2361                 ev->unprotect();
2362
2363                 $$ = velt;
2364         }
2365         | MULTI_MEASURE_REST optional_notemode_duration         {
2366                 SCM proc = ly_lily_module_constant ("make-multi-measure-rest");
2367                 SCM mus = scm_call_2 (proc, $2, make_input (@$));
2368                 $$ = unsmob_music (mus);
2369                 $$->protect ();
2370         }
2371
2372         | lyric_element optional_notemode_duration      {
2373                 if (!THIS->lexer_->is_lyric_state ())
2374                         THIS->parser_error (@1, _ ("have to be in Lyric mode for lyrics"));
2375
2376                 Music *levent = MY_MAKE_MUSIC ("LyricEvent");
2377                 levent->set_property ("text", $1);
2378                 levent->set_property ("duration",$2);
2379                 levent->set_spot (@$);
2380                 Music *velt = MY_MAKE_MUSIC ("EventChord");
2381                 velt->set_property ("elements", scm_list_1 (levent->self_scm ()));
2382
2383                 $$= velt;
2384         }
2385         | new_chord {
2386                 if (!THIS->lexer_->is_chord_state ())
2387                         THIS->parser_error (@1, _ ("have to be in Chord mode for chords"));
2388                 $$ = unsmob_music ($1);
2389         }
2390         ;
2391
2392 lyric_element:
2393         lyric_markup {
2394                 $$ = $1;
2395         }
2396         | LYRICS_STRING {
2397                 $$ = $1;
2398         }
2399         ;
2400
2401 new_chord:
2402         steno_tonic_pitch optional_notemode_duration   {
2403                 $$ = make_chord ($1, $2, SCM_EOL);
2404         }
2405         | steno_tonic_pitch optional_notemode_duration chord_separator chord_items {
2406                 SCM its = scm_reverse_x ($4, SCM_EOL);
2407                 $$ = make_chord ($1, $2, scm_cons ($3, its));
2408         }
2409         ;
2410
2411 chord_items:
2412         /**/ {
2413                 $$ = SCM_EOL;
2414         }
2415         | chord_items chord_item {
2416                 $$ = scm_cons ($2, $$);
2417         }
2418         ;
2419
2420 chord_separator:
2421         CHORD_COLON {
2422                 $$ = ly_symbol2scm ("chord-colon");
2423         }
2424         | CHORD_CARET {
2425                 $$ = ly_symbol2scm ("chord-caret");
2426         }
2427         | CHORD_SLASH steno_tonic_pitch {
2428                 $$ = scm_list_2 (ly_symbol2scm ("chord-slash"), $2);
2429         }
2430         | CHORD_BASS steno_tonic_pitch {
2431                 $$ = scm_list_2 (ly_symbol2scm ("chord-bass"), $2);
2432         }
2433         ;
2434
2435 chord_item:
2436         chord_separator {
2437                 $$ = $1;
2438         }
2439         | step_numbers {
2440                 $$ = scm_reverse_x ($1, SCM_EOL);
2441         }
2442         | CHORD_MODIFIER  {
2443                 $$ = $1;
2444         }
2445         ;
2446
2447 step_numbers:
2448         step_number { $$ = scm_cons ($1, SCM_EOL); }
2449         | step_numbers '.' step_number {
2450                 $$ = scm_cons ($3, $$);
2451         }
2452         ;
2453
2454 step_number:
2455         bare_unsigned {
2456                 $$ = make_chord_step ($1, 0);
2457         }
2458         | bare_unsigned '+' {
2459                 $$ = make_chord_step ($1, SHARP);
2460         }
2461         | bare_unsigned CHORD_MINUS {
2462                 $$ = make_chord_step ($1, FLAT);
2463         }
2464         ;
2465
2466 /*
2467         UTILITIES
2468
2469 TODO: should deprecate in favor of Scheme?
2470
2471  */
2472 number_expression:
2473         number_expression '+' number_term {
2474                 $$ = scm_sum ($1, $3);
2475         }
2476         | number_expression '-' number_term {
2477                 $$ = scm_difference ($1, $3);
2478         }
2479         | number_term
2480         ;
2481
2482 number_term:
2483         number_factor {
2484                 $$ = $1;
2485         }
2486         | number_factor '*' number_factor {
2487                 $$ = scm_product ($1, $3);
2488         }
2489         | number_factor '/' number_factor {
2490                 $$ = scm_divide ($1, $3);
2491         }
2492         ;
2493
2494 number_factor:
2495         '-'  number_factor { /* %prec UNARY_MINUS */
2496                 $$ = scm_difference ($2, SCM_UNDEFINED);
2497         }
2498         | bare_number
2499         ;
2500
2501
2502 bare_number:
2503         UNSIGNED        {
2504                 $$ = scm_from_int ($1);
2505         }
2506         | REAL          {
2507                 $$ = $1;
2508         }
2509         | NUMBER_IDENTIFIER             {
2510                 $$ = $1;
2511         }
2512         | REAL NUMBER_IDENTIFIER        {
2513                 $$ = scm_from_double (scm_to_double ($1) *scm_to_double ($2));
2514         }
2515         | UNSIGNED NUMBER_IDENTIFIER    {
2516                 $$ = scm_from_double ($1 *scm_to_double ($2));
2517         }
2518         ;
2519
2520
2521 bare_unsigned:
2522         UNSIGNED {
2523                         $$ = $1;
2524         }
2525         | DIGIT {
2526                 $$ = $1;
2527         }
2528         ;
2529
2530 exclamations:
2531                 { $$ = 0; }
2532         | exclamations '!'      { $$ ++; }
2533         ;
2534
2535 questions:
2536                 { $$ = 0; }
2537         | questions '?' { $$ ++; }
2538         ;
2539
2540 /*
2541 This should be done more dynamically if possible.
2542 */
2543
2544 lyric_markup:
2545         LYRIC_MARKUP_IDENTIFIER {
2546                 $$ = $1;
2547         }
2548         | LYRIC_MARKUP
2549                 { THIS->lexer_->push_markup_state (); }
2550         markup_top {
2551                 $$ = $3;
2552                 THIS->lexer_->pop_state ();
2553         }
2554         ;
2555
2556 full_markup:
2557         MARKUP_IDENTIFIER {
2558                 $$ = $1;
2559         }
2560         | MARKUP
2561                 { THIS->lexer_->push_markup_state (); }
2562         markup_top {
2563                 $$ = $3;
2564                 THIS->lexer_->pop_state ();
2565         }
2566         ;
2567
2568 markup_top:
2569         markup_list {
2570                 $$ = scm_list_2 (ly_lily_module_constant ("line-markup"),  $1);
2571         }
2572         | markup_head_1_list simple_markup      {
2573                 $$ = scm_car (scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, scm_list_1 ($2)));
2574         }
2575         | simple_markup {
2576                 $$ = $1;
2577         }
2578         ;
2579
2580 markup_list:
2581         markup_composed_list {
2582                 $$ = $1;
2583         }
2584         | markup_braced_list {
2585                 $$ = $1;
2586         }
2587         ;
2588
2589 markup_composed_list:
2590         markup_head_1_list markup_braced_list {
2591                 $$ = scm_call_2 (ly_lily_module_constant ("map-markup-command-list"), $1, $2);
2592
2593         }
2594         ;
2595
2596 markup_braced_list:
2597         '{' markup_braced_list_body '}' {
2598                 $$ = scm_reverse_x ($2, SCM_EOL);
2599         }
2600         ;
2601
2602 markup_braced_list_body:
2603         /* empty */     {  $$ = SCM_EOL; }
2604         | markup_braced_list_body markup {
2605                 $$ = scm_cons ($2, $1);
2606         }
2607         | markup_braced_list_body markup_list {
2608                 $$ = scm_append_x (scm_list_2 (scm_reverse_x ($2, SCM_EOL), $1));
2609         }
2610         ;
2611
2612 markup_head_1_item:
2613         MARKUP_HEAD_MARKUP0     {
2614                 $$ = scm_list_1 ($1);
2615         }
2616         | MARKUP_HEAD_SCM0_MARKUP1 embedded_scm {
2617                 $$ = scm_list_2 ($1, $2);
2618         }
2619         | MARKUP_HEAD_SCM0_SCM1_MARKUP2 embedded_scm embedded_scm       {
2620                 $$ = scm_list_3 ($1, $2, $3);
2621         }
2622         ;
2623
2624 markup_head_1_list:
2625         markup_head_1_item      {
2626                 $$ = scm_list_1 ($1);
2627         }
2628         | markup_head_1_list markup_head_1_item {
2629                 $$ = scm_cons ($2, $1);
2630         }
2631         ;
2632
2633 simple_markup:
2634         STRING {
2635                 $$ = make_simple_markup ($1);
2636         }
2637         | MARKUP_IDENTIFIER {
2638                 $$ = $1;
2639         }
2640         | LYRIC_MARKUP_IDENTIFIER {
2641                 $$ = $1;
2642         }
2643         | STRING_IDENTIFIER {
2644                 $$ = $1;
2645         }
2646         | SCORE {
2647                 SCM nn = THIS->lexer_->lookup_identifier ("pitchnames");
2648                 THIS->lexer_->push_note_state (alist_to_hashq (nn));
2649         } '{' score_body '}' {
2650                 Score * sc = $4;
2651                 $$ = scm_list_2 (ly_lily_module_constant ("score-markup"), sc->self_scm ());
2652                 sc->unprotect ();
2653                 THIS->lexer_->pop_state ();
2654         }
2655         | MARKUP_HEAD_SCM0 embedded_scm {
2656                 $$ = scm_list_2 ($1, $2);
2657         }
2658         | MARKUP_HEAD_SCM0_SCM1_SCM2 embedded_scm embedded_scm embedded_scm {
2659                 $$ = scm_list_4 ($1, $2, $3, $4);
2660         }
2661         | MARKUP_HEAD_SCM0_SCM1 embedded_scm embedded_scm {
2662                 $$ = scm_list_3 ($1, $2, $3);
2663         }
2664         | MARKUP_HEAD_EMPTY {
2665                 $$ = scm_list_1 ($1);
2666         }
2667         | MARKUP_HEAD_LIST0 markup_list {
2668                 $$ = scm_list_2 ($1,$2);
2669         }
2670         | MARKUP_HEAD_MARKUP0_MARKUP1 markup markup {
2671                 $$ = scm_list_3 ($1, $2, $3);
2672         }
2673         ;
2674
2675 markup:
2676         markup_head_1_list simple_markup        {
2677                 SCM mapper = ly_lily_module_constant ("map-markup-command-list");
2678                 $$ = scm_car (scm_call_2 (mapper, $1, scm_list_1 ($2)));
2679         }
2680         | simple_markup {
2681                 $$ = $1;
2682         }
2683         ;
2684
2685 %%
2686
2687 void
2688 Lily_parser::set_yydebug (bool )
2689 {
2690 #if 0
2691         yydebug = 1;
2692 #endif
2693 }
2694
2695 void
2696 Lily_parser::do_yyparse ()
2697 {
2698         yyparse ((void*)this);
2699 }
2700
2701
2702
2703
2704
2705 /*
2706
2707 It is a little strange to have this function in this file, but
2708 otherwise, we have to import music classes into the lexer.
2709
2710 */
2711 int
2712 Lily_lexer::try_special_identifiers (SCM *destination, SCM sid)
2713 {
2714         if (scm_is_string (sid)) {
2715                 *destination = sid;
2716                 return STRING_IDENTIFIER;
2717         } else if (scm_is_number (sid)) {
2718                 *destination = sid;
2719                 return NUMBER_IDENTIFIER;
2720         } else if (unsmob_context_def (sid)) {
2721                 *destination = unsmob_context_def (sid)->clone_scm ();
2722                 return CONTEXT_DEF_IDENTIFIER;
2723         } else if (unsmob_score (sid)) {
2724                 Score *score = new Score (*unsmob_score (sid));
2725                 *destination = score->self_scm ();
2726                 return SCORE_IDENTIFIER;
2727         } else if (Music *mus = unsmob_music (sid)) {
2728                 mus = mus->clone ();
2729                 *destination = mus->self_scm ();
2730                 unsmob_music (*destination)->
2731                         set_property ("origin", make_input (last_input_));
2732
2733                 bool is_event = scm_memq (ly_symbol2scm ("event"), mus->get_property ("types"))
2734                         != SCM_BOOL_F;
2735
2736                 return is_event ? EVENT_IDENTIFIER : MUSIC_IDENTIFIER;
2737         } else if (unsmob_duration (sid)) {
2738                 *destination = unsmob_duration (sid)->smobbed_copy ();
2739                 return DURATION_IDENTIFIER;
2740         } else if (unsmob_output_def (sid)) {
2741                 Output_def *p = unsmob_output_def (sid);
2742                 p = p->clone ();
2743
2744                 *destination = p->self_scm ();
2745                 return OUTPUT_DEF_IDENTIFIER;
2746         } else if (Text_interface::is_markup (sid)) {
2747                 *destination = sid;
2748                 if (is_lyric_state ())
2749                         return LYRIC_MARKUP_IDENTIFIER;
2750                 return MARKUP_IDENTIFIER;
2751         }
2752
2753         return -1;
2754 }
2755
2756 Music *
2757 property_op_to_music (SCM op)
2758 {
2759         Music *m = 0;
2760         SCM tag = scm_car (op);
2761         SCM symbol = scm_cadr (op);
2762         SCM args = scm_cddr (op);
2763         SCM grob_val = SCM_UNDEFINED;
2764         SCM grob_path = SCM_UNDEFINED;
2765         SCM val = SCM_UNDEFINED;
2766
2767         if (tag == ly_symbol2scm ("assign"))
2768                 {
2769                 m = MY_MAKE_MUSIC ("PropertySet");
2770                 val = scm_car (args);
2771                 }
2772         else if (tag == ly_symbol2scm ("unset"))
2773                 m = MY_MAKE_MUSIC ("PropertyUnset");
2774         else if (tag == ly_symbol2scm ("push"))
2775                 {
2776                 m = MY_MAKE_MUSIC ("OverrideProperty");
2777                 grob_val = scm_car (args);
2778                 grob_path = scm_cdr (args);
2779                 m->set_property ("pop-first", SCM_BOOL_T);
2780                 }
2781         else if (tag == ly_symbol2scm ("pop")) {
2782                 m = MY_MAKE_MUSIC ("RevertProperty");
2783                 grob_path = args;
2784                 }
2785
2786         m->set_property ("symbol", symbol);
2787
2788         if (val != SCM_UNDEFINED)
2789                 m->set_property ("value", val);
2790         if (grob_val != SCM_UNDEFINED)
2791                 m->set_property ("grob-value", grob_val);
2792         if (grob_path != SCM_UNDEFINED)
2793                 m->set_property ("grob-property-path", grob_path);
2794
2795         return m;
2796 }
2797
2798 Music*
2799 context_spec_music (SCM type, SCM id, Music *m, SCM ops)
2800 {
2801         Music *csm = MY_MAKE_MUSIC ("ContextSpeccedMusic");
2802
2803         csm->set_property ("element", m->self_scm ());
2804         m->unprotect ();
2805
2806         csm->set_property ("context-type",
2807                 scm_is_symbol (type) ? type : scm_string_to_symbol (type));
2808         csm->set_property ("property-operations", ops);
2809
2810         if (scm_is_string (id))
2811                 csm->set_property ("context-id", id);
2812         return csm;
2813 }
2814
2815 SCM
2816 get_next_unique_context_id ()
2817 {
2818         return scm_makfrom0str ("$uniqueContextId");
2819 }
2820
2821
2822 SCM
2823 get_next_unique_lyrics_context_id ()
2824 {
2825         static int new_context_count;
2826         char s[128];
2827         snprintf (s, 1024, "uniqueContext%d", new_context_count++);
2828         return scm_makfrom0str (s);
2829 }